arch/arm/mach-at91/arm926ejs/u-boot-spl.lds

   1 /*
   2  * Copyright (C) 2015 Atmel Corporation
   3  *                    Bo Shen <[email protected]>
   4  *
   5  * SPDX-License-Identifier:     GPL-2.0+
   6  */
   7
   8 MEMORY { .sram : ORIGIN = CONFIG_SPL_TEXT_BASE, \
   9                 LENGTH = CONFIG_SPL_MAX_SIZE }
  10 MEMORY { .sdram : ORIGIN = CONFIG_SPL_BSS_START_ADDR, \
  11                 LENGTH = CONFIG_SPL_BSS_MAX_SIZE }
  12
  13 OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
  14 OUTPUT_ARCH(arm)
  15 ENTRY(_start)
  16 SECTIONS
  17 {
  18         .text      :
  19         {
  20                 __start = .;
  21                 *(.vectors)
  22                 arch/arm/cpu/arm926ejs/start.o  (.text*)
  23                 *(.text*)
  24         } >.sram
  25
  26         . = ALIGN(4);
  27         .rodata : { *(SORT_BY_ALIGNMENT(.rodata*)) } >.sram
  28
  29         . = ALIGN(4);
  30         .data : { *(SORT_BY_ALIGNMENT(.data*)) } >.sram
  31
  32         . = ALIGN(4);
  33         .u_boot_list : { KEEP(*(SORT(.u_boot_list*))) } > .sram
  34
  35         . = ALIGN(4);
  36         __image_copy_end = .;
  37
  38         .end :
  39         {
  40                 *(.__end)
  41         } >.sram
  42
  43         .bss :
  44         {
  45                 . = ALIGN(4);
  46                 __bss_start = .;
  47                 *(.bss*)
  48                 . = ALIGN(4);
  49                 __bss_end = .;
  50         } >.sdram
  51 }