meson.build

   1 project('qemu', ['c'], meson_version: '>=0.61.3',
   2         default_options: ['warning_level=1', 'c_std=gnu11', 'cpp_std=gnu++11', 'b_colorout=auto',
   3                           'b_staticpic=false', 'stdsplit=false', 'optimization=2', 'b_pie=true'],
   4         version: files('VERSION'))
   5
   6 add_test_setup('quick', exclude_suites: ['slow', 'thorough'], is_default: true)
   7 add_test_setup('slow', exclude_suites: ['thorough'], env: ['G_TEST_SLOW=1', 'SPEED=slow'])
   8 add_test_setup('thorough', env: ['G_TEST_SLOW=1', 'SPEED=thorough'])
   9
  10 meson.add_postconf_script(find_program('scripts/symlink-install-tree.py'))
  11
  12 not_found = dependency('', required: false)
  13 keyval = import('keyval')
  14 ss = import('sourceset')
  15 fs = import('fs')
  16
  17 sh = find_program('sh')
  18 cc = meson.get_compiler('c')
  19 config_host = keyval.load(meson.current_build_dir() / 'config-host.mak')
  20 enable_modules = 'CONFIG_MODULES' in config_host
  21 enable_static = 'CONFIG_STATIC' in config_host
  22
  23 # Allow both shared and static libraries unless --enable-static
  24 static_kwargs = enable_static ? {'static': true} : {}
  25
  26 # Temporary directory used for files created while
  27 # configure runs. Since it is in the build directory
  28 # we can safely blow away any previous version of it
  29 # (and we need not jump through hoops to try to delete
  30 # it when configure exits.)
  31 tmpdir = meson.current_build_dir() / 'meson-private/temp'
  32
  33 if get_option('qemu_suffix').startswith('/')
  34   error('qemu_suffix cannot start with a /')
  35 endif
  36
  37 qemu_confdir = get_option('sysconfdir') / get_option('qemu_suffix')
  38 qemu_datadir = get_option('datadir') / get_option('qemu_suffix')
  39 qemu_docdir = get_option('docdir') / get_option('qemu_suffix')
  40 qemu_moddir = get_option('libdir') / get_option('qemu_suffix')
  41
  42 qemu_desktopdir = get_option('datadir') / 'applications'
  43 qemu_icondir = get_option('datadir') / 'icons'
  44
  45 config_host_data = configuration_data()
  46 genh = []
  47 qapi_trace_events = []
  48
  49 bsd_oses = ['gnu/kfreebsd', 'freebsd', 'netbsd', 'openbsd', 'dragonfly', 'darwin']
  50 supported_oses = ['windows', 'freebsd', 'netbsd', 'openbsd', 'darwin', 'sunos', 'linux']
  51 supported_cpus = ['ppc', 'ppc64', 's390x', 'riscv', 'x86', 'x86_64',
  52   'arm', 'aarch64', 'loongarch64', 'mips', 'mips64', 'sparc', 'sparc64']
  53
  54 cpu = host_machine.cpu_family()
  55
  56 # Unify riscv* to a single family.
  57 if cpu in ['riscv32', 'riscv64']
  58   cpu = 'riscv'
  59 endif
  60
  61 targetos = host_machine.system()
  62
  63 target_dirs = config_host['TARGET_DIRS'].split()
  64 have_linux_user = false
  65 have_bsd_user = false
  66 have_system = false
  67 foreach target : target_dirs
  68   have_linux_user = have_linux_user or target.endswith('linux-user')
  69   have_bsd_user = have_bsd_user or target.endswith('bsd-user')
  70   have_system = have_system or target.endswith('-softmmu')
  71 endforeach
  72 have_user = have_linux_user or have_bsd_user
  73 have_tools = get_option('tools') \
  74   .disable_auto_if(not have_system) \
  75   .allowed()
  76 have_ga = get_option('guest_agent') \
  77   .disable_auto_if(not have_system and not have_tools) \
  78   .require(targetos in ['sunos', 'linux', 'windows'],
  79            error_message: 'unsupported OS for QEMU guest agent') \
  80   .allowed()
  81 have_block = have_system or have_tools
  82
  83 python = import('python').find_installation()
  84
  85 if cpu not in supported_cpus
  86   host_arch = 'unknown'
  87 elif cpu == 'x86'
  88   host_arch = 'i386'
  89 elif cpu == 'mips64'
  90   host_arch = 'mips'
  91 else
  92   host_arch = cpu
  93 endif
  94
  95 if cpu in ['x86', 'x86_64']
  96   kvm_targets = ['i386-softmmu', 'x86_64-softmmu']
  97 elif cpu == 'aarch64'
  98   kvm_targets = ['aarch64-softmmu']
  99 elif cpu == 's390x'
 100   kvm_targets = ['s390x-softmmu']
 101 elif cpu in ['ppc', 'ppc64']
 102   kvm_targets = ['ppc-softmmu', 'ppc64-softmmu']
 103 elif cpu in ['mips', 'mips64']
 104   kvm_targets = ['mips-softmmu', 'mipsel-softmmu', 'mips64-softmmu', 'mips64el-softmmu']
 105 elif cpu in ['riscv']
 106   kvm_targets = ['riscv32-softmmu', 'riscv64-softmmu']
 107 else
 108   kvm_targets = []
 109 endif
 110
 111 kvm_targets_c = '""'
 112 if get_option('kvm').allowed() and targetos == 'linux'
 113   kvm_targets_c = '"' + '" ,"'.join(kvm_targets) + '"'
 114 endif
 115 config_host_data.set('CONFIG_KVM_TARGETS', kvm_targets_c)
 116
 117 accelerator_targets = { 'CONFIG_KVM': kvm_targets }
 118
 119 if cpu in ['aarch64']
 120   accelerator_targets += {
 121     'CONFIG_HVF': ['aarch64-softmmu']
 122   }
 123 endif
 124
 125 if cpu in ['x86', 'x86_64', 'arm', 'aarch64']
 126   # i386 emulator provides xenpv machine type for multiple architectures
 127   accelerator_targets += {
 128     'CONFIG_XEN': ['i386-softmmu', 'x86_64-softmmu'],
 129   }
 130 endif
 131 if cpu in ['x86', 'x86_64']
 132   accelerator_targets += {
 133     'CONFIG_HAX': ['i386-softmmu', 'x86_64-softmmu'],
 134     'CONFIG_HVF': ['x86_64-softmmu'],
 135     'CONFIG_NVMM': ['i386-softmmu', 'x86_64-softmmu'],
 136     'CONFIG_WHPX': ['i386-softmmu', 'x86_64-softmmu'],
 137   }
 138 endif
 139
 140 modular_tcg = []
 141 # Darwin does not support references to thread-local variables in modules
 142 if targetos != 'darwin'
 143   modular_tcg = ['i386-softmmu', 'x86_64-softmmu']
 144 endif
 145
 146 edk2_targets = [ 'arm-softmmu', 'aarch64-softmmu', 'i386-softmmu', 'x86_64-softmmu' ]
 147 unpack_edk2_blobs = false
 148 foreach target : edk2_targets
 149   if target in target_dirs
 150     bzip2 = find_program('bzip2', required: get_option('install_blobs'))
 151     unpack_edk2_blobs = bzip2.found()
 152     break
 153   endif
 154 endforeach
 155
 156 dtrace = not_found
 157 stap = not_found
 158 if 'dtrace' in get_option('trace_backends')
 159   dtrace = find_program('dtrace', required: true)
 160   stap = find_program('stap', required: false)
 161   if stap.found()
 162     # Workaround to avoid dtrace(1) producing a file with 'hidden' symbol
 163     # visibility. Define STAP_SDT_V2 to produce 'default' symbol visibility
 164     # instead. QEMU --enable-modules depends on this because the SystemTap
 165     # semaphores are linked into the main binary and not the module's shared
 166     # object.
 167     add_global_arguments('-DSTAP_SDT_V2',
 168                          native: false, language: ['c', 'cpp', 'objc'])
 169   endif
 170 endif
 171
 172 if get_option('iasl') == ''
 173   iasl = find_program('iasl', required: false)
 174 else
 175   iasl = find_program(get_option('iasl'), required: true)
 176 endif
 177
 178 ##################
 179 # Compiler flags #
 180 ##################
 181
 182 qemu_cflags = config_host['QEMU_CFLAGS'].split()
 183 qemu_objcflags = config_host['QEMU_OBJCFLAGS'].split()
 184 qemu_ldflags = config_host['QEMU_LDFLAGS'].split()
 185
 186 if enable_static
 187   qemu_ldflags += get_option('b_pie') ? '-static-pie' : '-static'
 188 endif
 189
 190 # Detect support for PT_GNU_RELRO + DT_BIND_NOW.
 191 # The combination is known as "full relro", because .got.plt is read-only too.
 192 qemu_ldflags += cc.get_supported_link_arguments('-Wl,-z,relro', '-Wl,-z,now')
 193
 194 if targetos == 'windows'
 195   qemu_ldflags += cc.get_supported_link_arguments('-Wl,--no-seh', '-Wl,--nxcompat')
 196   # Disable ASLR for debug builds to allow debugging with gdb
 197   if get_option('optimization') == '0'
 198     qemu_ldflags += cc.get_supported_link_arguments('-Wl,--dynamicbase')
 199   endif
 200 endif
 201
 202 if get_option('gprof')
 203   qemu_cflags += ['-p']
 204   qemu_objcflags += ['-p']
 205   qemu_ldflags += ['-p']
 206 endif
 207
 208 # Specify linker-script with add_project_link_arguments so that it is not placed
 209 # within a linker --start-group/--end-group pair
 210 if get_option('fuzzing')
 211   add_project_link_arguments(['-Wl,-T,',
 212                               (meson.current_source_dir() / 'tests/qtest/fuzz/fork_fuzz.ld')],
 213                              native: false, language: ['c', 'cpp', 'objc'])
 214
 215   # Specify a filter to only instrument code that is directly related to
 216   # virtual-devices.
 217   configure_file(output: 'instrumentation-filter',
 218                  input: 'scripts/oss-fuzz/instrumentation-filter-template',
 219                  copy: true)
 220
 221   if cc.compiles('int main () { return 0; }',
 222                   name: '-fsanitize-coverage-allowlist=/dev/null',
 223                  args: ['-fsanitize-coverage-allowlist=/dev/null',
 224                         '-fsanitize-coverage=trace-pc'] )
 225     add_global_arguments('-fsanitize-coverage-allowlist=instrumentation-filter',
 226                          native: false, language: ['c', 'cpp', 'objc'])
 227   endif
 228
 229   if get_option('fuzzing_engine') == ''
 230     # Add CFLAGS to tell clang to add fuzzer-related instrumentation to all the
 231     # compiled code.  To build non-fuzzer binaries with --enable-fuzzing, link
 232     # everything with fsanitize=fuzzer-no-link. Otherwise, the linker will be
 233     # unable to bind the fuzzer-related callbacks added by instrumentation.
 234     add_global_arguments('-fsanitize=fuzzer-no-link',
 235                          native: false, language: ['c', 'cpp', 'objc'])
 236     add_global_link_arguments('-fsanitize=fuzzer-no-link',
 237                               native: false, language: ['c', 'cpp', 'objc'])
 238     # For the actual fuzzer binaries, we need to link against the libfuzzer
 239     # library. They need to be configurable, to support OSS-Fuzz
 240     fuzz_exe_ldflags = ['-fsanitize=fuzzer']
 241   else
 242     # LIB_FUZZING_ENGINE was set; assume we are running on OSS-Fuzz, and
 243     # the needed CFLAGS have already been provided
 244     fuzz_exe_ldflags = get_option('fuzzing_engine').split()
 245   endif
 246 endif
 247
 248 add_global_arguments(qemu_cflags, native: false, language: ['c'])
 249 add_global_arguments(qemu_objcflags, native: false, language: ['objc'])
 250
 251 # Check that the C++ compiler exists and works with the C compiler.
 252 link_language = 'c'
 253 linker = cc
 254 qemu_cxxflags = []
 255 if add_languages('cpp', required: false, native: false)
 256   cxx = meson.get_compiler('cpp')
 257   add_global_arguments(['-D__STDC_LIMIT_MACROS', '-D__STDC_CONSTANT_MACROS', '-D__STDC_FORMAT_MACROS'],
 258                        native: false, language: 'cpp')
 259   foreach k: qemu_cflags
 260     if k not in ['-Wstrict-prototypes', '-Wmissing-prototypes', '-Wnested-externs',
 261                  '-Wold-style-declaration', '-Wold-style-definition', '-Wredundant-decls']
 262       qemu_cxxflags += [k]
 263     endif
 264   endforeach
 265   add_global_arguments(qemu_cxxflags, native: false, language: 'cpp')
 266
 267   if cxx.links(files('scripts/main.c'), args: qemu_cflags)
 268     link_language = 'cpp'
 269     linker = cxx
 270   else
 271     message('C++ compiler does not work with C compiler')
 272     message('Disabling C++-specific optional code')
 273   endif
 274 endif
 275
 276 # Exclude --warn-common with TSan to suppress warnings from the TSan libraries.
 277 if targetos != 'sunos' and not config_host.has_key('CONFIG_TSAN')
 278   qemu_ldflags += linker.get_supported_link_arguments('-Wl,--warn-common')
 279 endif
 280
 281 add_global_link_arguments(qemu_ldflags, native: false, language: ['c', 'cpp', 'objc'])
 282
 283 if targetos == 'linux'
 284   add_project_arguments('-isystem', meson.current_source_dir() / 'linux-headers',
 285                         '-isystem', 'linux-headers',
 286                         language: ['c', 'cpp'])
 287 endif
 288
 289 add_project_arguments('-iquote', '.',
 290                       '-iquote', meson.current_source_dir(),
 291                       '-iquote', meson.current_source_dir() / 'include',
 292                       language: ['c', 'cpp', 'objc'])
 293
 294 if host_machine.system() == 'darwin'
 295   add_languages('objc', required: false, native: false)
 296 endif
 297
 298 sparse = find_program('cgcc', required: get_option('sparse'))
 299 if sparse.found()
 300   run_target('sparse',
 301              command: [find_program('scripts/check_sparse.py'),
 302                        'compile_commands.json', sparse.full_path(), '-Wbitwise',
 303                        '-Wno-transparent-union', '-Wno-old-initializer',
 304                        '-Wno-non-pointer-null'])
 305 endif
 306
 307 ###########################################
 308 # Target-specific checks and dependencies #
 309 ###########################################
 310
 311 # Fuzzing
 312 if get_option('fuzzing') and get_option('fuzzing_engine') == '' and \
 313     not cc.links('''
 314           #include <stdint.h>
 315           #include <sys/types.h>
 316           int LLVMFuzzerTestOneInput(const uint8_t *Data, size_t Size);
 317           int LLVMFuzzerTestOneInput(const uint8_t *Data, size_t Size) { return 0; }
 318         ''',
 319         args: ['-Werror', '-fsanitize=fuzzer'])
 320   error('Your compiler does not support -fsanitize=fuzzer')
 321 endif
 322
 323 # Tracing backends
 324 if 'ftrace' in get_option('trace_backends') and targetos != 'linux'
 325   error('ftrace is supported only on Linux')
 326 endif
 327 if 'syslog' in get_option('trace_backends') and not cc.compiles('''
 328     #include <syslog.h>
 329     int main(void) {
 330         openlog("qemu", LOG_PID, LOG_DAEMON);
 331         syslog(LOG_INFO, "configure");
 332         return 0;
 333     }''')
 334   error('syslog is not supported on this system')
 335 endif
 336
 337 # Miscellaneous Linux-only features
 338 get_option('mpath') \
 339   .require(targetos == 'linux', error_message: 'Multipath is supported only on Linux')
 340
 341 multiprocess_allowed = get_option('multiprocess') \
 342   .require(targetos == 'linux', error_message: 'Multiprocess QEMU is supported only on Linux') \
 343   .allowed()
 344
 345 vfio_user_server_allowed = get_option('vfio_user_server') \
 346   .require(targetos == 'linux', error_message: 'vfio-user server is supported only on Linux') \
 347   .allowed()
 348
 349 have_tpm = get_option('tpm') \
 350   .require(targetos != 'windows', error_message: 'TPM emulation only available on POSIX systems') \
 351   .allowed()
 352
 353 # vhost
 354 have_vhost_user = get_option('vhost_user') \
 355   .disable_auto_if(targetos != 'linux') \
 356   .require(targetos != 'windows',
 357            error_message: 'vhost-user is not available on Windows').allowed()
 358 have_vhost_vdpa = get_option('vhost_vdpa') \
 359   .require(targetos == 'linux',
 360            error_message: 'vhost-vdpa is only available on Linux').allowed()
 361 have_vhost_kernel = get_option('vhost_kernel') \
 362   .require(targetos == 'linux',
 363            error_message: 'vhost-kernel is only available on Linux').allowed()
 364 have_vhost_user_crypto = get_option('vhost_crypto') \
 365   .require(have_vhost_user,
 366            error_message: 'vhost-crypto requires vhost-user to be enabled').allowed()
 367
 368 have_vhost = have_vhost_user or have_vhost_vdpa or have_vhost_kernel
 369
 370 have_vhost_net_user = have_vhost_user and get_option('vhost_net').allowed()
 371 have_vhost_net_vdpa = have_vhost_vdpa and get_option('vhost_net').allowed()
 372 have_vhost_net_kernel = have_vhost_kernel and get_option('vhost_net').allowed()
 373 have_vhost_net = have_vhost_net_kernel or have_vhost_net_user or have_vhost_net_vdpa
 374
 375 # Target-specific libraries and flags
 376 libm = cc.find_library('m', required: false)
 377 threads = dependency('threads')
 378 util = cc.find_library('util', required: false)
 379 winmm = []
 380 socket = []
 381 version_res = []
 382 coref = []
 383 iokit = []
 384 emulator_link_args = []
 385 nvmm =not_found
 386 hvf = not_found
 387 midl = not_found
 388 widl = not_found
 389 pathcch = not_found
 390 host_dsosuf = '.so'
 391 if targetos == 'windows'
 392   midl = find_program('midl', required: false)
 393   widl = find_program('widl', required: false)
 394   pathcch = cc.find_library('pathcch')
 395   socket = cc.find_library('ws2_32')
 396   winmm = cc.find_library('winmm')
 397
 398   win = import('windows')
 399   version_res = win.compile_resources('version.rc',
 400                                       depend_files: files('pc-bios/qemu-nsis.ico'),
 401                                       include_directories: include_directories('.'))
 402   host_dsosuf = '.dll'
 403 elif targetos == 'darwin'
 404   coref = dependency('appleframeworks', modules: 'CoreFoundation')
 405   iokit = dependency('appleframeworks', modules: 'IOKit', required: false)
 406   host_dsosuf = '.dylib'
 407 elif targetos == 'sunos'
 408   socket = [cc.find_library('socket'),
 409             cc.find_library('nsl'),
 410             cc.find_library('resolv')]
 411 elif targetos == 'haiku'
 412   socket = [cc.find_library('posix_error_mapper'),
 413             cc.find_library('network'),
 414             cc.find_library('bsd')]
 415 elif targetos == 'openbsd'
 416   if get_option('tcg').allowed() and target_dirs.length() > 0
 417     # Disable OpenBSD W^X if available
 418     emulator_link_args = cc.get_supported_link_arguments('-Wl,-z,wxneeded')
 419   endif
 420 endif
 421
 422 # Target-specific configuration of accelerators
 423 accelerators = []
 424 if get_option('kvm').allowed() and targetos == 'linux'
 425   accelerators += 'CONFIG_KVM'
 426 endif
 427 if get_option('whpx').allowed() and targetos == 'windows'
 428   if get_option('whpx').enabled() and host_machine.cpu() != 'x86_64'
 429     error('WHPX requires 64-bit host')
 430   elif cc.has_header('WinHvPlatform.h', required: get_option('whpx')) and \
 431        cc.has_header('WinHvEmulation.h', required: get_option('whpx'))
 432     accelerators += 'CONFIG_WHPX'
 433   endif
 434 endif
 435 if get_option('hvf').allowed()
 436   hvf = dependency('appleframeworks', modules: 'Hypervisor',
 437                    required: get_option('hvf'))
 438   if hvf.found()
 439     accelerators += 'CONFIG_HVF'
 440   endif
 441 endif
 442 if get_option('hax').allowed()
 443   if get_option('hax').enabled() or targetos in ['windows', 'darwin', 'netbsd']
 444     accelerators += 'CONFIG_HAX'
 445   endif
 446 endif
 447 if targetos == 'netbsd'
 448   nvmm = cc.find_library('nvmm', required: get_option('nvmm'))
 449   if nvmm.found()
 450     accelerators += 'CONFIG_NVMM'
 451   endif
 452 endif
 453
 454 tcg_arch = host_arch
 455 if get_option('tcg').allowed()
 456   if host_arch == 'unknown'
 457     if get_option('tcg_interpreter')
 458       warning('Unsupported CPU @0@, will use TCG with TCI (slow)'.format(cpu))
 459     else
 460       error('Unsupported CPU @0@, try --enable-tcg-interpreter'.format(cpu))
 461     endif
 462   elif get_option('tcg_interpreter')
 463     warning('Use of the TCG interpreter is not recommended on this host')
 464     warning('architecture. There is a native TCG execution backend available')
 465     warning('which provides substantially better performance and reliability.')
 466     warning('It is strongly recommended to remove the --enable-tcg-interpreter')
 467     warning('configuration option on this architecture to use the native')
 468     warning('backend.')
 469   endif
 470   if get_option('tcg_interpreter')
 471     tcg_arch = 'tci'
 472   elif host_arch == 'sparc64'
 473     tcg_arch = 'sparc'
 474   elif host_arch == 'x86_64'
 475     tcg_arch = 'i386'
 476   elif host_arch == 'ppc64'
 477     tcg_arch = 'ppc'
 478   endif
 479   add_project_arguments('-iquote', meson.current_source_dir() / 'tcg' / tcg_arch,
 480                         language: ['c', 'cpp', 'objc'])
 481
 482   accelerators += 'CONFIG_TCG'
 483   config_host += { 'CONFIG_TCG': 'y' }
 484 endif
 485
 486 if 'CONFIG_KVM' not in accelerators and get_option('kvm').enabled()
 487   error('KVM not available on this platform')
 488 endif
 489 if 'CONFIG_HVF' not in accelerators and get_option('hvf').enabled()
 490   error('HVF not available on this platform')
 491 endif
 492 if 'CONFIG_NVMM' not in accelerators and get_option('nvmm').enabled()
 493   error('NVMM not available on this platform')
 494 endif
 495 if 'CONFIG_WHPX' not in accelerators and get_option('whpx').enabled()
 496   error('WHPX not available on this platform')
 497 endif
 498
 499 ################
 500 # Dependencies #
 501 ################
 502
 503 # The path to glib.h is added to all compilation commands.  This was
 504 # grandfathered in from the QEMU Makefiles.
 505 add_project_arguments(config_host['GLIB_CFLAGS'].split(),
 506                       native: false, language: ['c', 'cpp', 'objc'])
 507 glib = declare_dependency(compile_args: config_host['GLIB_CFLAGS'].split(),
 508                           link_args: config_host['GLIB_LIBS'].split(),
 509                           version: config_host['GLIB_VERSION'],
 510                           variables: {
 511                             'bindir': config_host['GLIB_BINDIR'],
 512                           })
 513 # override glib dep with the configure results (for subprojects)
 514 meson.override_dependency('glib-2.0', glib)
 515
 516 gio = not_found
 517 gdbus_codegen = not_found
 518 gdbus_codegen_error = '@0@ requires gdbus-codegen, please install libgio'
 519 if not get_option('gio').auto() or have_system
 520   gio = dependency('gio-2.0', required: get_option('gio'),
 521                    method: 'pkg-config', kwargs: static_kwargs)
 522   if gio.found() and not cc.links('''
 523     #include <gio/gio.h>
 524     int main(void)
 525     {
 526       g_dbus_proxy_new_sync(0, 0, 0, 0, 0, 0, 0, 0);
 527       return 0;
 528     }''', dependencies: [glib, gio])
 529     if get_option('gio').enabled()
 530       error('The installed libgio is broken for static linking')
 531     endif
 532     gio = not_found
 533   endif
 534   if gio.found()
 535     gdbus_codegen = find_program(gio.get_variable('gdbus_codegen'),
 536                                  required: get_option('gio'))
 537     gio_unix = dependency('gio-unix-2.0', required: get_option('gio'),
 538                           method: 'pkg-config', kwargs: static_kwargs)
 539     gio = declare_dependency(dependencies: [gio, gio_unix],
 540                              version: gio.version())
 541   endif
 542 endif
 543 if gdbus_codegen.found() and get_option('cfi')
 544   gdbus_codegen = not_found
 545   gdbus_codegen_error = '@0@ uses gdbus-codegen, which does not support control flow integrity'
 546 endif
 547
 548 lttng = not_found
 549 if 'ust' in get_option('trace_backends')
 550   lttng = dependency('lttng-ust', required: true, version: '>= 2.1',
 551                      method: 'pkg-config', kwargs: static_kwargs)
 552 endif
 553 pixman = not_found
 554 if have_system or have_tools
 555   pixman = dependency('pixman-1', required: have_system, version:'>=0.21.8',
 556                       method: 'pkg-config', kwargs: static_kwargs)
 557 endif
 558 zlib = dependency('zlib', required: true, kwargs: static_kwargs)
 559
 560 libaio = not_found
 561 if not get_option('linux_aio').auto() or have_block
 562   libaio = cc.find_library('aio', has_headers: ['libaio.h'],
 563                            required: get_option('linux_aio'),
 564                            kwargs: static_kwargs)
 565 endif
 566
 567 linux_io_uring_test = '''
 568   #include <liburing.h>
 569   #include <linux/errqueue.h>
 570
 571   int main(void) { return 0; }'''
 572
 573 linux_io_uring = not_found
 574 if not get_option('linux_io_uring').auto() or have_block
 575   linux_io_uring = dependency('liburing', version: '>=0.3',
 576                               required: get_option('linux_io_uring'),
 577                               method: 'pkg-config', kwargs: static_kwargs)
 578   if not cc.links(linux_io_uring_test)
 579     linux_io_uring = not_found
 580   endif
 581 endif
 582
 583 libnfs = not_found
 584 if not get_option('libnfs').auto() or have_block
 585   libnfs = dependency('libnfs', version: '>=1.9.3',
 586                       required: get_option('libnfs'),
 587                       method: 'pkg-config', kwargs: static_kwargs)
 588 endif
 589
 590 libattr_test = '''
 591   #include <stddef.h>
 592   #include <sys/types.h>
 593   #ifdef CONFIG_LIBATTR
 594   #include <attr/xattr.h>
 595   #else
 596   #include <sys/xattr.h>
 597   #endif
 598   int main(void) { getxattr(NULL, NULL, NULL, 0); setxattr(NULL, NULL, NULL, 0, 0); return 0; }'''
 599
 600 libattr = not_found
 601 have_old_libattr = false
 602 if get_option('attr').allowed()
 603   if cc.links(libattr_test)
 604     libattr = declare_dependency()
 605   else
 606     libattr = cc.find_library('attr', has_headers: ['attr/xattr.h'],
 607                               required: get_option('attr'),
 608                               kwargs: static_kwargs)
 609     if libattr.found() and not \
 610       cc.links(libattr_test, dependencies: libattr, args: '-DCONFIG_LIBATTR')
 611       libattr = not_found
 612       if get_option('attr').enabled()
 613         error('could not link libattr')
 614       else
 615         warning('could not link libattr, disabling')
 616       endif
 617     else
 618       have_old_libattr = libattr.found()
 619     endif
 620   endif
 621 endif
 622
 623 cocoa = dependency('appleframeworks', modules: ['Cocoa', 'CoreVideo'],
 624                    required: get_option('cocoa'))
 625
 626 vmnet = dependency('appleframeworks', modules: 'vmnet', required: get_option('vmnet'))
 627 if vmnet.found() and not cc.has_header_symbol('vmnet/vmnet.h',
 628                                               'VMNET_BRIDGED_MODE',
 629                                               dependencies: vmnet)
 630   vmnet = not_found
 631   if get_option('vmnet').enabled()
 632     error('vmnet.framework API is outdated')
 633   else
 634     warning('vmnet.framework API is outdated, disabling')
 635   endif
 636 endif
 637
 638 seccomp = not_found
 639 seccomp_has_sysrawrc = false
 640 if not get_option('seccomp').auto() or have_system or have_tools
 641   seccomp = dependency('libseccomp', version: '>=2.3.0',
 642                        required: get_option('seccomp'),
 643                        method: 'pkg-config', kwargs: static_kwargs)
 644   if seccomp.found()
 645     seccomp_has_sysrawrc = cc.has_header_symbol('seccomp.h',
 646                                                 'SCMP_FLTATR_API_SYSRAWRC',
 647                                                 dependencies: seccomp)
 648   endif
 649 endif
 650
 651 libcap_ng = not_found
 652 if not get_option('cap_ng').auto() or have_system or have_tools
 653   libcap_ng = cc.find_library('cap-ng', has_headers: ['cap-ng.h'],
 654                               required: get_option('cap_ng'),
 655                               kwargs: static_kwargs)
 656 endif
 657 if libcap_ng.found() and not cc.links('''
 658    #include <cap-ng.h>
 659    int main(void)
 660    {
 661      capng_capability_to_name(CAPNG_EFFECTIVE);
 662      return 0;
 663    }''', dependencies: libcap_ng)
 664   libcap_ng = not_found
 665   if get_option('cap_ng').enabled()
 666     error('could not link libcap-ng')
 667   else
 668     warning('could not link libcap-ng, disabling')
 669   endif
 670 endif
 671
 672 if get_option('xkbcommon').auto() and not have_system and not have_tools
 673   xkbcommon = not_found
 674 else
 675   xkbcommon = dependency('xkbcommon', required: get_option('xkbcommon'),
 676                          method: 'pkg-config', kwargs: static_kwargs)
 677 endif
 678
 679 slirp = not_found
 680 if not get_option('slirp').auto() or have_system
 681   slirp = dependency('slirp', required: get_option('slirp'),
 682                      method: 'pkg-config', kwargs: static_kwargs)
 683   # slirp < 4.7 is incompatible with CFI support in QEMU.  This is because
 684   # it passes function pointers within libslirp as callbacks for timers.
 685   # When using a system-wide shared libslirp, the type information for the
 686   # callback is missing and the timer call produces a false positive with CFI.
 687   # Do not use the "version" keyword argument to produce a better error.
 688   # with control-flow integrity.
 689   if get_option('cfi') and slirp.found() and slirp.version().version_compare('<4.7')
 690     if get_option('slirp').enabled()
 691       error('Control-Flow Integrity requires libslirp 4.7.')
 692     else
 693       warning('Cannot use libslirp since Control-Flow Integrity requires libslirp >= 4.7.')
 694       slirp = not_found
 695     endif
 696   endif
 697 endif
 698
 699 vde = not_found
 700 if not get_option('vde').auto() or have_system or have_tools
 701   vde = cc.find_library('vdeplug', has_headers: ['libvdeplug.h'],
 702                            required: get_option('vde'),
 703                            kwargs: static_kwargs)
 704 endif
 705 if vde.found() and not cc.links('''
 706    #include <libvdeplug.h>
 707    int main(void)
 708    {
 709      struct vde_open_args a = {0, 0, 0};
 710      char s[] = "";
 711      vde_open(s, s, &a);
 712      return 0;
 713    }''', dependencies: vde)
 714   vde = not_found
 715   if get_option('cap_ng').enabled()
 716     error('could not link libvdeplug')
 717   else
 718     warning('could not link libvdeplug, disabling')
 719   endif
 720 endif
 721
 722 pulse = not_found
 723 if not get_option('pa').auto() or (targetos == 'linux' and have_system)
 724   pulse = dependency('libpulse', required: get_option('pa'),
 725                      method: 'pkg-config', kwargs: static_kwargs)
 726 endif
 727 alsa = not_found
 728 if not get_option('alsa').auto() or (targetos == 'linux' and have_system)
 729   alsa = dependency('alsa', required: get_option('alsa'),
 730                     method: 'pkg-config', kwargs: static_kwargs)
 731 endif
 732 jack = not_found
 733 if not get_option('jack').auto() or have_system
 734   jack = dependency('jack', required: get_option('jack'),
 735                     method: 'pkg-config', kwargs: static_kwargs)
 736 endif
 737 sndio = not_found
 738 if not get_option('sndio').auto() or have_system
 739   sndio = dependency('sndio', required: get_option('sndio'),
 740                     method: 'pkg-config', kwargs: static_kwargs)
 741 endif
 742
 743 spice_protocol = not_found
 744 if not get_option('spice_protocol').auto() or have_system
 745   spice_protocol = dependency('spice-protocol', version: '>=0.12.3',
 746                               required: get_option('spice_protocol'),
 747                               method: 'pkg-config', kwargs: static_kwargs)
 748 endif
 749 spice = not_found
 750 if not get_option('spice').auto() or have_system
 751   spice = dependency('spice-server', version: '>=0.12.5',
 752                      required: get_option('spice'),
 753                      method: 'pkg-config', kwargs: static_kwargs)
 754 endif
 755 spice_headers = spice.partial_dependency(compile_args: true, includes: true)
 756
 757 rt = cc.find_library('rt', required: false)
 758
 759 libiscsi = not_found
 760 if not get_option('libiscsi').auto() or have_block
 761   libiscsi = dependency('libiscsi', version: '>=1.9.0',
 762                          required: get_option('libiscsi'),
 763                          method: 'pkg-config', kwargs: static_kwargs)
 764 endif
 765 zstd = not_found
 766 if not get_option('zstd').auto() or have_block
 767   zstd = dependency('libzstd', version: '>=1.4.0',
 768                     required: get_option('zstd'),
 769                     method: 'pkg-config', kwargs: static_kwargs)
 770 endif
 771 virgl = not_found
 772
 773 have_vhost_user_gpu = have_tools and targetos == 'linux' and pixman.found()
 774 if not get_option('virglrenderer').auto() or have_system or have_vhost_user_gpu
 775   virgl = dependency('virglrenderer',
 776                      method: 'pkg-config',
 777                      required: get_option('virglrenderer'),
 778                      kwargs: static_kwargs)
 779 endif
 780 curl = not_found
 781 if not get_option('curl').auto() or have_block
 782   curl = dependency('libcurl', version: '>=7.29.0',
 783                     method: 'pkg-config',
 784                     required: get_option('curl'),
 785                     kwargs: static_kwargs)
 786 endif
 787 libudev = not_found
 788 if targetos == 'linux' and (have_system or have_tools)
 789   libudev = dependency('libudev',
 790                        method: 'pkg-config',
 791                        required: get_option('libudev'),
 792                        kwargs: static_kwargs)
 793 endif
 794
 795 mpathlibs = [libudev]
 796 mpathpersist = not_found
 797 mpathpersist_new_api = false
 798 if targetos == 'linux' and have_tools and get_option('mpath').allowed()
 799   mpath_test_source_new = '''
 800     #include <libudev.h>
 801     #include <mpath_persist.h>
 802     unsigned mpath_mx_alloc_len = 1024;
 803     int logsink;
 804     static struct config *multipath_conf;
 805     extern struct udev *udev;
 806     extern struct config *get_multipath_config(void);
 807     extern void put_multipath_config(struct config *conf);
 808     struct udev *udev;
 809     struct config *get_multipath_config(void) { return multipath_conf; }
 810     void put_multipath_config(struct config *conf) { }
 811     int main(void) {
 812         udev = udev_new();
 813         multipath_conf = mpath_lib_init();
 814         return 0;
 815     }'''
 816   mpath_test_source_old = '''
 817       #include <libudev.h>
 818       #include <mpath_persist.h>
 819       unsigned mpath_mx_alloc_len = 1024;
 820       int logsink;
 821       int main(void) {
 822           struct udev *udev = udev_new();
 823           mpath_lib_init(udev);
 824           return 0;
 825       }'''
 826   libmpathpersist = cc.find_library('mpathpersist',
 827                                     required: get_option('mpath'),
 828                                     kwargs: static_kwargs)
 829   if libmpathpersist.found()
 830     mpathlibs += libmpathpersist
 831     if enable_static
 832       mpathlibs += cc.find_library('devmapper',
 833                                      required: get_option('mpath'),
 834                                      kwargs: static_kwargs)
 835     endif
 836     mpathlibs += cc.find_library('multipath',
 837                                  required: get_option('mpath'),
 838                                  kwargs: static_kwargs)
 839     foreach lib: mpathlibs
 840       if not lib.found()
 841         mpathlibs = []
 842         break
 843       endif
 844     endforeach
 845     if mpathlibs.length() == 0
 846       msg = 'Dependencies missing for libmpathpersist'
 847     elif cc.links(mpath_test_source_new, dependencies: mpathlibs)
 848       mpathpersist = declare_dependency(dependencies: mpathlibs)
 849       mpathpersist_new_api = true
 850     elif cc.links(mpath_test_source_old, dependencies: mpathlibs)
 851       mpathpersist = declare_dependency(dependencies: mpathlibs)
 852     else
 853       msg = 'Cannot detect libmpathpersist API'
 854     endif
 855     if not mpathpersist.found()
 856       if get_option('mpath').enabled()
 857         error(msg)
 858       else
 859         warning(msg + ', disabling')
 860       endif
 861     endif
 862   endif
 863 endif
 864
 865 iconv = not_found
 866 curses = not_found
 867 if have_system and get_option('curses').allowed()
 868   curses_test = '''
 869     #if defined(__APPLE__) || defined(__OpenBSD__)
 870     #define _XOPEN_SOURCE_EXTENDED 1
 871     #endif
 872     #include <locale.h>
 873     #include <curses.h>
 874     #include <wchar.h>
 875     int main(void) {
 876       wchar_t wch = L'w';
 877       setlocale(LC_ALL, "");
 878       resize_term(0, 0);
 879       addwstr(L"wide chars\n");
 880       addnwstr(&wch, 1);
 881       add_wch(WACS_DEGREE);
 882       return 0;
 883     }'''
 884
 885   curses_dep_list = targetos == 'windows' ? ['ncurses', 'ncursesw'] : ['ncursesw']
 886   curses = dependency(curses_dep_list,
 887                       required: false,
 888                       method: 'pkg-config',
 889                       kwargs: static_kwargs)
 890   msg = get_option('curses').enabled() ? 'curses library not found' : ''
 891   curses_compile_args = ['-DNCURSES_WIDECHAR=1']
 892   if curses.found()
 893     if cc.links(curses_test, args: curses_compile_args, dependencies: [curses])
 894       curses = declare_dependency(compile_args: curses_compile_args, dependencies: [curses])
 895     else
 896       msg = 'curses package not usable'
 897       curses = not_found
 898     endif
 899   endif
 900   if not curses.found()
 901     has_curses_h = cc.has_header('curses.h', args: curses_compile_args)
 902     if targetos != 'windows' and not has_curses_h
 903       message('Trying with /usr/include/ncursesw')
 904       curses_compile_args += ['-I/usr/include/ncursesw']
 905       has_curses_h = cc.has_header('curses.h', args: curses_compile_args)
 906     endif
 907     if has_curses_h
 908       curses_libname_list = (targetos == 'windows' ? ['pdcurses'] : ['ncursesw', 'cursesw'])
 909       foreach curses_libname : curses_libname_list
 910         libcurses = cc.find_library(curses_libname,
 911                                     required: false,
 912                                     kwargs: static_kwargs)
 913         if libcurses.found()
 914           if cc.links(curses_test, args: curses_compile_args, dependencies: libcurses)
 915             curses = declare_dependency(compile_args: curses_compile_args,
 916                                         dependencies: [libcurses])
 917             break
 918           else
 919             msg = 'curses library not usable'
 920           endif
 921         endif
 922       endforeach
 923     endif
 924   endif
 925   if get_option('iconv').allowed()
 926     foreach link_args : [ ['-liconv'], [] ]
 927       # Programs will be linked with glib and this will bring in libiconv on FreeBSD.
 928       # We need to use libiconv if available because mixing libiconv's headers with
 929       # the system libc does not work.
 930       # However, without adding glib to the dependencies -L/usr/local/lib will not be
 931       # included in the command line and libiconv will not be found.
 932       if cc.links('''
 933         #include <iconv.h>
 934         int main(void) {
 935           iconv_t conv = iconv_open("WCHAR_T", "UCS-2");
 936           return conv != (iconv_t) -1;
 937         }''', args: config_host['GLIB_CFLAGS'].split() + config_host['GLIB_LIBS'].split() + link_args)
 938         iconv = declare_dependency(link_args: link_args, dependencies: glib)
 939         break
 940       endif
 941     endforeach
 942   endif
 943   if curses.found() and not iconv.found()
 944     if get_option('iconv').enabled()
 945       error('iconv not available')
 946     endif
 947     msg = 'iconv required for curses UI but not available'
 948     curses = not_found
 949   endif
 950   if not curses.found() and msg != ''
 951     if get_option('curses').enabled()
 952       error(msg)
 953     else
 954       warning(msg + ', disabling')
 955     endif
 956   endif
 957 endif
 958
 959 brlapi = not_found
 960 if not get_option('brlapi').auto() or have_system
 961   brlapi = cc.find_library('brlapi', has_headers: ['brlapi.h'],
 962                          required: get_option('brlapi'),
 963                          kwargs: static_kwargs)
 964   if brlapi.found() and not cc.links('''
 965      #include <brlapi.h>
 966      #include <stddef.h>
 967      int main(void) { return brlapi__openConnection (NULL, NULL, NULL); }''', dependencies: brlapi)
 968     brlapi = not_found
 969     if get_option('brlapi').enabled()
 970       error('could not link brlapi')
 971     else
 972       warning('could not link brlapi, disabling')
 973     endif
 974   endif
 975 endif
 976
 977 sdl = not_found
 978 if not get_option('sdl').auto() or have_system
 979   sdl = dependency('sdl2', required: get_option('sdl'), kwargs: static_kwargs)
 980   sdl_image = not_found
 981 endif
 982 if sdl.found()
 983   # work around 2.0.8 bug
 984   sdl = declare_dependency(compile_args: '-Wno-undef',
 985                            dependencies: sdl)
 986   sdl_image = dependency('SDL2_image', required: get_option('sdl_image'),
 987                          method: 'pkg-config', kwargs: static_kwargs)
 988 else
 989   if get_option('sdl_image').enabled()
 990     error('sdl-image required, but SDL was @0@'.format(
 991           get_option('sdl').disabled() ? 'disabled' : 'not found'))
 992   endif
 993   sdl_image = not_found
 994 endif
 995
 996 rbd = not_found
 997 if not get_option('rbd').auto() or have_block
 998   librados = cc.find_library('rados', required: get_option('rbd'),
 999                              kwargs: static_kwargs)
