configure.ac

   1 AC_PREREQ([2.60])
   2 AC_INIT([libsecp256k1],[0.1])
   3 AC_CONFIG_AUX_DIR([build-aux])
   4 AC_CONFIG_MACRO_DIR([build-aux/m4])
   5 AC_CANONICAL_HOST
   6 AH_TOP([#ifndef LIBSECP256K1_CONFIG_H])
   7 AH_TOP([#define LIBSECP256K1_CONFIG_H])
   8 AH_BOTTOM([#endif /*LIBSECP256K1_CONFIG_H*/])
   9 AM_INIT_AUTOMAKE([foreign subdir-objects])
  10
  11 # Set -g if CFLAGS are not already set, which matches the default autoconf
  12 # behavior (see PROG_CC in the Autoconf manual) with the exception that we don't
  13 # set -O2 here because we set it in any case (see further down).
  14 : ${CFLAGS="-g"}
  15 LT_INIT
  16
  17 # Make the compilation flags quiet unless V=1 is used.
  18 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  19
  20 PKG_PROG_PKG_CONFIG
  21
  22 AC_PATH_TOOL(AR, ar)
  23 AC_PATH_TOOL(RANLIB, ranlib)
  24 AC_PATH_TOOL(STRIP, strip)
  25 AX_PROG_CC_FOR_BUILD
  26
  27 AM_PROG_CC_C_O
  28
  29 AC_PROG_CC_C89
  30 if test x"$ac_cv_prog_cc_c89" = x"no"; then
  31   AC_MSG_ERROR([c89 compiler support required])
  32 fi
  33 AM_PROG_AS
  34
  35 case $host_os in
  36   *darwin*)
  37      if  test x$cross_compiling != xyes; then
  38        AC_PATH_PROG([BREW],brew,)
  39        if test x$BREW != x; then
  40          # These Homebrew packages may be keg-only, meaning that they won't be found
  41          # in expected paths because they may conflict with system files. Ask
  42          # Homebrew where each one is located, then adjust paths accordingly.
  43          openssl_prefix=`$BREW --prefix openssl 2>/dev/null`
  44          gmp_prefix=`$BREW --prefix gmp 2>/dev/null`
  45          valgrind_prefix=`$BREW --prefix valgrind 2>/dev/null`
  46          if test x$openssl_prefix != x; then
  47            PKG_CONFIG_PATH="$openssl_prefix/lib/pkgconfig:$PKG_CONFIG_PATH"
  48            export PKG_CONFIG_PATH
  49            CRYPTO_CPPFLAGS="-I$openssl_prefix/include"
  50          fi
  51          if test x$gmp_prefix != x; then
  52            GMP_CPPFLAGS="-I$gmp_prefix/include"
  53            GMP_LIBS="-L$gmp_prefix/lib"
  54          fi
  55          if test x$valgrind_prefix != x; then
  56            VALGRIND_CPPFLAGS="-I$valgrind_prefix/include"
  57          fi
  58        else
  59          AC_PATH_PROG([PORT],port,)
  60          # If homebrew isn't installed and macports is, add the macports default paths
  61          # as a last resort.
  62          if test x$PORT != x; then
  63            CPPFLAGS="$CPPFLAGS -isystem /opt/local/include"
  64            LDFLAGS="$LDFLAGS -L/opt/local/lib"
  65          fi
  66        fi
  67      fi
  68    ;;
  69 esac
  70
  71 CFLAGS="-W $CFLAGS"
  72
  73 warn_CFLAGS="-std=c89 -pedantic -Wall -Wextra -Wcast-align -Wnested-externs -Wshadow -Wstrict-prototypes -Wundef -Wno-unused-function -Wno-long-long -Wno-overlength-strings"
  74 saved_CFLAGS="$CFLAGS"
  75 CFLAGS="$warn_CFLAGS $CFLAGS"
  76 AC_MSG_CHECKING([if ${CC} supports ${warn_CFLAGS}])
  77 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[char foo;]])],
  78     [ AC_MSG_RESULT([yes]) ],
  79     [ AC_MSG_RESULT([no])
  80       CFLAGS="$saved_CFLAGS"
  81     ])
  82
  83 saved_CFLAGS="$CFLAGS"
  84 CFLAGS="-fvisibility=hidden $CFLAGS"
  85 AC_MSG_CHECKING([if ${CC} supports -fvisibility=hidden])
  86 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[char foo;]])],
  87     [ AC_MSG_RESULT([yes]) ],
  88     [ AC_MSG_RESULT([no])
  89       CFLAGS="$saved_CFLAGS"
  90     ])
  91
  92 ###
  93 ### Define config arguments
  94 ###
  95
  96 AC_ARG_ENABLE(benchmark,
  97     AS_HELP_STRING([--enable-benchmark],[compile benchmark [default=yes]]),
  98     [use_benchmark=$enableval],
  99     [use_benchmark=yes])
 100
 101 AC_ARG_ENABLE(coverage,
 102     AS_HELP_STRING([--enable-coverage],[enable compiler flags to support kcov coverage analysis [default=no]]),
 103     [enable_coverage=$enableval],
 104     [enable_coverage=no])
 105
 106 AC_ARG_ENABLE(tests,
 107     AS_HELP_STRING([--enable-tests],[compile tests [default=yes]]),
 108     [use_tests=$enableval],
 109     [use_tests=yes])
 110
 111 AC_ARG_ENABLE(openssl_tests,
 112     AS_HELP_STRING([--enable-openssl-tests],[enable OpenSSL tests [default=auto]]),
 113     [enable_openssl_tests=$enableval],
 114     [enable_openssl_tests=auto])
 115
 116 AC_ARG_ENABLE(experimental,
 117     AS_HELP_STRING([--enable-experimental],[allow experimental configure options [default=no]]),
 118     [use_experimental=$enableval],
 119     [use_experimental=no])
 120
 121 AC_ARG_ENABLE(exhaustive_tests,
 122     AS_HELP_STRING([--enable-exhaustive-tests],[compile exhaustive tests [default=yes]]),
 123     [use_exhaustive_tests=$enableval],
 124     [use_exhaustive_tests=yes])
 125
 126 AC_ARG_ENABLE(ecmult_static_precomputation,
 127     AS_HELP_STRING([--enable-ecmult-static-precomputation],[enable precomputed ecmult table for signing [default=auto]]),
 128     [use_ecmult_static_precomputation=$enableval],
 129     [use_ecmult_static_precomputation=auto])
 130
 131 AC_ARG_ENABLE(module_ecdh,
 132     AS_HELP_STRING([--enable-module-ecdh],[enable ECDH shared secret computation]),
 133     [enable_module_ecdh=$enableval],
 134     [enable_module_ecdh=no])
 135
 136 AC_ARG_ENABLE(module_recovery,
 137     AS_HELP_STRING([--enable-module-recovery],[enable ECDSA pubkey recovery module [default=no]]),
 138     [enable_module_recovery=$enableval],
 139     [enable_module_recovery=no])
 140
 141 AC_ARG_ENABLE(module_extrakeys,
 142     AS_HELP_STRING([--enable-module-extrakeys],[enable extrakeys module (experimental)]),
 143     [enable_module_extrakeys=$enableval],
 144     [enable_module_extrakeys=no])
 145
 146 AC_ARG_ENABLE(module_schnorrsig,
 147     AS_HELP_STRING([--enable-module-schnorrsig],[enable schnorrsig module (experimental)]),
 148     [enable_module_schnorrsig=$enableval],
 149     [enable_module_schnorrsig=no])
 150
 151 AC_ARG_ENABLE(external_default_callbacks,
 152     AS_HELP_STRING([--enable-external-default-callbacks],[enable external default callback functions [default=no]]),
 153     [use_external_default_callbacks=$enableval],
 154     [use_external_default_callbacks=no])
 155
 156 # Test-only override of the (autodetected by the C code) "widemul" setting.
 157 # Legal values are int64 (for [u]int64_t), int128 (for [unsigned] __int128), and auto (the default).
 158 AC_ARG_WITH([test-override-wide-multiply], [] ,[set_widemul=$withval], [set_widemul=auto])
 159
 160 AC_ARG_WITH([bignum], [AS_HELP_STRING([--with-bignum=gmp|no|auto],
 161 [bignum implementation to use [default=auto]])],[req_bignum=$withval], [req_bignum=auto])
 162
 163 AC_ARG_WITH([asm], [AS_HELP_STRING([--with-asm=x86_64|arm|no|auto],
 164 [assembly optimizations to use (experimental: arm) [default=auto]])],[req_asm=$withval], [req_asm=auto])
 165
 166 AC_ARG_WITH([ecmult-window], [AS_HELP_STRING([--with-ecmult-window=SIZE|auto],
 167 [window size for ecmult precomputation for verification, specified as integer in range [2..24].]
 168 [Larger values result in possibly better performance at the cost of an exponentially larger precomputed table.]
 169 [The table will store 2^(SIZE-1) * 64 bytes of data but can be larger in memory due to platform-specific padding and alignment.]
 170 ["auto" is a reasonable setting for desktop machines (currently 15). [default=auto]]
 171 )],
 172 [req_ecmult_window=$withval], [req_ecmult_window=auto])
 173
 174 AC_ARG_WITH([ecmult-gen-precision], [AS_HELP_STRING([--with-ecmult-gen-precision=2|4|8|auto],
 175 [Precision bits to tune the precomputed table size for signing.]
 176 [The size of the table is 32kB for 2 bits, 64kB for 4 bits, 512kB for 8 bits of precision.]
 177 [A larger table size usually results in possible faster signing.]
 178 ["auto" is a reasonable setting for desktop machines (currently 4). [default=auto]]
 179 )],
 180 [req_ecmult_gen_precision=$withval], [req_ecmult_gen_precision=auto])
 181
 182 AC_ARG_WITH([valgrind], [AS_HELP_STRING([--with-valgrind=yes|no|auto],
 183 [Build with extra checks for running inside Valgrind [default=auto]]
 184 )],
 185 [req_valgrind=$withval], [req_valgrind=auto])
 186
 187 ###
 188 ### Handle config options (except for modules)
 189 ###
 190
 191 if test x"$req_valgrind" = x"no"; then
 192   enable_valgrind=no
 193 else
 194   SECP_VALGRIND_CHECK
 195   if test x"$has_valgrind" != x"yes"; then
 196     if test x"$req_valgrind" = x"yes"; then
 197       AC_MSG_ERROR([Valgrind support explicitly requested but valgrind/memcheck.h header not available])
 198     fi
 199     enable_valgrind=no
 200   else
 201     enable_valgrind=yes
 202   fi
 203 fi
 204 AM_CONDITIONAL([VALGRIND_ENABLED],[test "$enable_valgrind" = "yes"])
 205
 206 if test x"$enable_coverage" = x"yes"; then
 207     AC_DEFINE(COVERAGE, 1, [Define this symbol to compile out all VERIFY code])
 208     CFLAGS="-O0 --coverage $CFLAGS"
 209     LDFLAGS="--coverage $LDFLAGS"
 210 else
 211     CFLAGS="-O2 $CFLAGS"
 212 fi
 213
 214 if test x"$req_asm" = x"auto"; then
 215   SECP_64BIT_ASM_CHECK
 216   if test x"$has_64bit_asm" = x"yes"; then
 217     set_asm=x86_64
 218   fi
 219   if test x"$set_asm" = x; then
 220     set_asm=no
 221   fi
 222 else
 223   set_asm=$req_asm
 224   case $set_asm in
 225   x86_64)
 226     SECP_64BIT_ASM_CHECK
 227     if test x"$has_64bit_asm" != x"yes"; then
 228       AC_MSG_ERROR([x86_64 assembly optimization requested but not available])
 229     fi
 230     ;;
 231   arm)
 232     ;;
 233   no)
 234     ;;
 235   *)
 236     AC_MSG_ERROR([invalid assembly optimization selection])
 237     ;;
 238   esac
 239 fi
 240
 241 if test x"$req_bignum" = x"auto"; then
 242   SECP_GMP_CHECK
 243   if test x"$has_gmp" = x"yes"; then
 244     set_bignum=gmp
 245   fi
 246
 247   if test x"$set_bignum" = x; then
 248     set_bignum=no
 249   fi
 250 else
 251   set_bignum=$req_bignum
 252   case $set_bignum in
 253   gmp)
 254     SECP_GMP_CHECK
 255     if test x"$has_gmp" != x"yes"; then
 256       AC_MSG_ERROR([gmp bignum explicitly requested but libgmp not available])
 257     fi
 258     ;;
 259   no)
 260     ;;
 261   *)
 262     AC_MSG_ERROR([invalid bignum implementation selection])
 263     ;;
 264   esac
 265 fi
 266
 267 # Select assembly optimization
 268 use_external_asm=no
 269
 270 case $set_asm in
 271 x86_64)
 272   AC_DEFINE(USE_ASM_X86_64, 1, [Define this symbol to enable x86_64 assembly optimizations])
 273   ;;
 274 arm)
 275   use_external_asm=yes
 276   ;;
 277 no)
 278   ;;
 279 *)
 280   AC_MSG_ERROR([invalid assembly optimizations])
 281   ;;
 282 esac
 283
 284 if test x"$use_external_asm" = x"yes"; then
 285   AC_DEFINE(USE_EXTERNAL_ASM, 1, [Define this symbol if an external (non-inline) assembly implementation is used])
 286 fi
 287
 288
 289 # Select wide multiplication implementation
 290 case $set_widemul in
 291 int128)
 292   AC_DEFINE(USE_FORCE_WIDEMUL_INT128, 1, [Define this symbol to force the use of the (unsigned) __int128 based wide multiplication implementation])
 293   ;;
 294 int64)
 295   AC_DEFINE(USE_FORCE_WIDEMUL_INT64, 1, [Define this symbol to force the use of the (u)int64_t based wide multiplication implementation])
 296   ;;
 297 auto)
 298   ;;
 299 *)
 300   AC_MSG_ERROR([invalid wide multiplication implementation])
 301   ;;
 302 esac
 303
 304 # Select bignum implementation
 305 case $set_bignum in
 306 gmp)
 307   AC_DEFINE(HAVE_LIBGMP, 1, [Define this symbol if libgmp is installed])
 308   AC_DEFINE(USE_NUM_GMP, 1, [Define this symbol to use the gmp implementation for num])
 309   AC_DEFINE(USE_FIELD_INV_NUM, 1, [Define this symbol to use the num-based field inverse implementation])
 310   AC_DEFINE(USE_SCALAR_INV_NUM, 1, [Define this symbol to use the num-based scalar inverse implementation])
 311   ;;
 312 no)
 313   AC_DEFINE(USE_NUM_NONE, 1, [Define this symbol to use no num implementation])
 314   AC_DEFINE(USE_FIELD_INV_BUILTIN, 1, [Define this symbol to use the native field inverse implementation])
 315   AC_DEFINE(USE_SCALAR_INV_BUILTIN, 1, [Define this symbol to use the native scalar inverse implementation])
 316   ;;
 317 *)
 318   AC_MSG_ERROR([invalid bignum implementation])
 319   ;;
 320 esac
 321
 322 # Set ecmult window size
 323 if test x"$req_ecmult_window" = x"auto"; then
 324   set_ecmult_window=15
 325 else
 326   set_ecmult_window=$req_ecmult_window
 327 fi
 328
 329 error_window_size=['window size for ecmult precomputation not an integer in range [2..24] or "auto"']
 330 case $set_ecmult_window in
 331 ''|*[[!0-9]]*)
 332   # no valid integer
 333   AC_MSG_ERROR($error_window_size)
 334   ;;
 335 *)
 336   if test "$set_ecmult_window" -lt 2 -o "$set_ecmult_window" -gt 24 ; then
 337     # not in range
 338     AC_MSG_ERROR($error_window_size)
 339   fi
 340   AC_DEFINE_UNQUOTED(ECMULT_WINDOW_SIZE, $set_ecmult_window, [Set window size for ecmult precomputation])
 341   ;;
 342 esac
 343
 344 # Set ecmult gen precision
 345 if test x"$req_ecmult_gen_precision" = x"auto"; then
 346   set_ecmult_gen_precision=4
 347 else
 348   set_ecmult_gen_precision=$req_ecmult_gen_precision
 349 fi
 350
 351 case $set_ecmult_gen_precision in
 352 2|4|8)
 353   AC_DEFINE_UNQUOTED(ECMULT_GEN_PREC_BITS, $set_ecmult_gen_precision, [Set ecmult gen precision bits])
 354   ;;
 355 *)
 356   AC_MSG_ERROR(['ecmult gen precision not 2, 4, 8 or "auto"'])
 357   ;;
 358 esac
 359
 360 if test x"$use_tests" = x"yes"; then
 361   SECP_OPENSSL_CHECK
 362   if test x"$enable_openssl_tests" != x"no" && test x"$has_openssl_ec" = x"yes"; then
 363       enable_openssl_tests=yes
 364       AC_DEFINE(ENABLE_OPENSSL_TESTS, 1, [Define this symbol if OpenSSL EC functions are available])
 365       SECP_TEST_INCLUDES="$SSL_CFLAGS $CRYPTO_CFLAGS $CRYPTO_CPPFLAGS"
 366       SECP_TEST_LIBS="$CRYPTO_LIBS"
 367
 368       case $host in
 369       *mingw*)
 370         SECP_TEST_LIBS="$SECP_TEST_LIBS -lgdi32"
 371         ;;
 372       esac
 373   else
 374     if test x"$enable_openssl_tests" = x"yes"; then
 375       AC_MSG_ERROR([OpenSSL tests requested but OpenSSL with EC support is not available])
 376     fi
 377     enable_openssl_tests=no
 378   fi
 379 else
 380   if test x"$enable_openssl_tests" = x"yes"; then
 381     AC_MSG_ERROR([OpenSSL tests requested but tests are not enabled])
 382   fi
 383   enable_openssl_tests=no
 384 fi
 385
 386 if test x"$set_bignum" = x"gmp"; then
 387   SECP_LIBS="$SECP_LIBS $GMP_LIBS"
 388   SECP_INCLUDES="$SECP_INCLUDES $GMP_CPPFLAGS"
 389 fi
 390
 391 if test x"$enable_valgrind" = x"yes"; then
 392   SECP_INCLUDES="$SECP_INCLUDES $VALGRIND_CPPFLAGS"
 393 fi
 394
 395 # Handle static precomputation (after everything which modifies CFLAGS and friends)
 396 if test x"$use_ecmult_static_precomputation" != x"no"; then
 397   # Temporarily switch to an environment for the native compiler
 398   save_cross_compiling=$cross_compiling
 399   cross_compiling=no
 400   SAVE_CC="$CC"
 401   CC="$CC_FOR_BUILD"
 402   SAVE_CFLAGS="$CFLAGS"
 403   CFLAGS="$CFLAGS_FOR_BUILD"
 404   SAVE_CPPFLAGS="$CPPFLAGS"
 405   CPPFLAGS="$CPPFLAGS_FOR_BUILD"
 406   SAVE_LDFLAGS="$LDFLAGS"
 407   LDFLAGS="$LDFLAGS_FOR_BUILD"
 408
 409   warn_CFLAGS_FOR_BUILD="-Wall -Wextra -Wno-unused-function"
 410   saved_CFLAGS="$CFLAGS"
 411   CFLAGS="$warn_CFLAGS_FOR_BUILD $CFLAGS"
 412   AC_MSG_CHECKING([if native ${CC_FOR_BUILD} supports ${warn_CFLAGS_FOR_BUILD}])
 413   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[char foo;]])],
 414       [ AC_MSG_RESULT([yes]) ],
 415       [ AC_MSG_RESULT([no])
 416         CFLAGS="$saved_CFLAGS"
 417       ])
 418
 419   AC_MSG_CHECKING([for working native compiler: ${CC_FOR_BUILD}])
 420   AC_RUN_IFELSE(
 421     [AC_LANG_PROGRAM([], [])],
 422     [working_native_cc=yes],
 423     [working_native_cc=no],[:])
 424
 425   CFLAGS_FOR_BUILD="$CFLAGS"
 426
 427   # Restore the environment
 428   cross_compiling=$save_cross_compiling
 429   CC="$SAVE_CC"
 430   CFLAGS="$SAVE_CFLAGS"
 431   CPPFLAGS="$SAVE_CPPFLAGS"
 432   LDFLAGS="$SAVE_LDFLAGS"
 433
 434   if test x"$working_native_cc" = x"no"; then
 435     AC_MSG_RESULT([no])
 436     set_precomp=no
 437     m4_define([please_set_for_build], [Please set CC_FOR_BUILD, CFLAGS_FOR_BUILD, CPPFLAGS_FOR_BUILD, and/or LDFLAGS_FOR_BUILD.])
 438     if test x"$use_ecmult_static_precomputation" = x"yes";  then
 439       AC_MSG_ERROR([native compiler ${CC_FOR_BUILD} does not produce working binaries. please_set_for_build])
 440     else
 441       AC_MSG_WARN([Disabling statically generated ecmult table because the native compiler ${CC_FOR_BUILD} does not produce working binaries. please_set_for_build])
 442     fi
 443   else
 444     AC_MSG_RESULT([yes])
 445     set_precomp=yes
 446   fi
 447 else
 448   set_precomp=no
 449 fi
 450
 451 if test x"$set_precomp" = x"yes"; then
 452   AC_DEFINE(USE_ECMULT_STATIC_PRECOMPUTATION, 1, [Define this symbol to use a statically generated ecmult table])
 453 fi
 454
 455 ###
 456 ### Handle module options
 457 ###
 458
 459 if test x"$enable_module_ecdh" = x"yes"; then
 460   AC_DEFINE(ENABLE_MODULE_ECDH, 1, [Define this symbol to enable the ECDH module])
 461 fi
 462
 463 if test x"$enable_module_recovery" = x"yes"; then
 464   AC_DEFINE(ENABLE_MODULE_RECOVERY, 1, [Define this symbol to enable the ECDSA pubkey recovery module])
 465 fi
 466
 467 if test x"$enable_module_schnorrsig" = x"yes"; then
 468   AC_DEFINE(ENABLE_MODULE_SCHNORRSIG, 1, [Define this symbol to enable the schnorrsig module])
 469   enable_module_extrakeys=yes
 470 fi
 471
 472 # Test if extrakeys is set after the schnorrsig module to allow the schnorrsig
 473 # module to set enable_module_extrakeys=yes
 474 if test x"$enable_module_extrakeys" = x"yes"; then
 475   AC_DEFINE(ENABLE_MODULE_EXTRAKEYS, 1, [Define this symbol to enable the extrakeys module])
 476 fi
 477
 478 if test x"$use_external_default_callbacks" = x"yes"; then
 479   AC_DEFINE(USE_EXTERNAL_DEFAULT_CALLBACKS, 1, [Define this symbol if an external implementation of the default callbacks is used])
 480 fi
 481
 482 ###
 483 ### Check for --enable-experimental if necessary
 484 ###
 485
 486 if test x"$enable_experimental" = x"yes"; then
 487   AC_MSG_NOTICE([******])
 488   AC_MSG_NOTICE([WARNING: experimental build])
 489   AC_MSG_NOTICE([Experimental features do not have stable APIs or properties, and may not be safe for production use.])
 490   AC_MSG_NOTICE([Building extrakeys module: $enable_module_extrakeys])
 491   AC_MSG_NOTICE([Building schnorrsig module: $enable_module_schnorrsig])
 492   AC_MSG_NOTICE([******])
 493 else
 494   if test x"$enable_module_extrakeys" = x"yes"; then
 495     AC_MSG_ERROR([extrakeys module is experimental. Use --enable-experimental to allow.])
 496   fi
 497   if test x"$enable_module_schnorrsig" = x"yes"; then
 498     AC_MSG_ERROR([schnorrsig module is experimental. Use --enable-experimental to allow.])
 499   fi
 500   if test x"$set_asm" = x"arm"; then
 501     AC_MSG_ERROR([ARM assembly optimization is experimental. Use --enable-experimental to allow.])
 502   fi
 503 fi
 504
 505 ###
 506 ### Generate output
 507 ###
 508
 509 AC_CONFIG_HEADERS([src/libsecp256k1-config.h])
 510 AC_CONFIG_FILES([Makefile libsecp256k1.pc])
 511 AC_SUBST(SECP_INCLUDES)
 512 AC_SUBST(SECP_LIBS)
 513 AC_SUBST(SECP_TEST_LIBS)
 514 AC_SUBST(SECP_TEST_INCLUDES)
 515 AM_CONDITIONAL([ENABLE_COVERAGE], [test x"$enable_coverage" = x"yes"])
 516 AM_CONDITIONAL([USE_TESTS], [test x"$use_tests" != x"no"])
 517 AM_CONDITIONAL([USE_EXHAUSTIVE_TESTS], [test x"$use_exhaustive_tests" != x"no"])
 518 AM_CONDITIONAL([USE_BENCHMARK], [test x"$use_benchmark" = x"yes"])
 519 AM_CONDITIONAL([USE_ECMULT_STATIC_PRECOMPUTATION], [test x"$set_precomp" = x"yes"])
 520 AM_CONDITIONAL([ENABLE_MODULE_ECDH], [test x"$enable_module_ecdh" = x"yes"])
 521 AM_CONDITIONAL([ENABLE_MODULE_RECOVERY], [test x"$enable_module_recovery" = x"yes"])
 522 AM_CONDITIONAL([ENABLE_MODULE_EXTRAKEYS], [test x"$enable_module_extrakeys" = x"yes"])
 523 AM_CONDITIONAL([ENABLE_MODULE_SCHNORRSIG], [test x"$enable_module_schnorrsig" = x"yes"])
 524 AM_CONDITIONAL([USE_EXTERNAL_ASM], [test x"$use_external_asm" = x"yes"])
 525 AM_CONDITIONAL([USE_ASM_ARM], [test x"$set_asm" = x"arm"])
 526
 527 # Make sure nothing new is exported so that we don't break the cache.
 528 PKGCONFIG_PATH_TEMP="$PKG_CONFIG_PATH"
 529 unset PKG_CONFIG_PATH
 530 PKG_CONFIG_PATH="$PKGCONFIG_PATH_TEMP"
 531
 532 AC_OUTPUT
 533
 534 echo
 535 echo "Build Options:"
 536 echo "  with ecmult precomp     = $set_precomp"
 537 echo "  with external callbacks = $use_external_default_callbacks"
 538 echo "  with benchmarks         = $use_benchmark"
 539 echo "  with tests              = $use_tests"
 540 echo "  with openssl tests      = $enable_openssl_tests"
 541 echo "  with coverage           = $enable_coverage"
 542 echo "  module ecdh             = $enable_module_ecdh"
 543 echo "  module recovery         = $enable_module_recovery"
 544 echo "  module extrakeys        = $enable_module_extrakeys"
 545 echo "  module schnorrsig       = $enable_module_schnorrsig"
 546 echo
 547 echo "  asm                     = $set_asm"
 548 echo "  bignum                  = $set_bignum"
 549 echo "  ecmult window size      = $set_ecmult_window"
 550 echo "  ecmult gen prec. bits   = $set_ecmult_gen_precision"
 551 # Hide test-only options unless they're used.
 552 if test x"$set_widemul" != xauto; then
 553 echo "  wide multiplication     = $set_widemul"
 554 fi
 555 echo
 556 echo "  valgrind                = $enable_valgrind"
 557 echo "  CC                      = $CC"
 558 echo "  CFLAGS                  = $CFLAGS"
 559 echo "  CPPFLAGS                = $CPPFLAGS"
 560 echo "  LDFLAGS                 = $LDFLAGS"
 561 echo