cpu/arm720t/start.S

   1 /*
   2  *  armboot - Startup Code for ARM720 CPU-core
   3  *
   4  *  Copyright (c) 2001  Marius Gröger <[email protected]>
   5  *  Copyright (c) 2002  Alex Züpke <[email protected]>
   6  *
   7  * See file CREDITS for list of people who contributed to this
   8  * project.
   9  *
  10  * This program is free software; you can redistribute it and/or
  11  * modify it under the terms of the GNU General Public License as
  12  * published by the Free Software Foundation; either version 2 of
  13  * the License, or (at your option) any later version.
  14  *
  15  * This program is distributed in the hope that it will be useful,
  16  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  17  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18  * GNU General Public License for more details.
  19  *
  20  * You should have received a copy of the GNU General Public License
  21  * along with this program; if not, write to the Free Software
  22  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  23  * MA 02111-1307 USA
  24  */
  25
  26
  27 #include <config.h>
  28 #include <version.h>
  29 #include <asm/hardware.h>
  30
  31 /*
  32  *************************************************************************
  33  *
  34  * Jump vector table as in table 3.1 in [1]
  35  *
  36  *************************************************************************
  37  */
  38
  39
  40 .globl _start
  41 _start: b       reset
  42         ldr     pc, _undefined_instruction
  43         ldr     pc, _software_interrupt
  44         ldr     pc, _prefetch_abort
  45         ldr     pc, _data_abort
  46         ldr     pc, _not_used
  47         ldr     pc, _irq
  48         ldr     pc, _fiq
  49
  50 _undefined_instruction: .word undefined_instruction
  51 _software_interrupt:    .word software_interrupt
  52 _prefetch_abort:        .word prefetch_abort
  53 _data_abort:            .word data_abort
  54 _not_used:              .word not_used
  55 _irq:                   .word irq
  56 _fiq:                   .word fiq
  57
  58         .balignl 16,0xdeadbeef
  59
  60
  61 /*
  62  *************************************************************************
  63  *
  64  * Startup Code (reset vector)
  65  *
  66  * do important init only if we don't start from RAM!
  67  * relocate armboot to ram
  68  * setup stack
  69  * jump to second stage
  70  *
  71  *************************************************************************
  72  */
  73
  74 _TEXT_BASE:
  75         .word   TEXT_BASE
  76
  77 .globl _armboot_start
  78 _armboot_start:
  79         .word _start
  80
  81 /*
  82  * These are defined in the board-specific linker script.
  83  */
  84 .globl _bss_start
  85 _bss_start:
  86         .word __bss_start
  87
  88 .globl _bss_end
  89 _bss_end:
  90         .word _end
  91
  92 #ifdef CONFIG_USE_IRQ
  93 /* IRQ stack memory (calculated at run-time) */
  94 .globl IRQ_STACK_START
  95 IRQ_STACK_START:
  96         .word   0x0badc0de
  97
  98 /* IRQ stack memory (calculated at run-time) */
  99 .globl FIQ_STACK_START
 100 FIQ_STACK_START:
 101         .word 0x0badc0de
 102 #endif
 103
 104
 105 /*
 106  * the actual reset code
 107  */
 108
 109 reset:
 110         /*
 111          * set the cpu to SVC32 mode
 112          */
 113         mrs     r0,cpsr
 114         bic     r0,r0,#0x1f
 115         orr     r0,r0,#0x13
 116         msr     cpsr,r0
 117
 118         /*
 119          * we do sys-critical inits only at reboot,
 120          * not when booting from ram!
 121          */
 122 #ifdef CONFIG_INIT_CRITICAL
 123         bl      cpu_init_crit
 124 #endif
 125
 126 relocate:                               /* relocate U-Boot to RAM           */
 127         adr     r0, _start              /* r0 <- current position of code   */
 128         ldr     r1, _TEXT_BASE          /* test if we run from flash or RAM */
 129         cmp     r0, r1                  /* don't reloc during debug         */
 130         beq     stack_setup
 131
 132         ldr     r2, _armboot_start
 133         ldr     r3, _bss_start
 134         sub     r2, r3, r2              /* r2 <- size of armboot            */
 135         add     r2, r0, r2              /* r2 <- source end address         */
 136
 137 copy_loop:
 138         ldmia   r0!, {r3-r10}           /* copy from source address [r0]    */
 139         stmia   r1!, {r3-r10}           /* copy to   target address [r1]    */
 140         cmp     r0, r2                  /* until source end addreee [r2]    */
 141         ble     copy_loop
 142
 143         /* Set up the stack                                                 */
 144 stack_setup:
 145         ldr     r0, _TEXT_BASE          /* upper 128 KiB: relocated uboot   */
 146         sub     r0, r0, #CFG_MALLOC_LEN /* malloc area                      */
 147         sub     r0, r0, #CFG_GBL_DATA_SIZE /* bdinfo                        */
 148 #ifdef CONFIG_USE_IRQ
 149         sub     r0, r0, #(CONFIG_STACKSIZE_IRQ+CONFIG_STACKSIZE_FIQ)
 150 #endif
 151         sub     sp, r0, #12             /* leave 3 words for abort-stack    */
 152
 153 clear_bss:
 154         ldr     r0, _bss_start          /* find start of bss segment        */
 155         ldr     r1, _bss_end            /* stop here                        */
 156         mov     r2, #0x00000000         /* clear                            */
 157
 158 clbss_l:str     r2, [r0]                /* clear loop...                    */
 159         add     r0, r0, #4
 160         cmp     r0, r1
 161         bne     clbss_l
 162
 163         ldr     pc, _start_armboot
 164
 165 _start_armboot: .word start_armboot
 166
 167 /*
 168  *************************************************************************
 169  *
 170  * CPU_init_critical registers
 171  *
 172  * setup important registers
 173  * setup memory timing
 174  *
 175  *************************************************************************
 176  */
 177
 178 #if defined(CONFIG_IMPA7) || defined(CONFIG_EP7312)
 179
 180 /* Interupt-Controller base addresses */
 181 INTMR1:         .word   0x80000280 @ 32 bit size
 182 INTMR2:         .word   0x80001280 @ 16 bit size
 183 INTMR3:         .word   0x80002280 @  8 bit size
 184
 185 /* SYSCONs */
 186 SYSCON1:        .word   0x80000100
 187 SYSCON2:        .word   0x80001100
 188 SYSCON3:        .word   0x80002200
 189
 190 #define CLKCTL         0x6  /* mask */
 191 #define CLKCTL_18      0x0  /* 18.432 MHz */
 192 #define CLKCTL_36      0x2  /* 36.864 MHz */
 193 #define CLKCTL_49      0x4  /* 49.152 MHz */
 194 #define CLKCTL_73      0x6  /* 73.728 MHz */
 195
 196 #endif
 197
 198 cpu_init_crit:
 199 #if defined(CONFIG_IMPA7) || defined(CONFIG_EP7312)
 200
 201         /*
 202          * mask all IRQs by clearing all bits in the INTMRs
 203          */
 204         mov     r1, #0x00
 205         ldr     r0, INTMR1
 206         str     r1, [r0]
 207         ldr     r0, INTMR2
 208         str     r1, [r0]
 209         ldr     r0, INTMR3
 210         str     r1, [r0]
 211
 212         /*
 213          * flush v4 I/D caches
 214          */
 215         mov     r0, #0
 216         mcr     p15, 0, r0, c7, c7, 0   /* flush v3/v4 cache */
 217         mcr     p15, 0, r0, c8, c7, 0   /* flush v4 TLB */
 218
 219         /*
 220          * disable MMU stuff and caches
 221          */
 222         mrc     p15,0,r0,c1,c0
 223         bic     r0, r0, #0x00002300     @ clear bits 13, 9:8 (--V- --RS)
 224         bic     r0, r0, #0x0000008f     @ clear bits 7, 3:0 (B--- WCAM)
 225         orr     r0, r0, #0x00000002     @ set bit 2 (A) Align
 226         mcr     p15,0,r0,c1,c0
 227 #elif defined(CONFIG_NETARM)
 228         /*
 229          * prior to software reset : need to set pin PORTC4 to be *HRESET
 230          */
 231         ldr     r0, =NETARM_GEN_MODULE_BASE
 232         ldr     r1, =(NETARM_GEN_PORT_MODE(0x10) | \
 233                         NETARM_GEN_PORT_DIR(0x10))
 234         str     r1, [r0, #+NETARM_GEN_PORTC]
 235         /*
 236          * software reset : see HW Ref. Guide 8.2.4 : Software Service register
 237          *                  for an explanation of this process
 238          */
 239         ldr     r0, =NETARM_GEN_MODULE_BASE
 240         ldr     r1, =NETARM_GEN_SW_SVC_RESETA
 241         str     r1, [r0, #+NETARM_GEN_SOFTWARE_SERVICE]
 242         ldr     r1, =NETARM_GEN_SW_SVC_RESETB
 243         str     r1, [r0, #+NETARM_GEN_SOFTWARE_SERVICE]
 244         ldr     r1, =NETARM_GEN_SW_SVC_RESETA
 245         str     r1, [r0, #+NETARM_GEN_SOFTWARE_SERVICE]
 246         ldr     r1, =NETARM_GEN_SW_SVC_RESETB
 247         str     r1, [r0, #+NETARM_GEN_SOFTWARE_SERVICE]
 248         /*
 249          * setup PLL and System Config
 250          */
 251         ldr     r0, =NETARM_GEN_MODULE_BASE
 252
 253         ldr     r1, =(  NETARM_GEN_SYS_CFG_LENDIAN | \
 254                         NETARM_GEN_SYS_CFG_BUSFULL | \
 255                         NETARM_GEN_SYS_CFG_USER_EN | \
 256                         NETARM_GEN_SYS_CFG_ALIGN_ABORT | \
 257                         NETARM_GEN_SYS_CFG_BUSARB_INT | \
 258                         NETARM_GEN_SYS_CFG_BUSMON_EN )
 259
 260         str     r1, [r0, #+NETARM_GEN_SYSTEM_CONTROL]
 261
 262         ldr     r1, =(  NETARM_GEN_PLL_CTL_PLLCNT(NETARM_PLL_COUNT_VAL) | \
 263                         NETARM_GEN_PLL_CTL_POLTST_DEF | \
 264                         NETARM_GEN_PLL_CTL_INDIV(1) | \
 265                         NETARM_GEN_PLL_CTL_ICP_DEF | \
 266                         NETARM_GEN_PLL_CTL_OUTDIV(2) )
 267         str     r1, [r0, #+NETARM_GEN_PLL_CONTROL]
 268         /*
 269          * mask all IRQs by clearing all bits in the INTMRs
 270          */
 271         mov     r1, #0
 272         ldr     r0, =NETARM_GEN_MODULE_BASE
 273         str     r1, [r0, #+NETARM_GEN_INTR_ENABLE]
 274
 275 #elif defined(CONFIG_S3C4510B)
 276
 277         /*
 278          * Mask off all IRQ sources
 279          */
 280         ldr     r1, =REG_INTMASK
 281         ldr     r0, =0x3FFFFF
 282         str     r0, [r1]
 283
 284         /*
 285          * Disable Cache
 286          */
 287         ldr r0, =REG_SYSCFG
 288         ldr r1, =0x83ffffa0     /* cache-disabled  */
 289         str r1, [r0]
 290
 291 #else
 292 #error No cpu_init_crit() defined for current CPU type
 293 #endif
 294
 295 #ifdef CONFIG_ARM7_REVD
 296         /* set clock speed */
 297         /* !!! we run @ 36 MHz due to a hardware flaw in Rev. D processors */
 298         /* !!! not doing DRAM refresh properly! */
 299         ldr     r0, SYSCON3
 300         ldr     r1, [r0]
 301         bic     r1, r1, #CLKCTL
 302         orr     r1, r1, #CLKCTL_36
 303         str     r1, [r0]
 304 #endif
 305
 306         /*
 307          * before relocating, we have to setup RAM timing
 308          * because memory timing is board-dependent, you will
 309          * find a memsetup.S in your board directory.
 310          */
 311         mov     ip, lr
 312         bl      memsetup
 313         mov     lr, ip
 314
 315         mov     pc, lr
 316
 317
 318 /*
 319  *************************************************************************
 320  *
 321  * Interrupt handling
 322  *
 323  *************************************************************************
 324  */
 325
 326 @
 327 @ IRQ stack frame.
 328 @
 329 #define S_FRAME_SIZE    72
 330
 331 #define S_OLD_R0        68
 332 #define S_PSR           64
 333 #define S_PC            60
 334 #define S_LR            56
 335 #define S_SP            52
 336
 337 #define S_IP            48
 338 #define S_FP            44
 339 #define S_R10           40
 340 #define S_R9            36
 341 #define S_R8            32
 342 #define S_R7            28
 343 #define S_R6            24
 344 #define S_R5            20
 345 #define S_R4            16
 346 #define S_R3            12
 347 #define S_R2            8
 348 #define S_R1            4
 349 #define S_R0            0
 350
 351 #define MODE_SVC 0x13
 352 #define I_BIT    0x80
 353
 354 /*
 355  * use bad_save_user_regs for abort/prefetch/undef/swi ...
 356  * use irq_save_user_regs / irq_restore_user_regs for IRQ/FIQ handling
 357  */
 358
 359         .macro  bad_save_user_regs
 360         sub     sp, sp, #S_FRAME_SIZE
 361         stmia   sp, {r0 - r12}                  @ Calling r0-r12
 362         add     r8, sp, #S_PC
 363
 364         ldr     r2, _armboot_start
 365         sub     r2, r2, #(CONFIG_STACKSIZE+CFG_MALLOC_LEN)
 366         sub     r2, r2, #(CFG_GBL_DATA_SIZE+8)  @ set base 2 words into abort stack
 367         ldmia   r2, {r2 - r4}                   @ get pc, cpsr, old_r0
 368         add     r0, sp, #S_FRAME_SIZE           @ restore sp_SVC
 369
 370         add     r5, sp, #S_SP
 371         mov     r1, lr
 372         stmia   r5, {r0 - r4}                   @ save sp_SVC, lr_SVC, pc, cpsr, old_r
 373         mov     r0, sp
 374         .endm
 375
 376         .macro  irq_save_user_regs
 377         sub     sp, sp, #S_FRAME_SIZE
 378         stmia   sp, {r0 - r12}                  @ Calling r0-r12
 379         add     r8, sp, #S_PC
 380         stmdb   r8, {sp, lr}^                   @ Calling SP, LR
 381         str     lr, [r8, #0]                    @ Save calling PC
 382         mrs     r6, spsr
 383         str     r6, [r8, #4]                    @ Save CPSR
 384         str     r0, [r8, #8]                    @ Save OLD_R0
 385         mov     r0, sp
 386         .endm
 387
 388         .macro  irq_restore_user_regs
 389         ldmia   sp, {r0 - lr}^                  @ Calling r0 - lr
 390         mov     r0, r0
 391         ldr     lr, [sp, #S_PC]                 @ Get PC
 392         add     sp, sp, #S_FRAME_SIZE
 393         subs    pc, lr, #4                      @ return & move spsr_svc into cpsr
 394         .endm
 395
 396         .macro get_bad_stack
 397         ldr     r13, _armboot_start             @ setup our mode stack
 398         sub     r13, r13, #(CONFIG_STACKSIZE+CFG_MALLOC_LEN)
 399         sub     r13, r13, #(CFG_GBL_DATA_SIZE+8) @ reserved a couple spots in abort stack
 400
 401         str     lr, [r13]                       @ save caller lr / spsr
 402         mrs     lr, spsr
 403         str     lr, [r13, #4]
 404
 405         mov     r13, #MODE_SVC                  @ prepare SVC-Mode
 406         msr     spsr_c, r13
 407         mov     lr, pc
 408         movs    pc, lr
 409         .endm
 410
 411         .macro get_irq_stack                    @ setup IRQ stack
 412         ldr     sp, IRQ_STACK_START
 413         .endm
 414
 415         .macro get_fiq_stack                    @ setup FIQ stack
 416         ldr     sp, FIQ_STACK_START
 417         .endm
 418
 419 /*
 420  * exception handlers
 421  */
 422         .align  5
 423 undefined_instruction:
 424         get_bad_stack
 425         bad_save_user_regs
 426         bl      do_undefined_instruction
 427
 428         .align  5
 429 software_interrupt:
 430         get_bad_stack
 431         bad_save_user_regs
 432         bl      do_software_interrupt
 433
 434         .align  5
 435 prefetch_abort:
 436         get_bad_stack
 437         bad_save_user_regs
 438         bl      do_prefetch_abort
 439
 440         .align  5
 441 data_abort:
 442         get_bad_stack
 443         bad_save_user_regs
 444         bl      do_data_abort
 445
 446         .align  5
 447 not_used:
 448         get_bad_stack
 449         bad_save_user_regs
 450         bl      do_not_used
 451
 452 #ifdef CONFIG_USE_IRQ
 453
 454         .align  5
 455 irq:
 456         get_irq_stack
 457         irq_save_user_regs
 458         bl      do_irq
 459         irq_restore_user_regs
 460
 461         .align  5
 462 fiq:
 463         get_fiq_stack
 464         /* someone ought to write a more effiction fiq_save_user_regs */
 465         irq_save_user_regs
 466         bl      do_fiq
 467         irq_restore_user_regs
 468
 469 #else
 470
 471         .align  5
 472 irq:
 473         get_bad_stack
 474         bad_save_user_regs
 475         bl      do_irq
 476
 477         .align  5
 478 fiq:
 479         get_bad_stack
 480         bad_save_user_regs
 481         bl      do_fiq
 482
 483 #endif
 484
 485 #if defined(CONFIG_IMPA7) || defined(CONFIG_EP7312)
 486         .align  5
 487 .globl reset_cpu
 488 reset_cpu:
 489         mov     ip, #0
 490         mcr     p15, 0, ip, c7, c7, 0           @ invalidate cache
 491         mcr     p15, 0, ip, c8, c7, 0           @ flush TLB (v4)
 492         mrc     p15, 0, ip, c1, c0, 0           @ get ctrl register
 493         bic     ip, ip, #0x000f                 @ ............wcam
 494         bic     ip, ip, #0x2100                 @ ..v....s........
 495         mcr     p15, 0, ip, c1, c0, 0           @ ctrl register
 496         mov     pc, r0
 497 #elif defined(CONFIG_NETARM)
 498         .align  5
 499 .globl reset_cpu
 500 reset_cpu:
 501         ldr     r1, =NETARM_MEM_MODULE_BASE
 502         ldr     r0, [r1, #+NETARM_MEM_CS0_BASE_ADDR]
 503         ldr     r1, =0xFFFFF000
 504         and     r0, r1, r0
 505         ldr     r1, =(relocate-TEXT_BASE)
 506         add     r0, r1, r0
 507         ldr     r4, =NETARM_GEN_MODULE_BASE
 508         ldr     r1, =NETARM_GEN_SW_SVC_RESETA
 509         str     r1, [r4, #+NETARM_GEN_SOFTWARE_SERVICE]
 510         ldr     r1, =NETARM_GEN_SW_SVC_RESETB
 511         str     r1, [r4, #+NETARM_GEN_SOFTWARE_SERVICE]
 512         ldr     r1, =NETARM_GEN_SW_SVC_RESETA
 513         str     r1, [r4, #+NETARM_GEN_SOFTWARE_SERVICE]
 514         ldr     r1, =NETARM_GEN_SW_SVC_RESETB
 515         str     r1, [r4, #+NETARM_GEN_SOFTWARE_SERVICE]
 516         mov     pc, r0
 517 #elif defined(CONFIG_S3C4510B)
 518 /* Nothing done here as reseting the CPU is board specific, depending
 519  * on external peripherals such as watchdog timers, etc. */
 520 #else
 521 #error No reset_cpu() defined for current CPU type
 522 #endif