1000   librbd = cc.find_library('rbd', has_headers: ['rbd/librbd.h'],
1001                            required: get_option('rbd'),
1002                            kwargs: static_kwargs)
1003   if librados.found() and librbd.found()
1004     if cc.links('''
1005       #include <stdio.h>
1006       #include <rbd/librbd.h>
1007       int main(void) {
1008         rados_t cluster;
1009         rados_create(&cluster, NULL);
1010         #if LIBRBD_VERSION_CODE < LIBRBD_VERSION(1, 12, 0)
1011         #error
1012         #endif
1013         return 0;
1014       }''', dependencies: [librbd, librados])
1015       rbd = declare_dependency(dependencies: [librbd, librados])
1016     elif get_option('rbd').enabled()
1017       error('librbd >= 1.12.0 required')
1018     else
1019       warning('librbd >= 1.12.0 not found, disabling')
1020     endif
1021   endif
1022 endif
1023
1024 glusterfs = not_found
1025 glusterfs_ftruncate_has_stat = false
1026 glusterfs_iocb_has_stat = false
1027 if not get_option('glusterfs').auto() or have_block
1028   glusterfs = dependency('glusterfs-api', version: '>=3',
1029                          required: get_option('glusterfs'),
1030                          method: 'pkg-config', kwargs: static_kwargs)
1031   if glusterfs.found()
1032     glusterfs_ftruncate_has_stat = cc.links('''
1033       #include <glusterfs/api/glfs.h>
1034
1035       int
1036       main(void)
1037       {
1038           /* new glfs_ftruncate() passes two additional args */
1039           return glfs_ftruncate(NULL, 0, NULL, NULL);
1040       }
1041     ''', dependencies: glusterfs)
1042     glusterfs_iocb_has_stat = cc.links('''
1043       #include <glusterfs/api/glfs.h>
1044
1045       /* new glfs_io_cbk() passes two additional glfs_stat structs */
1046       static void
1047       glusterfs_iocb(glfs_fd_t *fd, ssize_t ret, struct glfs_stat *prestat, struct glfs_stat *poststat, void *data)
1048       {}
1049
1050       int
1051       main(void)
1052       {
1053           glfs_io_cbk iocb = &glusterfs_iocb;
1054           iocb(NULL, 0 , NULL, NULL, NULL);
1055           return 0;
1056       }
1057     ''', dependencies: glusterfs)
1058   endif
1059 endif
1060
1061 libssh = not_found
1062 if not get_option('libssh').auto() or have_block
1063   libssh = dependency('libssh', version: '>=0.8.7',
1064                     method: 'pkg-config',
1065                     required: get_option('libssh'),
1066                     kwargs: static_kwargs)
1067 endif
1068
1069 libbzip2 = not_found
1070 if not get_option('bzip2').auto() or have_block
1071   libbzip2 = cc.find_library('bz2', has_headers: ['bzlib.h'],
1072                              required: get_option('bzip2'),
1073                              kwargs: static_kwargs)
1074   if libbzip2.found() and not cc.links('''
1075      #include <bzlib.h>
1076      int main(void) { BZ2_bzlibVersion(); return 0; }''', dependencies: libbzip2)
1077     libbzip2 = not_found
1078     if get_option('bzip2').enabled()
1079       error('could not link libbzip2')
1080     else
1081       warning('could not link libbzip2, disabling')
1082     endif
1083   endif
1084 endif
1085
1086 liblzfse = not_found
1087 if not get_option('lzfse').auto() or have_block
1088   liblzfse = cc.find_library('lzfse', has_headers: ['lzfse.h'],
1089                              required: get_option('lzfse'),
1090                              kwargs: static_kwargs)
1091 endif
1092 if liblzfse.found() and not cc.links('''
1093    #include <lzfse.h>
1094    int main(void) { lzfse_decode_scratch_size(); return 0; }''', dependencies: liblzfse)
1095   liblzfse = not_found
1096   if get_option('lzfse').enabled()
1097     error('could not link liblzfse')
1098   else
1099     warning('could not link liblzfse, disabling')
1100   endif
1101 endif
1102
1103 oss = not_found
1104 if get_option('oss').allowed() and have_system
1105   if not cc.has_header('sys/soundcard.h')
1106     # not found
1107   elif targetos == 'netbsd'
1108     oss = cc.find_library('ossaudio', required: get_option('oss'),
1109                           kwargs: static_kwargs)
1110   else
1111     oss = declare_dependency()
1112   endif
1113
1114   if not oss.found()
1115     if get_option('oss').enabled()
1116       error('OSS not found')
1117     endif
1118   endif
1119 endif
1120 dsound = not_found
1121 if not get_option('dsound').auto() or (targetos == 'windows' and have_system)
1122   if cc.has_header('dsound.h')
1123     dsound = declare_dependency(link_args: ['-lole32', '-ldxguid'])
1124   endif
1125
1126   if not dsound.found()
1127     if get_option('dsound').enabled()
1128       error('DirectSound not found')
1129     endif
1130   endif
1131 endif
1132
1133 coreaudio = not_found
1134 if not get_option('coreaudio').auto() or (targetos == 'darwin' and have_system)
1135   coreaudio = dependency('appleframeworks', modules: 'CoreAudio',
1136                          required: get_option('coreaudio'))
1137 endif
1138
1139 opengl = not_found
1140 if not get_option('opengl').auto() or have_system or have_vhost_user_gpu
1141   epoxy = dependency('epoxy', method: 'pkg-config',
1142                       required: get_option('opengl'), kwargs: static_kwargs)
1143   if cc.has_header('epoxy/egl.h', dependencies: epoxy)
1144     opengl = epoxy
1145   elif get_option('opengl').enabled()
1146     error('epoxy/egl.h not found')
1147   endif
1148 endif
1149 gbm = not_found
1150 if (have_system or have_tools) and (virgl.found() or opengl.found())
1151   gbm = dependency('gbm', method: 'pkg-config', required: false,
1152                    kwargs: static_kwargs)
1153 endif
1154 have_vhost_user_gpu = have_vhost_user_gpu and virgl.found() and opengl.found() and gbm.found()
1155
1156 gnutls = not_found
1157 gnutls_crypto = not_found
1158 if get_option('gnutls').enabled() or (get_option('gnutls').auto() and have_system)
1159   # For general TLS support our min gnutls matches
1160   # that implied by our platform support matrix
1161   #
1162   # For the crypto backends, we look for a newer
1163   # gnutls:
1164   #
1165   #   Version 3.6.8  is needed to get XTS
1166   #   Version 3.6.13 is needed to get PBKDF
1167   #   Version 3.6.14 is needed to get HW accelerated XTS
1168   #
1169   # If newer enough gnutls isn't available, we can
1170   # still use a different crypto backend to satisfy
1171   # the platform support requirements
1172   gnutls_crypto = dependency('gnutls', version: '>=3.6.14',
1173                              method: 'pkg-config',
1174                              required: false,
1175                              kwargs: static_kwargs)
1176   if gnutls_crypto.found()
1177     gnutls = gnutls_crypto
1178   else
1179     # Our min version if all we need is TLS
1180     gnutls = dependency('gnutls', version: '>=3.5.18',
1181                         method: 'pkg-config',
1182                         required: get_option('gnutls'),
1183                         kwargs: static_kwargs)
1184   endif
1185 endif
1186
1187 # We prefer use of gnutls for crypto, unless the options
1188 # explicitly asked for nettle or gcrypt.
1189 #
1190 # If gnutls isn't available for crypto, then we'll prefer
1191 # gcrypt over nettle for performance reasons.
1192 gcrypt = not_found
1193 nettle = not_found
1194 hogweed = not_found
1195 xts = 'none'
1196
1197 if get_option('nettle').enabled() and get_option('gcrypt').enabled()
1198   error('Only one of gcrypt & nettle can be enabled')
1199 endif
1200
1201 # Explicit nettle/gcrypt request, so ignore gnutls for crypto
1202 if get_option('nettle').enabled() or get_option('gcrypt').enabled()
1203   gnutls_crypto = not_found
1204 endif
1205
1206 if not gnutls_crypto.found()
1207   if (not get_option('gcrypt').auto() or have_system) and not get_option('nettle').enabled()
1208     gcrypt = dependency('libgcrypt', version: '>=1.8',
1209                         method: 'config-tool',
1210                         required: get_option('gcrypt'),
1211                         kwargs: static_kwargs)
1212     # Debian has removed -lgpg-error from libgcrypt-config
1213     # as it "spreads unnecessary dependencies" which in
1214     # turn breaks static builds...
1215     if gcrypt.found() and enable_static
1216       gcrypt = declare_dependency(dependencies: [
1217         gcrypt,
1218         cc.find_library('gpg-error', required: true, kwargs: static_kwargs)])
1219     endif
1220   endif
1221   if (not get_option('nettle').auto() or have_system) and not gcrypt.found()
1222     nettle = dependency('nettle', version: '>=3.4',
1223                         method: 'pkg-config',
1224                         required: get_option('nettle'),
1225                         kwargs: static_kwargs)
1226     if nettle.found() and not cc.has_header('nettle/xts.h', dependencies: nettle)
1227       xts = 'private'
1228     endif
1229   endif
1230 endif
1231
1232 gmp = dependency('gmp', required: false, method: 'pkg-config', kwargs: static_kwargs)
1233 if nettle.found() and gmp.found()
1234   hogweed = dependency('hogweed', version: '>=3.4',
1235                        method: 'pkg-config',
1236                        required: get_option('nettle'),
1237                        kwargs: static_kwargs)
1238 endif
1239
1240
1241 gtk = not_found
1242 gtkx11 = not_found
1243 vte = not_found
1244 if not get_option('gtk').auto() or have_system
1245   gtk = dependency('gtk+-3.0', version: '>=3.22.0',
1246                    method: 'pkg-config',
1247                    required: get_option('gtk'),
1248                    kwargs: static_kwargs)
1249   if gtk.found()
1250     gtkx11 = dependency('gtk+-x11-3.0', version: '>=3.22.0',
1251                         method: 'pkg-config',
1252                         required: false,
1253                         kwargs: static_kwargs)
1254     gtk = declare_dependency(dependencies: [gtk, gtkx11])
1255
1256     if not get_option('vte').auto() or have_system
1257       vte = dependency('vte-2.91',
1258                        method: 'pkg-config',
1259                        required: get_option('vte'),
1260                        kwargs: static_kwargs)
1261     endif
1262   endif
1263 endif
1264
1265 x11 = not_found
1266 if gtkx11.found()
1267   x11 = dependency('x11', method: 'pkg-config', required: gtkx11.found(),
1268                    kwargs: static_kwargs)
1269 endif
1270 png = not_found
1271 if get_option('png').allowed() and have_system
1272    png = dependency('libpng', version: '>=1.6.34', required: get_option('png'),
1273                     method: 'pkg-config', kwargs: static_kwargs)
1274 endif
1275 vnc = not_found
1276 jpeg = not_found
1277 sasl = not_found
1278 if get_option('vnc').allowed() and have_system
1279   vnc = declare_dependency() # dummy dependency
1280   jpeg = dependency('libjpeg', required: get_option('vnc_jpeg'),
1281                     method: 'pkg-config', kwargs: static_kwargs)
1282   sasl = cc.find_library('sasl2', has_headers: ['sasl/sasl.h'],
1283                          required: get_option('vnc_sasl'),
1284                          kwargs: static_kwargs)
1285   if sasl.found()
1286     sasl = declare_dependency(dependencies: sasl,
1287                               compile_args: '-DSTRUCT_IOVEC_DEFINED')
1288   endif
1289 endif
1290
1291 pam = not_found
1292 if not get_option('auth_pam').auto() or have_system
1293   pam = cc.find_library('pam', has_headers: ['security/pam_appl.h'],
1294                         required: get_option('auth_pam'),
1295                         kwargs: static_kwargs)
1296 endif
1297 if pam.found() and not cc.links('''
1298    #include <stddef.h>
1299    #include <security/pam_appl.h>
1300    int main(void) {
1301      const char *service_name = "qemu";
1302      const char *user = "frank";
1303      const struct pam_conv pam_conv = { 0 };
1304      pam_handle_t *pamh = NULL;
1305      pam_start(service_name, user, &pam_conv, &pamh);
1306      return 0;
1307    }''', dependencies: pam)
1308   pam = not_found
1309   if get_option('auth_pam').enabled()
1310     error('could not link libpam')
1311   else
1312     warning('could not link libpam, disabling')
1313   endif
1314 endif
1315
1316 snappy = not_found
1317 if not get_option('snappy').auto() or have_system
1318   snappy = cc.find_library('snappy', has_headers: ['snappy-c.h'],
1319                            required: get_option('snappy'),
1320                            kwargs: static_kwargs)
1321 endif
1322 if snappy.found() and not linker.links('''
1323    #include <snappy-c.h>
1324    int main(void) { snappy_max_compressed_length(4096); return 0; }''', dependencies: snappy)
1325   snappy = not_found
1326   if get_option('snappy').enabled()
1327     error('could not link libsnappy')
1328   else
1329     warning('could not link libsnappy, disabling')
1330   endif
1331 endif
1332
1333 lzo = not_found
1334 if not get_option('lzo').auto() or have_system
1335   lzo = cc.find_library('lzo2', has_headers: ['lzo/lzo1x.h'],
1336                         required: get_option('lzo'),
1337                         kwargs: static_kwargs)
1338 endif
1339 if lzo.found() and not cc.links('''
1340    #include <lzo/lzo1x.h>
1341    int main(void) { lzo_version(); return 0; }''', dependencies: lzo)
1342   lzo = not_found
1343   if get_option('lzo').enabled()
1344     error('could not link liblzo2')
1345   else
1346     warning('could not link liblzo2, disabling')
1347   endif
1348 endif
1349
1350 numa = not_found
1351 if not get_option('numa').auto() or have_system or have_tools
1352   numa = cc.find_library('numa', has_headers: ['numa.h'],
1353                               required: get_option('numa'),
1354                               kwargs: static_kwargs)
1355 endif
1356 if numa.found() and not cc.links('''
1357    #include <numa.h>
1358    int main(void) { return numa_available(); }
1359    ''', dependencies: numa)
1360   numa = not_found
1361   if get_option('numa').enabled()
1362     error('could not link numa')
1363   else
1364     warning('could not link numa, disabling')
1365   endif
1366 endif
1367
1368 rdma = not_found
1369 if not get_option('rdma').auto() or have_system
1370   libumad = cc.find_library('ibumad', required: get_option('rdma'))
1371   rdma_libs = [cc.find_library('rdmacm', has_headers: ['rdma/rdma_cma.h'],
1372                                required: get_option('rdma'),
1373                                kwargs: static_kwargs),
1374                cc.find_library('ibverbs', required: get_option('rdma'),
1375                                kwargs: static_kwargs),
1376                libumad]
1377   rdma = declare_dependency(dependencies: rdma_libs)
1378   foreach lib: rdma_libs
1379     if not lib.found()
1380       rdma = not_found
1381     endif
1382   endforeach
1383 endif
1384
1385 xen = not_found
1386 if get_option('xen').enabled() or (get_option('xen').auto() and have_system)
1387   xencontrol = dependency('xencontrol', required: false,
1388                           method: 'pkg-config', kwargs: static_kwargs)
1389   if xencontrol.found()
1390     xen_pc = declare_dependency(version: xencontrol.version(),
1391       dependencies: [
1392         xencontrol,
1393         # disabler: true makes xen_pc.found() return false if any is not found
1394         dependency('xenstore', required: false,
1395                    method: 'pkg-config', kwargs: static_kwargs,
1396                    disabler: true),
1397         dependency('xenforeignmemory', required: false,
1398                    method: 'pkg-config', kwargs: static_kwargs,
1399                    disabler: true),
1400         dependency('xengnttab', required: false,
1401                    method: 'pkg-config', kwargs: static_kwargs,
1402                    disabler: true),
1403         dependency('xenevtchn', required: false,
1404                    method: 'pkg-config', kwargs: static_kwargs,
1405                    disabler: true),
1406         dependency('xendevicemodel', required: false,
1407                    method: 'pkg-config', kwargs: static_kwargs,
1408                    disabler: true),
1409         # optional, no "disabler: true"
1410         dependency('xentoolcore', required: false,
1411                    method: 'pkg-config', kwargs: static_kwargs)])
1412     if xen_pc.found()
1413       xen = xen_pc
1414     endif
1415   endif
1416   if not xen.found()
1417     xen_tests = [ '4.11.0', '4.10.0', '4.9.0', '4.8.0', '4.7.1', '4.6.0', '4.5.0', '4.2.0' ]
1418     xen_libs = {
1419       '4.11.0': [ 'xenstore', 'xenctrl', 'xendevicemodel', 'xenforeignmemory', 'xengnttab', 'xenevtchn', 'xentoolcore' ],
1420       '4.10.0': [ 'xenstore', 'xenctrl', 'xendevicemodel', 'xenforeignmemory', 'xengnttab', 'xenevtchn', 'xentoolcore' ],
1421       '4.9.0': [ 'xenstore', 'xenctrl', 'xendevicemodel', 'xenforeignmemory', 'xengnttab', 'xenevtchn' ],
1422       '4.8.0': [ 'xenstore', 'xenctrl', 'xenforeignmemory', 'xengnttab', 'xenevtchn' ],
1423       '4.7.1': [ 'xenstore', 'xenctrl', 'xenforeignmemory', 'xengnttab', 'xenevtchn' ],
1424       '4.6.0': [ 'xenstore', 'xenctrl' ],
1425       '4.5.0': [ 'xenstore', 'xenctrl' ],
1426       '4.2.0': [ 'xenstore', 'xenctrl' ],
1427     }
1428     xen_deps = {}
1429     foreach ver: xen_tests
1430       # cache the various library tests to avoid polluting the logs
1431       xen_test_deps = []
1432       foreach l: xen_libs[ver]
1433         if l not in xen_deps
1434           xen_deps += { l: cc.find_library(l, required: false) }
1435         endif
1436         xen_test_deps += xen_deps[l]
1437       endforeach
1438
1439       # Use -D to pick just one of the test programs in scripts/xen-detect.c
1440       xen_version = ver.split('.')
1441       xen_ctrl_version = xen_version[0] + \
1442         ('0' + xen_version[1]).substring(-2) + \
1443         ('0' + xen_version[2]).substring(-2)
1444       if cc.links(files('scripts/xen-detect.c'),
1445                   args: '-DCONFIG_XEN_CTRL_INTERFACE_VERSION=' + xen_ctrl_version,
1446                   dependencies: xen_test_deps)
1447         xen = declare_dependency(version: ver, dependencies: xen_test_deps)
1448         break
1449       endif
1450     endforeach
1451   endif
1452   if xen.found()
1453     accelerators += 'CONFIG_XEN'
1454   elif get_option('xen').enabled()
1455     error('could not compile and link Xen test program')
1456   endif
1457 endif
1458 have_xen_pci_passthrough = get_option('xen_pci_passthrough') \
1459   .require(xen.found(),
1460            error_message: 'Xen PCI passthrough requested but Xen not enabled') \
1461   .require(targetos == 'linux',
1462            error_message: 'Xen PCI passthrough not available on this platform') \
1463   .allowed()
1464
1465
1466 cacard = not_found
1467 if not get_option('smartcard').auto() or have_system
1468   cacard = dependency('libcacard', required: get_option('smartcard'),
1469                       version: '>=2.5.1', method: 'pkg-config',
1470                       kwargs: static_kwargs)
1471 endif
1472 u2f = not_found
1473 if have_system
1474   u2f = dependency('u2f-emu', required: get_option('u2f'),
1475                    method: 'pkg-config',
1476                    kwargs: static_kwargs)
1477 endif
1478 canokey = not_found
1479 if have_system
1480   canokey = dependency('canokey-qemu', required: get_option('canokey'),
1481                    method: 'pkg-config',
1482                    kwargs: static_kwargs)
1483 endif
1484 usbredir = not_found
1485 if not get_option('usb_redir').auto() or have_system
1486   usbredir = dependency('libusbredirparser-0.5', required: get_option('usb_redir'),
1487                         version: '>=0.6', method: 'pkg-config',
1488                         kwargs: static_kwargs)
1489 endif
1490 libusb = not_found
1491 if not get_option('libusb').auto() or have_system
1492   libusb = dependency('libusb-1.0', required: get_option('libusb'),
1493                       version: '>=1.0.13', method: 'pkg-config',
1494                       kwargs: static_kwargs)
1495 endif
1496
1497 libpmem = not_found
1498 if not get_option('libpmem').auto() or have_system
1499   libpmem = dependency('libpmem', required: get_option('libpmem'),
1500                        method: 'pkg-config', kwargs: static_kwargs)
1501 endif
1502 libdaxctl = not_found
1503 if not get_option('libdaxctl').auto() or have_system
1504   libdaxctl = dependency('libdaxctl', required: get_option('libdaxctl'),
1505                          version: '>=57', method: 'pkg-config',
1506                          kwargs: static_kwargs)
1507 endif
1508 tasn1 = not_found
1509 if gnutls.found()
1510   tasn1 = dependency('libtasn1',
1511                      method: 'pkg-config',
1512                      kwargs: static_kwargs)
1513 endif
1514 keyutils = dependency('libkeyutils', required: false,
1515                       method: 'pkg-config', kwargs: static_kwargs)
1516
1517 has_gettid = cc.has_function('gettid')
1518
1519 # libselinux
1520 selinux = dependency('libselinux',
1521                      required: get_option('selinux'),
1522                      method: 'pkg-config', kwargs: static_kwargs)
1523
1524 # Malloc tests
1525
1526 malloc = []
1527 if get_option('malloc') == 'system'
1528   has_malloc_trim = \
1529     get_option('malloc_trim').allowed() and \
1530     cc.links('''#include <malloc.h>
1531                 int main(void) { malloc_trim(0); return 0; }''')
1532 else
1533   has_malloc_trim = false
1534   malloc = cc.find_library(get_option('malloc'), required: true)
1535 endif
1536 if not has_malloc_trim and get_option('malloc_trim').enabled()
1537   if get_option('malloc') == 'system'
1538     error('malloc_trim not available on this platform.')
1539   else
1540     error('malloc_trim not available with non-libc memory allocator')
1541   endif
1542 endif
1543
1544 # Check whether the glibc provides statx()
1545
1546 gnu_source_prefix = '''
1547   #ifndef _GNU_SOURCE
1548   #define _GNU_SOURCE
1549   #endif
1550 '''
1551 statx_test = gnu_source_prefix + '''
1552   #include <sys/stat.h>
1553   int main(void) {
1554     struct statx statxbuf;
1555     statx(0, "", 0, STATX_BASIC_STATS, &statxbuf);
1556     return 0;
1557   }'''
1558
1559 has_statx = cc.links(statx_test)
1560
1561 # Check whether statx() provides mount ID information
1562
1563 statx_mnt_id_test = gnu_source_prefix + '''
1564   #include <sys/stat.h>
1565   int main(void) {
1566     struct statx statxbuf;
1567     statx(0, "", 0, STATX_BASIC_STATS | STATX_MNT_ID, &statxbuf);
1568     return statxbuf.stx_mnt_id;
1569   }'''
1570
1571 has_statx_mnt_id = cc.links(statx_mnt_id_test)
1572
1573 have_vhost_user_blk_server = get_option('vhost_user_blk_server') \
1574   .require(targetos == 'linux',
1575            error_message: 'vhost_user_blk_server requires linux') \
1576   .require(have_vhost_user,
1577            error_message: 'vhost_user_blk_server requires vhost-user support') \
1578   .disable_auto_if(not have_tools and not have_system) \
1579   .allowed()
1580
1581 if get_option('fuse').disabled() and get_option('fuse_lseek').enabled()
1582   error('Cannot enable fuse-lseek while fuse is disabled')
1583 endif
1584
1585 fuse = dependency('fuse3', required: get_option('fuse'),
1586                   version: '>=3.1', method: 'pkg-config',
1587                   kwargs: static_kwargs)
1588
1589 fuse_lseek = not_found
1590 if get_option('fuse_lseek').allowed()
1591   if fuse.version().version_compare('>=3.8')
1592     # Dummy dependency
1593     fuse_lseek = declare_dependency()
1594   elif get_option('fuse_lseek').enabled()
1595     if fuse.found()
1596       error('fuse-lseek requires libfuse >=3.8, found ' + fuse.version())
1597     else
1598       error('fuse-lseek requires libfuse, which was not found')
1599     endif
1600   endif
1601 endif
1602
1603 have_libvduse = (targetos == 'linux')
1604 if get_option('libvduse').enabled()
1605     if targetos != 'linux'
1606         error('libvduse requires linux')
1607     endif
1608 elif get_option('libvduse').disabled()
1609     have_libvduse = false
1610 endif
1611
1612 have_vduse_blk_export = (have_libvduse and targetos == 'linux')
1613 if get_option('vduse_blk_export').enabled()
1614     if targetos != 'linux'
1615         error('vduse_blk_export requires linux')
1616     elif not have_libvduse
1617         error('vduse_blk_export requires libvduse support')
1618     endif
1619 elif get_option('vduse_blk_export').disabled()
1620     have_vduse_blk_export = false
1621 endif
1622
1623 # libbpf
1624 libbpf = dependency('libbpf', required: get_option('bpf'), method: 'pkg-config')
1625 if libbpf.found() and not cc.links('''
1626    #include <bpf/libbpf.h>
1627    int main(void)
1628    {
1629      bpf_object__destroy_skeleton(NULL);
1630      return 0;
1631    }''', dependencies: libbpf)
1632   libbpf = not_found
1633   if get_option('bpf').enabled()
1634     error('libbpf skeleton test failed')
1635   else
1636     warning('libbpf skeleton test failed, disabling')
1637   endif
1638 endif
1639
1640 #################
1641 # config-host.h #
1642 #################
1643
1644 audio_drivers_selected = []
1645 if have_system
1646   audio_drivers_available = {
1647     'alsa': alsa.found(),
1648     'coreaudio': coreaudio.found(),
1649     'dsound': dsound.found(),
1650     'jack': jack.found(),
1651     'oss': oss.found(),
1652     'pa': pulse.found(),
1653     'sdl': sdl.found(),
1654     'sndio': sndio.found(),
1655   }
1656   foreach k, v: audio_drivers_available
1657     config_host_data.set('CONFIG_AUDIO_' + k.to_upper(), v)
1658   endforeach
1659
1660   # Default to native drivers first, OSS second, SDL third
1661   audio_drivers_priority = \
1662     [ 'pa', 'coreaudio', 'dsound', 'sndio', 'oss' ] + \
1663     (targetos == 'linux' ? [] : [ 'sdl' ])
1664   audio_drivers_default = []
1665   foreach k: audio_drivers_priority
1666     if audio_drivers_available[k]
1667       audio_drivers_default += k
1668     endif
1669   endforeach
1670
1671   foreach k: get_option('audio_drv_list')
1672     if k == 'default'
1673       audio_drivers_selected += audio_drivers_default
1674     elif not audio_drivers_available[k]
1675       error('Audio driver "@0@" not available.'.format(k))
1676     else
1677       audio_drivers_selected += k
1678     endif
1679   endforeach
1680 endif
1681 config_host_data.set('CONFIG_AUDIO_DRIVERS',
1682                      '"' + '", "'.join(audio_drivers_selected) + '", ')
1683
1684 if get_option('cfi')
1685   cfi_flags=[]
1686   # Check for dependency on LTO
1687   if not get_option('b_lto')
1688     error('Selected Control-Flow Integrity but LTO is disabled')
1689   endif
1690   if config_host.has_key('CONFIG_MODULES')
1691     error('Selected Control-Flow Integrity is not compatible with modules')
1692   endif
1693   # Check for cfi flags. CFI requires LTO so we can't use
1694   # get_supported_arguments, but need a more complex "compiles" which allows
1695   # custom arguments
1696   if cc.compiles('int main () { return 0; }', name: '-fsanitize=cfi-icall',
1697                  args: ['-flto', '-fsanitize=cfi-icall'] )
1698     cfi_flags += '-fsanitize=cfi-icall'
1699   else
1700     error('-fsanitize=cfi-icall is not supported by the compiler')
1701   endif
1702   if cc.compiles('int main () { return 0; }',
1703                  name: '-fsanitize-cfi-icall-generalize-pointers',
1704                  args: ['-flto', '-fsanitize=cfi-icall',
1705                         '-fsanitize-cfi-icall-generalize-pointers'] )
1706     cfi_flags += '-fsanitize-cfi-icall-generalize-pointers'
1707   else
1708     error('-fsanitize-cfi-icall-generalize-pointers is not supported by the compiler')
1709   endif
1710   if get_option('cfi_debug')
1711     if cc.compiles('int main () { return 0; }',
1712                    name: '-fno-sanitize-trap=cfi-icall',
1713                    args: ['-flto', '-fsanitize=cfi-icall',
1714                           '-fno-sanitize-trap=cfi-icall'] )
1715       cfi_flags += '-fno-sanitize-trap=cfi-icall'
1716     else
1717       error('-fno-sanitize-trap=cfi-icall is not supported by the compiler')
1718     endif
1719   endif
1720   add_global_arguments(cfi_flags, native: false, language: ['c', 'cpp', 'objc'])
1721   add_global_link_arguments(cfi_flags, native: false, language: ['c', 'cpp', 'objc'])
1722 endif
1723
1724 have_host_block_device = (targetos != 'darwin' or
1725     cc.has_header('IOKit/storage/IOMedia.h'))
1726
1727 dbus_display = get_option('dbus_display') \
1728   .require(gio.version().version_compare('>=2.64'),
1729            error_message: '-display dbus requires glib>=2.64') \
1730   .require(gdbus_codegen.found(),
1731            error_message: gdbus_codegen_error.format('-display dbus')) \
1732   .require(opengl.found() and gbm.found(),
1733            error_message: '-display dbus requires epoxy/egl and gbm') \
1734   .allowed()
1735
1736 have_virtfs = get_option('virtfs') \
1737     .require(targetos == 'linux' or targetos == 'darwin',
1738              error_message: 'virtio-9p (virtfs) requires Linux or macOS') \
1739     .require(targetos == 'linux' or cc.has_function('pthread_fchdir_np'),
1740              error_message: 'virtio-9p (virtfs) on macOS requires the presence of pthread_fchdir_np') \
1741     .require(targetos == 'darwin' or (libattr.found() and libcap_ng.found()),
1742              error_message: 'virtio-9p (virtfs) on Linux requires libcap-ng-devel and libattr-devel') \
1743     .disable_auto_if(not have_tools and not have_system) \
1744     .allowed()
1745
1746 have_virtfs_proxy_helper = targetos != 'darwin' and have_virtfs and have_tools
1747
1748 if get_option('block_drv_ro_whitelist') == ''
1749   config_host_data.set('CONFIG_BDRV_RO_WHITELIST', '')
1750 else
1751   config_host_data.set('CONFIG_BDRV_RO_WHITELIST',
1752         '"' + get_option('block_drv_ro_whitelist').replace(',', '", "') + '", ')
1753 endif
1754 if get_option('block_drv_rw_whitelist') == ''
1755   config_host_data.set('CONFIG_BDRV_RW_WHITELIST', '')
1756 else
1757   config_host_data.set('CONFIG_BDRV_RW_WHITELIST',
1758         '"' + get_option('block_drv_rw_whitelist').replace(',', '", "') + '", ')
1759 endif
1760
1761 foreach k : get_option('trace_backends')
1762   config_host_data.set('CONFIG_TRACE_' + k.to_upper(), true)
1763 endforeach
1764 config_host_data.set_quoted('CONFIG_TRACE_FILE', get_option('trace_file'))
1765 config_host_data.set_quoted('CONFIG_TLS_PRIORITY', get_option('tls_priority'))
1766 if iasl.found()
1767   config_host_data.set_quoted('CONFIG_IASL', iasl.full_path())
1768 endif
1769 config_host_data.set_quoted('CONFIG_BINDIR', get_option('prefix') / get_option('bindir'))
1770 config_host_data.set_quoted('CONFIG_PREFIX', get_option('prefix'))
1771 config_host_data.set_quoted('CONFIG_QEMU_CONFDIR', get_option('prefix') / qemu_confdir)
1772 config_host_data.set_quoted('CONFIG_QEMU_DATADIR', get_option('prefix') / qemu_datadir)
1773 config_host_data.set_quoted('CONFIG_QEMU_DESKTOPDIR', get_option('prefix') / qemu_desktopdir)
1774
1775 qemu_firmwarepath = ''
1776 foreach k : get_option('qemu_firmwarepath')
1777   qemu_firmwarepath += '"' + get_option('prefix') / k + '", '
1778 endforeach
1779 config_host_data.set('CONFIG_QEMU_FIRMWAREPATH', qemu_firmwarepath)
1780
1781 config_host_data.set_quoted('CONFIG_QEMU_HELPERDIR', get_option('prefix') / get_option('libexecdir'))
1782 config_host_data.set_quoted('CONFIG_QEMU_ICONDIR', get_option('prefix') / qemu_icondir)
1783 config_host_data.set_quoted('CONFIG_QEMU_LOCALEDIR', get_option('prefix') / get_option('localedir'))
1784 config_host_data.set_quoted('CONFIG_QEMU_LOCALSTATEDIR', get_option('prefix') / get_option('localstatedir'))
1785 config_host_data.set_quoted('CONFIG_QEMU_MODDIR', get_option('prefix') / qemu_moddir)
1786 config_host_data.set_quoted('CONFIG_SYSCONFDIR', get_option('prefix') / get_option('sysconfdir'))
1787
1788 if config_host.has_key('CONFIG_MODULES')
1789   config_host_data.set('CONFIG_STAMP', run_command(
1790       meson.current_source_dir() / 'scripts/qemu-stamp.py',
1791       meson.project_version(), get_option('pkgversion'), '--',
1792       meson.current_source_dir() / 'configure',
1793       capture: true, check: true).stdout().strip())
1794 endif
1795
1796 have_slirp_smbd = get_option('slirp_smbd') \
1797   .require(targetos != 'windows', error_message: 'Host smbd not supported on this platform.') \
1798   .allowed()
1799 if have_slirp_smbd
1800   smbd_path = get_option('smbd')
1801   if smbd_path == ''
1802     smbd_path = (targetos == 'solaris' ? '/usr/sfw/sbin/smbd' : '/usr/sbin/smbd')
1803   endif
1804   config_host_data.set_quoted('CONFIG_SMBD_COMMAND', smbd_path)
1805 endif
1806
1807 config_host_data.set('HOST_' + host_arch.to_upper(), 1)
1808
1809 if get_option('module_upgrades') and not enable_modules
1810   error('Cannot enable module-upgrades as modules are not enabled')
1811 endif
1812 config_host_data.set('CONFIG_MODULE_UPGRADES', get_option('module_upgrades'))
1813
1814 config_host_data.set('CONFIG_ATTR', libattr.found())
1815 config_host_data.set('CONFIG_BDRV_WHITELIST_TOOLS', get_option('block_drv_whitelist_in_tools'))
1816 config_host_data.set('CONFIG_BRLAPI', brlapi.found())
1817 config_host_data.set('CONFIG_COCOA', cocoa.found())
1818 config_host_data.set('CONFIG_FUZZ', get_option('fuzzing'))
1819 config_host_data.set('CONFIG_GCOV', get_option('b_coverage'))
1820 config_host_data.set('CONFIG_LIBUDEV', libudev.found())
1821 config_host_data.set('CONFIG_LZO', lzo.found())
1822 config_host_data.set('CONFIG_MPATH', mpathpersist.found())
1823 config_host_data.set('CONFIG_MPATH_NEW_API', mpathpersist_new_api)
1824 config_host_data.set('CONFIG_CURL', curl.found())
1825 config_host_data.set('CONFIG_CURSES', curses.found())
1826 config_host_data.set('CONFIG_GBM', gbm.found())
1827 config_host_data.set('CONFIG_GIO', gio.found())
1828 config_host_data.set('CONFIG_GLUSTERFS', glusterfs.found())
1829 if glusterfs.found()
1830   config_host_data.set('CONFIG_GLUSTERFS_XLATOR_OPT', glusterfs.version().version_compare('>=4'))
1831   config_host_data.set('CONFIG_GLUSTERFS_DISCARD', glusterfs.version().version_compare('>=5'))
1832   config_host_data.set('CONFIG_GLUSTERFS_FALLOCATE', glusterfs.version().version_compare('>=6'))
1833   config_host_data.set('CONFIG_GLUSTERFS_ZEROFILL', glusterfs.version().version_compare('>=6'))
1834   config_host_data.set('CONFIG_GLUSTERFS_FTRUNCATE_HAS_STAT', glusterfs_ftruncate_has_stat)
1835   config_host_data.set('CONFIG_GLUSTERFS_IOCB_HAS_STAT', glusterfs_iocb_has_stat)
1836 endif
1837 config_host_data.set('CONFIG_GTK', gtk.found())
1838 config_host_data.set('CONFIG_VTE', vte.found())
1839 config_host_data.set('CONFIG_LIBATTR', have_old_libattr)
1840 config_host_data.set('CONFIG_LIBCAP_NG', libcap_ng.found())
1841 config_host_data.set('CONFIG_EBPF', libbpf.found())
1842 config_host_data.set('CONFIG_LIBDAXCTL', libdaxctl.found())
1843 config_host_data.set('CONFIG_LIBISCSI', libiscsi.found())
1844 config_host_data.set('CONFIG_LIBNFS', libnfs.found())
1845 config_host_data.set('CONFIG_LIBSSH', libssh.found())
1846 config_host_data.set('CONFIG_LINUX_AIO', libaio.found())
1847 config_host_data.set('CONFIG_LINUX_IO_URING', linux_io_uring.found())
1848 config_host_data.set('CONFIG_LIBURING_REGISTER_RING_FD', cc.has_function('io_uring_register_ring_fd', prefix: '#include <liburing.h>', dependencies:linux_io_uring))
1849 config_host_data.set('CONFIG_LIBPMEM', libpmem.found())
1850 config_host_data.set('CONFIG_NUMA', numa.found())
1851 config_host_data.set('CONFIG_OPENGL', opengl.found())
1852 config_host_data.set('CONFIG_PROFILER', get_option('profiler'))
1853 config_host_data.set('CONFIG_RBD', rbd.found())
1854 config_host_data.set('CONFIG_RDMA', rdma.found())
1855 config_host_data.set('CONFIG_SDL', sdl.found())
1856 config_host_data.set('CONFIG_SDL_IMAGE', sdl_image.found())
1857 config_host_data.set('CONFIG_SECCOMP', seccomp.found())
1858 if seccomp.found()
1859   config_host_data.set('CONFIG_SECCOMP_SYSRAWRC', seccomp_has_sysrawrc)
1860 endif
1861 config_host_data.set('CONFIG_SNAPPY', snappy.found())
1862 config_host_data.set('CONFIG_TPM', have_tpm)
1863 config_host_data.set('CONFIG_USB_LIBUSB', libusb.found())
1864 config_host_data.set('CONFIG_VDE', vde.found())
1865 config_host_data.set('CONFIG_VHOST_NET', have_vhost_net)
1866 config_host_data.set('CONFIG_VHOST_NET_USER', have_vhost_net_user)
1867 config_host_data.set('CONFIG_VHOST_NET_VDPA', have_vhost_net_vdpa)
1868 config_host_data.set('CONFIG_VHOST_KERNEL', have_vhost_kernel)
1869 config_host_data.set('CONFIG_VHOST_USER', have_vhost_user)
1870 config_host_data.set('CONFIG_VHOST_CRYPTO', have_vhost_user_crypto)
1871 config_host_data.set('CONFIG_VHOST_VDPA', have_vhost_vdpa)
1872 config_host_data.set('CONFIG_VMNET', vmnet.found())
1873 config_host_data.set('CONFIG_VHOST_USER_BLK_SERVER', have_vhost_user_blk_server)
1874 config_host_data.set('CONFIG_VDUSE_BLK_EXPORT', have_vduse_blk_export)
1875 config_host_data.set('CONFIG_PNG', png.found())
1876 config_host_data.set('CONFIG_VNC', vnc.found())
1877 config_host_data.set('CONFIG_VNC_JPEG', jpeg.found())
1878 config_host_data.set('CONFIG_VNC_SASL', sasl.found())
1879 config_host_data.set('CONFIG_VIRTFS', have_virtfs)
1880 config_host_data.set('CONFIG_VTE', vte.found())
1881 config_host_data.set('CONFIG_XKBCOMMON', xkbcommon.found())
1882 config_host_data.set('CONFIG_KEYUTILS', keyutils.found())
1883 config_host_data.set('CONFIG_GETTID', has_gettid)
1884 config_host_data.set('CONFIG_GNUTLS', gnutls.found())
1885 config_host_data.set('CONFIG_GNUTLS_CRYPTO', gnutls_crypto.found())
1886 config_host_data.set('CONFIG_TASN1', tasn1.found())
1887 config_host_data.set('CONFIG_GCRYPT', gcrypt.found())
1888 config_host_data.set('CONFIG_NETTLE', nettle.found())
1889 config_host_data.set('CONFIG_HOGWEED', hogweed.found())
1890 config_host_data.set('CONFIG_QEMU_PRIVATE_XTS', xts == 'private')
1891 config_host_data.set('CONFIG_MALLOC_TRIM', has_malloc_trim)
1892 config_host_data.set('CONFIG_STATX', has_statx)
1893 config_host_data.set('CONFIG_STATX_MNT_ID', has_statx_mnt_id)
1894 config_host_data.set('CONFIG_ZSTD', zstd.found())
1895 config_host_data.set('CONFIG_FUSE', fuse.found())
1896 config_host_data.set('CONFIG_FUSE_LSEEK', fuse_lseek.found())
1897 config_host_data.set('CONFIG_SPICE_PROTOCOL', spice_protocol.found())
1898 if spice_protocol.found()
1899 config_host_data.set('CONFIG_SPICE_PROTOCOL_MAJOR', spice_protocol.version().split('.')[0])
1900 config_host_data.set('CONFIG_SPICE_PROTOCOL_MINOR', spice_protocol.version().split('.')[1])
1901 config_host_data.set('CONFIG_SPICE_PROTOCOL_MICRO', spice_protocol.version().split('.')[2])
1902 endif
1903 config_host_data.set('CONFIG_SPICE', spice.found())
1904 config_host_data.set('CONFIG_X11', x11.found())
1905 config_host_data.set('CONFIG_DBUS_DISPLAY', dbus_display)
1906 config_host_data.set('CONFIG_CFI', get_option('cfi'))
1907 config_host_data.set('CONFIG_SELINUX', selinux.found())
1908 config_host_data.set('CONFIG_XEN_BACKEND', xen.found())
1909 if xen.found()
1910   # protect from xen.version() having less than three components
1911   xen_version = xen.version().split('.') + ['0', '0']
1912   xen_ctrl_version = xen_version[0] + \
1913     ('0' + xen_version[1]).substring(-2) + \
1914     ('0' + xen_version[2]).substring(-2)
1915   config_host_data.set('CONFIG_XEN_CTRL_INTERFACE_VERSION', xen_ctrl_version)
1916 endif
1917 config_host_data.set('QEMU_VERSION', '"@0@"'.format(meson.project_version()))
1918 config_host_data.set('QEMU_VERSION_MAJOR', meson.project_version().split('.')[0])
1919 config_host_data.set('QEMU_VERSION_MINOR', meson.project_version().split('.')[1])
1920 config_host_data.set('QEMU_VERSION_MICRO', meson.project_version().split('.')[2])
1921
1922 config_host_data.set_quoted('CONFIG_HOST_DSOSUF', host_dsosuf)
1923 config_host_data.set('HAVE_HOST_BLOCK_DEVICE', have_host_block_device)
1924
1925 have_coroutine_pool = get_option('coroutine_pool')
1926 if get_option('debug_stack_usage') and have_coroutine_pool
1927   message('Disabling coroutine pool to measure stack usage')
1928   have_coroutine_pool = false
1929 endif
1930 config_host_data.set10('CONFIG_COROUTINE_POOL', have_coroutine_pool)
1931 config_host_data.set('CONFIG_DEBUG_MUTEX', get_option('debug_mutex'))
1932 config_host_data.set('CONFIG_DEBUG_STACK_USAGE', get_option('debug_stack_usage'))
1933 config_host_data.set('CONFIG_GPROF', get_option('gprof'))
1934 config_host_data.set('CONFIG_LIVE_BLOCK_MIGRATION', get_option('live_block_migration').allowed())
1935 config_host_data.set('CONFIG_QOM_CAST_DEBUG', get_option('qom_cast_debug'))
1936 config_host_data.set('CONFIG_REPLICATION', get_option('replication').allowed())
1937
1938 # has_header
1939 config_host_data.set('CONFIG_EPOLL', cc.has_header('sys/epoll.h'))
1940 config_host_data.set('CONFIG_LINUX_MAGIC_H', cc.has_header('linux/magic.h'))
1941 config_host_data.set('CONFIG_VALGRIND_H', cc.has_header('valgrind/valgrind.h'))
1942 config_host_data.set('HAVE_BTRFS_H', cc.has_header('linux/btrfs.h'))
1943 config_host_data.set('HAVE_DRM_H', cc.has_header('libdrm/drm.h'))
1944 config_host_data.set('HAVE_PTY_H', cc.has_header('pty.h'))
1945 config_host_data.set('HAVE_SYS_DISK_H', cc.has_header('sys/disk.h'))
1946 config_host_data.set('HAVE_SYS_IOCCOM_H', cc.has_header('sys/ioccom.h'))
1947 config_host_data.set('HAVE_SYS_KCOV_H', cc.has_header('sys/kcov.h'))
1948 if targetos == 'windows'
1949   config_host_data.set('HAVE_AFUNIX_H', cc.has_header('afunix.h'))
1950 endif
1951
1952 # has_function
1953 config_host_data.set('CONFIG_ACCEPT4', cc.has_function('accept4'))
1954 config_host_data.set('CONFIG_CLOCK_ADJTIME', cc.has_function('clock_adjtime'))
1955 config_host_data.set('CONFIG_DUP3', cc.has_function('dup3'))
1956 config_host_data.set('CONFIG_FALLOCATE', cc.has_function('fallocate'))
1957 config_host_data.set('CONFIG_POSIX_FALLOCATE', cc.has_function('posix_fallocate'))
1958 # Note that we need to specify prefix: here to avoid incorrectly
1959 # thinking that Windows has posix_memalign()
1960 config_host_data.set('CONFIG_POSIX_MEMALIGN', cc.has_function('posix_memalign', prefix: '#include <stdlib.h>'))
1961 config_host_data.set('CONFIG_ALIGNED_MALLOC', cc.has_function('_aligned_malloc'))
1962 config_host_data.set('CONFIG_VALLOC', cc.has_function('valloc'))
1963 config_host_data.set('CONFIG_MEMALIGN', cc.has_function('memalign'))
1964 config_host_data.set('CONFIG_PPOLL', cc.has_function('ppoll'))
1965 config_host_data.set('CONFIG_PREADV', cc.has_function('preadv', prefix: '#include <sys/uio.h>'))
1966 config_host_data.set('CONFIG_PTHREAD_FCHDIR_NP', cc.has_function('pthread_fchdir_np'))
1967 config_host_data.set('CONFIG_SENDFILE', cc.has_function('sendfile'))
1968 config_host_data.set('CONFIG_SETNS', cc.has_function('setns') and cc.has_function('unshare'))
1969 config_host_data.set('CONFIG_SYNCFS', cc.has_function('syncfs'))
1970 config_host_data.set('CONFIG_SYNC_FILE_RANGE', cc.has_function('sync_file_range'))
1971 config_host_data.set('CONFIG_TIMERFD', cc.has_function('timerfd_create'))
1972 config_host_data.set('HAVE_COPY_FILE_RANGE', cc.has_function('copy_file_range'))
1973 config_host_data.set('HAVE_GETIFADDRS', cc.has_function('getifaddrs'))
1974 config_host_data.set('HAVE_OPENPTY', cc.has_function('openpty', dependencies: util))
1975 config_host_data.set('HAVE_STRCHRNUL', cc.has_function('strchrnul'))
1976 config_host_data.set('HAVE_SYSTEM_FUNCTION', cc.has_function('system', prefix: '#include <stdlib.h>'))
1977 if rbd.found()
1978   config_host_data.set('HAVE_RBD_NAMESPACE_EXISTS',
1979                        cc.has_function('rbd_namespace_exists',
1980                                        dependencies: rbd,
1981                                        prefix: '#include <rbd/librbd.h>'))
1982 endif
1983 if rdma.found()
1984   config_host_data.set('HAVE_IBV_ADVISE_MR',
1985                        cc.has_function('ibv_advise_mr',
1986                                        dependencies: rdma,
1987                                        prefix: '#include <infiniband/verbs.h>'))
1988 endif
1989
1990 # has_header_symbol
1991 config_host_data.set('CONFIG_BYTESWAP_H',
1992                      cc.has_header_symbol('byteswap.h', 'bswap_32'))
1993 config_host_data.set('CONFIG_EPOLL_CREATE1',
1994                      cc.has_header_symbol('sys/epoll.h', 'epoll_create1'))
1995 config_host_data.set('CONFIG_FALLOCATE_PUNCH_HOLE',
1996                      cc.has_header_symbol('linux/falloc.h', 'FALLOC_FL_PUNCH_HOLE') and
1997                      cc.has_header_symbol('linux/falloc.h', 'FALLOC_FL_KEEP_SIZE'))
1998 config_host_data.set('CONFIG_FALLOCATE_ZERO_RANGE',
1999                      cc.has_header_symbol('linux/falloc.h', 'FALLOC_FL_ZERO_RANGE'))
2000 config_host_data.set('CONFIG_FIEMAP',
2001                      cc.has_header('linux/fiemap.h') and
2002                      cc.has_header_symbol('linux/fs.h', 'FS_IOC_FIEMAP'))
2003 config_host_data.set('CONFIG_GETRANDOM',
2004                      cc.has_function('getrandom') and
2005                      cc.has_header_symbol('sys/random.h', 'GRND_NONBLOCK'))
2006 config_host_data.set('CONFIG_INOTIFY',
2007                      cc.has_header_symbol('sys/inotify.h', 'inotify_init'))
2008 config_host_data.set('CONFIG_INOTIFY1',
2009                      cc.has_header_symbol('sys/inotify.h', 'inotify_init1'))
2010 config_host_data.set('CONFIG_MACHINE_BSWAP_H',
2011                      cc.has_header_symbol('machine/bswap.h', 'bswap32',
2012                                           prefix: '''#include <sys/endian.h>
2013                                                      #include <sys/types.h>'''))
2014 config_host_data.set('CONFIG_PRCTL_PR_SET_TIMERSLACK',
2015                      cc.has_header_symbol('sys/prctl.h', 'PR_SET_TIMERSLACK'))
2016 config_host_data.set('CONFIG_RTNETLINK',
2017                      cc.has_header_symbol('linux/rtnetlink.h', 'IFLA_PROTO_DOWN'))
2018 config_host_data.set('CONFIG_SYSMACROS',
2019                      cc.has_header_symbol('sys/sysmacros.h', 'makedev'))
2020 config_host_data.set('HAVE_OPTRESET',
2021                      cc.has_header_symbol('getopt.h', 'optreset'))
2022 config_host_data.set('HAVE_IPPROTO_MPTCP',
2023                      cc.has_header_symbol('netinet/in.h', 'IPPROTO_MPTCP'))
2024 config_host_data.set('HAVE_SYS_MOUNT_FSCONFIG',
2025                      cc.has_header_symbol('sys/mount.h', 'FSCONFIG_SET_FLAG'))
2026
2027 # has_member
2028 config_host_data.set('HAVE_SIGEV_NOTIFY_THREAD_ID',
2029                      cc.has_member('struct sigevent', 'sigev_notify_thread_id',
2030                                    prefix: '#include <signal.h>'))
2031 config_host_data.set('HAVE_STRUCT_STAT_ST_ATIM',
2032                      cc.has_member('struct stat', 'st_atim',
2033                                    prefix: '#include <sys/stat.h>'))
2034
2035 # has_type
2036 config_host_data.set('CONFIG_IOVEC',
2037                      cc.has_type('struct iovec',
2038                                  prefix: '#include <sys/uio.h>'))
2039 config_host_data.set('HAVE_UTMPX',
2040                      cc.has_type('struct utmpx',
2041                                  prefix: '#include <utmpx.h>'))
2042
2043 config_host_data.set('CONFIG_EVENTFD', cc.links('''
2044   #include <sys/eventfd.h>
2045   int main(void) { return eventfd(0, EFD_NONBLOCK | EFD_CLOEXEC); }'''))
2046 config_host_data.set('CONFIG_FDATASYNC', cc.links(gnu_source_prefix + '''
2047   #include <unistd.h>
2048   int main(void) {
2049   #if defined(_POSIX_SYNCHRONIZED_IO) && _POSIX_SYNCHRONIZED_IO > 0
2050   return fdatasync(0);
2051   #else
2052   #error Not supported
2053   #endif
2054   }'''))
2055
2056 has_madvise = cc.links(gnu_source_prefix + '''
2057   #include <sys/types.h>
2058   #include <sys/mman.h>
2059   #include <stddef.h>
2060   int main(void) { return madvise(NULL, 0, MADV_DONTNEED); }''')
2061 missing_madvise_proto = false
2062 if has_madvise
2063   # Some platforms (illumos and Solaris before Solaris 11) provide madvise()
2064   # but forget to prototype it. In this case, has_madvise will be true (the
2065   # test program links despite a compile warning). To detect the
2066   # missing-prototype case, we try again with a definitely-bogus prototype.
2067   # This will only compile if the system headers don't provide the prototype;
2068   # otherwise the conflicting prototypes will cause a compiler error.
2069   missing_madvise_proto = cc.links(gnu_source_prefix + '''
2070     #include <sys/types.h>
2071     #include <sys/mman.h>
2072     #include <stddef.h>
2073     extern int madvise(int);
2074     int main(void) { return madvise(0); }''')
2075 endif
2076 config_host_data.set('CONFIG_MADVISE', has_madvise)
2077 config_host_data.set('HAVE_MADVISE_WITHOUT_PROTOTYPE', missing_madvise_proto)
2078
2079 config_host_data.set('CONFIG_MEMFD', cc.links(gnu_source_prefix + '''
2080   #include <sys/mman.h>
2081   int main(void) { return memfd_create("foo", MFD_ALLOW_SEALING); }'''))
2082 config_host_data.set('CONFIG_OPEN_BY_HANDLE', cc.links(gnu_source_prefix + '''
2083   #include <fcntl.h>
2084   #if !defined(AT_EMPTY_PATH)
2085   # error missing definition
2086   #else
2087   int main(void) { struct file_handle fh; return open_by_handle_at(0, &fh, 0); }
2088   #endif'''))
2089 config_host_data.set('CONFIG_POSIX_MADVISE', cc.links(gnu_source_prefix + '''
2090   #include <sys/mman.h>
2091   #include <stddef.h>
2092   int main(void) { return posix_madvise(NULL, 0, POSIX_MADV_DONTNEED); }'''))
2093
2094 config_host_data.set('CONFIG_PTHREAD_SETNAME_NP_W_TID', cc.links(gnu_source_prefix + '''
2095   #include <pthread.h>
2096
2097   static void *f(void *p) { return NULL; }
2098   int main(void)
2099   {
2100     pthread_t thread;
2101     pthread_create(&thread, 0, f, 0);
2102     pthread_setname_np(thread, "QEMU");
2103     return 0;
2104   }''', dependencies: threads))
2105 config_host_data.set('CONFIG_PTHREAD_SETNAME_NP_WO_TID', cc.links(gnu_source_prefix + '''
2106   #include <pthread.h>
2107
2108   static void *f(void *p) { pthread_setname_np("QEMU"); return NULL; }
2109   int main(void)
2110   {
2111     pthread_t thread;
2112     pthread_create(&thread, 0, f, 0);
2113     return 0;
2114   }''', dependencies: threads))
2115 config_host_data.set('CONFIG_PTHREAD_CONDATTR_SETCLOCK', cc.links(gnu_source_prefix + '''
2116   #include <pthread.h>
2117   #include <time.h>
2118
2119   int main(void)
2120   {
2121     pthread_condattr_t attr
2122     pthread_condattr_init(&attr);
2123     pthread_condattr_setclock(&attr, CLOCK_MONOTONIC);
2124     return 0;
2125   }''', dependencies: threads))
2126
2127 config_host_data.set('CONFIG_SIGNALFD', cc.links(gnu_source_prefix + '''
2128   #include <sys/signalfd.h>
2129   #include <stddef.h>
2130   int main(void) { return signalfd(-1, NULL, SFD_CLOEXEC); }'''))
2131 config_host_data.set('CONFIG_SPLICE', cc.links(gnu_source_prefix + '''
2132   #include <unistd.h>
2133   #include <fcntl.h>
2134   #include <limits.h>
2135
2136   int main(void)
2137   {
2138     int len, fd = 0;
2139     len = tee(STDIN_FILENO, STDOUT_FILENO, INT_MAX, SPLICE_F_NONBLOCK);
2140     splice(STDIN_FILENO, NULL, fd, NULL, len, SPLICE_F_MOVE);
2141     return 0;
2142   }'''))
2143
2144 config_host_data.set('HAVE_MLOCKALL', cc.links(gnu_source_prefix + '''
2145   #include <sys/mman.h>
2146   int main(int argc, char *argv[]) {
2147     return mlockall(MCL_FUTURE);
2148   }'''))
2149
2150 have_l2tpv3 = false
2151 if get_option('l2tpv3').allowed() and have_system
2152   have_l2tpv3 = cc.has_type('struct mmsghdr',
2153     prefix: gnu_source_prefix + '''
2154       #include <sys/socket.h>
2155       #include <linux/ip.h>''')
2156 endif
2157 config_host_data.set('CONFIG_L2TPV3', have_l2tpv3)
2158
2159 have_netmap = false
2160 if get_option('netmap').allowed() and have_system
2161   have_netmap = cc.compiles('''
2162     #include <inttypes.h>
2163     #include <net/if.h>
2164     #include <net/netmap.h>
2165     #include <net/netmap_user.h>
2166     #if (NETMAP_API < 11) || (NETMAP_API > 15)
2167     #error
2168     #endif
2169     int main(void) { return 0; }''')
2170   if not have_netmap and get_option('netmap').enabled()
2171     error('Netmap headers not available')
2172   endif
2173 endif
2174 config_host_data.set('CONFIG_NETMAP', have_netmap)
2175
2176 # Work around a system header bug with some kernel/XFS header
2177 # versions where they both try to define 'struct fsxattr':
2178 # xfs headers will not try to redefine structs from linux headers
2179 # if this macro is set.
2180 config_host_data.set('HAVE_FSXATTR', cc.links('''
2181   #include <linux/fs.h>
2182   struct fsxattr foo;
2183   int main(void) {
2184     return 0;
2185   }'''))
2186
2187 # Some versions of Mac OS X incorrectly define SIZE_MAX
2188 config_host_data.set('HAVE_BROKEN_SIZE_MAX', not cc.compiles('''
2189     #include <stdint.h>
2190     #include <stdio.h>
2191     int main(int argc, char *argv[]) {
2192         return printf("%zu", SIZE_MAX);
2193     }''', args: ['-Werror']))
2194
2195 atomic_test = '''
2196   #include <stdint.h>
2197   int main(void)
2198   {
2199     @0@ x = 0, y = 0;
2200     y = __atomic_load_n(&x, __ATOMIC_RELAXED);
2201     __atomic_store_n(&x, y, __ATOMIC_RELAXED);
2202     __atomic_compare_exchange_n(&x, &y, x, 0, __ATOMIC_RELAXED, __ATOMIC_RELAXED);
2203     __atomic_exchange_n(&x, y, __ATOMIC_RELAXED);
2204     __atomic_fetch_add(&x, y, __ATOMIC_RELAXED);
2205     return 0;
2206   }'''
2207
2208 # See if 64-bit atomic operations are supported.
2209 # Note that without __atomic builtins, we can only
2210 # assume atomic loads/stores max at pointer size.
2211 config_host_data.set('CONFIG_ATOMIC64', cc.links(atomic_test.format('uint64_t')))
2212
2213 has_int128 = cc.links('''
2214   __int128_t a;
2215   __uint128_t b;
2216   int main (void) {
2217     a = a + b;
2218     b = a * b;
2219     a = a * a;
2220     return 0;
2221   }''')
2222
2223 config_host_data.set('CONFIG_INT128', has_int128)
2224
2225 if has_int128
2226   # "do we have 128-bit atomics which are handled inline and specifically not
2227   # via libatomic". The reason we can't use libatomic is documented in the
2228   # comment starting "GCC is a house divided" in include/qemu/atomic128.h.
2229   has_atomic128 = cc.links(atomic_test.format('unsigned __int128'))
2230
2231   config_host_data.set('CONFIG_ATOMIC128', has_atomic128)
2232
2233   if not has_atomic128
2234     has_cmpxchg128 = cc.links('''
2235       int main(void)
2236       {
2237         unsigned __int128 x = 0, y = 0;
2238         __sync_val_compare_and_swap_16(&x, y, x);
2239         return 0;
2240       }
2241     ''')
2242
2243     config_host_data.set('CONFIG_CMPXCHG128', has_cmpxchg128)
2244   endif
2245 endif
2246
2247 config_host_data.set('CONFIG_GETAUXVAL', cc.links(gnu_source_prefix + '''
2248   #include <sys/auxv.h>
2249   int main(void) {
2250     return getauxval(AT_HWCAP) == 0;
2251   }'''))
2252
2253 config_host_data.set('CONFIG_USBFS', have_linux_user and cc.compiles('''
2254   #include <linux/usbdevice_fs.h>
2255
2256   #ifndef USBDEVFS_GET_CAPABILITIES
2257   #error "USBDEVFS_GET_CAPABILITIES undefined"
2258   #endif
2259
2260   #ifndef USBDEVFS_DISCONNECT_CLAIM
2261   #error "USBDEVFS_DISCONNECT_CLAIM undefined"
2262   #endif
2263
2264   int main(void) { return 0; }'''))
2265
2266 have_keyring = get_option('keyring') \
2267   .require(targetos == 'linux', error_message: 'keyring is only available on Linux') \
2268   .require(cc.compiles('''
2269     #include <errno.h>
2270     #include <asm/unistd.h>
2271     #include <linux/keyctl.h>
2272     #include <sys/syscall.h>
2273     #include <unistd.h>
2274     int main(void) {
2275         return syscall(__NR_keyctl, KEYCTL_READ, 0, NULL, NULL, 0);
2276     }'''), error_message: 'keyctl syscall not available on this system').allowed()
2277 config_host_data.set('CONFIG_SECRET_KEYRING', have_keyring)
2278
2279 have_cpuid_h = cc.links('''
2280   #include <cpuid.h>
2281   int main(void) {
2282     unsigned a, b, c, d;
2283     unsigned max = __get_cpuid_max(0, 0);
2284
2285     if (max >= 1) {
2286         __cpuid(1, a, b, c, d);
2287     }
2288
2289     if (max >= 7) {
2290         __cpuid_count(7, 0, a, b, c, d);
2291     }
2292
2293     return 0;
2294   }''')
2295 config_host_data.set('CONFIG_CPUID_H', have_cpuid_h)
2296
2297 config_host_data.set('CONFIG_AVX2_OPT', get_option('avx2') \
2298   .require(have_cpuid_h, error_message: 'cpuid.h not available, cannot enable AVX2') \
2299   .require(cc.links('''
2300     #pragma GCC push_options
2301     #pragma GCC target("avx2")
2302     #include <cpuid.h>
2303     #include <immintrin.h>
2304     static int bar(void *a) {
2305       __m256i x = *(__m256i *)a;
2306       return _mm256_testz_si256(x, x);
2307     }
2308     int main(int argc, char *argv[]) { return bar(argv[0]); }
2309   '''), error_message: 'AVX2 not available').allowed())
2310
2311 config_host_data.set('CONFIG_AVX512F_OPT', get_option('avx512f') \
2312   .require(have_cpuid_h, error_message: 'cpuid.h not available, cannot enable AVX512F') \
2313   .require(cc.links('''
2314     #pragma GCC push_options
2315     #pragma GCC target("avx512f")
2316     #include <cpuid.h>
2317     #include <immintrin.h>
2318     static int bar(void *a) {
2319       __m512i x = *(__m512i *)a;
2320       return _mm512_test_epi64_mask(x, x);
2321     }
2322     int main(int argc, char *argv[]) { return bar(argv[0]); }
2323   '''), error_message: 'AVX512F not available').allowed())
2324
2325 have_pvrdma = get_option('pvrdma') \
2326   .require(rdma.found(), error_message: 'PVRDMA requires OpenFabrics libraries') \
2327   .require(cc.compiles(gnu_source_prefix + '''
2328     #include <sys/mman.h>
2329     int main(void)
2330     {
2331       char buf = 0;
2332       void *addr = &buf;
2333       addr = mremap(addr, 0, 1, MREMAP_MAYMOVE | MREMAP_FIXED);
2334
2335       return 0;
2336     }'''), error_message: 'PVRDMA requires mremap').allowed()
2337
2338 if have_pvrdma
2339   config_host_data.set('LEGACY_RDMA_REG_MR', not cc.links('''
2340     #include <infiniband/verbs.h>
2341     int main(void)
2342     {
2343       struct ibv_mr *mr;
2344       struct ibv_pd *pd = NULL;
2345       size_t length = 10;
2346       uint64_t iova = 0;
2347       int access = 0;
2348       void *addr = NULL;
2349
2350       mr = ibv_reg_mr_iova(pd, addr, length, iova, access);
2351       ibv_dereg_mr(mr);
2352       return 0;
2353     }'''))
2354 endif
2355
2356 if get_option('membarrier').disabled()
2357   have_membarrier = false
2358 elif targetos == 'windows'
2359   have_membarrier = true
2360 elif targetos == 'linux'
2361   have_membarrier = cc.compiles('''
2362     #include <linux/membarrier.h>
2363     #include <sys/syscall.h>
2364     #include <unistd.h>
2365     #include <stdlib.h>
2366     int main(void) {
2367         syscall(__NR_membarrier, MEMBARRIER_CMD_QUERY, 0);
2368         syscall(__NR_membarrier, MEMBARRIER_CMD_SHARED, 0);
2369         exit(0);
2370     }''')
2371 endif
2372 config_host_data.set('CONFIG_MEMBARRIER', get_option('membarrier') \
2373   .require(have_membarrier, error_message: 'membarrier system call not available') \
2374   .allowed())
2375
2376 have_afalg = get_option('crypto_afalg') \
2377   .require(cc.compiles(gnu_source_prefix + '''
2378     #include <errno.h>
2379     #include <sys/types.h>
2380     #include <sys/socket.h>
2381     #include <linux/if_alg.h>
2382     int main(void) {
2383       int sock;
2384       sock = socket(AF_ALG, SOCK_SEQPACKET, 0);
2385       return sock;
2386     }
2387   '''), error_message: 'AF_ALG requested but could not be detected').allowed()
2388 config_host_data.set('CONFIG_AF_ALG', have_afalg)
2389
2390 config_host_data.set('CONFIG_AF_VSOCK', cc.has_header_symbol(
2391   'linux/vm_sockets.h', 'AF_VSOCK',
2392   prefix: '#include <sys/socket.h>',
2393 ))
2394
2395 have_vss = false
2396 have_vss_sdk = false # old xp/2003 SDK
2397 if targetos == 'windows' and link_language == 'cpp'
2398   have_vss = cxx.compiles('''
2399     #define __MIDL_user_allocate_free_DEFINED__
2400     #include <vss.h>
2401     int main(void) { return VSS_CTX_BACKUP; }''')
2402   have_vss_sdk = cxx.has_header('vscoordint.h')
2403 endif
2404 config_host_data.set('HAVE_VSS_SDK', have_vss_sdk)
2405
2406 foreach k, v: config_host
2407   if k.startswith('CONFIG_')
2408     config_host_data.set(k, v == 'y' ? 1 : v)
2409   endif
2410 endforeach
2411
2412 # Older versions of MinGW do not import _lock_file and _unlock_file properly.
2413 # This was fixed for v6.0.0 with commit b48e3ac8969d.
2414 if targetos == 'windows'
2415   config_host_data.set('HAVE__LOCK_FILE', cc.links('''
2416     #include <stdio.h>
2417     int main(void) {
2418       _lock_file(NULL);
2419       _unlock_file(NULL);
2420       return 0;
2421     }''', name: '_lock_file and _unlock_file'))
2422 endif
2423
2424 ########################
2425 # Target configuration #
2426 ########################
2427
2428 minikconf = find_program('scripts/minikconf.py')
2429 config_all = {}
2430 config_all_devices = {}
2431 config_all_disas = {}
2432 config_devices_mak_list = []
2433 config_devices_h = {}
2434 config_target_h = {}
2435 config_target_mak = {}
2436
2437 disassemblers = {
2438   'alpha' : ['CONFIG_ALPHA_DIS'],
2439   'avr' : ['CONFIG_AVR_DIS'],
2440   'cris' : ['CONFIG_CRIS_DIS'],
2441   'hexagon' : ['CONFIG_HEXAGON_DIS'],
2442   'hppa' : ['CONFIG_HPPA_DIS'],
2443   'i386' : ['CONFIG_I386_DIS'],
2444   'x86_64' : ['CONFIG_I386_DIS'],
2445   'm68k' : ['CONFIG_M68K_DIS'],
2446   'microblaze' : ['CONFIG_MICROBLAZE_DIS'],
2447   'mips' : ['CONFIG_MIPS_DIS'],
2448   'nios2' : ['CONFIG_NIOS2_DIS'],
2449   'or1k' : ['CONFIG_OPENRISC_DIS'],
2450   'ppc' : ['CONFIG_PPC_DIS'],
2451   'riscv' : ['CONFIG_RISCV_DIS'],
2452   'rx' : ['CONFIG_RX_DIS'],
2453   's390' : ['CONFIG_S390_DIS'],
2454   'sh4' : ['CONFIG_SH4_DIS'],
2455   'sparc' : ['CONFIG_SPARC_DIS'],
2456   'xtensa' : ['CONFIG_XTENSA_DIS'],
2457   'loongarch' : ['CONFIG_LOONGARCH_DIS'],
2458 }
2459 if link_language == 'cpp'
2460   disassemblers += {
2461     'mips' : [ 'CONFIG_MIPS_DIS', 'CONFIG_NANOMIPS_DIS'],
2462   }
2463 endif
2464
2465 have_ivshmem = config_host_data.get('CONFIG_EVENTFD')
2466 host_kconfig = \
2467   (get_option('fuzzing') ? ['CONFIG_FUZZ=y'] : []) + \
2468   (have_tpm ? ['CONFIG_TPM=y'] : []) + \
2469   (spice.found() ? ['CONFIG_SPICE=y'] : []) + \
2470   (have_ivshmem ? ['CONFIG_IVSHMEM=y'] : []) + \
2471   (opengl.found() ? ['CONFIG_OPENGL=y'] : []) + \
2472   (x11.found() ? ['CONFIG_X11=y'] : []) + \
2473   (have_vhost_user ? ['CONFIG_VHOST_USER=y'] : []) + \
2474   (have_vhost_vdpa ? ['CONFIG_VHOST_VDPA=y'] : []) + \
2475   (have_vhost_kernel ? ['CONFIG_VHOST_KERNEL=y'] : []) + \
2476   (have_virtfs ? ['CONFIG_VIRTFS=y'] : []) + \
2477   ('CONFIG_LINUX' in config_host ? ['CONFIG_LINUX=y'] : []) + \
2478   (have_pvrdma ? ['CONFIG_PVRDMA=y'] : []) + \
2479   (multiprocess_allowed ? ['CONFIG_MULTIPROCESS_ALLOWED=y'] : []) + \
2480   (vfio_user_server_allowed ? ['CONFIG_VFIO_USER_SERVER_ALLOWED=y'] : [])
2481
2482 ignored = [ 'TARGET_XML_FILES', 'TARGET_ABI_DIR', 'TARGET_ARCH' ]
2483
2484 default_targets = 'CONFIG_DEFAULT_TARGETS' in config_host
2485 actual_target_dirs = []
2486 fdt_required = []
2487 foreach target : target_dirs
2488   config_target = { 'TARGET_NAME': target.split('-')[0] }
2489   if target.endswith('linux-user')
2490     if targetos != 'linux'
2491       if default_targets
2492         continue
2493       endif
2494       error('Target @0@ is only available on a Linux host'.format(target))
2495     endif
2496     config_target += { 'CONFIG_LINUX_USER': 'y' }
2497   elif target.endswith('bsd-user')
2498     if 'CONFIG_BSD' not in config_host
2499       if default_targets
2500         continue
2501       endif
2502       error('Target @0@ is only available on a BSD host'.format(target))
2503     endif
2504     config_target += { 'CONFIG_BSD_USER': 'y' }
2505   elif target.endswith('softmmu')
2506     config_target += { 'CONFIG_SOFTMMU': 'y' }
2507   endif
2508   if target.endswith('-user')
2509     config_target += {
2510       'CONFIG_USER_ONLY': 'y',
2511       'CONFIG_QEMU_INTERP_PREFIX':
2512         get_option('interp_prefix').replace('%M', config_target['TARGET_NAME'])
2513     }
2514   endif
2515
2516   accel_kconfig = []
2517   foreach sym: accelerators
2518     if sym == 'CONFIG_TCG' or target in accelerator_targets.get(sym, [])
2519       config_target += { sym: 'y' }
2520       config_all += { sym: 'y' }
2521       if sym == 'CONFIG_TCG' and tcg_arch == 'tci'
2522         config_target += { 'CONFIG_TCG_INTERPRETER': 'y' }
2523       endif
2524       if target in modular_tcg
2525         config_target += { 'CONFIG_TCG_MODULAR': 'y' }
2526       else
2527         config_target += { 'CONFIG_TCG_BUILTIN': 'y' }
2528       endif
2529       accel_kconfig += [ sym + '=y' ]
2530     endif
2531   endforeach
2532   if accel_kconfig.length() == 0
2533     if default_targets
2534       continue
2535     endif
2536     error('No accelerator available for target @0@'.format(target))
2537   endif
2538
2539   actual_target_dirs += target
2540   config_target += keyval.load('configs/targets' / target + '.mak')
2541   config_target += { 'TARGET_' + config_target['TARGET_ARCH'].to_upper(): 'y' }
2542
2543   if 'TARGET_NEED_FDT' in config_target
2544     fdt_required += target
2545   endif
2546
2547   # Add default keys
2548   if 'TARGET_BASE_ARCH' not in config_target
2549     config_target += {'TARGET_BASE_ARCH': config_target['TARGET_ARCH']}
2550   endif
2551   if 'TARGET_ABI_DIR' not in config_target
2552     config_target += {'TARGET_ABI_DIR': config_target['TARGET_ARCH']}
2553   endif
2554   if 'TARGET_BIG_ENDIAN' not in config_target
2555     config_target += {'TARGET_BIG_ENDIAN': 'n'}
2556   endif
2557
2558   foreach k, v: disassemblers
2559     if host_arch.startswith(k) or config_target['TARGET_BASE_ARCH'].startswith(k)
2560       foreach sym: v
2561         config_target += { sym: 'y' }
2562         config_all_disas += { sym: 'y' }
2563       endforeach
2564     endif
2565   endforeach
2566
2567   config_target_data = configuration_data()
2568   foreach k, v: config_target
2569     if not k.startswith('TARGET_') and not k.startswith('CONFIG_')
2570       # do nothing
2571     elif ignored.contains(k)
2572       # do nothing
2573     elif k == 'TARGET_BASE_ARCH'
2574       # Note that TARGET_BASE_ARCH ends up in config-target.h but it is
2575       # not used to select files from sourcesets.
2576       config_target_data.set('TARGET_' + v.to_upper(), 1)
2577     elif k == 'TARGET_NAME' or k == 'CONFIG_QEMU_INTERP_PREFIX'
2578       config_target_data.set_quoted(k, v)
2579     elif v == 'y'
2580       config_target_data.set(k, 1)
2581     elif v == 'n'
2582       config_target_data.set(k, 0)
2583     else
2584       config_target_data.set(k, v)
2585     endif
2586   endforeach
2587   config_target_data.set('QEMU_ARCH',
2588                          'QEMU_ARCH_' + config_target['TARGET_BASE_ARCH'].to_upper())
2589   config_target_h += {target: configure_file(output: target + '-config-target.h',
2590                                                configuration: config_target_data)}
2591
2592   if target.endswith('-softmmu')
2593     config_input = meson.get_external_property(target, 'default')
2594     config_devices_mak = target + '-config-devices.mak'
2595     config_devices_mak = configure_file(
2596       input: ['configs/devices' / target / config_input + '.mak', 'Kconfig'],
2597       output: config_devices_mak,
2598       depfile: config_devices_mak + '.d',
2599       capture: true,
2600       command: [minikconf,
2601                 get_option('default_devices') ? '--defconfig' : '--allnoconfig',
2602                 config_devices_mak, '@DEPFILE@', '@INPUT@',
2603                 host_kconfig, accel_kconfig,
2604                 'CONFIG_' + config_target['TARGET_ARCH'].to_upper() + '=y'])
2605
2606     config_devices_data = configuration_data()
2607     config_devices = keyval.load(config_devices_mak)
2608     foreach k, v: config_devices
2609       config_devices_data.set(k, 1)
2610     endforeach
2611     config_devices_mak_list += config_devices_mak
2612     config_devices_h += {target: configure_file(output: target + '-config-devices.h',
2613                                                 configuration: config_devices_data)}
2614     config_target += config_devices
2615     config_all_devices += config_devices
2616   endif
2617   config_target_mak += {target: config_target}
2618 endforeach
2619 target_dirs = actual_target_dirs
2620
2621 # This configuration is used to build files that are shared by
2622 # multiple binaries, and then extracted out of the "common"
2623 # static_library target.
2624 #
2625 # We do not use all_sources()/all_dependencies(), because it would
2626 # build literally all source files, including devices only used by
2627 # targets that are not built for this compilation.  The CONFIG_ALL
2628 # pseudo symbol replaces it.
2629
2630 config_all += config_all_devices
2631 config_all += config_host
2632 config_all += config_all_disas
2633 config_all += {
2634   'CONFIG_XEN': xen.found(),
2635   'CONFIG_SOFTMMU': have_system,
2636   'CONFIG_USER_ONLY': have_user,
2637   'CONFIG_ALL': true,
2638 }
2639
2640 target_configs_h = []
2641 foreach target: target_dirs
2642   target_configs_h += config_target_h[target]
2643   target_configs_h += config_devices_h.get(target, [])
2644 endforeach
2645 genh += custom_target('config-poison.h',
2646                       input: [target_configs_h],
2647                       output: 'config-poison.h',
2648                       capture: true,
2649                       command: [find_program('scripts/make-config-poison.sh'),
2650                                 target_configs_h])
2651
2652 ##############
2653 # Submodules #
2654 ##############
2655
2656 capstone = not_found
2657 if not get_option('capstone').auto() or have_system or have_user
2658   capstone = dependency('capstone', version: '>=3.0.5',
2659                         kwargs: static_kwargs, method: 'pkg-config',
2660                         required: get_option('capstone'))
2661
2662   # Some versions of capstone have broken pkg-config file
2663   # that reports a wrong -I path, causing the #include to
2664   # fail later. If the system has such a broken version
2665   # do not use it.
2666   if capstone.found() and not cc.compiles('#include <capstone.h>',
2667                                           dependencies: [capstone])
2668     capstone = not_found
2669     if get_option('capstone').enabled()
2670       error('capstone requested, but it does not appear to work')
2671     endif
2672   endif
2673 endif
2674
2675 libvfio_user_dep = not_found
2676 if have_system and vfio_user_server_allowed
2677   have_internal = fs.exists(meson.current_source_dir() / 'subprojects/libvfio-user/meson.build')
2678
2679   if not have_internal
2680     error('libvfio-user source not found - please pull git submodule')
2681   endif
2682
2683   libvfio_user_proj = subproject('libvfio-user')
2684
2685   libvfio_user_lib = libvfio_user_proj.get_variable('libvfio_user_dep')
2686
2687   libvfio_user_dep = declare_dependency(dependencies: [libvfio_user_lib])
2688 endif
2689
2690 fdt = not_found
2691 if have_system
2692   fdt_opt = get_option('fdt')
2693   if fdt_opt in ['enabled', 'auto', 'system']
2694     have_internal = fs.exists(meson.current_source_dir() / 'dtc/libfdt/Makefile.libfdt')
2695     fdt = cc.find_library('fdt', kwargs: static_kwargs,
2696                           required: fdt_opt == 'system' or
2697                                     fdt_opt == 'enabled' and not have_internal)
2698     if fdt.found() and cc.links('''
2699        #include <libfdt.h>
2700        #include <libfdt_env.h>
2701        int main(void) { fdt_find_max_phandle(NULL, NULL); return 0; }''',
2702          dependencies: fdt)
2703       fdt_opt = 'system'
2704     elif fdt_opt == 'system'
2705        error('system libfdt requested, but it is too old (1.5.1 or newer required)')
2706     elif have_internal
2707       fdt_opt = 'internal'
2708     else
2709       fdt_opt = 'disabled'
2710       fdt = not_found
2711     endif
2712   endif
2713   if fdt_opt == 'internal'
2714     fdt_files = files(
2715       'dtc/libfdt/fdt.c',
2716       'dtc/libfdt/fdt_ro.c',
2717       'dtc/libfdt/fdt_wip.c',
2718       'dtc/libfdt/fdt_sw.c',
2719       'dtc/libfdt/fdt_rw.c',
2720       'dtc/libfdt/fdt_strerror.c',
2721       'dtc/libfdt/fdt_empty_tree.c',
2722       'dtc/libfdt/fdt_addresses.c',
2723       'dtc/libfdt/fdt_overlay.c',
2724       'dtc/libfdt/fdt_check.c',
2725     )
2726
2727     fdt_inc = include_directories('dtc/libfdt')
2728     libfdt = static_library('fdt',
2729                             build_by_default: false,
2730                             sources: fdt_files,
2731                             include_directories: fdt_inc)
2732     fdt = declare_dependency(link_with: libfdt,
2733                              include_directories: fdt_inc)
2734   endif
2735 else
2736   fdt_opt = 'disabled'
2737 endif
2738 if not fdt.found() and fdt_required.length() > 0
2739   error('fdt not available but required by targets ' + ', '.join(fdt_required))
2740 endif
2741
2742 config_host_data.set('CONFIG_CAPSTONE', capstone.found())
2743 config_host_data.set('CONFIG_FDT', fdt.found())
2744 config_host_data.set('CONFIG_SLIRP', slirp.found())
2745
2746 #####################
2747 # Generated sources #
2748 #####################
2749
2750 genh += configure_file(output: 'config-host.h', configuration: config_host_data)
2751
2752 hxtool = find_program('scripts/hxtool')
2753 shaderinclude = find_program('scripts/shaderinclude.pl')
2754 qapi_gen = find_program('scripts/qapi-gen.py')
2755 qapi_gen_depends = [ meson.current_source_dir() / 'scripts/qapi/__init__.py',
2756                      meson.current_source_dir() / 'scripts/qapi/commands.py',
2757                      meson.current_source_dir() / 'scripts/qapi/common.py',
2758                      meson.current_source_dir() / 'scripts/qapi/error.py',
2759                      meson.current_source_dir() / 'scripts/qapi/events.py',
2760                      meson.current_source_dir() / 'scripts/qapi/expr.py',
2761                      meson.current_source_dir() / 'scripts/qapi/gen.py',
2762                      meson.current_source_dir() / 'scripts/qapi/introspect.py',
2763                      meson.current_source_dir() / 'scripts/qapi/parser.py',
2764                      meson.current_source_dir() / 'scripts/qapi/schema.py',
2765                      meson.current_source_dir() / 'scripts/qapi/source.py',
2766                      meson.current_source_dir() / 'scripts/qapi/types.py',
2767                      meson.current_source_dir() / 'scripts/qapi/visit.py',
2768                      meson.current_source_dir() / 'scripts/qapi/common.py',
2769                      meson.current_source_dir() / 'scripts/qapi-gen.py'
2770 ]
2771
2772 tracetool = [
2773   python, files('scripts/tracetool.py'),
2774    '--backend=' + ','.join(get_option('trace_backends'))
2775 ]
2776 tracetool_depends = files(
2777   'scripts/tracetool/backend/log.py',
2778   'scripts/tracetool/backend/__init__.py',
2779   'scripts/tracetool/backend/dtrace.py',
2780   'scripts/tracetool/backend/ftrace.py',
2781   'scripts/tracetool/backend/simple.py',
2782   'scripts/tracetool/backend/syslog.py',
2783   'scripts/tracetool/backend/ust.py',
2784   'scripts/tracetool/format/ust_events_c.py',
2785   'scripts/tracetool/format/ust_events_h.py',
2786   'scripts/tracetool/format/__init__.py',
2787   'scripts/tracetool/format/d.py',
2788   'scripts/tracetool/format/simpletrace_stap.py',
2789   'scripts/tracetool/format/c.py',
2790   'scripts/tracetool/format/h.py',
2791   'scripts/tracetool/format/log_stap.py',
2792   'scripts/tracetool/format/stap.py',
2793   'scripts/tracetool/__init__.py',
2794   'scripts/tracetool/transform.py',
2795   'scripts/tracetool/vcpu.py'
2796 )
2797
2798 qemu_version_cmd = [find_program('scripts/qemu-version.sh'),
2799                     meson.current_source_dir(),
2800                     get_option('pkgversion'), meson.project_version()]
2801 qemu_version = custom_target('qemu-version.h',
2802                              output: 'qemu-version.h',
2803                              command: qemu_version_cmd,
2804                              capture: true,
2805                              build_by_default: true,
2806                              build_always_stale: true)
2807 genh += qemu_version
2808
2809 hxdep = []
2810 hx_headers = [
2811   ['qemu-options.hx', 'qemu-options.def'],
2812   ['qemu-img-cmds.hx', 'qemu-img-cmds.h'],
2813 ]
2814 if have_system
2815   hx_headers += [
2816     ['hmp-commands.hx', 'hmp-commands.h'],
2817     ['hmp-commands-info.hx', 'hmp-commands-info.h'],
2818   ]
2819 endif
2820 foreach d : hx_headers
2821   hxdep += custom_target(d[1],
2822                 input: files(d[0]),
2823                 output: d[1],
2824                 capture: true,
2825                 build_by_default: true, # to be removed when added to a target
2826                 command: [hxtool, '-h', '@INPUT0@'])
2827 endforeach
2828 genh += hxdep
2829
2830 ###################
2831 # Collect sources #
2832 ###################
2833
2834 authz_ss = ss.source_set()
2835 blockdev_ss = ss.source_set()
2836 block_ss = ss.source_set()
2837 chardev_ss = ss.source_set()
2838 common_ss = ss.source_set()
2839 crypto_ss = ss.source_set()
2840 hwcore_ss = ss.source_set()
2841 io_ss = ss.source_set()
2842 qmp_ss = ss.source_set()
2843 qom_ss = ss.source_set()
2844 softmmu_ss = ss.source_set()
2845 specific_fuzz_ss = ss.source_set()
2846 specific_ss = ss.source_set()
2847 stub_ss = ss.source_set()
2848 trace_ss = ss.source_set()
2849 user_ss = ss.source_set()
2850 util_ss = ss.source_set()
2851
2852 # accel modules
2853 qtest_module_ss = ss.source_set()
2854 tcg_module_ss = ss.source_set()
2855
2856 modules = {}
2857 target_modules = {}
2858 hw_arch = {}
2859 target_arch = {}
2860 target_softmmu_arch = {}
2861 target_user_arch = {}
2862
2863 ###############
2864 # Trace files #
2865 ###############
2866
2867 # TODO: add each directory to the subdirs from its own meson.build, once
2868 # we have those
2869 trace_events_subdirs = [
2870   'crypto',
2871   'qapi',
2872   'qom',
2873   'monitor',
2874   'util',
2875   'gdbstub',
2876 ]
2877 if have_linux_user
2878   trace_events_subdirs += [ 'linux-user' ]
2879 endif
2880 if have_bsd_user
2881   trace_events_subdirs += [ 'bsd-user' ]
2882 endif
2883 if have_block
2884   trace_events_subdirs += [
2885     'authz',
2886     'block',
2887     'io',
2888     'nbd',
2889     'scsi',
2890   ]
2891 endif
2892 if have_system
2893   trace_events_subdirs += [
2894     'accel/kvm',
2895     'audio',
2896     'backends',
2897     'backends/tpm',
2898     'chardev',
2899     'ebpf',
2900     'hw/9pfs',
2901     'hw/acpi',
2902     'hw/adc',
2903     'hw/alpha',
2904     'hw/arm',
2905     'hw/audio',
2906     'hw/block',
2907     'hw/block/dataplane',
2908     'hw/char',
2909     'hw/display',
2910     'hw/dma',
2911     'hw/hyperv',
2912     'hw/i2c',
2913     'hw/i386',
2914     'hw/i386/xen',
2915     'hw/ide',
2916     'hw/input',
2917     'hw/intc',
2918     'hw/isa',
2919     'hw/mem',
2920     'hw/mips',
2921     'hw/misc',
2922     'hw/misc/macio',
2923     'hw/net',
2924     'hw/net/can',
2925     'hw/nubus',
2926     'hw/nvme',
2927     'hw/nvram',
2928     'hw/pci',
2929     'hw/pci-host',
2930     'hw/ppc',
2931     'hw/rdma',
2932     'hw/rdma/vmw',
2933     'hw/rtc',
2934     'hw/s390x',
2935     'hw/scsi',
2936     'hw/sd',
2937     'hw/sh4',
2938     'hw/sparc',
2939     'hw/sparc64',
2940     'hw/ssi',
2941     'hw/timer',
2942     'hw/tpm',
2943     'hw/usb',
2944     'hw/vfio',
2945     'hw/virtio',
2946     'hw/watchdog',
2947     'hw/xen',
2948     'hw/gpio',
2949     'migration',
2950     'net',
2951     'softmmu',
2952     'ui',
2953     'hw/remote',
2954   ]
2955 endif
2956 if have_system or have_user
2957   trace_events_subdirs += [
2958     'accel/tcg',
2959     'hw/core',
2960     'target/arm',
2961     'target/arm/hvf',
2962     'target/hppa',
2963     'target/i386',
2964     'target/i386/kvm',
2965     'target/mips/tcg',
2966     'target/nios2',
2967     'target/ppc',
2968     'target/riscv',
2969     'target/s390x',
2970     'target/s390x/kvm',
2971     'target/sparc',
2972   ]
2973 endif
2974
2975 vhost_user = not_found
2976 if targetos == 'linux' and have_vhost_user
2977   libvhost_user = subproject('libvhost-user')
2978   vhost_user = libvhost_user.get_variable('vhost_user_dep')
2979 endif
2980
2981 libvduse = not_found
2982 if have_libvduse
2983   libvduse_proj = subproject('libvduse')
2984   libvduse = libvduse_proj.get_variable('libvduse_dep')
2985 endif
2986
2987 # NOTE: the trace/ subdirectory needs the qapi_trace_events variable
2988 # that is filled in by qapi/.
2989 subdir('qapi')
2990 subdir('qobject')
2991 subdir('stubs')
2992 subdir('trace')
2993 subdir('util')
2994 subdir('qom')
2995 subdir('authz')
2996 subdir('crypto')
2997 subdir('ui')
2998 subdir('hw')
2999 subdir('gdbstub')
3000
3001
3002 if enable_modules
3003   libmodulecommon = static_library('module-common', files('module-common.c') + genh, pic: true, c_args: '-DBUILD_DSO')
3004   modulecommon = declare_dependency(link_whole: libmodulecommon, compile_args: '-DBUILD_DSO')
3005 endif
3006
3007 qom_ss = qom_ss.apply(config_host, strict: false)
3008 libqom = static_library('qom', qom_ss.sources() + genh,
3009                         dependencies: [qom_ss.dependencies()],
3010                         name_suffix: 'fa')
3011 qom = declare_dependency(link_whole: libqom)
3012
3013 event_loop_base = files('event-loop-base.c')
3014 event_loop_base = static_library('event-loop-base', sources: event_loop_base + genh,
3015                                  build_by_default: true)
3016 event_loop_base = declare_dependency(link_whole: event_loop_base,
3017                                      dependencies: [qom])
3018
3019 stub_ss = stub_ss.apply(config_all, strict: false)
3020
3021 util_ss.add_all(trace_ss)
3022 util_ss = util_ss.apply(config_all, strict: false)
3023 libqemuutil = static_library('qemuutil',
3024                              sources: util_ss.sources() + stub_ss.sources() + genh,
3025                              dependencies: [util_ss.dependencies(), libm, threads, glib, socket, malloc, pixman])
3026 qemuutil = declare_dependency(link_with: libqemuutil,
3027                               sources: genh + version_res,
3028                               dependencies: [event_loop_base])
3029
3030 if have_system or have_user
3031   decodetree = generator(find_program('scripts/decodetree.py'),
3032                          output: 'decode-@[email protected]',
3033                          arguments: ['@INPUT@', '@EXTRA_ARGS@', '-o', '@OUTPUT@'])
3034   subdir('libdecnumber')
3035   subdir('target')
3036 endif
3037
3038 subdir('audio')
3039 subdir('io')
3040 subdir('chardev')
3041 subdir('fsdev')
3042 subdir('dump')
3043
3044 if have_block
3045   block_ss.add(files(
3046     'block.c',
3047     'blockjob.c',
3048     'job.c',
3049     'qemu-io-cmds.c',
3050   ))
3051   if config_host_data.get('CONFIG_REPLICATION')
3052     block_ss.add(files('replication.c'))
3053   endif
3054
3055   subdir('nbd')
3056   subdir('scsi')
3057   subdir('block')
3058
3059   blockdev_ss.add(files(
3060     'blockdev.c',
3061     'blockdev-nbd.c',
3062     'iothread.c',
3063     'job-qmp.c',
3064   ), gnutls)
3065
3066   # os-posix.c contains POSIX-specific functions used by qemu-storage-daemon,
3067   # os-win32.c does not
3068   blockdev_ss.add(when: 'CONFIG_POSIX', if_true: files('os-posix.c'))
3069   softmmu_ss.add(when: 'CONFIG_WIN32', if_true: [files('os-win32.c')])
3070 endif
3071
3072 common_ss.add(files('cpus-common.c'))
3073
3074 subdir('softmmu')
3075
3076 common_ss.add(capstone)
3077 specific_ss.add(files('cpu.c', 'disas.c'), capstone)
3078
3079 # Work around a gcc bug/misfeature wherein constant propagation looks
3080 # through an alias:
3081 #   https://gcc.gnu.org/bugzilla/show_bug.cgi?id=99696
3082 # to guess that a const variable is always zero.  Without lto, this is
3083 # impossible, as the alias is restricted to page-vary-common.c.  Indeed,
3084 # without lto, not even the alias is required -- we simply use different
3085 # declarations in different compilation units.
3086 pagevary = files('page-vary-common.c')
3087 if get_option('b_lto')
3088   pagevary_flags = ['-fno-lto']
3089   if get_option('cfi')
3090     pagevary_flags += '-fno-sanitize=cfi-icall'
3091   endif
3092   pagevary = static_library('page-vary-common', sources: pagevary + genh,
3093                             c_args: pagevary_flags)
3094   pagevary = declare_dependency(link_with: pagevary)
3095 endif
3096 common_ss.add(pagevary)
3097 specific_ss.add(files('page-vary.c'))
3098
3099 subdir('backends')
3100 subdir('disas')
3101 subdir('migration')
3102 subdir('monitor')
3103 subdir('net')
3104 subdir('replay')
3105 subdir('semihosting')
3106 subdir('tcg')
3107 subdir('fpu')
3108 subdir('accel')
3109 subdir('plugins')
3110 subdir('ebpf')
3111
3112 common_user_inc = []
3113
3114 subdir('common-user')
3115 subdir('bsd-user')
3116 subdir('linux-user')
3117
3118 # needed for fuzzing binaries
3119 subdir('tests/qtest/libqos')
3120 subdir('tests/qtest/fuzz')
3121
3122 # accel modules
3123 tcg_real_module_ss = ss.source_set()
3124 tcg_real_module_ss.add_all(when: 'CONFIG_TCG_MODULAR', if_true: tcg_module_ss)
3125 specific_ss.add_all(when: 'CONFIG_TCG_BUILTIN', if_true: tcg_module_ss)
3126 target_modules += { 'accel' : { 'qtest': qtest_module_ss,
3127                                 'tcg': tcg_real_module_ss }}
3128
3129 ########################
3130 # Library dependencies #
3131 ########################
3132
3133 modinfo_collect = find_program('scripts/modinfo-collect.py')
3134 modinfo_generate = find_program('scripts/modinfo-generate.py')
3135 modinfo_files = []
3136
3137 block_mods = []
3138 softmmu_mods = []
3139 foreach d, list : modules
3140   foreach m, module_ss : list
3141     if enable_modules and targetos != 'windows'
3142       module_ss = module_ss.apply(config_all, strict: false)
3143       sl = static_library(d + '-' + m, [genh, module_ss.sources()],
3144                           dependencies: [modulecommon, module_ss.dependencies()], pic: true)
3145       if d == 'block'
3146         block_mods += sl
3147       else
3148         softmmu_mods += sl
3149       endif
3150       if module_ss.sources() != []
3151         # FIXME: Should use sl.extract_all_objects(recursive: true) as
3152         # input. Sources can be used multiple times but objects are
3153         # unique when it comes to lookup in compile_commands.json.
3154         # Depnds on a mesion version with
3155         # https://github.com/mesonbuild/meson/pull/8900
3156         modinfo_files += custom_target(d + '-' + m + '.modinfo',
3157                                        output: d + '-' + m + '.modinfo',
3158                                        input: module_ss.sources() + genh,
3159                                        capture: true,
3160                                        command: [modinfo_collect, module_ss.sources()])
3161       endif
3162     else
3163       if d == 'block'
3164         block_ss.add_all(module_ss)
3165       else
3166         softmmu_ss.add_all(module_ss)
3167       endif
3168     endif
3169   endforeach
3170 endforeach
3171
3172 foreach d, list : target_modules
3173   foreach m, module_ss : list
3174     if enable_modules and targetos != 'windows'
3175       foreach target : target_dirs
3176         if target.endswith('-softmmu')
3177           config_target = config_target_mak[target]
3178           config_target += config_host
3179           target_inc = [include_directories('target' / config_target['TARGET_BASE_ARCH'])]
3180           c_args = ['-DNEED_CPU_H',
3181                     '-DCONFIG_TARGET="@[email protected]"'.format(target),
3182                     '-DCONFIG_DEVICES="@[email protected]"'.format(target)]
3183           target_module_ss = module_ss.apply(config_target, strict: false)
3184           if target_module_ss.sources() != []
3185             module_name = d + '-' + m + '-' + config_target['TARGET_NAME']
3186             sl = static_library(module_name,
3187                                 [genh, target_module_ss.sources()],
3188                                 dependencies: [modulecommon, target_module_ss.dependencies()],
3189                                 include_directories: target_inc,
3190                                 c_args: c_args,
3191                                 pic: true)
3192             softmmu_mods += sl
3193             # FIXME: Should use sl.extract_all_objects(recursive: true) too.
3194             modinfo_files += custom_target(module_name + '.modinfo',
3195                                            output: module_name + '.modinfo',
3196                                            input: target_module_ss.sources() + genh,
3197                                            capture: true,
3198                                            command: [modinfo_collect, '--target', target, target_module_ss.sources()])
3199           endif
3200         endif
3201       endforeach
3202     else
3203       specific_ss.add_all(module_ss)
3204     endif
3205   endforeach
3206 endforeach
3207
3208 if enable_modules
3209   foreach target : target_dirs
3210     if target.endswith('-softmmu')
3211       config_target = config_target_mak[target]
3212       config_devices_mak = target + '-config-devices.mak'
3213       modinfo_src = custom_target('modinfo-' + target + '.c',
3214                                   output: 'modinfo-' + target + '.c',
3215                                   input: modinfo_files,
3216                                   command: [modinfo_generate, '--devices', config_devices_mak, '@INPUT@'],
3217                                   capture: true)
3218
3219       modinfo_lib = static_library('modinfo-' + target + '.c', modinfo_src)
3220       modinfo_dep = declare_dependency(link_with: modinfo_lib)
3221
3222       arch = config_target['TARGET_NAME'] == 'sparc64' ? 'sparc64' : config_target['TARGET_BASE_ARCH']
3223       hw_arch[arch].add(modinfo_dep)
3224     endif
3225   endforeach
3226 endif
3227
3228 nm = find_program('nm')
3229 undefsym = find_program('scripts/undefsym.py')
3230 block_syms = custom_target('block.syms', output: 'block.syms',
3231                              input: [libqemuutil, block_mods],
3232                              capture: true,
3233                              command: [undefsym, nm, '@INPUT@'])
3234 qemu_syms = custom_target('qemu.syms', output: 'qemu.syms',
3235                              input: [libqemuutil, softmmu_mods],
3236                              capture: true,
3237                              command: [undefsym, nm, '@INPUT@'])
3238
3239 authz_ss = authz_ss.apply(config_host, strict: false)
3240 libauthz = static_library('authz', authz_ss.sources() + genh,
3241                           dependencies: [authz_ss.dependencies()],
3242                           name_suffix: 'fa',
3243                           build_by_default: false)
3244
3245 authz = declare_dependency(link_whole: libauthz,
3246                            dependencies: qom)
3247
3248 crypto_ss = crypto_ss.apply(config_host, strict: false)
3249 libcrypto = static_library('crypto', crypto_ss.sources() + genh,
3250                            dependencies: [crypto_ss.dependencies()],
3251                            name_suffix: 'fa',
3252                            build_by_default: false)
3253
3254 crypto = declare_dependency(link_whole: libcrypto,
3255                             dependencies: [authz, qom])
3256
3257 io_ss = io_ss.apply(config_host, strict: false)
3258 libio = static_library('io', io_ss.sources() + genh,
3259                        dependencies: [io_ss.dependencies()],
3260                        link_with: libqemuutil,
3261                        name_suffix: 'fa',
3262                        build_by_default: false)
3263
3264 io = declare_dependency(link_whole: libio, dependencies: [crypto, qom])
3265
3266 libmigration = static_library('migration', sources: migration_files + genh,
3267                               name_suffix: 'fa',
3268                               build_by_default: false)
3269 migration = declare_dependency(link_with: libmigration,
3270                                dependencies: [zlib, qom, io])
3271 softmmu_ss.add(migration)
3272
3273 block_ss = block_ss.apply(config_host, strict: false)
3274 libblock = static_library('block', block_ss.sources() + genh,
3275                           dependencies: block_ss.dependencies(),
3276                           link_depends: block_syms,
3277                           name_suffix: 'fa',
3278                           build_by_default: false)
3279
3280 block = declare_dependency(link_whole: [libblock],
3281                            link_args: '@block.syms',
3282                            dependencies: [crypto, io])
3283
3284 blockdev_ss = blockdev_ss.apply(config_host, strict: false)
3285 libblockdev = static_library('blockdev', blockdev_ss.sources() + genh,
3286                              dependencies: blockdev_ss.dependencies(),
3287                              name_suffix: 'fa',
3288                              build_by_default: false)
3289
3290 blockdev = declare_dependency(link_whole: [libblockdev],
3291                               dependencies: [block, event_loop_base])
3292
3293 qmp_ss = qmp_ss.apply(config_host, strict: false)
3294 libqmp = static_library('qmp', qmp_ss.sources() + genh,
3295                         dependencies: qmp_ss.dependencies(),
3296                         name_suffix: 'fa',
3297                         build_by_default: false)
3298
3299 qmp = declare_dependency(link_whole: [libqmp])
3300
3301 libchardev = static_library('chardev', chardev_ss.sources() + genh,
3302                             name_suffix: 'fa',
3303                             dependencies: chardev_ss.dependencies(),
3304                             build_by_default: false)
3305
3306 chardev = declare_dependency(link_whole: libchardev)
3307
3308 hwcore_ss = hwcore_ss.apply(config_host, strict: false)
3309 libhwcore = static_library('hwcore', sources: hwcore_ss.sources() + genh,
3310                            name_suffix: 'fa',
3311                            build_by_default: false)
3312 hwcore = declare_dependency(link_whole: libhwcore)
3313 common_ss.add(hwcore)
3314
3315 ###########
3316 # Targets #
3317 ###########
3318
3319 emulator_modules = []
3320 foreach m : block_mods + softmmu_mods
3321   emulator_modules += shared_module(m.name(),
3322                 build_by_default: true,
3323                 name_prefix: '',
3324                 link_whole: m,
3325                 install: true,
3326                 install_dir: qemu_moddir)
3327 endforeach
3328 if emulator_modules.length() > 0
3329   alias_target('modules', emulator_modules)
3330 endif
3331
3332 softmmu_ss.add(authz, blockdev, chardev, crypto, io, qmp)
3333 common_ss.add(qom, qemuutil)
3334
3335 common_ss.add_all(when: 'CONFIG_SOFTMMU', if_true: [softmmu_ss])
3336 common_ss.add_all(when: 'CONFIG_USER_ONLY', if_true: user_ss)
3337
3338 common_all = common_ss.apply(config_all, strict: false)
3339 common_all = static_library('common',
3340                             build_by_default: false,
3341                             sources: common_all.sources() + genh,
3342                             include_directories: common_user_inc,
3343                             implicit_include_directories: false,
3344                             dependencies: common_all.dependencies(),
3345                             name_suffix: 'fa')
3346
3347 feature_to_c = find_program('scripts/feature_to_c.sh')
3348
3349 if targetos == 'darwin'
3350   entitlement = find_program('scripts/entitlement.sh')
3351 endif
3352
3353 emulators = {}
3354 foreach target : target_dirs
3355   config_target = config_target_mak[target]
3356   target_name = config_target['TARGET_NAME']
3357   target_base_arch = config_target['TARGET_BASE_ARCH']
3358   arch_srcs = [config_target_h[target]]
3359   arch_deps = []
3360   c_args = ['-DNEED_CPU_H',
3361             '-DCONFIG_TARGET="@[email protected]"'.format(target),
3362             '-DCONFIG_DEVICES="@[email protected]"'.format(target)]
3363   link_args = emulator_link_args
3364
3365   config_target += config_host
3366   target_inc = [include_directories('target' / config_target['TARGET_BASE_ARCH'])]
3367   if targetos == 'linux'
3368     target_inc += include_directories('linux-headers', is_system: true)
3369   endif
3370   if target.endswith('-softmmu')
3371     target_type='system'
3372     t = target_softmmu_arch[target_base_arch].apply(config_target, strict: false)
3373     arch_srcs += t.sources()
3374     arch_deps += t.dependencies()
3375
3376     hw_dir = target_name == 'sparc64' ? 'sparc64' : target_base_arch
3377     hw = hw_arch[hw_dir].apply(config_target, strict: false)
3378     arch_srcs += hw.sources()
3379     arch_deps += hw.dependencies()
3380
3381     arch_srcs += config_devices_h[target]
3382     link_args += ['@block.syms', '@qemu.syms']
3383   else
3384     abi = config_target['TARGET_ABI_DIR']
3385     target_type='user'
3386     target_inc += common_user_inc
3387     if target_base_arch in target_user_arch
3388       t = target_user_arch[target_base_arch].apply(config_target, strict: false)
3389       arch_srcs += t.sources()
3390       arch_deps += t.dependencies()
3391     endif
3392     if 'CONFIG_LINUX_USER' in config_target
3393       base_dir = 'linux-user'
3394     endif
3395     if 'CONFIG_BSD_USER' in config_target
3396       base_dir = 'bsd-user'
3397       target_inc += include_directories('bsd-user/' / targetos)
3398       target_inc += include_directories('bsd-user/host/' / host_arch)
3399       dir = base_dir / abi
3400       arch_srcs += files(dir / 'signal.c', dir / 'target_arch_cpu.c')
3401     endif
3402     target_inc += include_directories(
3403       base_dir,
3404       base_dir / abi,
3405     )
3406     if 'CONFIG_LINUX_USER' in config_target
3407       dir = base_dir / abi
3408       arch_srcs += files(dir / 'signal.c', dir / 'cpu_loop.c')
3409       if config_target.has_key('TARGET_SYSTBL_ABI')
3410         arch_srcs += \
3411           syscall_nr_generators[abi].process(base_dir / abi / config_target['TARGET_SYSTBL'],
3412                                              extra_args : config_target['TARGET_SYSTBL_ABI'])
3413       endif
3414     endif
3415   endif
3416
3417   if 'TARGET_XML_FILES' in config_target
3418     gdbstub_xml = custom_target(target + '-gdbstub-xml.c',
3419                                 output: target + '-gdbstub-xml.c',
3420                                 input: files(config_target['TARGET_XML_FILES'].split()),
3421                                 command: [feature_to_c, '@INPUT@'],
3422                                 capture: true)
3423     arch_srcs += gdbstub_xml
3424   endif
3425
3426   t = target_arch[target_base_arch].apply(config_target, strict: false)
3427   arch_srcs += t.sources()
3428   arch_deps += t.dependencies()
3429
3430   target_common = common_ss.apply(config_target, strict: false)
3431   objects = common_all.extract_objects(target_common.sources())
3432   deps = target_common.dependencies()
3433
3434   target_specific = specific_ss.apply(config_target, strict: false)
3435   arch_srcs += target_specific.sources()
3436   arch_deps += target_specific.dependencies()
3437
3438   lib = static_library('qemu-' + target,
3439                  sources: arch_srcs + genh,
3440                  dependencies: arch_deps,
3441                  objects: objects,
3442                  include_directories: target_inc,
3443                  c_args: c_args,
3444                  build_by_default: false,
3445                  name_suffix: 'fa')
3446
3447   if target.endswith('-softmmu')
3448     execs = [{
3449       'name': 'qemu-system-' + target_name,
3450       'win_subsystem': 'console',
3451       'sources': files('softmmu/main.c'),
3452       'dependencies': []
3453     }]
3454     if targetos == 'windows' and (sdl.found() or gtk.found())
3455       execs += [{
3456         'name': 'qemu-system-' + target_name + 'w',
3457         'win_subsystem': 'windows',
3458         'sources': files('softmmu/main.c'),
3459         'dependencies': []
3460       }]
3461     endif
3462     if get_option('fuzzing')
3463       specific_fuzz = specific_fuzz_ss.apply(config_target, strict: false)
3464       execs += [{
3465         'name': 'qemu-fuzz-' + target_name,
3466         'win_subsystem': 'console',
3467         'sources': specific_fuzz.sources(),
3468         'dependencies': specific_fuzz.dependencies(),
3469       }]
3470     endif
3471   else
3472     execs = [{
3473       'name': 'qemu-' + target_name,
3474       'win_subsystem': 'console',
3475       'sources': [],
3476       'dependencies': []
3477     }]
3478   endif
3479   foreach exe: execs
3480     exe_name = exe['name']
3481     if targetos == 'darwin'
3482       exe_name += '-unsigned'
3483     endif
3484
3485     emulator = executable(exe_name, exe['sources'],
3486                install: true,
3487                c_args: c_args,
3488                dependencies: arch_deps + deps + exe['dependencies'],
3489                objects: lib.extract_all_objects(recursive: true),
3490                link_language: link_language,
3491                link_depends: [block_syms, qemu_syms] + exe.get('link_depends', []),
3492                link_args: link_args,
3493                win_subsystem: exe['win_subsystem'])
3494
3495     if targetos == 'darwin'
3496       icon = 'pc-bios/qemu.rsrc'
3497       build_input = [emulator, files(icon)]
3498       install_input = [
3499         get_option('bindir') / exe_name,
3500         meson.current_source_dir() / icon
3501       ]
3502       if 'CONFIG_HVF' in config_target
3503         entitlements = 'accel/hvf/entitlements.plist'
3504         build_input += files(entitlements)
3505         install_input += meson.current_source_dir() / entitlements
3506       endif
3507
3508       emulators += {exe['name'] : custom_target(exe['name'],
3509                    input: build_input,
3510                    output: exe['name'],
3511                    command: [entitlement, '@OUTPUT@', '@INPUT@'])
3512       }
3513
3514       meson.add_install_script(entitlement, '--install',
3515                                get_option('bindir') / exe['name'],
3516                                install_input)
3517     else
3518       emulators += {exe['name']: emulator}
3519     endif
3520
3521     if stap.found()
3522       foreach stp: [
3523         {'ext': '.stp-build', 'fmt': 'stap', 'bin': meson.current_build_dir() / exe['name'], 'install': false},
3524         {'ext': '.stp', 'fmt': 'stap', 'bin': get_option('prefix') / get_option('bindir') / exe['name'], 'install': true},
3525         {'ext': '-simpletrace.stp', 'fmt': 'simpletrace-stap', 'bin': '', 'install': true},
3526         {'ext': '-log.stp', 'fmt': 'log-stap', 'bin': '', 'install': true},
3527       ]
3528         custom_target(exe['name'] + stp['ext'],
3529                       input: trace_events_all,
3530                       output: exe['name'] + stp['ext'],
3531                       install: stp['install'],
3532                       install_dir: get_option('datadir') / 'systemtap/tapset',
3533                       command: [
3534                         tracetool, '--group=all', '--format=' + stp['fmt'],
3535                         '--binary=' + stp['bin'],
3536                         '--target-name=' + target_name,
3537                         '--target-type=' + target_type,
3538                         '--probe-prefix=qemu.' + target_type + '.' + target_name,
3539                         '@INPUT@', '@OUTPUT@'
3540                       ],
3541                       depend_files: tracetool_depends)
3542       endforeach
3543     endif
3544   endforeach
3545 endforeach
3546
3547 # Other build targets
3548
3549 if 'CONFIG_PLUGIN' in config_host
3550   install_headers('include/qemu/qemu-plugin.h')
3551 endif
3552
3553 subdir('qga')
3554
3555 # Don't build qemu-keymap if xkbcommon is not explicitly enabled
3556 # when we don't build tools or system
3557 if xkbcommon.found()
3558   # used for the update-keymaps target, so include rules even if !have_tools
3559   qemu_keymap = executable('qemu-keymap', files('qemu-keymap.c', 'ui/input-keymap.c') + genh,
3560                            dependencies: [qemuutil, xkbcommon], install: have_tools)
3561 endif
3562
3563 if have_tools
3564   qemu_img = executable('qemu-img', [files('qemu-img.c'), hxdep],
3565              dependencies: [authz, block, crypto, io, qom, qemuutil], install: true)
3566   qemu_io = executable('qemu-io', files('qemu-io.c'),
3567              dependencies: [block, qemuutil], install: true)
3568   qemu_nbd = executable('qemu-nbd', files('qemu-nbd.c'),
3569                dependencies: [blockdev, qemuutil, gnutls, selinux],
3570                install: true)
3571
3572   subdir('storage-daemon')
3573   subdir('contrib/rdmacm-mux')
3574   subdir('contrib/elf2dmp')
3575
3576   executable('qemu-edid', files('qemu-edid.c', 'hw/display/edid-generate.c'),
3577              dependencies: qemuutil,
3578              install: true)
3579
3580   if have_vhost_user
3581     subdir('contrib/vhost-user-blk')
3582     subdir('contrib/vhost-user-gpu')
3583     subdir('contrib/vhost-user-input')
3584     subdir('contrib/vhost-user-scsi')
3585   endif
3586
3587   if targetos == 'linux'
3588     executable('qemu-bridge-helper', files('qemu-bridge-helper.c'),
3589                dependencies: [qemuutil, libcap_ng],
3590                install: true,
3591                install_dir: get_option('libexecdir'))
3592
3593     executable('qemu-pr-helper', files('scsi/qemu-pr-helper.c', 'scsi/utils.c'),
3594                dependencies: [authz, crypto, io, qom, qemuutil,
3595                               libcap_ng, mpathpersist],
3596                install: true)
3597   endif
3598
3599   if have_ivshmem
3600     subdir('contrib/ivshmem-client')
3601     subdir('contrib/ivshmem-server')
3602   endif
3603 endif
3604
3605 subdir('scripts')
3606 subdir('tools')
3607 subdir('pc-bios')
3608 subdir('docs')
3609 subdir('tests')
3610 if gtk.found()
3611   subdir('po')
3612 endif
3613
3614 if host_machine.system() == 'windows'
3615   nsis_cmd = [
3616     find_program('scripts/nsis.py'),
3617     '@OUTPUT@',
3618     get_option('prefix'),
3619     meson.current_source_dir(),
3620     host_machine.cpu(),
3621     '--',
3622     '-DDISPLAYVERSION=' + meson.project_version(),
3623   ]
3624   if build_docs
3625     nsis_cmd += '-DCONFIG_DOCUMENTATION=y'
3626   endif
3627   if gtk.found()
3628     nsis_cmd += '-DCONFIG_GTK=y'
3629   endif
3630
3631   nsis = custom_target('nsis',
3632                        output: 'qemu-setup-' + meson.project_version() + '.exe',
3633                        input: files('qemu.nsi'),
3634                        build_always_stale: true,
3635                        command: nsis_cmd + ['@INPUT@'])
3636   alias_target('installer', nsis)
3637 endif
3638
3639 #########################
3640 # Configuration summary #
3641 #########################
3642
3643 # Directories
3644 summary_info = {}
3645 summary_info += {'Install prefix':    get_option('prefix')}
3646 summary_info += {'BIOS directory':    qemu_datadir}
3647 pathsep = targetos == 'windows' ? ';' : ':'
3648 summary_info += {'firmware path':     pathsep.join(get_option('qemu_firmwarepath'))}
3649 summary_info += {'binary directory':  get_option('prefix') / get_option('bindir')}
3650 summary_info += {'library directory': get_option('prefix') / get_option('libdir')}
3651 summary_info += {'module directory':  qemu_moddir}
3652 summary_info += {'libexec directory': get_option('prefix') / get_option('libexecdir')}
3653 summary_info += {'include directory': get_option('prefix') / get_option('includedir')}
3654 summary_info += {'config directory':  get_option('prefix') / get_option('sysconfdir')}
3655 if targetos != 'windows'
3656   summary_info += {'local state directory': get_option('prefix') / get_option('localstatedir')}
3657   summary_info += {'Manual directory':      get_option('prefix') / get_option('mandir')}
3658 else
3659   summary_info += {'local state directory': 'queried at runtime'}
3660 endif
3661 summary_info += {'Doc directory':     get_option('prefix') / get_option('docdir')}
3662 summary_info += {'Build directory':   meson.current_build_dir()}
3663 summary_info += {'Source path':       meson.current_source_dir()}
3664 summary_info += {'GIT submodules':    config_host['GIT_SUBMODULES']}
3665 summary(summary_info, bool_yn: true, section: 'Directories')
3666
3667 # Host binaries
3668 summary_info = {}
3669 summary_info += {'git':               config_host['GIT']}
3670 summary_info += {'make':              config_host['MAKE']}
3671 summary_info += {'python':            '@0@ (version: @1@)'.format(python.full_path(), python.language_version())}
3672 summary_info += {'sphinx-build':      sphinx_build}
3673 if config_host.has_key('HAVE_GDB_BIN')
3674   summary_info += {'gdb':             config_host['HAVE_GDB_BIN']}
3675 endif
3676 summary_info += {'iasl':              iasl}
3677 summary_info += {'genisoimage':       config_host['GENISOIMAGE']}
3678 if targetos == 'windows' and have_ga
3679   summary_info += {'wixl':            wixl}
3680 endif
3681 if slirp.found() and have_system
3682   summary_info += {'smbd':            have_slirp_smbd ? smbd_path : false}
3683 endif
3684 summary(summary_info, bool_yn: true, section: 'Host binaries')
3685
3686 # Configurable features
3687 summary_info = {}
3688 summary_info += {'Documentation':     build_docs}
3689 summary_info += {'system-mode emulation': have_system}
3690 summary_info += {'user-mode emulation': have_user}
3691 summary_info += {'block layer':       have_block}
3692 summary_info += {'Install blobs':     get_option('install_blobs')}
3693 summary_info += {'module support':    config_host.has_key('CONFIG_MODULES')}
3694 if config_host.has_key('CONFIG_MODULES')
3695   summary_info += {'alternative module path': get_option('module_upgrades')}
3696 endif
3697 summary_info += {'fuzzing support':   get_option('fuzzing')}
3698 if have_system
3699   summary_info += {'Audio drivers':     ' '.join(audio_drivers_selected)}
3700 endif
3701 summary_info += {'Trace backends':    ','.join(get_option('trace_backends'))}
3702 if 'simple' in get_option('trace_backends')
3703   summary_info += {'Trace output file': get_option('trace_file') + '-<pid>'}
3704 endif
3705 summary_info += {'D-Bus display':     dbus_display}
3706 summary_info += {'QOM debugging':     get_option('qom_cast_debug')}
3707 summary_info += {'vhost-kernel support': have_vhost_kernel}
3708 summary_info += {'vhost-net support': have_vhost_net}
3709 summary_info += {'vhost-user support': have_vhost_user}
3710 summary_info += {'vhost-user-crypto support': have_vhost_user_crypto}
3711 summary_info += {'vhost-user-blk server support': have_vhost_user_blk_server}
3712 summary_info += {'vhost-vdpa support': have_vhost_vdpa}
3713 summary_info += {'build guest agent': have_ga}
3714 summary(summary_info, bool_yn: true, section: 'Configurable features')
3715
3716 # Compilation information
3717 summary_info = {}
3718 summary_info += {'host CPU':          cpu}
3719 summary_info += {'host endianness':   build_machine.endian()}
3720 summary_info += {'C compiler':        ' '.join(meson.get_compiler('c').cmd_array())}
3721 summary_info += {'Host C compiler':   ' '.join(meson.get_compiler('c', native: true).cmd_array())}
3722 if link_language == 'cpp'
3723   summary_info += {'C++ compiler':    ' '.join(meson.get_compiler('cpp').cmd_array())}
3724 else
3725   summary_info += {'C++ compiler':      false}
3726 endif
3727 if targetos == 'darwin'
3728   summary_info += {'Objective-C compiler': ' '.join(meson.get_compiler('objc').cmd_array())}
3729 endif
3730 summary_info += {'CFLAGS':            ' '.join(get_option('c_args')
3731                                                + ['-O' + get_option('optimization')]
3732                                                + (get_option('debug') ? ['-g'] : []))}
3733 if link_language == 'cpp'
3734   summary_info += {'CXXFLAGS':        ' '.join(get_option('cpp_args')
3735                                                + ['-O' + get_option('optimization')]
3736                                                + (get_option('debug') ? ['-g'] : []))}
3737 endif
3738 if targetos == 'darwin'
3739   summary_info += {'OBJCFLAGS':       ' '.join(get_option('objc_args')
3740                                                + ['-O' + get_option('optimization')]
3741                                                + (get_option('debug') ? ['-g'] : []))}
3742 endif
3743 link_args = get_option(link_language + '_link_args')
3744 if link_args.length() > 0
3745   summary_info += {'LDFLAGS':         ' '.join(link_args)}
3746 endif
3747 summary_info += {'QEMU_CFLAGS':       ' '.join(qemu_cflags)}
3748 summary_info += {'QEMU_CXXFLAGS':     ' '.join(qemu_cxxflags)}
3749 summary_info += {'QEMU_OBJCFLAGS':    ' '.join(qemu_objcflags)}
3750 summary_info += {'QEMU_LDFLAGS':      ' '.join(qemu_ldflags)}
3751 summary_info += {'profiler':          get_option('profiler')}
3752 summary_info += {'link-time optimization (LTO)': get_option('b_lto')}
3753 summary_info += {'PIE':               get_option('b_pie')}
3754 summary_info += {'static build':      config_host.has_key('CONFIG_STATIC')}
3755 summary_info += {'malloc trim support': has_malloc_trim}
3756 summary_info += {'membarrier':        have_membarrier}
3757 summary_info += {'debug stack usage': get_option('debug_stack_usage')}
3758 summary_info += {'mutex debugging':   get_option('debug_mutex')}
3759 summary_info += {'memory allocator':  get_option('malloc')}
3760 summary_info += {'avx2 optimization': config_host_data.get('CONFIG_AVX2_OPT')}
3761 summary_info += {'avx512f optimization': config_host_data.get('CONFIG_AVX512F_OPT')}
3762 summary_info += {'gprof enabled':     get_option('gprof')}
3763 summary_info += {'gcov':              get_option('b_coverage')}
3764 summary_info += {'thread sanitizer':  config_host.has_key('CONFIG_TSAN')}
3765 summary_info += {'CFI support':       get_option('cfi')}
3766 if get_option('cfi')
3767   summary_info += {'CFI debug support': get_option('cfi_debug')}
3768 endif
3769 summary_info += {'strip binaries':    get_option('strip')}
3770 summary_info += {'sparse':            sparse}
3771 summary_info += {'mingw32 support':   targetos == 'windows'}
3772 summary(summary_info, bool_yn: true, section: 'Compilation')
3773
3774 # snarf the cross-compilation information for tests
3775 summary_info = {}
3776 have_cross = false
3777 foreach target: target_dirs
3778   tcg_mak = meson.current_build_dir() / 'tests/tcg' / target / 'config-target.mak'
3779   if fs.exists(tcg_mak)
3780     config_cross_tcg = keyval.load(tcg_mak)
3781     if 'CC' in config_cross_tcg
3782       summary_info += {config_cross_tcg['TARGET_NAME']: config_cross_tcg['CC']}
3783       have_cross = true
3784     endif
3785   endif
3786 endforeach
3787 if have_cross
3788   summary(summary_info, bool_yn: true, section: 'Cross compilers')
3789 endif
3790
3791 # Targets and accelerators
3792 summary_info = {}
3793 if have_system
3794   summary_info += {'KVM support':       config_all.has_key('CONFIG_KVM')}
3795   summary_info += {'HAX support':       config_all.has_key('CONFIG_HAX')}
3796   summary_info += {'HVF support':       config_all.has_key('CONFIG_HVF')}
3797   summary_info += {'WHPX support':      config_all.has_key('CONFIG_WHPX')}
3798   summary_info += {'NVMM support':      config_all.has_key('CONFIG_NVMM')}
3799   summary_info += {'Xen support':       xen.found()}
3800   if xen.found()
3801     summary_info += {'xen ctrl version':  xen.version()}
3802   endif
3803 endif
3804 summary_info += {'TCG support':       config_all.has_key('CONFIG_TCG')}
3805 if config_all.has_key('CONFIG_TCG')
3806   if get_option('tcg_interpreter')
3807     summary_info += {'TCG backend':   'TCI (TCG with bytecode interpreter, slow)'}
3808   else
3809     summary_info += {'TCG backend':   'native (@0@)'.format(cpu)}
3810   endif
3811   summary_info += {'TCG plugins': config_host.has_key('CONFIG_PLUGIN')}
3812   summary_info += {'TCG debug enabled': config_host.has_key('CONFIG_DEBUG_TCG')}
3813 endif
3814 summary_info += {'target list':       ' '.join(target_dirs)}
3815 if have_system
3816   summary_info += {'default devices':   get_option('default_devices')}
3817   summary_info += {'out of process emulation': multiprocess_allowed}
3818   summary_info += {'vfio-user server': vfio_user_server_allowed}
3819 endif
3820 summary(summary_info, bool_yn: true, section: 'Targets and accelerators')
3821
3822 # Block layer
3823 summary_info = {}
3824 summary_info += {'coroutine backend': config_host['CONFIG_COROUTINE_BACKEND']}
3825 summary_info += {'coroutine pool':    have_coroutine_pool}
3826 if have_block
3827   summary_info += {'Block whitelist (rw)': get_option('block_drv_rw_whitelist')}
3828   summary_info += {'Block whitelist (ro)': get_option('block_drv_ro_whitelist')}
3829   summary_info += {'Use block whitelist in tools': get_option('block_drv_whitelist_in_tools')}
3830   summary_info += {'VirtFS support':    have_virtfs}
3831   summary_info += {'build virtiofs daemon': have_virtiofsd}
3832   summary_info += {'Live block migration': config_host_data.get('CONFIG_LIVE_BLOCK_MIGRATION')}
3833   summary_info += {'replication support': config_host_data.get('CONFIG_REPLICATION')}
3834   summary_info += {'bochs support':     get_option('bochs').allowed()}
3835   summary_info += {'cloop support':     get_option('cloop').allowed()}
3836   summary_info += {'dmg support':       get_option('dmg').allowed()}
3837   summary_info += {'qcow v1 support':   get_option('qcow1').allowed()}
3838   summary_info += {'vdi support':       get_option('vdi').allowed()}
3839   summary_info += {'vvfat support':     get_option('vvfat').allowed()}
3840   summary_info += {'qed support':       get_option('qed').allowed()}
3841   summary_info += {'parallels support': get_option('parallels').allowed()}
3842   summary_info += {'FUSE exports':      fuse}
3843   summary_info += {'VDUSE block exports': have_vduse_blk_export}
3844 endif
3845 summary(summary_info, bool_yn: true, section: 'Block layer support')
3846
3847 # Crypto
3848 summary_info = {}
3849 summary_info += {'TLS priority':      get_option('tls_priority')}
3850 summary_info += {'GNUTLS support':    gnutls}
3851 if gnutls.found()
3852   summary_info += {'  GNUTLS crypto':   gnutls_crypto.found()}
3853 endif
3854 summary_info += {'libgcrypt':         gcrypt}
3855 summary_info += {'nettle':            nettle}
3856 if nettle.found()
3857    summary_info += {'  XTS':             xts != 'private'}
3858 endif
3859 summary_info += {'AF_ALG support':    have_afalg}
3860 summary_info += {'rng-none':          get_option('rng_none')}
3861 summary_info += {'Linux keyring':     have_keyring}
3862 summary(summary_info, bool_yn: true, section: 'Crypto')
3863
3864 # Libraries
3865 summary_info = {}
3866 if targetos == 'darwin'
3867   summary_info += {'Cocoa support':           cocoa}
3868   summary_info += {'vmnet.framework support': vmnet}
3869 endif
3870 summary_info += {'SDL support':       sdl}
3871 summary_info += {'SDL image support': sdl_image}
3872 summary_info += {'GTK support':       gtk}
3873 summary_info += {'pixman':            pixman}
3874 summary_info += {'VTE support':       vte}
3875 summary_info += {'slirp support':     slirp}
3876 summary_info += {'libtasn1':          tasn1}
3877 summary_info += {'PAM':               pam}
3878 summary_info += {'iconv support':     iconv}
3879 summary_info += {'curses support':    curses}
3880 summary_info += {'virgl support':     virgl}
3881 summary_info += {'curl support':      curl}
3882 summary_info += {'Multipath support': mpathpersist}
3883 summary_info += {'PNG support':       png}
3884 summary_info += {'VNC support':       vnc}
3885 if vnc.found()
3886   summary_info += {'VNC SASL support':  sasl}
3887   summary_info += {'VNC JPEG support':  jpeg}
3888 endif
3889 if targetos not in ['darwin', 'haiku', 'windows']
3890   summary_info += {'OSS support':     oss}
3891   summary_info += {'sndio support':   sndio}
3892 elif targetos == 'darwin'
3893   summary_info += {'CoreAudio support': coreaudio}
3894 elif targetos == 'windows'
3895   summary_info += {'DirectSound support': dsound}
3896 endif
3897 if targetos == 'linux'
3898   summary_info += {'ALSA support':    alsa}
3899   summary_info += {'PulseAudio support': pulse}
3900 endif
3901 summary_info += {'JACK support':      jack}
3902 summary_info += {'brlapi support':    brlapi}
3903 summary_info += {'vde support':       vde}
3904 summary_info += {'netmap support':    have_netmap}
3905 summary_info += {'l2tpv3 support':    have_l2tpv3}
3906 summary_info += {'Linux AIO support': libaio}
3907 summary_info += {'Linux io_uring support': linux_io_uring}
3908 summary_info += {'ATTR/XATTR support': libattr}
3909 summary_info += {'RDMA support':      rdma}
3910 summary_info += {'PVRDMA support':    have_pvrdma}
3911 summary_info += {'fdt support':       fdt_opt == 'disabled' ? false : fdt_opt}
3912 summary_info += {'libcap-ng support': libcap_ng}
3913 summary_info += {'bpf support':       libbpf}
3914 summary_info += {'spice protocol support': spice_protocol}
3915 if spice_protocol.found()
3916   summary_info += {'  spice server support': spice}
3917 endif
3918 summary_info += {'rbd support':       rbd}
3919 summary_info += {'smartcard support': cacard}
3920 summary_info += {'U2F support':       u2f}
3921 summary_info += {'libusb':            libusb}
3922 summary_info += {'usb net redir':     usbredir}
3923 summary_info += {'OpenGL support (epoxy)': opengl}
3924 summary_info += {'GBM':               gbm}
3925 summary_info += {'libiscsi support':  libiscsi}
3926 summary_info += {'libnfs support':    libnfs}
3927 if targetos == 'windows'
3928   if have_ga
3929     summary_info += {'QGA VSS support':   have_qga_vss}
3930   endif
3931 endif
3932 summary_info += {'seccomp support':   seccomp}
3933 summary_info += {'GlusterFS support': glusterfs}
3934 summary_info += {'TPM support':       have_tpm}
3935 summary_info += {'libssh support':    libssh}
3936 summary_info += {'lzo support':       lzo}
3937 summary_info += {'snappy support':    snappy}
3938 summary_info += {'bzip2 support':     libbzip2}
3939 summary_info += {'lzfse support':     liblzfse}
3940 summary_info += {'zstd support':      zstd}
3941 summary_info += {'NUMA host support': numa}
3942 summary_info += {'capstone':          capstone}
3943 summary_info += {'libpmem support':   libpmem}
3944 summary_info += {'libdaxctl support': libdaxctl}
3945 summary_info += {'libudev':           libudev}
3946 # Dummy dependency, keep .found()
3947 summary_info += {'FUSE lseek':        fuse_lseek.found()}
3948 summary_info += {'selinux':           selinux}
3949 summary(summary_info, bool_yn: true, section: 'Dependencies')
3950
3951 if not supported_cpus.contains(cpu)
3952   message()
3953   warning('SUPPORT FOR THIS HOST CPU WILL GO AWAY IN FUTURE RELEASES!')
3954   message()
3955   message('CPU host architecture ' + cpu + ' support is not currently maintained.')
3956   message('The QEMU project intends to remove support for this host CPU in')
3957   message('a future release if nobody volunteers to maintain it and to')
3958   message('provide a build host for our continuous integration setup.')
3959   message('configure has succeeded and you can continue to build, but')
3960   message('if you care about QEMU on this platform you should contact')
3961   message('us upstream at [email protected].')
3962 endif
3963
3964 if not supported_oses.contains(targetos)
3965   message()
3966   warning('WARNING: SUPPORT FOR THIS HOST OS WILL GO AWAY IN FUTURE RELEASES!')
3967   message()
3968   message('Host OS ' + targetos + 'support is not currently maintained.')
3969   message('The QEMU project intends to remove support for this host OS in')
3970   message('a future release if nobody volunteers to maintain it and to')
3971   message('provide a build host for our continuous integration setup.')
3972   message('configure has succeeded and you can continue to build, but')
3973   message('if you care about QEMU on this platform you should contact')
3974   message('us upstream at [email protected].')
3975 endif