arch/arm/lib/crt0_64.S

   1 /*
   2  * crt0 - C-runtime startup Code for AArch64 U-Boot
   3  *
   4  * (C) Copyright 2013
   5  * David Feng <[email protected]>
   6  *
   7  * (C) Copyright 2012
   8  * Albert ARIBAUD <[email protected]>
   9  *
  10  * SPDX-License-Identifier:     GPL-2.0+
  11  */
  12
  13 #include <config.h>
  14 #include <asm-offsets.h>
  15 #include <asm/macro.h>
  16 #include <linux/linkage.h>
  17
  18 /*
  19  * This file handles the target-independent stages of the U-Boot
  20  * start-up where a C runtime environment is needed. Its entry point
  21  * is _main and is branched into from the target's start.S file.
  22  *
  23  * _main execution sequence is:
  24  *
  25  * 1. Set up initial environment for calling board_init_f().
  26  *    This environment only provides a stack and a place to store
  27  *    the GD ('global data') structure, both located in some readily
  28  *    available RAM (SRAM, locked cache...). In this context, VARIABLE
  29  *    global data, initialized or not (BSS), are UNAVAILABLE; only
  30  *    CONSTANT initialized data are available.
  31  *
  32  * 2. Call board_init_f(). This function prepares the hardware for
  33  *    execution from system RAM (DRAM, DDR...) As system RAM may not
  34  *    be available yet, , board_init_f() must use the current GD to
  35  *    store any data which must be passed on to later stages. These
  36  *    data include the relocation destination, the future stack, and
  37  *    the future GD location.
  38  *
  39  * (the following applies only to non-SPL builds)
  40  *
  41  * 3. Set up intermediate environment where the stack and GD are the
  42  *    ones allocated by board_init_f() in system RAM, but BSS and
  43  *    initialized non-const data are still not available.
  44  *
  45  * 4. Call relocate_code(). This function relocates U-Boot from its
  46  *    current location into the relocation destination computed by
  47  *    board_init_f().
  48  *
  49  * 5. Set up final environment for calling board_init_r(). This
  50  *    environment has BSS (initialized to 0), initialized non-const
  51  *    data (initialized to their intended value), and stack in system
  52  *    RAM. GD has retained values set by board_init_f(). Some CPUs
  53  *    have some work left to do at this point regarding memory, so
  54  *    call c_runtime_cpu_setup.
  55  *
  56  * 6. Branch to board_init_r().
  57  */
  58
  59 ENTRY(_main)
  60
  61 /*
  62  * Set up initial C runtime environment and call board_init_f(0).
  63  */
  64         ldr     x0, =(CONFIG_SYS_INIT_SP_ADDR)
  65         sub     x0, x0, #GD_SIZE        /* allocate one GD above SP */
  66         bic     sp, x0, #0xf    /* 16-byte alignment for ABI compliance */
  67         mov     x18, sp                 /* GD is above SP */
  68         mov     x0, #0
  69         bl      board_init_f
  70
  71 /*
  72  * Set up intermediate environment (new sp and gd) and call
  73  * relocate_code(addr_moni). Trick here is that we'll return
  74  * 'here' but relocated.
  75  */
  76         ldr     x0, [x18, #GD_START_ADDR_SP]    /* x0 <- gd->start_addr_sp */
  77         bic     sp, x0, #0xf    /* 16-byte alignment for ABI compliance */
  78         ldr     x18, [x18, #GD_BD]              /* x18 <- gd->bd */
  79         sub     x18, x18, #GD_SIZE              /* new GD is below bd */
  80
  81         adr     lr, relocation_return
  82         ldr     x9, [x18, #GD_RELOC_OFF]        /* x9 <- gd->reloc_off */
  83         add     lr, lr, x9      /* new return address after relocation */
  84         ldr     x0, [x18, #GD_RELOCADDR]        /* x0 <- gd->relocaddr */
  85         b       relocate_code
  86
  87 relocation_return:
  88
  89 /*
  90  * Set up final (full) environment
  91  */
  92         bl      c_runtime_cpu_setup             /* still call old routine */
  93
  94 /*
  95  * Clear BSS section
  96  */
  97         ldr     x0, =__bss_start                /* this is auto-relocated! */
  98         ldr     x1, =__bss_end                  /* this is auto-relocated! */
  99         mov     x2, #0
 100 clear_loop:
 101         str     x2, [x0]
 102         add     x0, x0, #8
 103         cmp     x0, x1
 104         b.lo    clear_loop
 105
 106         /* call board_init_r(gd_t *id, ulong dest_addr) */
 107         mov     x0, x18                         /* gd_t */
 108         ldr     x1, [x18, #GD_RELOCADDR]        /* dest_addr */
 109         b       board_init_r                    /* PC relative jump */
 110
 111         /* NOTREACHED - board_init_r() does not return */
 112
 113 ENDPROC(_main)