board/sc520_spunk/u-boot.lds

   1
   2 /*
   3  * (C) Copyright 2002
   4  * Daniel Engström, Omicron Ceti AB, [email protected].
   5  *
   6  * See file CREDITS for list of people who contributed to this
   7  * project.
   8  *
   9  * This program is free software; you can redistribute it and/or
  10  * modify it under the terms of the GNU General Public License as
  11  * published by the Free Software Foundation; either version 2 of
  12  * the License, or (at your option) any later version.
  13  *
  14  * This program is distributed in the hope that it will be useful,
  15  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  16  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17  * GNU General Public License for more details.
  18  *
  19  * You should have received a copy of the GNU General Public License
  20  * along with this program; if not, write to the Free Software
  21  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  22  * MA 02111-1307 USA
  23  */
  24
  25 OUTPUT_FORMAT("elf32-i386", "elf32-i386", "elf32-i386")
  26 OUTPUT_ARCH(i386)
  27 ENTRY(_start)
  28
  29 SECTIONS
  30 {
  31         . = 0x387c0000;                     /* Where bootcode in the flash is mapped */
  32         .text  : { *(.text); }
  33
  34         . = ALIGN(4);
  35         .rodata : { *(.rodata) }
  36
  37         . = 0x400000;                       /* Ram data segment to use */
  38         _i386boot_romdata_dest = ABSOLUTE(.);
  39         .data : AT ( LOADADDR(.rodata) + SIZEOF(.rodata) ) { *(.data) }
  40         _i386boot_romdata_start = LOADADDR(.data);
  41
  42         . = ALIGN(4);
  43         .got : AT ( LOADADDR(.data) + SIZEOF(.data) ) { *(.got) }
  44         _i386boot_romdata_size = SIZEOF(.data) + SIZEOF(.got);
  45
  46
  47         . = ALIGN(4);
  48         _i386boot_bss_start = ABSOLUTE(.);
  49         .bss : { *(.bss) }
  50         _i386boot_bss_size = SIZEOF(.bss);
  51
  52
  53   __u_boot_cmd_start = .;
  54   .u_boot_cmd : { *(.u_boot_cmd) }
  55   __u_boot_cmd_end = .;
  56
  57
  58         /* 16bit realmode trampoline code */
  59         .realmode 0x7c0 : AT ( LOADADDR(.got) + SIZEOF(.got) ) { *(.realmode) }
  60
  61         _i386boot_realmode = LOADADDR(.realmode);
  62         _i386boot_realmode_size = SIZEOF(.realmode);
  63
  64         /* 16bit BIOS emulation code (just enough to boot Linux) */
  65         .bios 0 : AT ( LOADADDR(.realmode) + SIZEOF(.realmode) ) { *(.bios) }
  66
  67         _i386boot_bios = LOADADDR(.bios);
  68         _i386boot_bios_size = SIZEOF(.bios);
  69
  70
  71         /* The load addresses below assumes that the flash
  72          * will be mapped so that 0x387f0000 == 0xffff0000
  73          * at reset time
  74          *
  75          * The fe00 and ff00 offsets of the start32 and start16
  76          * segments are arbitrary, the just have to be mapped
  77          * at reset and the code have to fit.
  78          * The fff0 offset of reset is important, however.
  79          */
  80
  81
  82         . = 0xfffffe00;
  83         .start32 : AT (0x387ffe00) { *(.start32); }
  84
  85         . = 0xff00;
  86         .start16 : AT (0x387fff00) { *(.start16); }
  87
  88         . = 0xfff0;
  89         .reset : AT (0x387ffff0) { *(.reset); }
  90         _i386boot_end = (LOADADDR(.reset) + SIZEOF(.reset) );
  91 }