configure.ac

   1 AC_PREREQ([2.60])
   2 AC_INIT([libsecp256k1],[0.1])
   3 AC_CONFIG_AUX_DIR([build-aux])
   4 AC_CONFIG_MACRO_DIR([build-aux/m4])
   5 AC_CANONICAL_HOST
   6 AH_TOP([#ifndef LIBSECP256K1_CONFIG_H])
   7 AH_TOP([#define LIBSECP256K1_CONFIG_H])
   8 AH_BOTTOM([#endif /*LIBSECP256K1_CONFIG_H*/])
   9 AM_INIT_AUTOMAKE([foreign subdir-objects])
  10
  11 # Set -g if CFLAGS are not already set, which matches the default autoconf
  12 # behavior (see PROG_CC in the Autoconf manual) with the exception that we don't
  13 # set -O2 here because we set it in any case (see further down).
  14 : ${CFLAGS="-g"}
  15 LT_INIT
  16
  17 # Make the compilation flags quiet unless V=1 is used.
  18 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  19
  20 PKG_PROG_PKG_CONFIG
  21
  22 AC_PATH_TOOL(AR, ar)
  23 AC_PATH_TOOL(RANLIB, ranlib)
  24 AC_PATH_TOOL(STRIP, strip)
  25
  26 # Save definition of AC_PROG_CC because AM_PROG_CC_C_O in automake<=1.13 will
  27 # redefine AC_PROG_CC to exit with an error, which avoids the user calling it
  28 # accidently and screwing up the effect of AM_PROG_CC_C_O. However, we'll need
  29 # AC_PROG_CC later on in AX_PROG_CC_FOR_BUILD, where its usage is fine, and
  30 # we'll carefully make sure not to call AC_PROG_CC anywhere else.
  31 m4_copy([AC_PROG_CC], [saved_AC_PROG_CC])
  32 AM_PROG_CC_C_O
  33 # Restore AC_PROG_CC
  34 m4_rename_force([saved_AC_PROG_CC], [AC_PROG_CC])
  35
  36 AC_PROG_CC_C89
  37 if test x"$ac_cv_prog_cc_c89" = x"no"; then
  38   AC_MSG_ERROR([c89 compiler support required])
  39 fi
  40 AM_PROG_AS
  41
  42 case $host_os in
  43   *darwin*)
  44      if  test x$cross_compiling != xyes; then
  45        AC_PATH_PROG([BREW],brew,)
  46        if test x$BREW != x; then
  47          # These Homebrew packages may be keg-only, meaning that they won't be found
  48          # in expected paths because they may conflict with system files. Ask
  49          # Homebrew where each one is located, then adjust paths accordingly.
  50          openssl_prefix=`$BREW --prefix openssl 2>/dev/null`
  51          valgrind_prefix=`$BREW --prefix valgrind 2>/dev/null`
  52          if test x$openssl_prefix != x; then
  53            PKG_CONFIG_PATH="$openssl_prefix/lib/pkgconfig:$PKG_CONFIG_PATH"
  54            export PKG_CONFIG_PATH
  55            CRYPTO_CPPFLAGS="-I$openssl_prefix/include"
  56          fi
  57          if test x$valgrind_prefix != x; then
  58            VALGRIND_CPPFLAGS="-I$valgrind_prefix/include"
  59          fi
  60        else
  61          AC_PATH_PROG([PORT],port,)
  62          # If homebrew isn't installed and macports is, add the macports default paths
  63          # as a last resort.
  64          if test x$PORT != x; then
  65            CPPFLAGS="$CPPFLAGS -isystem /opt/local/include"
  66            LDFLAGS="$LDFLAGS -L/opt/local/lib"
  67          fi
  68        fi
  69      fi
  70    ;;
  71 esac
  72
  73 CFLAGS="-W $CFLAGS"
  74
  75 warn_CFLAGS="-std=c89 -pedantic -Wall -Wextra -Wcast-align -Wnested-externs -Wshadow -Wstrict-prototypes -Wundef -Wno-unused-function -Wno-long-long -Wno-overlength-strings"
  76 saved_CFLAGS="$CFLAGS"
  77 CFLAGS="$warn_CFLAGS $CFLAGS"
  78 AC_MSG_CHECKING([if ${CC} supports ${warn_CFLAGS}])
  79 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[char foo;]])],
  80     [ AC_MSG_RESULT([yes]) ],
  81     [ AC_MSG_RESULT([no])
  82       CFLAGS="$saved_CFLAGS"
  83     ])
  84
  85 saved_CFLAGS="$CFLAGS"
  86 CFLAGS="-fvisibility=hidden $CFLAGS"
  87 AC_MSG_CHECKING([if ${CC} supports -fvisibility=hidden])
  88 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[char foo;]])],
  89     [ AC_MSG_RESULT([yes]) ],
  90     [ AC_MSG_RESULT([no])
  91       CFLAGS="$saved_CFLAGS"
  92     ])
  93
  94 ###
  95 ### Define config arguments
  96 ###
  97
  98 AC_ARG_ENABLE(benchmark,
  99     AS_HELP_STRING([--enable-benchmark],[compile benchmark [default=yes]]),
 100     [use_benchmark=$enableval],
 101     [use_benchmark=yes])
 102
 103 AC_ARG_ENABLE(coverage,
 104     AS_HELP_STRING([--enable-coverage],[enable compiler flags to support kcov coverage analysis [default=no]]),
 105     [enable_coverage=$enableval],
 106     [enable_coverage=no])
 107
 108 AC_ARG_ENABLE(tests,
 109     AS_HELP_STRING([--enable-tests],[compile tests [default=yes]]),
 110     [use_tests=$enableval],
 111     [use_tests=yes])
 112
 113 AC_ARG_ENABLE(openssl_tests,
 114     AS_HELP_STRING([--enable-openssl-tests],[enable OpenSSL tests [default=auto]]),
 115     [enable_openssl_tests=$enableval],
 116     [enable_openssl_tests=auto])
 117
 118 AC_ARG_ENABLE(experimental,
 119     AS_HELP_STRING([--enable-experimental],[allow experimental configure options [default=no]]),
 120     [use_experimental=$enableval],
 121     [use_experimental=no])
 122
 123 AC_ARG_ENABLE(exhaustive_tests,
 124     AS_HELP_STRING([--enable-exhaustive-tests],[compile exhaustive tests [default=yes]]),
 125     [use_exhaustive_tests=$enableval],
 126     [use_exhaustive_tests=yes])
 127
 128 AC_ARG_ENABLE(ecmult_static_precomputation,
 129     AS_HELP_STRING([--enable-ecmult-static-precomputation],[enable precomputed ecmult table for signing [default=auto]]),
 130     [use_ecmult_static_precomputation=$enableval],
 131     [use_ecmult_static_precomputation=auto])
 132
 133 AC_ARG_ENABLE(module_ecdh,
 134     AS_HELP_STRING([--enable-module-ecdh],[enable ECDH shared secret computation]),
 135     [enable_module_ecdh=$enableval],
 136     [enable_module_ecdh=no])
 137
 138 AC_ARG_ENABLE(module_recovery,
 139     AS_HELP_STRING([--enable-module-recovery],[enable ECDSA pubkey recovery module [default=no]]),
 140     [enable_module_recovery=$enableval],
 141     [enable_module_recovery=no])
 142
 143 AC_ARG_ENABLE(module_extrakeys,
 144     AS_HELP_STRING([--enable-module-extrakeys],[enable extrakeys module (experimental)]),
 145     [enable_module_extrakeys=$enableval],
 146     [enable_module_extrakeys=no])
 147
 148 AC_ARG_ENABLE(module_schnorrsig,
 149     AS_HELP_STRING([--enable-module-schnorrsig],[enable schnorrsig module (experimental)]),
 150     [enable_module_schnorrsig=$enableval],
 151     [enable_module_schnorrsig=no])
 152
 153 AC_ARG_ENABLE(external_default_callbacks,
 154     AS_HELP_STRING([--enable-external-default-callbacks],[enable external default callback functions [default=no]]),
 155     [use_external_default_callbacks=$enableval],
 156     [use_external_default_callbacks=no])
 157
 158 # Test-only override of the (autodetected by the C code) "widemul" setting.
 159 # Legal values are int64 (for [u]int64_t), int128 (for [unsigned] __int128), and auto (the default).
 160 AC_ARG_WITH([test-override-wide-multiply], [] ,[set_widemul=$withval], [set_widemul=auto])
 161
 162 AC_ARG_WITH([asm], [AS_HELP_STRING([--with-asm=x86_64|arm|no|auto],
 163 [assembly optimizations to use (experimental: arm) [default=auto]])],[req_asm=$withval], [req_asm=auto])
 164
 165 AC_ARG_WITH([ecmult-window], [AS_HELP_STRING([--with-ecmult-window=SIZE|auto],
 166 [window size for ecmult precomputation for verification, specified as integer in range [2..24].]
 167 [Larger values result in possibly better performance at the cost of an exponentially larger precomputed table.]
 168 [The table will store 2^(SIZE-1) * 64 bytes of data but can be larger in memory due to platform-specific padding and alignment.]
 169 ["auto" is a reasonable setting for desktop machines (currently 15). [default=auto]]
 170 )],
 171 [req_ecmult_window=$withval], [req_ecmult_window=auto])
 172
 173 AC_ARG_WITH([ecmult-gen-precision], [AS_HELP_STRING([--with-ecmult-gen-precision=2|4|8|auto],
 174 [Precision bits to tune the precomputed table size for signing.]
 175 [The size of the table is 32kB for 2 bits, 64kB for 4 bits, 512kB for 8 bits of precision.]
 176 [A larger table size usually results in possible faster signing.]
 177 ["auto" is a reasonable setting for desktop machines (currently 4). [default=auto]]
 178 )],
 179 [req_ecmult_gen_precision=$withval], [req_ecmult_gen_precision=auto])
 180
 181 AC_ARG_WITH([valgrind], [AS_HELP_STRING([--with-valgrind=yes|no|auto],
 182 [Build with extra checks for running inside Valgrind [default=auto]]
 183 )],
 184 [req_valgrind=$withval], [req_valgrind=auto])
 185
 186 ###
 187 ### Handle config options (except for modules)
 188 ###
 189
 190 if test x"$req_valgrind" = x"no"; then
 191   enable_valgrind=no
 192 else
 193   SECP_VALGRIND_CHECK
 194   if test x"$has_valgrind" != x"yes"; then
 195     if test x"$req_valgrind" = x"yes"; then
 196       AC_MSG_ERROR([Valgrind support explicitly requested but valgrind/memcheck.h header not available])
 197     fi
 198     enable_valgrind=no
 199   else
 200     enable_valgrind=yes
 201   fi
 202 fi
 203 AM_CONDITIONAL([VALGRIND_ENABLED],[test "$enable_valgrind" = "yes"])
 204
 205 if test x"$enable_coverage" = x"yes"; then
 206     AC_DEFINE(COVERAGE, 1, [Define this symbol to compile out all VERIFY code])
 207     CFLAGS="-O0 --coverage $CFLAGS"
 208     LDFLAGS="--coverage $LDFLAGS"
 209 else
 210     CFLAGS="-O2 $CFLAGS"
 211 fi
 212
 213 if test x"$req_asm" = x"auto"; then
 214   SECP_64BIT_ASM_CHECK
 215   if test x"$has_64bit_asm" = x"yes"; then
 216     set_asm=x86_64
 217   fi
 218   if test x"$set_asm" = x; then
 219     set_asm=no
 220   fi
 221 else
 222   set_asm=$req_asm
 223   case $set_asm in
 224   x86_64)
 225     SECP_64BIT_ASM_CHECK
 226     if test x"$has_64bit_asm" != x"yes"; then
 227       AC_MSG_ERROR([x86_64 assembly optimization requested but not available])
 228     fi
 229     ;;
 230   arm)
 231     ;;
 232   no)
 233     ;;
 234   *)
 235     AC_MSG_ERROR([invalid assembly optimization selection])
 236     ;;
 237   esac
 238 fi
 239
 240 # Select assembly optimization
 241 use_external_asm=no
 242
 243 case $set_asm in
 244 x86_64)
 245   AC_DEFINE(USE_ASM_X86_64, 1, [Define this symbol to enable x86_64 assembly optimizations])
 246   ;;
 247 arm)
 248   use_external_asm=yes
 249   ;;
 250 no)
 251   ;;
 252 *)
 253   AC_MSG_ERROR([invalid assembly optimizations])
 254   ;;
 255 esac
 256
 257 if test x"$use_external_asm" = x"yes"; then
 258   AC_DEFINE(USE_EXTERNAL_ASM, 1, [Define this symbol if an external (non-inline) assembly implementation is used])
 259 fi
 260
 261
 262 # Select wide multiplication implementation
 263 case $set_widemul in
 264 int128)
 265   AC_DEFINE(USE_FORCE_WIDEMUL_INT128, 1, [Define this symbol to force the use of the (unsigned) __int128 based wide multiplication implementation])
 266   ;;
 267 int64)
 268   AC_DEFINE(USE_FORCE_WIDEMUL_INT64, 1, [Define this symbol to force the use of the (u)int64_t based wide multiplication implementation])
 269   ;;
 270 auto)
 271   ;;
 272 *)
 273   AC_MSG_ERROR([invalid wide multiplication implementation])
 274   ;;
 275 esac
 276
 277 # Set ecmult window size
 278 if test x"$req_ecmult_window" = x"auto"; then
 279   set_ecmult_window=15
 280 else
 281   set_ecmult_window=$req_ecmult_window
 282 fi
 283
 284 error_window_size=['window size for ecmult precomputation not an integer in range [2..24] or "auto"']
 285 case $set_ecmult_window in
 286 ''|*[[!0-9]]*)
 287   # no valid integer
 288   AC_MSG_ERROR($error_window_size)
 289   ;;
 290 *)
 291   if test "$set_ecmult_window" -lt 2 -o "$set_ecmult_window" -gt 24 ; then
 292     # not in range
 293     AC_MSG_ERROR($error_window_size)
 294   fi
 295   AC_DEFINE_UNQUOTED(ECMULT_WINDOW_SIZE, $set_ecmult_window, [Set window size for ecmult precomputation])
 296   ;;
 297 esac
 298
 299 # Set ecmult gen precision
 300 if test x"$req_ecmult_gen_precision" = x"auto"; then
 301   set_ecmult_gen_precision=4
 302 else
 303   set_ecmult_gen_precision=$req_ecmult_gen_precision
 304 fi
 305
 306 case $set_ecmult_gen_precision in
 307 2|4|8)
 308   AC_DEFINE_UNQUOTED(ECMULT_GEN_PREC_BITS, $set_ecmult_gen_precision, [Set ecmult gen precision bits])
 309   ;;
 310 *)
 311   AC_MSG_ERROR(['ecmult gen precision not 2, 4, 8 or "auto"'])
 312   ;;
 313 esac
 314
 315 if test x"$use_tests" = x"yes"; then
 316   SECP_OPENSSL_CHECK
 317   if test x"$enable_openssl_tests" != x"no" && test x"$has_openssl_ec" = x"yes"; then
 318       enable_openssl_tests=yes
 319       AC_DEFINE(ENABLE_OPENSSL_TESTS, 1, [Define this symbol if OpenSSL EC functions are available])
 320       SECP_TEST_INCLUDES="$SSL_CFLAGS $CRYPTO_CFLAGS $CRYPTO_CPPFLAGS"
 321       SECP_TEST_LIBS="$CRYPTO_LIBS"
 322
 323       case $host in
 324       *mingw*)
 325         SECP_TEST_LIBS="$SECP_TEST_LIBS -lgdi32"
 326         ;;
 327       esac
 328   else
 329     if test x"$enable_openssl_tests" = x"yes"; then
 330       AC_MSG_ERROR([OpenSSL tests requested but OpenSSL with EC support is not available])
 331     fi
 332     enable_openssl_tests=no
 333   fi
 334 else
 335   if test x"$enable_openssl_tests" = x"yes"; then
 336     AC_MSG_ERROR([OpenSSL tests requested but tests are not enabled])
 337   fi
 338   enable_openssl_tests=no
 339 fi
 340
 341 if test x"$enable_valgrind" = x"yes"; then
 342   SECP_INCLUDES="$SECP_INCLUDES $VALGRIND_CPPFLAGS"
 343 fi
 344
 345 # Handle static precomputation (after everything which modifies CFLAGS and friends)
 346 if test x"$use_ecmult_static_precomputation" != x"no"; then
 347   if test x"$cross_compiling" = x"no"; then
 348     set_precomp=yes
 349     if test x"${CC_FOR_BUILD+x}${CFLAGS_FOR_BUILD+x}${CPPFLAGS_FOR_BUILD+x}${LDFLAGS_FOR_BUILD+x}" != x; then
 350       AC_MSG_WARN([CC_FOR_BUILD, CFLAGS_FOR_BUILD, CPPFLAGS_FOR_BUILD, and/or LDFLAGS_FOR_BUILD is set but ignored because we are not cross-compiling.])
 351     fi
 352     # If we're not cross-compiling, simply use the same compiler for building the static precompation code.
 353     CC_FOR_BUILD="$CC"
 354     CFLAGS_FOR_BUILD="$CFLAGS"
 355     CPPFLAGS_FOR_BUILD="$CPPFLAGS"
 356     LDFLAGS_FOR_BUILD="$LDFLAGS"
 357   else
 358     AX_PROG_CC_FOR_BUILD
 359
 360     # Temporarily switch to an environment for the native compiler
 361     save_cross_compiling=$cross_compiling
 362     cross_compiling=no
 363     SAVE_CC="$CC"
 364     CC="$CC_FOR_BUILD"
 365     SAVE_CFLAGS="$CFLAGS"
 366     CFLAGS="$CFLAGS_FOR_BUILD"
 367     SAVE_CPPFLAGS="$CPPFLAGS"
 368     CPPFLAGS="$CPPFLAGS_FOR_BUILD"
 369     SAVE_LDFLAGS="$LDFLAGS"
 370     LDFLAGS="$LDFLAGS_FOR_BUILD"
 371
 372     warn_CFLAGS_FOR_BUILD="-Wall -Wextra -Wno-unused-function"
 373     saved_CFLAGS="$CFLAGS"
 374     CFLAGS="$warn_CFLAGS_FOR_BUILD $CFLAGS"
 375     AC_MSG_CHECKING([if native ${CC_FOR_BUILD} supports ${warn_CFLAGS_FOR_BUILD}])
 376     AC_COMPILE_IFELSE([AC_LANG_SOURCE([[char foo;]])],
 377         [ AC_MSG_RESULT([yes]) ],
 378         [ AC_MSG_RESULT([no])
 379           CFLAGS="$saved_CFLAGS"
 380         ])
 381
 382     AC_MSG_CHECKING([for working native compiler: ${CC_FOR_BUILD}])
 383     AC_RUN_IFELSE(
 384       [AC_LANG_PROGRAM([], [])],
 385       [working_native_cc=yes],
 386       [working_native_cc=no],[:])
 387
 388     CFLAGS_FOR_BUILD="$CFLAGS"
 389
 390     # Restore the environment
 391     cross_compiling=$save_cross_compiling
 392     CC="$SAVE_CC"
 393     CFLAGS="$SAVE_CFLAGS"
 394     CPPFLAGS="$SAVE_CPPFLAGS"
 395     LDFLAGS="$SAVE_LDFLAGS"
 396
 397     if test x"$working_native_cc" = x"no"; then
 398       AC_MSG_RESULT([no])
 399       set_precomp=no
 400       m4_define([please_set_for_build], [Please set CC_FOR_BUILD, CFLAGS_FOR_BUILD, CPPFLAGS_FOR_BUILD, and/or LDFLAGS_FOR_BUILD.])
 401       if test x"$use_ecmult_static_precomputation" = x"yes";  then
 402         AC_MSG_ERROR([native compiler ${CC_FOR_BUILD} does not produce working binaries. please_set_for_build])
 403       else
 404         AC_MSG_WARN([Disabling statically generated ecmult table because the native compiler ${CC_FOR_BUILD} does not produce working binaries. please_set_for_build])
 405       fi
 406     else
 407       AC_MSG_RESULT([yes])
 408       set_precomp=yes
 409     fi
 410   fi
 411
 412   AC_SUBST(CC_FOR_BUILD)
 413   AC_SUBST(CFLAGS_FOR_BUILD)
 414   AC_SUBST(CPPFLAGS_FOR_BUILD)
 415   AC_SUBST(LDFLAGS_FOR_BUILD)
 416 else
 417   set_precomp=no
 418 fi
 419
 420 if test x"$set_precomp" = x"yes"; then
 421   AC_DEFINE(USE_ECMULT_STATIC_PRECOMPUTATION, 1, [Define this symbol to use a statically generated ecmult table])
 422 fi
 423
 424 ###
 425 ### Handle module options
 426 ###
 427
 428 if test x"$enable_module_ecdh" = x"yes"; then
 429   AC_DEFINE(ENABLE_MODULE_ECDH, 1, [Define this symbol to enable the ECDH module])
 430 fi
 431
 432 if test x"$enable_module_recovery" = x"yes"; then
 433   AC_DEFINE(ENABLE_MODULE_RECOVERY, 1, [Define this symbol to enable the ECDSA pubkey recovery module])
 434 fi
 435
 436 if test x"$enable_module_schnorrsig" = x"yes"; then
 437   AC_DEFINE(ENABLE_MODULE_SCHNORRSIG, 1, [Define this symbol to enable the schnorrsig module])
 438   enable_module_extrakeys=yes
 439 fi
 440
 441 # Test if extrakeys is set after the schnorrsig module to allow the schnorrsig
 442 # module to set enable_module_extrakeys=yes
 443 if test x"$enable_module_extrakeys" = x"yes"; then
 444   AC_DEFINE(ENABLE_MODULE_EXTRAKEYS, 1, [Define this symbol to enable the extrakeys module])
 445 fi
 446
 447 if test x"$use_external_default_callbacks" = x"yes"; then
 448   AC_DEFINE(USE_EXTERNAL_DEFAULT_CALLBACKS, 1, [Define this symbol if an external implementation of the default callbacks is used])
 449 fi
 450
 451 ###
 452 ### Check for --enable-experimental if necessary
 453 ###
 454
 455 if test x"$enable_experimental" = x"yes"; then
 456   AC_MSG_NOTICE([******])
 457   AC_MSG_NOTICE([WARNING: experimental build])
 458   AC_MSG_NOTICE([Experimental features do not have stable APIs or properties, and may not be safe for production use.])
 459   AC_MSG_NOTICE([Building extrakeys module: $enable_module_extrakeys])
 460   AC_MSG_NOTICE([Building schnorrsig module: $enable_module_schnorrsig])
 461   AC_MSG_NOTICE([******])
 462 else
 463   if test x"$enable_module_extrakeys" = x"yes"; then
 464     AC_MSG_ERROR([extrakeys module is experimental. Use --enable-experimental to allow.])
 465   fi
 466   if test x"$enable_module_schnorrsig" = x"yes"; then
 467     AC_MSG_ERROR([schnorrsig module is experimental. Use --enable-experimental to allow.])
 468   fi
 469   if test x"$set_asm" = x"arm"; then
 470     AC_MSG_ERROR([ARM assembly optimization is experimental. Use --enable-experimental to allow.])
 471   fi
 472 fi
 473
 474 ###
 475 ### Generate output
 476 ###
 477
 478 AC_CONFIG_HEADERS([src/libsecp256k1-config.h])
 479 AC_CONFIG_FILES([Makefile libsecp256k1.pc])
 480 AC_SUBST(SECP_INCLUDES)
 481 AC_SUBST(SECP_LIBS)
 482 AC_SUBST(SECP_TEST_LIBS)
 483 AC_SUBST(SECP_TEST_INCLUDES)
 484 AM_CONDITIONAL([ENABLE_COVERAGE], [test x"$enable_coverage" = x"yes"])
 485 AM_CONDITIONAL([USE_TESTS], [test x"$use_tests" != x"no"])
 486 AM_CONDITIONAL([USE_EXHAUSTIVE_TESTS], [test x"$use_exhaustive_tests" != x"no"])
 487 AM_CONDITIONAL([USE_BENCHMARK], [test x"$use_benchmark" = x"yes"])
 488 AM_CONDITIONAL([USE_ECMULT_STATIC_PRECOMPUTATION], [test x"$set_precomp" = x"yes"])
 489 AM_CONDITIONAL([ENABLE_MODULE_ECDH], [test x"$enable_module_ecdh" = x"yes"])
 490 AM_CONDITIONAL([ENABLE_MODULE_RECOVERY], [test x"$enable_module_recovery" = x"yes"])
 491 AM_CONDITIONAL([ENABLE_MODULE_EXTRAKEYS], [test x"$enable_module_extrakeys" = x"yes"])
 492 AM_CONDITIONAL([ENABLE_MODULE_SCHNORRSIG], [test x"$enable_module_schnorrsig" = x"yes"])
 493 AM_CONDITIONAL([USE_EXTERNAL_ASM], [test x"$use_external_asm" = x"yes"])
 494 AM_CONDITIONAL([USE_ASM_ARM], [test x"$set_asm" = x"arm"])
 495
 496 # Make sure nothing new is exported so that we don't break the cache.
 497 PKGCONFIG_PATH_TEMP="$PKG_CONFIG_PATH"
 498 unset PKG_CONFIG_PATH
 499 PKG_CONFIG_PATH="$PKGCONFIG_PATH_TEMP"
 500
 501 AC_OUTPUT
 502
 503 echo
 504 echo "Build Options:"
 505 echo "  with ecmult precomp     = $set_precomp"
 506 echo "  with external callbacks = $use_external_default_callbacks"
 507 echo "  with benchmarks         = $use_benchmark"
 508 echo "  with tests              = $use_tests"
 509 echo "  with openssl tests      = $enable_openssl_tests"
 510 echo "  with coverage           = $enable_coverage"
 511 echo "  module ecdh             = $enable_module_ecdh"
 512 echo "  module recovery         = $enable_module_recovery"
 513 echo "  module extrakeys        = $enable_module_extrakeys"
 514 echo "  module schnorrsig       = $enable_module_schnorrsig"
 515 echo
 516 echo "  asm                     = $set_asm"
 517 echo "  ecmult window size      = $set_ecmult_window"
 518 echo "  ecmult gen prec. bits   = $set_ecmult_gen_precision"
 519 # Hide test-only options unless they're used.
 520 if test x"$set_widemul" != xauto; then
 521 echo "  wide multiplication     = $set_widemul"
 522 fi
 523 echo
 524 echo "  valgrind                = $enable_valgrind"
 525 echo "  CC                      = $CC"
 526 echo "  CFLAGS                  = $CFLAGS"
 527 echo "  CPPFLAGS                = $CPPFLAGS"
 528 echo "  LDFLAGS                 = $LDFLAGS"
 529 echo
 530 if test x"$set_precomp" = x"yes"; then
 531 echo "  CC_FOR_BUILD            = $CC_FOR_BUILD"
 532 echo "  CFLAGS_FOR_BUILD        = $CFLAGS_FOR_BUILD"
 533 echo "  CPPFLAGS_FOR_BUILD      = $CPPFLAGS_FOR_BUILD"
 534 echo "  LDFLAGS_FOR_BUILD       = $LDFLAGS_FOR_BUILD"
 535 fi