arch/arm/cpu/u-boot.lds

   1 /*
   2  * Copyright (c) 2004-2008 Texas Instruments
   3  *
   4  * (C) Copyright 2002
   5  * Gary Jennejohn, DENX Software Engineering, <[email protected]>
   6  *
   7  * SPDX-License-Identifier:     GPL-2.0+
   8  */
   9
  10 OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
  11 OUTPUT_ARCH(arm)
  12 ENTRY(_start)
  13 SECTIONS
  14 {
  15         . = 0x00000000;
  16
  17         . = ALIGN(4);
  18         .text :
  19         {
  20                 *(.__image_copy_start)
  21                 *(.vectors)
  22                 CPUDIR/start.o (.text*)
  23                 *(.text*)
  24         }
  25
  26         . = ALIGN(4);
  27         .rodata : { *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*))) }
  28
  29         . = ALIGN(4);
  30         .data : {
  31                 *(.data*)
  32         }
  33
  34         . = ALIGN(4);
  35
  36         . = .;
  37
  38         . = ALIGN(4);
  39         .u_boot_list : {
  40                 KEEP(*(SORT(.u_boot_list*)));
  41         }
  42
  43         . = ALIGN(4);
  44
  45         .image_copy_end :
  46         {
  47                 *(.__image_copy_end)
  48         }
  49
  50         .rel_dyn_start :
  51         {
  52                 *(.__rel_dyn_start)
  53         }
  54
  55         .rel.dyn : {
  56                 *(.rel*)
  57         }
  58
  59         .rel_dyn_end :
  60         {
  61                 *(.__rel_dyn_end)
  62         }
  63
  64         .end :
  65         {
  66                 *(.__end)
  67         }
  68
  69         _image_binary_end = .;
  70
  71         /*
  72          * Deprecated: this MMU section is used by pxa at present but
  73          * should not be used by new boards/CPUs.
  74          */
  75         . = ALIGN(4096);
  76         .mmutable : {
  77                 *(.mmutable)
  78         }
  79
  80 /*
  81  * Compiler-generated __bss_start and __bss_end, see arch/arm/lib/bss.c
  82  * __bss_base and __bss_limit are for linker only (overlay ordering)
  83  */
  84
  85         .bss_start __rel_dyn_start (OVERLAY) : {
  86                 KEEP(*(.__bss_start));
  87                 __bss_base = .;
  88         }
  89
  90         .bss __bss_base (OVERLAY) : {
  91                 *(.bss*)
  92                  . = ALIGN(4);
  93                  __bss_limit = .;
  94         }
  95
  96         .bss_end __bss_limit (OVERLAY) : {
  97                 KEEP(*(.__bss_end));
  98         }
  99
 100         .dynsym _image_binary_end : { *(.dynsym) }
 101         .dynbss : { *(.dynbss) }
 102         .dynstr : { *(.dynstr*) }
 103         .dynamic : { *(.dynamic*) }
 104         .plt : { *(.plt*) }
 105         .interp : { *(.interp*) }
 106         .gnu.hash : { *(.gnu.hash) }
 107         .gnu : { *(.gnu*) }
 108         .ARM.exidx : { *(.ARM.exidx*) }
 109         .gnu.linkonce.armexidx : { *(.gnu.linkonce.armexidx.*) }
 110 }