configure.ac

   1 AC_PREREQ([2.60])
   2 AC_INIT([libsecp256k1],[0.1])
   3 AC_CONFIG_AUX_DIR([build-aux])
   4 AC_CONFIG_MACRO_DIR([build-aux/m4])
   5 AC_CANONICAL_HOST
   6 AH_TOP([#ifndef LIBSECP256K1_CONFIG_H])
   7 AH_TOP([#define LIBSECP256K1_CONFIG_H])
   8 AH_BOTTOM([#endif /*LIBSECP256K1_CONFIG_H*/])
   9 AM_INIT_AUTOMAKE([foreign subdir-objects])
  10
  11 # Set -g if CFLAGS are not already set, which matches the default autoconf
  12 # behavior (see PROG_CC in the Autoconf manual) with the exception that we don't
  13 # set -O2 here because we set it in any case (see further down).
  14 : ${CFLAGS="-g"}
  15 LT_INIT
  16
  17 # Make the compilation flags quiet unless V=1 is used.
  18 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  19
  20 PKG_PROG_PKG_CONFIG
  21
  22 AC_PATH_TOOL(AR, ar)
  23 AC_PATH_TOOL(RANLIB, ranlib)
  24 AC_PATH_TOOL(STRIP, strip)
  25
  26 # Save definition of AC_PROG_CC because AM_PROG_CC_C_O in automake<=1.13 will
  27 # redefine AC_PROG_CC to exit with an error, which avoids the user calling it
  28 # accidently and screwing up the effect of AM_PROG_CC_C_O. However, we'll need
  29 # AC_PROG_CC later on in AX_PROG_CC_FOR_BUILD, where its usage is fine, and
  30 # we'll carefully make sure not to call AC_PROG_CC anywhere else.
  31 m4_copy([AC_PROG_CC], [saved_AC_PROG_CC])
  32 AM_PROG_CC_C_O
  33 # Restore AC_PROG_CC
  34 m4_rename_force([saved_AC_PROG_CC], [AC_PROG_CC])
  35
  36 AC_PROG_CC_C89
  37 if test x"$ac_cv_prog_cc_c89" = x"no"; then
  38   AC_MSG_ERROR([c89 compiler support required])
  39 fi
  40 AM_PROG_AS
  41
  42 case $host_os in
  43   *darwin*)
  44      if  test x$cross_compiling != xyes; then
  45        AC_PATH_PROG([BREW],brew,)
  46        if test x$BREW != x; then
  47          # These Homebrew packages may be keg-only, meaning that they won't be found
  48          # in expected paths because they may conflict with system files. Ask
  49          # Homebrew where each one is located, then adjust paths accordingly.
  50          openssl_prefix=`$BREW --prefix openssl 2>/dev/null`
  51          valgrind_prefix=`$BREW --prefix valgrind 2>/dev/null`
  52          if test x$openssl_prefix != x; then
  53            PKG_CONFIG_PATH="$openssl_prefix/lib/pkgconfig:$PKG_CONFIG_PATH"
  54            export PKG_CONFIG_PATH
  55            CRYPTO_CPPFLAGS="-I$openssl_prefix/include"
  56          fi
  57          if test x$valgrind_prefix != x; then
  58            VALGRIND_CPPFLAGS="-I$valgrind_prefix/include"
  59          fi
  60        else
  61          AC_PATH_PROG([PORT],port,)
  62          # If homebrew isn't installed and macports is, add the macports default paths
  63          # as a last resort.
  64          if test x$PORT != x; then
  65            CPPFLAGS="$CPPFLAGS -isystem /opt/local/include"
  66            LDFLAGS="$LDFLAGS -L/opt/local/lib"
  67          fi
  68        fi
  69      fi
  70    ;;
  71 esac
  72
  73 # Try if some desirable compiler flags are supported and append them to SECP_CFLAGS.
  74 #
  75 # These are our own flags, so we append them to our own SECP_CFLAGS variable (instead of CFLAGS) as
  76 # recommended in the automake manual (Section "Flag Variables Ordering"). CFLAGS belongs to the user
  77 # and we are not supposed to touch it. In the Makefile, we will need to ensure that SECP_CFLAGS
  78 # is prepended to CFLAGS when invoking the compiler so that the user always has the last word (flag).
  79 #
  80 # Another advantage of not touching CFLAGS is that the contents of CFLAGS will be picked up by
  81 # libtool for compiling helper executables. For example, when compiling for Windows, libtool will
  82 # generate entire wrapper executables (instead of simple wrapper scripts as on Unix) to ensure
  83 # proper operation of uninstalled programs linked by libtool against the uninstalled shared library.
  84 # These executables are compiled from C source file for which our flags may not be appropriate,
  85 # e.g., -std=c89 flag has lead to undesirable warnings in the past.
  86 #
  87 # TODO We still touch the CFLAGS for --coverage and -O0/-O2.
  88 # TODO We should analogously not touch CPPFLAGS and LDFLAGS but currently there are no issues.
  89 AC_DEFUN([SECP_TRY_APPEND_DEFAULT_CFLAGS], [
  90     # Try to append -Werror=unknown-warning-option to CFLAGS temporarily. Otherwise clang will
  91     # not error out if it gets unknown warning flags and the checks here will always succeed
  92     # no matter if clang knows the flag or not.
  93     SECP_TRY_APPEND_DEFAULT_CFLAGS_saved_CFLAGS="$CFLAGS"
  94     SECP_TRY_APPEND_CFLAGS([-Werror=unknown-warning-option], CFLAGS)
  95
  96     SECP_TRY_APPEND_CFLAGS([-std=c89 -pedantic -Wno-long-long -Wnested-externs -Wshadow -Wstrict-prototypes -Wundef], $1) # GCC >= 3.0, -Wlong-long is implied by -pedantic.
  97     SECP_TRY_APPEND_CFLAGS([-Wno-overlength-strings], $1) # GCC >= 4.2, -Woverlength-strings is implied by -pedantic.
  98     SECP_TRY_APPEND_CFLAGS([-Wall], $1) # GCC >= 2.95 and probably many other compilers
  99     SECP_TRY_APPEND_CFLAGS([-Wno-unused-function], $1) # GCC >= 3.0, -Wunused-function is implied by -Wall.
 100     SECP_TRY_APPEND_CFLAGS([-Wextra], $1) # GCC >= 3.4, this is the newer name of -W, which we don't use because older GCCs will warn about unused functions.
 101     SECP_TRY_APPEND_CFLAGS([-Wcast-align], $1) # GCC >= 2.95
 102     SECP_TRY_APPEND_CFLAGS([-Wcast-align=strict], $1) # GCC >= 8.0
 103     SECP_TRY_APPEND_CFLAGS([-Wconditional-uninitialized], $1) # Clang >= 3.0 only
 104     SECP_TRY_APPEND_CFLAGS([-fvisibility=hidden], $1) # GCC >= 4.0
 105
 106     CFLAGS="$SECP_TRY_APPEND_DEFAULT_CFLAGS_saved_CFLAGS"
 107 ])
 108 SECP_TRY_APPEND_DEFAULT_CFLAGS(SECP_CFLAGS)
 109
 110 ###
 111 ### Define config arguments
 112 ###
 113
 114 AC_ARG_ENABLE(benchmark,
 115     AS_HELP_STRING([--enable-benchmark],[compile benchmark [default=yes]]),
 116     [use_benchmark=$enableval],
 117     [use_benchmark=yes])
 118
 119 AC_ARG_ENABLE(coverage,
 120     AS_HELP_STRING([--enable-coverage],[enable compiler flags to support kcov coverage analysis [default=no]]),
 121     [enable_coverage=$enableval],
 122     [enable_coverage=no])
 123
 124 AC_ARG_ENABLE(tests,
 125     AS_HELP_STRING([--enable-tests],[compile tests [default=yes]]),
 126     [use_tests=$enableval],
 127     [use_tests=yes])
 128
 129 AC_ARG_ENABLE(openssl_tests,
 130     AS_HELP_STRING([--enable-openssl-tests],[enable OpenSSL tests [default=auto]]),
 131     [enable_openssl_tests=$enableval],
 132     [enable_openssl_tests=auto])
 133
 134 AC_ARG_ENABLE(experimental,
 135     AS_HELP_STRING([--enable-experimental],[allow experimental configure options [default=no]]),
 136     [use_experimental=$enableval],
 137     [use_experimental=no])
 138
 139 AC_ARG_ENABLE(exhaustive_tests,
 140     AS_HELP_STRING([--enable-exhaustive-tests],[compile exhaustive tests [default=yes]]),
 141     [use_exhaustive_tests=$enableval],
 142     [use_exhaustive_tests=yes])
 143
 144 AC_ARG_ENABLE(ecmult_static_precomputation,
 145     AS_HELP_STRING([--enable-ecmult-static-precomputation],[enable precomputed ecmult table for signing [default=auto]]),
 146     [use_ecmult_static_precomputation=$enableval],
 147     [use_ecmult_static_precomputation=auto])
 148
 149 AC_ARG_ENABLE(module_ecdh,
 150     AS_HELP_STRING([--enable-module-ecdh],[enable ECDH shared secret computation]),
 151     [enable_module_ecdh=$enableval],
 152     [enable_module_ecdh=no])
 153
 154 AC_ARG_ENABLE(module_recovery,
 155     AS_HELP_STRING([--enable-module-recovery],[enable ECDSA pubkey recovery module [default=no]]),
 156     [enable_module_recovery=$enableval],
 157     [enable_module_recovery=no])
 158
 159 AC_ARG_ENABLE(module_extrakeys,
 160     AS_HELP_STRING([--enable-module-extrakeys],[enable extrakeys module (experimental)]),
 161     [enable_module_extrakeys=$enableval],
 162     [enable_module_extrakeys=no])
 163
 164 AC_ARG_ENABLE(module_schnorrsig,
 165     AS_HELP_STRING([--enable-module-schnorrsig],[enable schnorrsig module (experimental)]),
 166     [enable_module_schnorrsig=$enableval],
 167     [enable_module_schnorrsig=no])
 168
 169 AC_ARG_ENABLE(external_default_callbacks,
 170     AS_HELP_STRING([--enable-external-default-callbacks],[enable external default callback functions [default=no]]),
 171     [use_external_default_callbacks=$enableval],
 172     [use_external_default_callbacks=no])
 173
 174 # Test-only override of the (autodetected by the C code) "widemul" setting.
 175 # Legal values are int64 (for [u]int64_t), int128 (for [unsigned] __int128), and auto (the default).
 176 AC_ARG_WITH([test-override-wide-multiply], [] ,[set_widemul=$withval], [set_widemul=auto])
 177
 178 AC_ARG_WITH([asm], [AS_HELP_STRING([--with-asm=x86_64|arm|no|auto],
 179 [assembly optimizations to use (experimental: arm) [default=auto]])],[req_asm=$withval], [req_asm=auto])
 180
 181 AC_ARG_WITH([ecmult-window], [AS_HELP_STRING([--with-ecmult-window=SIZE|auto],
 182 [window size for ecmult precomputation for verification, specified as integer in range [2..24].]
 183 [Larger values result in possibly better performance at the cost of an exponentially larger precomputed table.]
 184 [The table will store 2^(SIZE-1) * 64 bytes of data but can be larger in memory due to platform-specific padding and alignment.]
 185 ["auto" is a reasonable setting for desktop machines (currently 15). [default=auto]]
 186 )],
 187 [req_ecmult_window=$withval], [req_ecmult_window=auto])
 188
 189 AC_ARG_WITH([ecmult-gen-precision], [AS_HELP_STRING([--with-ecmult-gen-precision=2|4|8|auto],
 190 [Precision bits to tune the precomputed table size for signing.]
 191 [The size of the table is 32kB for 2 bits, 64kB for 4 bits, 512kB for 8 bits of precision.]
 192 [A larger table size usually results in possible faster signing.]
 193 ["auto" is a reasonable setting for desktop machines (currently 4). [default=auto]]
 194 )],
 195 [req_ecmult_gen_precision=$withval], [req_ecmult_gen_precision=auto])
 196
 197 AC_ARG_WITH([valgrind], [AS_HELP_STRING([--with-valgrind=yes|no|auto],
 198 [Build with extra checks for running inside Valgrind [default=auto]]
 199 )],
 200 [req_valgrind=$withval], [req_valgrind=auto])
 201
 202 ###
 203 ### Handle config options (except for modules)
 204 ###
 205
 206 if test x"$req_valgrind" = x"no"; then
 207   enable_valgrind=no
 208 else
 209   SECP_VALGRIND_CHECK
 210   if test x"$has_valgrind" != x"yes"; then
 211     if test x"$req_valgrind" = x"yes"; then
 212       AC_MSG_ERROR([Valgrind support explicitly requested but valgrind/memcheck.h header not available])
 213     fi
 214     enable_valgrind=no
 215   else
 216     enable_valgrind=yes
 217   fi
 218 fi
 219 AM_CONDITIONAL([VALGRIND_ENABLED],[test "$enable_valgrind" = "yes"])
 220
 221 if test x"$enable_coverage" = x"yes"; then
 222     AC_DEFINE(COVERAGE, 1, [Define this symbol to compile out all VERIFY code])
 223     CFLAGS="-O0 --coverage $CFLAGS"
 224     LDFLAGS="--coverage $LDFLAGS"
 225 else
 226     CFLAGS="-O2 $CFLAGS"
 227 fi
 228
 229 if test x"$req_asm" = x"auto"; then
 230   SECP_64BIT_ASM_CHECK
 231   if test x"$has_64bit_asm" = x"yes"; then
 232     set_asm=x86_64
 233   fi
 234   if test x"$set_asm" = x; then
 235     set_asm=no
 236   fi
 237 else
 238   set_asm=$req_asm
 239   case $set_asm in
 240   x86_64)
 241     SECP_64BIT_ASM_CHECK
 242     if test x"$has_64bit_asm" != x"yes"; then
 243       AC_MSG_ERROR([x86_64 assembly optimization requested but not available])
 244     fi
 245     ;;
 246   arm)
 247     ;;
 248   no)
 249     ;;
 250   *)
 251     AC_MSG_ERROR([invalid assembly optimization selection])
 252     ;;
 253   esac
 254 fi
 255
 256 # Select assembly optimization
 257 use_external_asm=no
 258
 259 case $set_asm in
 260 x86_64)
 261   AC_DEFINE(USE_ASM_X86_64, 1, [Define this symbol to enable x86_64 assembly optimizations])
 262   ;;
 263 arm)
 264   use_external_asm=yes
 265   ;;
 266 no)
 267   ;;
 268 *)
 269   AC_MSG_ERROR([invalid assembly optimizations])
 270   ;;
 271 esac
 272
 273 if test x"$use_external_asm" = x"yes"; then
 274   AC_DEFINE(USE_EXTERNAL_ASM, 1, [Define this symbol if an external (non-inline) assembly implementation is used])
 275 fi
 276
 277
 278 # Select wide multiplication implementation
 279 case $set_widemul in
 280 int128)
 281   AC_DEFINE(USE_FORCE_WIDEMUL_INT128, 1, [Define this symbol to force the use of the (unsigned) __int128 based wide multiplication implementation])
 282   ;;
 283 int64)
 284   AC_DEFINE(USE_FORCE_WIDEMUL_INT64, 1, [Define this symbol to force the use of the (u)int64_t based wide multiplication implementation])
 285   ;;
 286 auto)
 287   ;;
 288 *)
 289   AC_MSG_ERROR([invalid wide multiplication implementation])
 290   ;;
 291 esac
 292
 293 # Set ecmult window size
 294 if test x"$req_ecmult_window" = x"auto"; then
 295   set_ecmult_window=15
 296 else
 297   set_ecmult_window=$req_ecmult_window
 298 fi
 299
 300 error_window_size=['window size for ecmult precomputation not an integer in range [2..24] or "auto"']
 301 case $set_ecmult_window in
 302 ''|*[[!0-9]]*)
 303   # no valid integer
 304   AC_MSG_ERROR($error_window_size)
 305   ;;
 306 *)
 307   if test "$set_ecmult_window" -lt 2 -o "$set_ecmult_window" -gt 24 ; then
 308     # not in range
 309     AC_MSG_ERROR($error_window_size)
 310   fi
 311   AC_DEFINE_UNQUOTED(ECMULT_WINDOW_SIZE, $set_ecmult_window, [Set window size for ecmult precomputation])
 312   ;;
 313 esac
 314
 315 # Set ecmult gen precision
 316 if test x"$req_ecmult_gen_precision" = x"auto"; then
 317   set_ecmult_gen_precision=4
 318 else
 319   set_ecmult_gen_precision=$req_ecmult_gen_precision
 320 fi
 321
 322 case $set_ecmult_gen_precision in
 323 2|4|8)
 324   AC_DEFINE_UNQUOTED(ECMULT_GEN_PREC_BITS, $set_ecmult_gen_precision, [Set ecmult gen precision bits])
 325   ;;
 326 *)
 327   AC_MSG_ERROR(['ecmult gen precision not 2, 4, 8 or "auto"'])
 328   ;;
 329 esac
 330
 331 if test x"$use_tests" = x"yes"; then
 332   SECP_OPENSSL_CHECK
 333   if test x"$enable_openssl_tests" != x"no" && test x"$has_openssl_ec" = x"yes"; then
 334       enable_openssl_tests=yes
 335       AC_DEFINE(ENABLE_OPENSSL_TESTS, 1, [Define this symbol if OpenSSL EC functions are available])
 336       SECP_TEST_INCLUDES="$SSL_CFLAGS $CRYPTO_CFLAGS $CRYPTO_CPPFLAGS"
 337       SECP_TEST_LIBS="$CRYPTO_LIBS"
 338
 339       case $host in
 340       *mingw*)
 341         SECP_TEST_LIBS="$SECP_TEST_LIBS -lgdi32"
 342         ;;
 343       esac
 344   else
 345     if test x"$enable_openssl_tests" = x"yes"; then
 346       AC_MSG_ERROR([OpenSSL tests requested but OpenSSL with EC support is not available])
 347     fi
 348     enable_openssl_tests=no
 349   fi
 350 else
 351   if test x"$enable_openssl_tests" = x"yes"; then
 352     AC_MSG_ERROR([OpenSSL tests requested but tests are not enabled])
 353   fi
 354   enable_openssl_tests=no
 355 fi
 356
 357 if test x"$enable_valgrind" = x"yes"; then
 358   SECP_INCLUDES="$SECP_INCLUDES $VALGRIND_CPPFLAGS"
 359 fi
 360
 361 # Handle static precomputation (after everything which modifies CFLAGS and friends)
 362 if test x"$use_ecmult_static_precomputation" != x"no"; then
 363   if test x"$cross_compiling" = x"no"; then
 364     set_precomp=yes
 365     if test x"${CC_FOR_BUILD+x}${CFLAGS_FOR_BUILD+x}${CPPFLAGS_FOR_BUILD+x}${LDFLAGS_FOR_BUILD+x}" != x; then
 366       AC_MSG_WARN([CC_FOR_BUILD, CFLAGS_FOR_BUILD, CPPFLAGS_FOR_BUILD, and/or LDFLAGS_FOR_BUILD is set but ignored because we are not cross-compiling.])
 367     fi
 368     # If we're not cross-compiling, simply use the same compiler for building the static precompation code.
 369     CC_FOR_BUILD="$CC"
 370     CPPFLAGS_FOR_BUILD="$CPPFLAGS"
 371     SECP_CFLAGS_FOR_BUILD="$SECP_CFLAGS"
 372     CFLAGS_FOR_BUILD="$CFLAGS"
 373     LDFLAGS_FOR_BUILD="$LDFLAGS"
 374   else
 375     AX_PROG_CC_FOR_BUILD
 376
 377     # Temporarily switch to an environment for the native compiler
 378     save_cross_compiling=$cross_compiling
 379     cross_compiling=no
 380     SAVE_CC="$CC"
 381     CC="$CC_FOR_BUILD"
 382     SAVE_CPPFLAGS="$CPPFLAGS"
 383     CPPFLAGS="$CPPFLAGS_FOR_BUILD"
 384     SAVE_CFLAGS="$CFLAGS"
 385     CFLAGS="$CFLAGS_FOR_BUILD"
 386     SAVE_LDFLAGS="$LDFLAGS"
 387     LDFLAGS="$LDFLAGS_FOR_BUILD"
 388
 389     SECP_TRY_APPEND_DEFAULT_CFLAGS(SECP_CFLAGS_FOR_BUILD)
 390
 391     AC_MSG_CHECKING([for working native compiler: ${CC_FOR_BUILD}])
 392     AC_RUN_IFELSE(
 393       [AC_LANG_PROGRAM([], [])],
 394       [working_native_cc=yes],
 395       [working_native_cc=no],[:])
 396
 397     # Restore the environment
 398     cross_compiling=$save_cross_compiling
 399     CC="$SAVE_CC"
 400     CPPFLAGS="$SAVE_CPPFLAGS"
 401     CFLAGS="$SAVE_CFLAGS"
 402     LDFLAGS="$SAVE_LDFLAGS"
 403
 404     if test x"$working_native_cc" = x"no"; then
 405       AC_MSG_RESULT([no])
 406       set_precomp=no
 407       m4_define([please_set_for_build], [Please set CC_FOR_BUILD, CPPFLAGS_FOR_BUILD, CFLAGS_FOR_BUILD, and/or LDFLAGS_FOR_BUILD.])
 408       if test x"$use_ecmult_static_precomputation" = x"yes";  then
 409         AC_MSG_ERROR([native compiler ${CC_FOR_BUILD} does not produce working binaries. please_set_for_build])
 410       else
 411         AC_MSG_WARN([Disabling statically generated ecmult table because the native compiler ${CC_FOR_BUILD} does not produce working binaries. please_set_for_build])
 412       fi
 413     else
 414       AC_MSG_RESULT([yes])
 415       set_precomp=yes
 416     fi
 417   fi
 418
 419   AC_SUBST(CC_FOR_BUILD)
 420   AC_SUBST(CPPFLAGS_FOR_BUILD)
 421   AC_SUBST(SECP_CFLAGS_FOR_BUILD)
 422   AC_SUBST(CFLAGS_FOR_BUILD)
 423   AC_SUBST(LDFLAGS_FOR_BUILD)
 424 else
 425   set_precomp=no
 426 fi
 427
 428 if test x"$set_precomp" = x"yes"; then
 429   AC_DEFINE(USE_ECMULT_STATIC_PRECOMPUTATION, 1, [Define this symbol to use a statically generated ecmult table])
 430 fi
 431
 432 ###
 433 ### Handle module options
 434 ###
 435
 436 if test x"$enable_module_ecdh" = x"yes"; then
 437   AC_DEFINE(ENABLE_MODULE_ECDH, 1, [Define this symbol to enable the ECDH module])
 438 fi
 439
 440 if test x"$enable_module_recovery" = x"yes"; then
 441   AC_DEFINE(ENABLE_MODULE_RECOVERY, 1, [Define this symbol to enable the ECDSA pubkey recovery module])
 442 fi
 443
 444 if test x"$enable_module_schnorrsig" = x"yes"; then
 445   AC_DEFINE(ENABLE_MODULE_SCHNORRSIG, 1, [Define this symbol to enable the schnorrsig module])
 446   enable_module_extrakeys=yes
 447 fi
 448
 449 # Test if extrakeys is set after the schnorrsig module to allow the schnorrsig
 450 # module to set enable_module_extrakeys=yes
 451 if test x"$enable_module_extrakeys" = x"yes"; then
 452   AC_DEFINE(ENABLE_MODULE_EXTRAKEYS, 1, [Define this symbol to enable the extrakeys module])
 453 fi
 454
 455 if test x"$use_external_default_callbacks" = x"yes"; then
 456   AC_DEFINE(USE_EXTERNAL_DEFAULT_CALLBACKS, 1, [Define this symbol if an external implementation of the default callbacks is used])
 457 fi
 458
 459 ###
 460 ### Check for --enable-experimental if necessary
 461 ###
 462
 463 if test x"$enable_experimental" = x"yes"; then
 464   AC_MSG_NOTICE([******])
 465   AC_MSG_NOTICE([WARNING: experimental build])
 466   AC_MSG_NOTICE([Experimental features do not have stable APIs or properties, and may not be safe for production use.])
 467   AC_MSG_NOTICE([Building extrakeys module: $enable_module_extrakeys])
 468   AC_MSG_NOTICE([Building schnorrsig module: $enable_module_schnorrsig])
 469   AC_MSG_NOTICE([******])
 470 else
 471   if test x"$enable_module_extrakeys" = x"yes"; then
 472     AC_MSG_ERROR([extrakeys module is experimental. Use --enable-experimental to allow.])
 473   fi
 474   if test x"$enable_module_schnorrsig" = x"yes"; then
 475     AC_MSG_ERROR([schnorrsig module is experimental. Use --enable-experimental to allow.])
 476   fi
 477   if test x"$set_asm" = x"arm"; then
 478     AC_MSG_ERROR([ARM assembly optimization is experimental. Use --enable-experimental to allow.])
 479   fi
 480 fi
 481
 482 ###
 483 ### Generate output
 484 ###
 485
 486 AC_CONFIG_HEADERS([src/libsecp256k1-config.h])
 487 AC_CONFIG_FILES([Makefile libsecp256k1.pc])
 488 AC_SUBST(SECP_INCLUDES)
 489 AC_SUBST(SECP_LIBS)
 490 AC_SUBST(SECP_TEST_LIBS)
 491 AC_SUBST(SECP_TEST_INCLUDES)
 492 AC_SUBST(SECP_CFLAGS)
 493 AM_CONDITIONAL([ENABLE_COVERAGE], [test x"$enable_coverage" = x"yes"])
 494 AM_CONDITIONAL([USE_TESTS], [test x"$use_tests" != x"no"])
 495 AM_CONDITIONAL([USE_EXHAUSTIVE_TESTS], [test x"$use_exhaustive_tests" != x"no"])
 496 AM_CONDITIONAL([USE_BENCHMARK], [test x"$use_benchmark" = x"yes"])
 497 AM_CONDITIONAL([USE_ECMULT_STATIC_PRECOMPUTATION], [test x"$set_precomp" = x"yes"])
 498 AM_CONDITIONAL([ENABLE_MODULE_ECDH], [test x"$enable_module_ecdh" = x"yes"])
 499 AM_CONDITIONAL([ENABLE_MODULE_RECOVERY], [test x"$enable_module_recovery" = x"yes"])
 500 AM_CONDITIONAL([ENABLE_MODULE_EXTRAKEYS], [test x"$enable_module_extrakeys" = x"yes"])
 501 AM_CONDITIONAL([ENABLE_MODULE_SCHNORRSIG], [test x"$enable_module_schnorrsig" = x"yes"])
 502 AM_CONDITIONAL([USE_EXTERNAL_ASM], [test x"$use_external_asm" = x"yes"])
 503 AM_CONDITIONAL([USE_ASM_ARM], [test x"$set_asm" = x"arm"])
 504
 505 # Make sure nothing new is exported so that we don't break the cache.
 506 PKGCONFIG_PATH_TEMP="$PKG_CONFIG_PATH"
 507 unset PKG_CONFIG_PATH
 508 PKG_CONFIG_PATH="$PKGCONFIG_PATH_TEMP"
 509
 510 AC_OUTPUT
 511
 512 echo
 513 echo "Build Options:"
 514 echo "  with ecmult precomp     = $set_precomp"
 515 echo "  with external callbacks = $use_external_default_callbacks"
 516 echo "  with benchmarks         = $use_benchmark"
 517 echo "  with tests              = $use_tests"
 518 echo "  with openssl tests      = $enable_openssl_tests"
 519 echo "  with coverage           = $enable_coverage"
 520 echo "  module ecdh             = $enable_module_ecdh"
 521 echo "  module recovery         = $enable_module_recovery"
 522 echo "  module extrakeys        = $enable_module_extrakeys"
 523 echo "  module schnorrsig       = $enable_module_schnorrsig"
 524 echo
 525 echo "  asm                     = $set_asm"
 526 echo "  ecmult window size      = $set_ecmult_window"
 527 echo "  ecmult gen prec. bits   = $set_ecmult_gen_precision"
 528 # Hide test-only options unless they're used.
 529 if test x"$set_widemul" != xauto; then
 530 echo "  wide multiplication     = $set_widemul"
 531 fi
 532 echo
 533 echo "  valgrind                = $enable_valgrind"
 534 echo "  CC                      = $CC"
 535 echo "  CPPFLAGS                = $CPPFLAGS"
 536 echo "  SECP_CFLAGS             = $SECP_CFLAGS"
 537 echo "  CFLAGS                  = $CFLAGS"
 538 echo "  LDFLAGS                 = $LDFLAGS"
 539 echo
 540 if test x"$set_precomp" = x"yes"; then
 541 echo "  CC_FOR_BUILD            = $CC_FOR_BUILD"
 542 echo "  CPPFLAGS_FOR_BUILD      = $CPPFLAGS_FOR_BUILD"
 543 echo "  SECP_CFLAGS_FOR_BUILD   = $SECP_CFLAGS_FOR_BUILD"
 544 echo "  CFLAGS_FOR_BUILD        = $CFLAGS_FOR_BUILD"
 545 echo "  LDFLAGS_FOR_BUILD       = $LDFLAGS_FOR_BUILD"
 546 fi