configure.ac

   1 AC_PREREQ([2.60])
   2 AC_INIT([libsecp256k1],[0.1])
   3 AC_CONFIG_AUX_DIR([build-aux])
   4 AC_CONFIG_MACRO_DIR([build-aux/m4])
   5 AC_CANONICAL_HOST
   6 AH_TOP([#ifndef LIBSECP256K1_CONFIG_H])
   7 AH_TOP([#define LIBSECP256K1_CONFIG_H])
   8 AH_BOTTOM([#endif /*LIBSECP256K1_CONFIG_H*/])
   9 AM_INIT_AUTOMAKE([foreign subdir-objects])
  10
  11 # Set -g if CFLAGS are not already set, which matches the default autoconf
  12 # behavior (see PROG_CC in the Autoconf manual) with the exception that we don't
  13 # set -O2 here because we set it in any case (see further down).
  14 : ${CFLAGS="-g"}
  15 LT_INIT
  16
  17 # Make the compilation flags quiet unless V=1 is used.
  18 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  19
  20 PKG_PROG_PKG_CONFIG
  21
  22 AC_PATH_TOOL(AR, ar)
  23 AC_PATH_TOOL(RANLIB, ranlib)
  24 AC_PATH_TOOL(STRIP, strip)
  25
  26 # Save definition of AC_PROG_CC because AM_PROG_CC_C_O in automake<=1.13 will
  27 # redefine AC_PROG_CC to exit with an error, which avoids the user calling it
  28 # accidently and screwing up the effect of AM_PROG_CC_C_O. However, we'll need
  29 # AC_PROG_CC later on in AX_PROG_CC_FOR_BUILD, where its usage is fine, and
  30 # we'll carefully make sure not to call AC_PROG_CC anywhere else.
  31 m4_copy([AC_PROG_CC], [saved_AC_PROG_CC])
  32 AM_PROG_CC_C_O
  33 # Restore AC_PROG_CC
  34 m4_rename_force([saved_AC_PROG_CC], [AC_PROG_CC])
  35
  36 AC_PROG_CC_C89
  37 if test x"$ac_cv_prog_cc_c89" = x"no"; then
  38   AC_MSG_ERROR([c89 compiler support required])
  39 fi
  40 AM_PROG_AS
  41
  42 case $host_os in
  43   *darwin*)
  44      if  test x$cross_compiling != xyes; then
  45        AC_PATH_PROG([BREW],brew,)
  46        if test x$BREW != x; then
  47          # These Homebrew packages may be keg-only, meaning that they won't be found
  48          # in expected paths because they may conflict with system files. Ask
  49          # Homebrew where each one is located, then adjust paths accordingly.
  50          openssl_prefix=`$BREW --prefix openssl 2>/dev/null`
  51          gmp_prefix=`$BREW --prefix gmp 2>/dev/null`
  52          valgrind_prefix=`$BREW --prefix valgrind 2>/dev/null`
  53          if test x$openssl_prefix != x; then
  54            PKG_CONFIG_PATH="$openssl_prefix/lib/pkgconfig:$PKG_CONFIG_PATH"
  55            export PKG_CONFIG_PATH
  56            CRYPTO_CPPFLAGS="-I$openssl_prefix/include"
  57          fi
  58          if test x$gmp_prefix != x; then
  59            GMP_CPPFLAGS="-I$gmp_prefix/include"
  60            GMP_LIBS="-L$gmp_prefix/lib"
  61          fi
  62          if test x$valgrind_prefix != x; then
  63            VALGRIND_CPPFLAGS="-I$valgrind_prefix/include"
  64          fi
  65        else
  66          AC_PATH_PROG([PORT],port,)
  67          # If homebrew isn't installed and macports is, add the macports default paths
  68          # as a last resort.
  69          if test x$PORT != x; then
  70            CPPFLAGS="$CPPFLAGS -isystem /opt/local/include"
  71            LDFLAGS="$LDFLAGS -L/opt/local/lib"
  72          fi
  73        fi
  74      fi
  75    ;;
  76 esac
  77
  78 CFLAGS="-W $CFLAGS"
  79
  80 warn_CFLAGS="-std=c89 -pedantic -Wall -Wextra -Wcast-align -Wnested-externs -Wshadow -Wstrict-prototypes -Wundef -Wno-unused-function -Wno-long-long -Wno-overlength-strings"
  81 saved_CFLAGS="$CFLAGS"
  82 CFLAGS="$warn_CFLAGS $CFLAGS"
  83 AC_MSG_CHECKING([if ${CC} supports ${warn_CFLAGS}])
  84 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[char foo;]])],
  85     [ AC_MSG_RESULT([yes]) ],
  86     [ AC_MSG_RESULT([no])
  87       CFLAGS="$saved_CFLAGS"
  88     ])
  89
  90 saved_CFLAGS="$CFLAGS"
  91 CFLAGS="-fvisibility=hidden $CFLAGS"
  92 AC_MSG_CHECKING([if ${CC} supports -fvisibility=hidden])
  93 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[char foo;]])],
  94     [ AC_MSG_RESULT([yes]) ],
  95     [ AC_MSG_RESULT([no])
  96       CFLAGS="$saved_CFLAGS"
  97     ])
  98
  99 ###
 100 ### Define config arguments
 101 ###
 102
 103 AC_ARG_ENABLE(benchmark,
 104     AS_HELP_STRING([--enable-benchmark],[compile benchmark [default=yes]]),
 105     [use_benchmark=$enableval],
 106     [use_benchmark=yes])
 107
 108 AC_ARG_ENABLE(coverage,
 109     AS_HELP_STRING([--enable-coverage],[enable compiler flags to support kcov coverage analysis [default=no]]),
 110     [enable_coverage=$enableval],
 111     [enable_coverage=no])
 112
 113 AC_ARG_ENABLE(tests,
 114     AS_HELP_STRING([--enable-tests],[compile tests [default=yes]]),
 115     [use_tests=$enableval],
 116     [use_tests=yes])
 117
 118 AC_ARG_ENABLE(openssl_tests,
 119     AS_HELP_STRING([--enable-openssl-tests],[enable OpenSSL tests [default=auto]]),
 120     [enable_openssl_tests=$enableval],
 121     [enable_openssl_tests=auto])
 122
 123 AC_ARG_ENABLE(experimental,
 124     AS_HELP_STRING([--enable-experimental],[allow experimental configure options [default=no]]),
 125     [use_experimental=$enableval],
 126     [use_experimental=no])
 127
 128 AC_ARG_ENABLE(exhaustive_tests,
 129     AS_HELP_STRING([--enable-exhaustive-tests],[compile exhaustive tests [default=yes]]),
 130     [use_exhaustive_tests=$enableval],
 131     [use_exhaustive_tests=yes])
 132
 133 AC_ARG_ENABLE(ecmult_static_precomputation,
 134     AS_HELP_STRING([--enable-ecmult-static-precomputation],[enable precomputed ecmult table for signing [default=auto]]),
 135     [use_ecmult_static_precomputation=$enableval],
 136     [use_ecmult_static_precomputation=auto])
 137
 138 AC_ARG_ENABLE(module_ecdh,
 139     AS_HELP_STRING([--enable-module-ecdh],[enable ECDH shared secret computation]),
 140     [enable_module_ecdh=$enableval],
 141     [enable_module_ecdh=no])
 142
 143 AC_ARG_ENABLE(module_recovery,
 144     AS_HELP_STRING([--enable-module-recovery],[enable ECDSA pubkey recovery module [default=no]]),
 145     [enable_module_recovery=$enableval],
 146     [enable_module_recovery=no])
 147
 148 AC_ARG_ENABLE(module_extrakeys,
 149     AS_HELP_STRING([--enable-module-extrakeys],[enable extrakeys module (experimental)]),
 150     [enable_module_extrakeys=$enableval],
 151     [enable_module_extrakeys=no])
 152
 153 AC_ARG_ENABLE(module_schnorrsig,
 154     AS_HELP_STRING([--enable-module-schnorrsig],[enable schnorrsig module (experimental)]),
 155     [enable_module_schnorrsig=$enableval],
 156     [enable_module_schnorrsig=no])
 157
 158 AC_ARG_ENABLE(external_default_callbacks,
 159     AS_HELP_STRING([--enable-external-default-callbacks],[enable external default callback functions [default=no]]),
 160     [use_external_default_callbacks=$enableval],
 161     [use_external_default_callbacks=no])
 162
 163 # Test-only override of the (autodetected by the C code) "widemul" setting.
 164 # Legal values are int64 (for [u]int64_t), int128 (for [unsigned] __int128), and auto (the default).
 165 AC_ARG_WITH([test-override-wide-multiply], [] ,[set_widemul=$withval], [set_widemul=auto])
 166
 167 AC_ARG_WITH([bignum], [AS_HELP_STRING([--with-bignum=gmp|no|auto],
 168 [bignum implementation to use [default=auto]])],[req_bignum=$withval], [req_bignum=auto])
 169
 170 AC_ARG_WITH([asm], [AS_HELP_STRING([--with-asm=x86_64|arm|no|auto],
 171 [assembly optimizations to use (experimental: arm) [default=auto]])],[req_asm=$withval], [req_asm=auto])
 172
 173 AC_ARG_WITH([ecmult-window], [AS_HELP_STRING([--with-ecmult-window=SIZE|auto],
 174 [window size for ecmult precomputation for verification, specified as integer in range [2..24].]
 175 [Larger values result in possibly better performance at the cost of an exponentially larger precomputed table.]
 176 [The table will store 2^(SIZE-1) * 64 bytes of data but can be larger in memory due to platform-specific padding and alignment.]
 177 ["auto" is a reasonable setting for desktop machines (currently 15). [default=auto]]
 178 )],
 179 [req_ecmult_window=$withval], [req_ecmult_window=auto])
 180
 181 AC_ARG_WITH([ecmult-gen-precision], [AS_HELP_STRING([--with-ecmult-gen-precision=2|4|8|auto],
 182 [Precision bits to tune the precomputed table size for signing.]
 183 [The size of the table is 32kB for 2 bits, 64kB for 4 bits, 512kB for 8 bits of precision.]
 184 [A larger table size usually results in possible faster signing.]
 185 ["auto" is a reasonable setting for desktop machines (currently 4). [default=auto]]
 186 )],
 187 [req_ecmult_gen_precision=$withval], [req_ecmult_gen_precision=auto])
 188
 189 AC_ARG_WITH([valgrind], [AS_HELP_STRING([--with-valgrind=yes|no|auto],
 190 [Build with extra checks for running inside Valgrind [default=auto]]
 191 )],
 192 [req_valgrind=$withval], [req_valgrind=auto])
 193
 194 ###
 195 ### Handle config options (except for modules)
 196 ###
 197
 198 if test x"$req_valgrind" = x"no"; then
 199   enable_valgrind=no
 200 else
 201   SECP_VALGRIND_CHECK
 202   if test x"$has_valgrind" != x"yes"; then
 203     if test x"$req_valgrind" = x"yes"; then
 204       AC_MSG_ERROR([Valgrind support explicitly requested but valgrind/memcheck.h header not available])
 205     fi
 206     enable_valgrind=no
 207   else
 208     enable_valgrind=yes
 209   fi
 210 fi
 211 AM_CONDITIONAL([VALGRIND_ENABLED],[test "$enable_valgrind" = "yes"])
 212
 213 if test x"$enable_coverage" = x"yes"; then
 214     AC_DEFINE(COVERAGE, 1, [Define this symbol to compile out all VERIFY code])
 215     CFLAGS="-O0 --coverage $CFLAGS"
 216     LDFLAGS="--coverage $LDFLAGS"
 217 else
 218     CFLAGS="-O2 $CFLAGS"
 219 fi
 220
 221 if test x"$req_asm" = x"auto"; then
 222   SECP_64BIT_ASM_CHECK
 223   if test x"$has_64bit_asm" = x"yes"; then
 224     set_asm=x86_64
 225   fi
 226   if test x"$set_asm" = x; then
 227     set_asm=no
 228   fi
 229 else
 230   set_asm=$req_asm
 231   case $set_asm in
 232   x86_64)
 233     SECP_64BIT_ASM_CHECK
 234     if test x"$has_64bit_asm" != x"yes"; then
 235       AC_MSG_ERROR([x86_64 assembly optimization requested but not available])
 236     fi
 237     ;;
 238   arm)
 239     ;;
 240   no)
 241     ;;
 242   *)
 243     AC_MSG_ERROR([invalid assembly optimization selection])
 244     ;;
 245   esac
 246 fi
 247
 248 if test x"$req_bignum" = x"auto"; then
 249   SECP_GMP_CHECK
 250   if test x"$has_gmp" = x"yes"; then
 251     set_bignum=gmp
 252   fi
 253
 254   if test x"$set_bignum" = x; then
 255     set_bignum=no
 256   fi
 257 else
 258   set_bignum=$req_bignum
 259   case $set_bignum in
 260   gmp)
 261     SECP_GMP_CHECK
 262     if test x"$has_gmp" != x"yes"; then
 263       AC_MSG_ERROR([gmp bignum explicitly requested but libgmp not available])
 264     fi
 265     ;;
 266   no)
 267     ;;
 268   *)
 269     AC_MSG_ERROR([invalid bignum implementation selection])
 270     ;;
 271   esac
 272 fi
 273
 274 # Select assembly optimization
 275 use_external_asm=no
 276
 277 case $set_asm in
 278 x86_64)
 279   AC_DEFINE(USE_ASM_X86_64, 1, [Define this symbol to enable x86_64 assembly optimizations])
 280   ;;
 281 arm)
 282   use_external_asm=yes
 283   ;;
 284 no)
 285   ;;
 286 *)
 287   AC_MSG_ERROR([invalid assembly optimizations])
 288   ;;
 289 esac
 290
 291 if test x"$use_external_asm" = x"yes"; then
 292   AC_DEFINE(USE_EXTERNAL_ASM, 1, [Define this symbol if an external (non-inline) assembly implementation is used])
 293 fi
 294
 295
 296 # Select wide multiplication implementation
 297 case $set_widemul in
 298 int128)
 299   AC_DEFINE(USE_FORCE_WIDEMUL_INT128, 1, [Define this symbol to force the use of the (unsigned) __int128 based wide multiplication implementation])
 300   ;;
 301 int64)
 302   AC_DEFINE(USE_FORCE_WIDEMUL_INT64, 1, [Define this symbol to force the use of the (u)int64_t based wide multiplication implementation])
 303   ;;
 304 auto)
 305   ;;
 306 *)
 307   AC_MSG_ERROR([invalid wide multiplication implementation])
 308   ;;
 309 esac
 310
 311 # Select bignum implementation
 312 case $set_bignum in
 313 gmp)
 314   AC_DEFINE(HAVE_LIBGMP, 1, [Define this symbol if libgmp is installed])
 315   AC_DEFINE(USE_NUM_GMP, 1, [Define this symbol to use the gmp implementation for num])
 316   AC_DEFINE(USE_FIELD_INV_NUM, 1, [Define this symbol to use the num-based field inverse implementation])
 317   AC_DEFINE(USE_SCALAR_INV_NUM, 1, [Define this symbol to use the num-based scalar inverse implementation])
 318   ;;
 319 no)
 320   AC_DEFINE(USE_NUM_NONE, 1, [Define this symbol to use no num implementation])
 321   AC_DEFINE(USE_FIELD_INV_BUILTIN, 1, [Define this symbol to use the native field inverse implementation])
 322   AC_DEFINE(USE_SCALAR_INV_BUILTIN, 1, [Define this symbol to use the native scalar inverse implementation])
 323   ;;
 324 *)
 325   AC_MSG_ERROR([invalid bignum implementation])
 326   ;;
 327 esac
 328
 329 # Set ecmult window size
 330 if test x"$req_ecmult_window" = x"auto"; then
 331   set_ecmult_window=15
 332 else
 333   set_ecmult_window=$req_ecmult_window
 334 fi
 335
 336 error_window_size=['window size for ecmult precomputation not an integer in range [2..24] or "auto"']
 337 case $set_ecmult_window in
 338 ''|*[[!0-9]]*)
 339   # no valid integer
 340   AC_MSG_ERROR($error_window_size)
 341   ;;
 342 *)
 343   if test "$set_ecmult_window" -lt 2 -o "$set_ecmult_window" -gt 24 ; then
 344     # not in range
 345     AC_MSG_ERROR($error_window_size)
 346   fi
 347   AC_DEFINE_UNQUOTED(ECMULT_WINDOW_SIZE, $set_ecmult_window, [Set window size for ecmult precomputation])
 348   ;;
 349 esac
 350
 351 # Set ecmult gen precision
 352 if test x"$req_ecmult_gen_precision" = x"auto"; then
 353   set_ecmult_gen_precision=4
 354 else
 355   set_ecmult_gen_precision=$req_ecmult_gen_precision
 356 fi
 357
 358 case $set_ecmult_gen_precision in
 359 2|4|8)
 360   AC_DEFINE_UNQUOTED(ECMULT_GEN_PREC_BITS, $set_ecmult_gen_precision, [Set ecmult gen precision bits])
 361   ;;
 362 *)
 363   AC_MSG_ERROR(['ecmult gen precision not 2, 4, 8 or "auto"'])
 364   ;;
 365 esac
 366
 367 if test x"$use_tests" = x"yes"; then
 368   SECP_OPENSSL_CHECK
 369   if test x"$enable_openssl_tests" != x"no" && test x"$has_openssl_ec" = x"yes"; then
 370       enable_openssl_tests=yes
 371       AC_DEFINE(ENABLE_OPENSSL_TESTS, 1, [Define this symbol if OpenSSL EC functions are available])
 372       SECP_TEST_INCLUDES="$SSL_CFLAGS $CRYPTO_CFLAGS $CRYPTO_CPPFLAGS"
 373       SECP_TEST_LIBS="$CRYPTO_LIBS"
 374
 375       case $host in
 376       *mingw*)
 377         SECP_TEST_LIBS="$SECP_TEST_LIBS -lgdi32"
 378         ;;
 379       esac
 380   else
 381     if test x"$enable_openssl_tests" = x"yes"; then
 382       AC_MSG_ERROR([OpenSSL tests requested but OpenSSL with EC support is not available])
 383     fi
 384     enable_openssl_tests=no
 385   fi
 386 else
 387   if test x"$enable_openssl_tests" = x"yes"; then
 388     AC_MSG_ERROR([OpenSSL tests requested but tests are not enabled])
 389   fi
 390   enable_openssl_tests=no
 391 fi
 392
 393 if test x"$set_bignum" = x"gmp"; then
 394   SECP_LIBS="$SECP_LIBS $GMP_LIBS"
 395   SECP_INCLUDES="$SECP_INCLUDES $GMP_CPPFLAGS"
 396 fi
 397
 398 if test x"$enable_valgrind" = x"yes"; then
 399   SECP_INCLUDES="$SECP_INCLUDES $VALGRIND_CPPFLAGS"
 400 fi
 401
 402 # Handle static precomputation (after everything which modifies CFLAGS and friends)
 403 if test x"$use_ecmult_static_precomputation" != x"no"; then
 404   if test x"$cross_compiling" = x"no"; then
 405     set_precomp=yes
 406     if test x"${CC_FOR_BUILD+x}${CFLAGS_FOR_BUILD+x}${CPPFLAGS_FOR_BUILD+x}${LDFLAGS_FOR_BUILD+x}" != x; then
 407       AC_MSG_WARN([CC_FOR_BUILD, CFLAGS_FOR_BUILD, CPPFLAGS_FOR_BUILD, and/or LDFLAGS_FOR_BUILD is set but ignored because we are not cross-compiling.])
 408     fi
 409     # If we're not cross-compiling, simply use the same compiler for building the static precompation code.
 410     CC_FOR_BUILD="$CC"
 411     CFLAGS_FOR_BUILD="$CFLAGS"
 412     CPPFLAGS_FOR_BUILD="$CPPFLAGS"
 413     LDFLAGS_FOR_BUILD="$LDFLAGS"
 414   else
 415     AX_PROG_CC_FOR_BUILD
 416
 417     # Temporarily switch to an environment for the native compiler
 418     save_cross_compiling=$cross_compiling
 419     cross_compiling=no
 420     SAVE_CC="$CC"
 421     CC="$CC_FOR_BUILD"
 422     SAVE_CFLAGS="$CFLAGS"
 423     CFLAGS="$CFLAGS_FOR_BUILD"
 424     SAVE_CPPFLAGS="$CPPFLAGS"
 425     CPPFLAGS="$CPPFLAGS_FOR_BUILD"
 426     SAVE_LDFLAGS="$LDFLAGS"
 427     LDFLAGS="$LDFLAGS_FOR_BUILD"
 428
 429     warn_CFLAGS_FOR_BUILD="-Wall -Wextra -Wno-unused-function"
 430     saved_CFLAGS="$CFLAGS"
 431     CFLAGS="$warn_CFLAGS_FOR_BUILD $CFLAGS"
 432     AC_MSG_CHECKING([if native ${CC_FOR_BUILD} supports ${warn_CFLAGS_FOR_BUILD}])
 433     AC_COMPILE_IFELSE([AC_LANG_SOURCE([[char foo;]])],
 434         [ AC_MSG_RESULT([yes]) ],
 435         [ AC_MSG_RESULT([no])
 436           CFLAGS="$saved_CFLAGS"
 437         ])
 438
 439     AC_MSG_CHECKING([for working native compiler: ${CC_FOR_BUILD}])
 440     AC_RUN_IFELSE(
 441       [AC_LANG_PROGRAM([], [])],
 442       [working_native_cc=yes],
 443       [working_native_cc=no],[:])
 444
 445     CFLAGS_FOR_BUILD="$CFLAGS"
 446
 447     # Restore the environment
 448     cross_compiling=$save_cross_compiling
 449     CC="$SAVE_CC"
 450     CFLAGS="$SAVE_CFLAGS"
 451     CPPFLAGS="$SAVE_CPPFLAGS"
 452     LDFLAGS="$SAVE_LDFLAGS"
 453
 454     if test x"$working_native_cc" = x"no"; then
 455       AC_MSG_RESULT([no])
 456       set_precomp=no
 457       m4_define([please_set_for_build], [Please set CC_FOR_BUILD, CFLAGS_FOR_BUILD, CPPFLAGS_FOR_BUILD, and/or LDFLAGS_FOR_BUILD.])
 458       if test x"$use_ecmult_static_precomputation" = x"yes";  then
 459         AC_MSG_ERROR([native compiler ${CC_FOR_BUILD} does not produce working binaries. please_set_for_build])
 460       else
 461         AC_MSG_WARN([Disabling statically generated ecmult table because the native compiler ${CC_FOR_BUILD} does not produce working binaries. please_set_for_build])
 462       fi
 463     else
 464       AC_MSG_RESULT([yes])
 465       set_precomp=yes
 466     fi
 467   fi
 468
 469   AC_SUBST(CC_FOR_BUILD)
 470   AC_SUBST(CFLAGS_FOR_BUILD)
 471   AC_SUBST(CPPFLAGS_FOR_BUILD)
 472   AC_SUBST(LDFLAGS_FOR_BUILD)
 473 else
 474   set_precomp=no
 475 fi
 476
 477 if test x"$set_precomp" = x"yes"; then
 478   AC_DEFINE(USE_ECMULT_STATIC_PRECOMPUTATION, 1, [Define this symbol to use a statically generated ecmult table])
 479 fi
 480
 481 ###
 482 ### Handle module options
 483 ###
 484
 485 if test x"$enable_module_ecdh" = x"yes"; then
 486   AC_DEFINE(ENABLE_MODULE_ECDH, 1, [Define this symbol to enable the ECDH module])
 487 fi
 488
 489 if test x"$enable_module_recovery" = x"yes"; then
 490   AC_DEFINE(ENABLE_MODULE_RECOVERY, 1, [Define this symbol to enable the ECDSA pubkey recovery module])
 491 fi
 492
 493 if test x"$enable_module_schnorrsig" = x"yes"; then
 494   AC_DEFINE(ENABLE_MODULE_SCHNORRSIG, 1, [Define this symbol to enable the schnorrsig module])
 495   enable_module_extrakeys=yes
 496 fi
 497
 498 # Test if extrakeys is set after the schnorrsig module to allow the schnorrsig
 499 # module to set enable_module_extrakeys=yes
 500 if test x"$enable_module_extrakeys" = x"yes"; then
 501   AC_DEFINE(ENABLE_MODULE_EXTRAKEYS, 1, [Define this symbol to enable the extrakeys module])
 502 fi
 503
 504 if test x"$use_external_default_callbacks" = x"yes"; then
 505   AC_DEFINE(USE_EXTERNAL_DEFAULT_CALLBACKS, 1, [Define this symbol if an external implementation of the default callbacks is used])
 506 fi
 507
 508 ###
 509 ### Check for --enable-experimental if necessary
 510 ###
 511
 512 if test x"$enable_experimental" = x"yes"; then
 513   AC_MSG_NOTICE([******])
 514   AC_MSG_NOTICE([WARNING: experimental build])
 515   AC_MSG_NOTICE([Experimental features do not have stable APIs or properties, and may not be safe for production use.])
 516   AC_MSG_NOTICE([Building extrakeys module: $enable_module_extrakeys])
 517   AC_MSG_NOTICE([Building schnorrsig module: $enable_module_schnorrsig])
 518   AC_MSG_NOTICE([******])
 519 else
 520   if test x"$enable_module_extrakeys" = x"yes"; then
 521     AC_MSG_ERROR([extrakeys module is experimental. Use --enable-experimental to allow.])
 522   fi
 523   if test x"$enable_module_schnorrsig" = x"yes"; then
 524     AC_MSG_ERROR([schnorrsig module is experimental. Use --enable-experimental to allow.])
 525   fi
 526   if test x"$set_asm" = x"arm"; then
 527     AC_MSG_ERROR([ARM assembly optimization is experimental. Use --enable-experimental to allow.])
 528   fi
 529 fi
 530
 531 ###
 532 ### Generate output
 533 ###
 534
 535 AC_CONFIG_HEADERS([src/libsecp256k1-config.h])
 536 AC_CONFIG_FILES([Makefile libsecp256k1.pc])
 537 AC_SUBST(SECP_INCLUDES)
 538 AC_SUBST(SECP_LIBS)
 539 AC_SUBST(SECP_TEST_LIBS)
 540 AC_SUBST(SECP_TEST_INCLUDES)
 541 AM_CONDITIONAL([ENABLE_COVERAGE], [test x"$enable_coverage" = x"yes"])
 542 AM_CONDITIONAL([USE_TESTS], [test x"$use_tests" != x"no"])
 543 AM_CONDITIONAL([USE_EXHAUSTIVE_TESTS], [test x"$use_exhaustive_tests" != x"no"])
 544 AM_CONDITIONAL([USE_BENCHMARK], [test x"$use_benchmark" = x"yes"])
 545 AM_CONDITIONAL([USE_ECMULT_STATIC_PRECOMPUTATION], [test x"$set_precomp" = x"yes"])
 546 AM_CONDITIONAL([ENABLE_MODULE_ECDH], [test x"$enable_module_ecdh" = x"yes"])
 547 AM_CONDITIONAL([ENABLE_MODULE_RECOVERY], [test x"$enable_module_recovery" = x"yes"])
 548 AM_CONDITIONAL([ENABLE_MODULE_EXTRAKEYS], [test x"$enable_module_extrakeys" = x"yes"])
 549 AM_CONDITIONAL([ENABLE_MODULE_SCHNORRSIG], [test x"$enable_module_schnorrsig" = x"yes"])
 550 AM_CONDITIONAL([USE_EXTERNAL_ASM], [test x"$use_external_asm" = x"yes"])
 551 AM_CONDITIONAL([USE_ASM_ARM], [test x"$set_asm" = x"arm"])
 552
 553 # Make sure nothing new is exported so that we don't break the cache.
 554 PKGCONFIG_PATH_TEMP="$PKG_CONFIG_PATH"
 555 unset PKG_CONFIG_PATH
 556 PKG_CONFIG_PATH="$PKGCONFIG_PATH_TEMP"
 557
 558 AC_OUTPUT
 559
 560 echo
 561 echo "Build Options:"
 562 echo "  with ecmult precomp     = $set_precomp"
 563 echo "  with external callbacks = $use_external_default_callbacks"
 564 echo "  with benchmarks         = $use_benchmark"
 565 echo "  with tests              = $use_tests"
 566 echo "  with openssl tests      = $enable_openssl_tests"
 567 echo "  with coverage           = $enable_coverage"
 568 echo "  module ecdh             = $enable_module_ecdh"
 569 echo "  module recovery         = $enable_module_recovery"
 570 echo "  module extrakeys        = $enable_module_extrakeys"
 571 echo "  module schnorrsig       = $enable_module_schnorrsig"
 572 echo
 573 echo "  asm                     = $set_asm"
 574 echo "  bignum                  = $set_bignum"
 575 echo "  ecmult window size      = $set_ecmult_window"
 576 echo "  ecmult gen prec. bits   = $set_ecmult_gen_precision"
 577 # Hide test-only options unless they're used.
 578 if test x"$set_widemul" != xauto; then
 579 echo "  wide multiplication     = $set_widemul"
 580 fi
 581 echo
 582 echo "  valgrind                = $enable_valgrind"
 583 echo "  CC                      = $CC"
 584 echo "  CFLAGS                  = $CFLAGS"
 585 echo "  CPPFLAGS                = $CPPFLAGS"
 586 echo "  LDFLAGS                 = $LDFLAGS"
 587 echo
 588 if test x"$set_precomp" = x"yes"; then
 589 echo "  CC_FOR_BUILD            = $CC_FOR_BUILD"
 590 echo "  CFLAGS_FOR_BUILD        = $CFLAGS_FOR_BUILD"
 591 echo "  CPPFLAGS_FOR_BUILD      = $CPPFLAGS_FOR_BUILD"
 592 echo "  LDFLAGS_FOR_BUILD       = $LDFLAGS_FOR_BUILD"
 593 fi