configure.ac

   1 AC_PREREQ([2.60])
   2 AC_INIT([libsecp256k1],[0.1])
   3 AC_CONFIG_AUX_DIR([build-aux])
   4 AC_CONFIG_MACRO_DIR([build-aux/m4])
   5 AC_CANONICAL_HOST
   6 AH_TOP([#ifndef LIBSECP256K1_CONFIG_H])
   7 AH_TOP([#define LIBSECP256K1_CONFIG_H])
   8 AH_BOTTOM([#endif /*LIBSECP256K1_CONFIG_H*/])
   9 AM_INIT_AUTOMAKE([foreign subdir-objects])
  10
  11 # Set -g if CFLAGS are not already set, which matches the default autoconf
  12 # behavior (see PROG_CC in the Autoconf manual) with the exception that we don't
  13 # set -O2 here because we set it in any case (see further down).
  14 : ${CFLAGS="-g"}
  15 LT_INIT
  16
  17 # Make the compilation flags quiet unless V=1 is used.
  18 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  19
  20 PKG_PROG_PKG_CONFIG
  21
  22 AC_PATH_TOOL(AR, ar)
  23 AC_PATH_TOOL(RANLIB, ranlib)
  24 AC_PATH_TOOL(STRIP, strip)
  25
  26 AM_PROG_CC_C_O
  27
  28 AC_PROG_CC_C89
  29 if test x"$ac_cv_prog_cc_c89" = x"no"; then
  30   AC_MSG_ERROR([c89 compiler support required])
  31 fi
  32 AM_PROG_AS
  33
  34 case $host_os in
  35   *darwin*)
  36      if  test x$cross_compiling != xyes; then
  37        AC_PATH_PROG([BREW],brew,)
  38        if test x$BREW != x; then
  39          # These Homebrew packages may be keg-only, meaning that they won't be found
  40          # in expected paths because they may conflict with system files. Ask
  41          # Homebrew where each one is located, then adjust paths accordingly.
  42          openssl_prefix=`$BREW --prefix openssl 2>/dev/null`
  43          gmp_prefix=`$BREW --prefix gmp 2>/dev/null`
  44          valgrind_prefix=`$BREW --prefix valgrind 2>/dev/null`
  45          if test x$openssl_prefix != x; then
  46            PKG_CONFIG_PATH="$openssl_prefix/lib/pkgconfig:$PKG_CONFIG_PATH"
  47            export PKG_CONFIG_PATH
  48            CRYPTO_CPPFLAGS="-I$openssl_prefix/include"
  49          fi
  50          if test x$gmp_prefix != x; then
  51            GMP_CPPFLAGS="-I$gmp_prefix/include"
  52            GMP_LIBS="-L$gmp_prefix/lib"
  53          fi
  54          if test x$valgrind_prefix != x; then
  55            VALGRIND_CPPFLAGS="-I$valgrind_prefix/include"
  56          fi
  57        else
  58          AC_PATH_PROG([PORT],port,)
  59          # If homebrew isn't installed and macports is, add the macports default paths
  60          # as a last resort.
  61          if test x$PORT != x; then
  62            CPPFLAGS="$CPPFLAGS -isystem /opt/local/include"
  63            LDFLAGS="$LDFLAGS -L/opt/local/lib"
  64          fi
  65        fi
  66      fi
  67    ;;
  68 esac
  69
  70 CFLAGS="-W $CFLAGS"
  71
  72 warn_CFLAGS="-std=c89 -pedantic -Wall -Wextra -Wcast-align -Wnested-externs -Wshadow -Wstrict-prototypes -Wundef -Wno-unused-function -Wno-long-long -Wno-overlength-strings"
  73 saved_CFLAGS="$CFLAGS"
  74 CFLAGS="$warn_CFLAGS $CFLAGS"
  75 AC_MSG_CHECKING([if ${CC} supports ${warn_CFLAGS}])
  76 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[char foo;]])],
  77     [ AC_MSG_RESULT([yes]) ],
  78     [ AC_MSG_RESULT([no])
  79       CFLAGS="$saved_CFLAGS"
  80     ])
  81
  82 saved_CFLAGS="$CFLAGS"
  83 CFLAGS="-Wconditional-uninitialized $CFLAGS"
  84 AC_MSG_CHECKING([if ${CC} supports -Wconditional-uninitialized])
  85 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[char foo;]])],
  86     [ AC_MSG_RESULT([yes]) ],
  87     [ AC_MSG_RESULT([no])
  88       CFLAGS="$saved_CFLAGS"
  89     ])
  90
  91 saved_CFLAGS="$CFLAGS"
  92 CFLAGS="-fvisibility=hidden $CFLAGS"
  93 AC_MSG_CHECKING([if ${CC} supports -fvisibility=hidden])
  94 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[char foo;]])],
  95     [ AC_MSG_RESULT([yes]) ],
  96     [ AC_MSG_RESULT([no])
  97       CFLAGS="$saved_CFLAGS"
  98     ])
  99
 100 ###
 101 ### Define config arguments
 102 ###
 103
 104 AC_ARG_ENABLE(benchmark,
 105     AS_HELP_STRING([--enable-benchmark],[compile benchmark [default=yes]]),
 106     [use_benchmark=$enableval],
 107     [use_benchmark=yes])
 108
 109 AC_ARG_ENABLE(coverage,
 110     AS_HELP_STRING([--enable-coverage],[enable compiler flags to support kcov coverage analysis [default=no]]),
 111     [enable_coverage=$enableval],
 112     [enable_coverage=no])
 113
 114 AC_ARG_ENABLE(tests,
 115     AS_HELP_STRING([--enable-tests],[compile tests [default=yes]]),
 116     [use_tests=$enableval],
 117     [use_tests=yes])
 118
 119 AC_ARG_ENABLE(openssl_tests,
 120     AS_HELP_STRING([--enable-openssl-tests],[enable OpenSSL tests [default=auto]]),
 121     [enable_openssl_tests=$enableval],
 122     [enable_openssl_tests=auto])
 123
 124 AC_ARG_ENABLE(experimental,
 125     AS_HELP_STRING([--enable-experimental],[allow experimental configure options [default=no]]),
 126     [use_experimental=$enableval],
 127     [use_experimental=no])
 128
 129 AC_ARG_ENABLE(exhaustive_tests,
 130     AS_HELP_STRING([--enable-exhaustive-tests],[compile exhaustive tests [default=yes]]),
 131     [use_exhaustive_tests=$enableval],
 132     [use_exhaustive_tests=yes])
 133
 134 AC_ARG_ENABLE(ecmult_static_precomputation,
 135     AS_HELP_STRING([--enable-ecmult-static-precomputation],[enable precomputed ecmult table for signing [default=auto]]),
 136     [use_ecmult_static_precomputation=$enableval],
 137     [use_ecmult_static_precomputation=auto])
 138
 139 AC_ARG_ENABLE(module_ecdh,
 140     AS_HELP_STRING([--enable-module-ecdh],[enable ECDH shared secret computation]),
 141     [enable_module_ecdh=$enableval],
 142     [enable_module_ecdh=no])
 143
 144 AC_ARG_ENABLE(module_recovery,
 145     AS_HELP_STRING([--enable-module-recovery],[enable ECDSA pubkey recovery module [default=no]]),
 146     [enable_module_recovery=$enableval],
 147     [enable_module_recovery=no])
 148
 149 AC_ARG_ENABLE(module_extrakeys,
 150     AS_HELP_STRING([--enable-module-extrakeys],[enable extrakeys module (experimental)]),
 151     [enable_module_extrakeys=$enableval],
 152     [enable_module_extrakeys=no])
 153
 154 AC_ARG_ENABLE(module_schnorrsig,
 155     AS_HELP_STRING([--enable-module-schnorrsig],[enable schnorrsig module (experimental)]),
 156     [enable_module_schnorrsig=$enableval],
 157     [enable_module_schnorrsig=no])
 158
 159 AC_ARG_ENABLE(external_default_callbacks,
 160     AS_HELP_STRING([--enable-external-default-callbacks],[enable external default callback functions [default=no]]),
 161     [use_external_default_callbacks=$enableval],
 162     [use_external_default_callbacks=no])
 163
 164 # Test-only override of the (autodetected by the C code) "widemul" setting.
 165 # Legal values are int64 (for [u]int64_t), int128 (for [unsigned] __int128), and auto (the default).
 166 AC_ARG_WITH([test-override-wide-multiply], [] ,[set_widemul=$withval], [set_widemul=auto])
 167
 168 AC_ARG_WITH([bignum], [AS_HELP_STRING([--with-bignum=gmp|no|auto],
 169 [bignum implementation to use [default=auto]])],[req_bignum=$withval], [req_bignum=auto])
 170
 171 AC_ARG_WITH([asm], [AS_HELP_STRING([--with-asm=x86_64|arm|no|auto],
 172 [assembly optimizations to use (experimental: arm) [default=auto]])],[req_asm=$withval], [req_asm=auto])
 173
 174 AC_ARG_WITH([ecmult-window], [AS_HELP_STRING([--with-ecmult-window=SIZE|auto],
 175 [window size for ecmult precomputation for verification, specified as integer in range [2..24].]
 176 [Larger values result in possibly better performance at the cost of an exponentially larger precomputed table.]
 177 [The table will store 2^(SIZE-1) * 64 bytes of data but can be larger in memory due to platform-specific padding and alignment.]
 178 ["auto" is a reasonable setting for desktop machines (currently 15). [default=auto]]
 179 )],
 180 [req_ecmult_window=$withval], [req_ecmult_window=auto])
 181
 182 AC_ARG_WITH([ecmult-gen-precision], [AS_HELP_STRING([--with-ecmult-gen-precision=2|4|8|auto],
 183 [Precision bits to tune the precomputed table size for signing.]
 184 [The size of the table is 32kB for 2 bits, 64kB for 4 bits, 512kB for 8 bits of precision.]
 185 [A larger table size usually results in possible faster signing.]
 186 ["auto" is a reasonable setting for desktop machines (currently 4). [default=auto]]
 187 )],
 188 [req_ecmult_gen_precision=$withval], [req_ecmult_gen_precision=auto])
 189
 190 AC_ARG_WITH([valgrind], [AS_HELP_STRING([--with-valgrind=yes|no|auto],
 191 [Build with extra checks for running inside Valgrind [default=auto]]
 192 )],
 193 [req_valgrind=$withval], [req_valgrind=auto])
 194
 195 ###
 196 ### Handle config options (except for modules)
 197 ###
 198
 199 if test x"$req_valgrind" = x"no"; then
 200   enable_valgrind=no
 201 else
 202   SECP_VALGRIND_CHECK
 203   if test x"$has_valgrind" != x"yes"; then
 204     if test x"$req_valgrind" = x"yes"; then
 205       AC_MSG_ERROR([Valgrind support explicitly requested but valgrind/memcheck.h header not available])
 206     fi
 207     enable_valgrind=no
 208   else
 209     enable_valgrind=yes
 210   fi
 211 fi
 212 AM_CONDITIONAL([VALGRIND_ENABLED],[test "$enable_valgrind" = "yes"])
 213
 214 if test x"$enable_coverage" = x"yes"; then
 215     AC_DEFINE(COVERAGE, 1, [Define this symbol to compile out all VERIFY code])
 216     CFLAGS="-O0 --coverage $CFLAGS"
 217     LDFLAGS="--coverage $LDFLAGS"
 218 else
 219     CFLAGS="-O2 $CFLAGS"
 220 fi
 221
 222 if test x"$req_asm" = x"auto"; then
 223   SECP_64BIT_ASM_CHECK
 224   if test x"$has_64bit_asm" = x"yes"; then
 225     set_asm=x86_64
 226   fi
 227   if test x"$set_asm" = x; then
 228     set_asm=no
 229   fi
 230 else
 231   set_asm=$req_asm
 232   case $set_asm in
 233   x86_64)
 234     SECP_64BIT_ASM_CHECK
 235     if test x"$has_64bit_asm" != x"yes"; then
 236       AC_MSG_ERROR([x86_64 assembly optimization requested but not available])
 237     fi
 238     ;;
 239   arm)
 240     ;;
 241   no)
 242     ;;
 243   *)
 244     AC_MSG_ERROR([invalid assembly optimization selection])
 245     ;;
 246   esac
 247 fi
 248
 249 if test x"$req_bignum" = x"auto"; then
 250   SECP_GMP_CHECK
 251   if test x"$has_gmp" = x"yes"; then
 252     set_bignum=gmp
 253   fi
 254
 255   if test x"$set_bignum" = x; then
 256     set_bignum=no
 257   fi
 258 else
 259   set_bignum=$req_bignum
 260   case $set_bignum in
 261   gmp)
 262     SECP_GMP_CHECK
 263     if test x"$has_gmp" != x"yes"; then
 264       AC_MSG_ERROR([gmp bignum explicitly requested but libgmp not available])
 265     fi
 266     ;;
 267   no)
 268     ;;
 269   *)
 270     AC_MSG_ERROR([invalid bignum implementation selection])
 271     ;;
 272   esac
 273 fi
 274
 275 # Select assembly optimization
 276 use_external_asm=no
 277
 278 case $set_asm in
 279 x86_64)
 280   AC_DEFINE(USE_ASM_X86_64, 1, [Define this symbol to enable x86_64 assembly optimizations])
 281   ;;
 282 arm)
 283   use_external_asm=yes
 284   ;;
 285 no)
 286   ;;
 287 *)
 288   AC_MSG_ERROR([invalid assembly optimizations])
 289   ;;
 290 esac
 291
 292 if test x"$use_external_asm" = x"yes"; then
 293   AC_DEFINE(USE_EXTERNAL_ASM, 1, [Define this symbol if an external (non-inline) assembly implementation is used])
 294 fi
 295
 296
 297 # Select wide multiplication implementation
 298 case $set_widemul in
 299 int128)
 300   AC_DEFINE(USE_FORCE_WIDEMUL_INT128, 1, [Define this symbol to force the use of the (unsigned) __int128 based wide multiplication implementation])
 301   ;;
 302 int64)
 303   AC_DEFINE(USE_FORCE_WIDEMUL_INT64, 1, [Define this symbol to force the use of the (u)int64_t based wide multiplication implementation])
 304   ;;
 305 auto)
 306   ;;
 307 *)
 308   AC_MSG_ERROR([invalid wide multiplication implementation])
 309   ;;
 310 esac
 311
 312 # Select bignum implementation
 313 case $set_bignum in
 314 gmp)
 315   AC_DEFINE(HAVE_LIBGMP, 1, [Define this symbol if libgmp is installed])
 316   AC_DEFINE(USE_NUM_GMP, 1, [Define this symbol to use the gmp implementation for num])
 317   AC_DEFINE(USE_FIELD_INV_NUM, 1, [Define this symbol to use the num-based field inverse implementation])
 318   AC_DEFINE(USE_SCALAR_INV_NUM, 1, [Define this symbol to use the num-based scalar inverse implementation])
 319   ;;
 320 no)
 321   AC_DEFINE(USE_NUM_NONE, 1, [Define this symbol to use no num implementation])
 322   AC_DEFINE(USE_FIELD_INV_BUILTIN, 1, [Define this symbol to use the native field inverse implementation])
 323   AC_DEFINE(USE_SCALAR_INV_BUILTIN, 1, [Define this symbol to use the native scalar inverse implementation])
 324   ;;
 325 *)
 326   AC_MSG_ERROR([invalid bignum implementation])
 327   ;;
 328 esac
 329
 330 # Set ecmult window size
 331 if test x"$req_ecmult_window" = x"auto"; then
 332   set_ecmult_window=15
 333 else
 334   set_ecmult_window=$req_ecmult_window
 335 fi
 336
 337 error_window_size=['window size for ecmult precomputation not an integer in range [2..24] or "auto"']
 338 case $set_ecmult_window in
 339 ''|*[[!0-9]]*)
 340   # no valid integer
 341   AC_MSG_ERROR($error_window_size)
 342   ;;
 343 *)
 344   if test "$set_ecmult_window" -lt 2 -o "$set_ecmult_window" -gt 24 ; then
 345     # not in range
 346     AC_MSG_ERROR($error_window_size)
 347   fi
 348   AC_DEFINE_UNQUOTED(ECMULT_WINDOW_SIZE, $set_ecmult_window, [Set window size for ecmult precomputation])
 349   ;;
 350 esac
 351
 352 # Set ecmult gen precision
 353 if test x"$req_ecmult_gen_precision" = x"auto"; then
 354   set_ecmult_gen_precision=4
 355 else
 356   set_ecmult_gen_precision=$req_ecmult_gen_precision
 357 fi
 358
 359 case $set_ecmult_gen_precision in
 360 2|4|8)
 361   AC_DEFINE_UNQUOTED(ECMULT_GEN_PREC_BITS, $set_ecmult_gen_precision, [Set ecmult gen precision bits])
 362   ;;
 363 *)
 364   AC_MSG_ERROR(['ecmult gen precision not 2, 4, 8 or "auto"'])
 365   ;;
 366 esac
 367
 368 if test x"$use_tests" = x"yes"; then
 369   SECP_OPENSSL_CHECK
 370   if test x"$enable_openssl_tests" != x"no" && test x"$has_openssl_ec" = x"yes"; then
 371       enable_openssl_tests=yes
 372       AC_DEFINE(ENABLE_OPENSSL_TESTS, 1, [Define this symbol if OpenSSL EC functions are available])
 373       SECP_TEST_INCLUDES="$SSL_CFLAGS $CRYPTO_CFLAGS $CRYPTO_CPPFLAGS"
 374       SECP_TEST_LIBS="$CRYPTO_LIBS"
 375
 376       case $host in
 377       *mingw*)
 378         SECP_TEST_LIBS="$SECP_TEST_LIBS -lgdi32"
 379         ;;
 380       esac
 381   else
 382     if test x"$enable_openssl_tests" = x"yes"; then
 383       AC_MSG_ERROR([OpenSSL tests requested but OpenSSL with EC support is not available])
 384     fi
 385     enable_openssl_tests=no
 386   fi
 387 else
 388   if test x"$enable_openssl_tests" = x"yes"; then
 389     AC_MSG_ERROR([OpenSSL tests requested but tests are not enabled])
 390   fi
 391   enable_openssl_tests=no
 392 fi
 393
 394 if test x"$set_bignum" = x"gmp"; then
 395   SECP_LIBS="$SECP_LIBS $GMP_LIBS"
 396   SECP_INCLUDES="$SECP_INCLUDES $GMP_CPPFLAGS"
 397 fi
 398
 399 if test x"$enable_valgrind" = x"yes"; then
 400   SECP_INCLUDES="$SECP_INCLUDES $VALGRIND_CPPFLAGS"
 401 fi
 402
 403 # Handle static precomputation (after everything which modifies CFLAGS and friends)
 404 if test x"$use_ecmult_static_precomputation" != x"no"; then
 405   if test x"$cross_compiling" = x"no"; then
 406     set_precomp=yes
 407     if test x"${CC_FOR_BUILD+x}${CFLAGS_FOR_BUILD+x}${CPPFLAGS_FOR_BUILD+x}${LDFLAGS_FOR_BUILD+x}" != x; then
 408       AC_MSG_WARN([CC_FOR_BUILD, CFLAGS_FOR_BUILD, CPPFLAGS_FOR_BUILD, and/or LDFLAGS_FOR_BUILD is set but ignored because we are not cross-compiling.])
 409     fi
 410     # If we're not cross-compiling, simply use the same compiler for building the static precompation code.
 411     CC_FOR_BUILD="$CC"
 412     CFLAGS_FOR_BUILD="$CFLAGS"
 413     CPPFLAGS_FOR_BUILD="$CPPFLAGS"
 414     LDFLAGS_FOR_BUILD="$LDFLAGS"
 415   else
 416     AX_PROG_CC_FOR_BUILD
 417
 418     # Temporarily switch to an environment for the native compiler
 419     save_cross_compiling=$cross_compiling
 420     cross_compiling=no
 421     SAVE_CC="$CC"
 422     CC="$CC_FOR_BUILD"
 423     SAVE_CFLAGS="$CFLAGS"
 424     CFLAGS="$CFLAGS_FOR_BUILD"
 425     SAVE_CPPFLAGS="$CPPFLAGS"
 426     CPPFLAGS="$CPPFLAGS_FOR_BUILD"
 427     SAVE_LDFLAGS="$LDFLAGS"
 428     LDFLAGS="$LDFLAGS_FOR_BUILD"
 429
 430     warn_CFLAGS_FOR_BUILD="-Wall -Wextra -Wno-unused-function"
 431     saved_CFLAGS="$CFLAGS"
 432     CFLAGS="$warn_CFLAGS_FOR_BUILD $CFLAGS"
 433     AC_MSG_CHECKING([if native ${CC_FOR_BUILD} supports ${warn_CFLAGS_FOR_BUILD}])
 434     AC_COMPILE_IFELSE([AC_LANG_SOURCE([[char foo;]])],
 435         [ AC_MSG_RESULT([yes]) ],
 436         [ AC_MSG_RESULT([no])
 437           CFLAGS="$saved_CFLAGS"
 438         ])
 439
 440     AC_MSG_CHECKING([for working native compiler: ${CC_FOR_BUILD}])
 441     AC_RUN_IFELSE(
 442       [AC_LANG_PROGRAM([], [])],
 443       [working_native_cc=yes],
 444       [working_native_cc=no],[:])
 445
 446     CFLAGS_FOR_BUILD="$CFLAGS"
 447
 448     # Restore the environment
 449     cross_compiling=$save_cross_compiling
 450     CC="$SAVE_CC"
 451     CFLAGS="$SAVE_CFLAGS"
 452     CPPFLAGS="$SAVE_CPPFLAGS"
 453     LDFLAGS="$SAVE_LDFLAGS"
 454
 455     if test x"$working_native_cc" = x"no"; then
 456       AC_MSG_RESULT([no])
 457       set_precomp=no
 458       m4_define([please_set_for_build], [Please set CC_FOR_BUILD, CFLAGS_FOR_BUILD, CPPFLAGS_FOR_BUILD, and/or LDFLAGS_FOR_BUILD.])
 459       if test x"$use_ecmult_static_precomputation" = x"yes";  then
 460         AC_MSG_ERROR([native compiler ${CC_FOR_BUILD} does not produce working binaries. please_set_for_build])
 461       else
 462         AC_MSG_WARN([Disabling statically generated ecmult table because the native compiler ${CC_FOR_BUILD} does not produce working binaries. please_set_for_build])
 463       fi
 464     else
 465       AC_MSG_RESULT([yes])
 466       set_precomp=yes
 467     fi
 468   fi
 469
 470   AC_SUBST(CC_FOR_BUILD)
 471   AC_SUBST(CFLAGS_FOR_BUILD)
 472   AC_SUBST(CPPFLAGS_FOR_BUILD)
 473   AC_SUBST(LDFLAGS_FOR_BUILD)
 474 else
 475   set_precomp=no
 476 fi
 477
 478 if test x"$set_precomp" = x"yes"; then
 479   AC_DEFINE(USE_ECMULT_STATIC_PRECOMPUTATION, 1, [Define this symbol to use a statically generated ecmult table])
 480 fi
 481
 482 ###
 483 ### Handle module options
 484 ###
 485
 486 if test x"$enable_module_ecdh" = x"yes"; then
 487   AC_DEFINE(ENABLE_MODULE_ECDH, 1, [Define this symbol to enable the ECDH module])
 488 fi
 489
 490 if test x"$enable_module_recovery" = x"yes"; then
 491   AC_DEFINE(ENABLE_MODULE_RECOVERY, 1, [Define this symbol to enable the ECDSA pubkey recovery module])
 492 fi
 493
 494 if test x"$enable_module_schnorrsig" = x"yes"; then
 495   AC_DEFINE(ENABLE_MODULE_SCHNORRSIG, 1, [Define this symbol to enable the schnorrsig module])
 496   enable_module_extrakeys=yes
 497 fi
 498
 499 # Test if extrakeys is set after the schnorrsig module to allow the schnorrsig
 500 # module to set enable_module_extrakeys=yes
 501 if test x"$enable_module_extrakeys" = x"yes"; then
 502   AC_DEFINE(ENABLE_MODULE_EXTRAKEYS, 1, [Define this symbol to enable the extrakeys module])
 503 fi
 504
 505 if test x"$use_external_default_callbacks" = x"yes"; then
 506   AC_DEFINE(USE_EXTERNAL_DEFAULT_CALLBACKS, 1, [Define this symbol if an external implementation of the default callbacks is used])
 507 fi
 508
 509 ###
 510 ### Check for --enable-experimental if necessary
 511 ###
 512
 513 if test x"$enable_experimental" = x"yes"; then
 514   AC_MSG_NOTICE([******])
 515   AC_MSG_NOTICE([WARNING: experimental build])
 516   AC_MSG_NOTICE([Experimental features do not have stable APIs or properties, and may not be safe for production use.])
 517   AC_MSG_NOTICE([Building extrakeys module: $enable_module_extrakeys])
 518   AC_MSG_NOTICE([Building schnorrsig module: $enable_module_schnorrsig])
 519   AC_MSG_NOTICE([******])
 520 else
 521   if test x"$enable_module_extrakeys" = x"yes"; then
 522     AC_MSG_ERROR([extrakeys module is experimental. Use --enable-experimental to allow.])
 523   fi
 524   if test x"$enable_module_schnorrsig" = x"yes"; then
 525     AC_MSG_ERROR([schnorrsig module is experimental. Use --enable-experimental to allow.])
 526   fi
 527   if test x"$set_asm" = x"arm"; then
 528     AC_MSG_ERROR([ARM assembly optimization is experimental. Use --enable-experimental to allow.])
 529   fi
 530 fi
 531
 532 ###
 533 ### Generate output
 534 ###
 535
 536 AC_CONFIG_HEADERS([src/libsecp256k1-config.h])
 537 AC_CONFIG_FILES([Makefile libsecp256k1.pc])
 538 AC_SUBST(SECP_INCLUDES)
 539 AC_SUBST(SECP_LIBS)
 540 AC_SUBST(SECP_TEST_LIBS)
 541 AC_SUBST(SECP_TEST_INCLUDES)
 542 AM_CONDITIONAL([ENABLE_COVERAGE], [test x"$enable_coverage" = x"yes"])
 543 AM_CONDITIONAL([USE_TESTS], [test x"$use_tests" != x"no"])
 544 AM_CONDITIONAL([USE_EXHAUSTIVE_TESTS], [test x"$use_exhaustive_tests" != x"no"])
 545 AM_CONDITIONAL([USE_BENCHMARK], [test x"$use_benchmark" = x"yes"])
 546 AM_CONDITIONAL([USE_ECMULT_STATIC_PRECOMPUTATION], [test x"$set_precomp" = x"yes"])
 547 AM_CONDITIONAL([ENABLE_MODULE_ECDH], [test x"$enable_module_ecdh" = x"yes"])
 548 AM_CONDITIONAL([ENABLE_MODULE_RECOVERY], [test x"$enable_module_recovery" = x"yes"])
 549 AM_CONDITIONAL([ENABLE_MODULE_EXTRAKEYS], [test x"$enable_module_extrakeys" = x"yes"])
 550 AM_CONDITIONAL([ENABLE_MODULE_SCHNORRSIG], [test x"$enable_module_schnorrsig" = x"yes"])
 551 AM_CONDITIONAL([USE_EXTERNAL_ASM], [test x"$use_external_asm" = x"yes"])
 552 AM_CONDITIONAL([USE_ASM_ARM], [test x"$set_asm" = x"arm"])
 553
 554 # Make sure nothing new is exported so that we don't break the cache.
 555 PKGCONFIG_PATH_TEMP="$PKG_CONFIG_PATH"
 556 unset PKG_CONFIG_PATH
 557 PKG_CONFIG_PATH="$PKGCONFIG_PATH_TEMP"
 558
 559 AC_OUTPUT
 560
 561 echo
 562 echo "Build Options:"
 563 echo "  with ecmult precomp     = $set_precomp"
 564 echo "  with external callbacks = $use_external_default_callbacks"
 565 echo "  with benchmarks         = $use_benchmark"
 566 echo "  with tests              = $use_tests"
 567 echo "  with openssl tests      = $enable_openssl_tests"
 568 echo "  with coverage           = $enable_coverage"
 569 echo "  module ecdh             = $enable_module_ecdh"
 570 echo "  module recovery         = $enable_module_recovery"
 571 echo "  module extrakeys        = $enable_module_extrakeys"
 572 echo "  module schnorrsig       = $enable_module_schnorrsig"
 573 echo
 574 echo "  asm                     = $set_asm"
 575 echo "  bignum                  = $set_bignum"
 576 echo "  ecmult window size      = $set_ecmult_window"
 577 echo "  ecmult gen prec. bits   = $set_ecmult_gen_precision"
 578 # Hide test-only options unless they're used.
 579 if test x"$set_widemul" != xauto; then
 580 echo "  wide multiplication     = $set_widemul"
 581 fi
 582 echo
 583 echo "  valgrind                = $enable_valgrind"
 584 echo "  CC                      = $CC"
 585 echo "  CFLAGS                  = $CFLAGS"
 586 echo "  CPPFLAGS                = $CPPFLAGS"
 587 echo "  LDFLAGS                 = $LDFLAGS"
 588 echo
 589 if test x"$set_precomp" = x"yes"; then
 590 echo "  CC_FOR_BUILD            = $CC_FOR_BUILD"
 591 echo "  CFLAGS_FOR_BUILD        = $CFLAGS_FOR_BUILD"
 592 echo "  CPPFLAGS_FOR_BUILD      = $CPPFLAGS_FOR_BUILD"
 593 echo "  LDFLAGS_FOR_BUILD       = $LDFLAGS_FOR_BUILD"
 594 fi