arch/x86/entry/calling.h

   1 /*
   2
   3  x86 function call convention, 64-bit:
   4  -------------------------------------
   5   arguments           |  callee-saved      | extra caller-saved | return
   6  [callee-clobbered]   |                    | [callee-clobbered] |
   7  ---------------------------------------------------------------------------
   8  rdi rsi rdx rcx r8-9 | rbx rbp [*] r12-15 | r10-11             | rax, rdx [**]
   9
  10  ( rsp is obviously invariant across normal function calls. (gcc can 'merge'
  11    functions when it sees tail-call optimization possibilities) rflags is
  12    clobbered. Leftover arguments are passed over the stack frame.)
  13
  14  [*]  In the frame-pointers case rbp is fixed to the stack frame.
  15
  16  [**] for struct return values wider than 64 bits the return convention is a
  17       bit more complex: up to 128 bits width we return small structures
  18       straight in rax, rdx. For structures larger than that (3 words or
  19       larger) the caller puts a pointer to an on-stack return struct
  20       [allocated in the caller's stack frame] into the first argument - i.e.
  21       into rdi. All other arguments shift up by one in this case.
  22       Fortunately this case is rare in the kernel.
  23
  24 For 32-bit we have the following conventions - kernel is built with
  25 -mregparm=3 and -freg-struct-return:
  26
  27  x86 function calling convention, 32-bit:
  28  ----------------------------------------
  29   arguments         | callee-saved        | extra caller-saved | return
  30  [callee-clobbered] |                     | [callee-clobbered] |
  31  -------------------------------------------------------------------------
  32  eax edx ecx        | ebx edi esi ebp [*] | <none>             | eax, edx [**]
  33
  34  ( here too esp is obviously invariant across normal function calls. eflags
  35    is clobbered. Leftover arguments are passed over the stack frame. )
  36
  37  [*]  In the frame-pointers case ebp is fixed to the stack frame.
  38
  39  [**] We build with -freg-struct-return, which on 32-bit means similar
  40       semantics as on 64-bit: edx can be used for a second return value
  41       (i.e. covering integer and structure sizes up to 64 bits) - after that
  42       it gets more complex and more expensive: 3-word or larger struct returns
  43       get done in the caller's frame and the pointer to the return struct goes
  44       into regparm0, i.e. eax - the other arguments shift up and the
  45       function's register parameters degenerate to regparm=2 in essence.
  46
  47 */
  48
  49 #ifdef CONFIG_X86_64
  50
  51 /*
  52  * 64-bit system call stack frame layout defines and helpers,
  53  * for assembly code:
  54  */
  55
  56 /* The layout forms the "struct pt_regs" on the stack: */
  57 /*
  58  * C ABI says these regs are callee-preserved. They aren't saved on kernel entry
  59  * unless syscall needs a complete, fully filled "struct pt_regs".
  60  */
  61 #define R15             0*8
  62 #define R14             1*8
  63 #define R13             2*8
  64 #define R12             3*8
  65 #define RBP             4*8
  66 #define RBX             5*8
  67 /* These regs are callee-clobbered. Always saved on kernel entry. */
  68 #define R11             6*8
  69 #define R10             7*8
  70 #define R9              8*8
  71 #define R8              9*8
  72 #define RAX             10*8
  73 #define RCX             11*8
  74 #define RDX             12*8
  75 #define RSI             13*8
  76 #define RDI             14*8
  77 /*
  78  * On syscall entry, this is syscall#. On CPU exception, this is error code.
  79  * On hw interrupt, it's IRQ number:
  80  */
  81 #define ORIG_RAX        15*8
  82 /* Return frame for iretq */
  83 #define RIP             16*8
  84 #define CS              17*8
  85 #define EFLAGS          18*8
  86 #define RSP             19*8
  87 #define SS              20*8
  88
  89 #define SIZEOF_PTREGS   21*8
  90
  91         .macro ALLOC_PT_GPREGS_ON_STACK addskip=0
  92         addq    $-(15*8+\addskip), %rsp
  93         .endm
  94
  95         .macro SAVE_C_REGS_HELPER offset=0 rax=1 rcx=1 r8910=1 r11=1
  96         .if \r11
  97         movq %r11, 6*8+\offset(%rsp)
  98         .endif
  99         .if \r8910
 100         movq %r10, 7*8+\offset(%rsp)
 101         movq %r9,  8*8+\offset(%rsp)
 102         movq %r8,  9*8+\offset(%rsp)
 103         .endif
 104         .if \rax
 105         movq %rax, 10*8+\offset(%rsp)
 106         .endif
 107         .if \rcx
 108         movq %rcx, 11*8+\offset(%rsp)
 109         .endif
 110         movq %rdx, 12*8+\offset(%rsp)
 111         movq %rsi, 13*8+\offset(%rsp)
 112         movq %rdi, 14*8+\offset(%rsp)
 113         .endm
 114         .macro SAVE_C_REGS offset=0
 115         SAVE_C_REGS_HELPER \offset, 1, 1, 1, 1
 116         .endm
 117         .macro SAVE_C_REGS_EXCEPT_RAX_RCX offset=0
 118         SAVE_C_REGS_HELPER \offset, 0, 0, 1, 1
 119         .endm
 120         .macro SAVE_C_REGS_EXCEPT_R891011
 121         SAVE_C_REGS_HELPER 0, 1, 1, 0, 0
 122         .endm
 123         .macro SAVE_C_REGS_EXCEPT_RCX_R891011
 124         SAVE_C_REGS_HELPER 0, 1, 0, 0, 0
 125         .endm
 126         .macro SAVE_C_REGS_EXCEPT_RAX_RCX_R11
 127         SAVE_C_REGS_HELPER 0, 0, 0, 1, 0
 128         .endm
 129
 130         .macro SAVE_EXTRA_REGS offset=0
 131         movq %r15, 0*8+\offset(%rsp)
 132         movq %r14, 1*8+\offset(%rsp)
 133         movq %r13, 2*8+\offset(%rsp)
 134         movq %r12, 3*8+\offset(%rsp)
 135         movq %rbp, 4*8+\offset(%rsp)
 136         movq %rbx, 5*8+\offset(%rsp)
 137         .endm
 138         .macro SAVE_EXTRA_REGS_RBP offset=0
 139         movq %rbp, 4*8+\offset(%rsp)
 140         .endm
 141
 142         .macro RESTORE_EXTRA_REGS offset=0
 143         movq 0*8+\offset(%rsp), %r15
 144         movq 1*8+\offset(%rsp), %r14
 145         movq 2*8+\offset(%rsp), %r13
 146         movq 3*8+\offset(%rsp), %r12
 147         movq 4*8+\offset(%rsp), %rbp
 148         movq 5*8+\offset(%rsp), %rbx
 149         .endm
 150
 151         .macro ZERO_EXTRA_REGS
 152         xorl    %r15d, %r15d
 153         xorl    %r14d, %r14d
 154         xorl    %r13d, %r13d
 155         xorl    %r12d, %r12d
 156         xorl    %ebp, %ebp
 157         xorl    %ebx, %ebx
 158         .endm
 159
 160         .macro RESTORE_C_REGS_HELPER rstor_rax=1, rstor_rcx=1, rstor_r11=1, rstor_r8910=1, rstor_rdx=1
 161         .if \rstor_r11
 162         movq 6*8(%rsp), %r11
 163         .endif
 164         .if \rstor_r8910
 165         movq 7*8(%rsp), %r10
 166         movq 8*8(%rsp), %r9
 167         movq 9*8(%rsp), %r8
 168         .endif
 169         .if \rstor_rax
 170         movq 10*8(%rsp), %rax
 171         .endif
 172         .if \rstor_rcx
 173         movq 11*8(%rsp), %rcx
 174         .endif
 175         .if \rstor_rdx
 176         movq 12*8(%rsp), %rdx
 177         .endif
 178         movq 13*8(%rsp), %rsi
 179         movq 14*8(%rsp), %rdi
 180         .endm
 181         .macro RESTORE_C_REGS
 182         RESTORE_C_REGS_HELPER 1,1,1,1,1
 183         .endm
 184         .macro RESTORE_C_REGS_EXCEPT_RAX
 185         RESTORE_C_REGS_HELPER 0,1,1,1,1
 186         .endm
 187         .macro RESTORE_C_REGS_EXCEPT_RCX
 188         RESTORE_C_REGS_HELPER 1,0,1,1,1
 189         .endm
 190         .macro RESTORE_C_REGS_EXCEPT_R11
 191         RESTORE_C_REGS_HELPER 1,1,0,1,1
 192         .endm
 193         .macro RESTORE_C_REGS_EXCEPT_RCX_R11
 194         RESTORE_C_REGS_HELPER 1,0,0,1,1
 195         .endm
 196         .macro RESTORE_RSI_RDI
 197         RESTORE_C_REGS_HELPER 0,0,0,0,0
 198         .endm
 199         .macro RESTORE_RSI_RDI_RDX
 200         RESTORE_C_REGS_HELPER 0,0,0,0,1
 201         .endm
 202
 203         .macro REMOVE_PT_GPREGS_FROM_STACK addskip=0
 204         subq $-(15*8+\addskip), %rsp
 205         .endm
 206
 207         .macro icebp
 208         .byte 0xf1
 209         .endm
 210
 211 #else /* CONFIG_X86_64 */
 212
 213 /*
 214  * For 32bit only simplified versions of SAVE_ALL/RESTORE_ALL. These
 215  * are different from the entry_32.S versions in not changing the segment
 216  * registers. So only suitable for in kernel use, not when transitioning
 217  * from or to user space. The resulting stack frame is not a standard
 218  * pt_regs frame. The main use case is calling C code from assembler
 219  * when all the registers need to be preserved.
 220  */
 221
 222         .macro SAVE_ALL
 223         pushl %eax
 224         pushl %ebp
 225         pushl %edi
 226         pushl %esi
 227         pushl %edx
 228         pushl %ecx
 229         pushl %ebx
 230         .endm
 231
 232         .macro RESTORE_ALL
 233         popl %ebx
 234         popl %ecx
 235         popl %edx
 236         popl %esi
 237         popl %edi
 238         popl %ebp
 239         popl %eax
 240         .endm
 241
 242 #endif /* CONFIG_X86_64 */
 243