arch/s390/kernel/mcount.S

   1 /* SPDX-License-Identifier: GPL-2.0 */
   2 /*
   3  * Copyright IBM Corp. 2008, 2009
   4  *
   5  *   Author(s): Heiko Carstens <[email protected]>,
   6  *
   7  */
   8
   9 #include <linux/linkage.h>
  10 #include <asm/asm-offsets.h>
  11 #include <asm/ftrace.h>
  12 #include <asm/nospec-insn.h>
  13 #include <asm/ptrace.h>
  14 #include <asm/export.h>
  15
  16         GEN_BR_THUNK %r1
  17         GEN_BR_THUNK %r14
  18
  19         .section .kprobes.text, "ax"
  20
  21 ENTRY(ftrace_stub)
  22         BR_EX   %r14
  23 ENDPROC(ftrace_stub)
  24
  25 #define STACK_FRAME_SIZE        (STACK_FRAME_OVERHEAD + __PT_SIZE)
  26 #define STACK_PTREGS            (STACK_FRAME_OVERHEAD)
  27 #define STACK_PTREGS_GPRS       (STACK_PTREGS + __PT_GPRS)
  28 #define STACK_PTREGS_PSW        (STACK_PTREGS + __PT_PSW)
  29 #define STACK_PTREGS_ORIG_GPR2  (STACK_PTREGS + __PT_ORIG_GPR2)
  30 #ifdef __PACK_STACK
  31 /* allocate just enough for r14, r15 and backchain */
  32 #define TRACED_FUNC_FRAME_SIZE  24
  33 #else
  34 #define TRACED_FUNC_FRAME_SIZE  STACK_FRAME_OVERHEAD
  35 #endif
  36
  37         .macro  ftrace_regs_entry, allregs=0
  38         stg     %r14,(__SF_GPRS+8*8)(%r15)      # save traced function caller
  39
  40         .if \allregs == 1
  41         lghi    %r14,0                          # save condition code
  42         ipm     %r14                            # don't put any instructions
  43         sllg    %r14,%r14,16                    # clobbering CC before this point
  44         .endif
  45
  46         lgr     %r1,%r15
  47         # allocate stack frame for ftrace_caller to contain traced function
  48         aghi    %r15,-TRACED_FUNC_FRAME_SIZE
  49         stg     %r1,__SF_BACKCHAIN(%r15)
  50         stg     %r0,(__SF_GPRS+8*8)(%r15)
  51         stg     %r15,(__SF_GPRS+9*8)(%r15)
  52         # allocate pt_regs and stack frame for ftrace_trace_function
  53         aghi    %r15,-STACK_FRAME_SIZE
  54         stg     %r1,(STACK_PTREGS_GPRS+15*8)(%r15)
  55         xc      STACK_PTREGS_ORIG_GPR2(8,%r15),STACK_PTREGS_ORIG_GPR2(%r15)
  56
  57         .if \allregs == 1
  58         stg     %r14,(STACK_PTREGS_PSW)(%r15)
  59         stosm   (STACK_PTREGS_PSW)(%r15),0
  60         .endif
  61
  62         lg      %r14,(__SF_GPRS+8*8)(%r1)       # restore original return address
  63         aghi    %r1,-TRACED_FUNC_FRAME_SIZE
  64         stg     %r1,__SF_BACKCHAIN(%r15)
  65         stg     %r0,(STACK_PTREGS_PSW+8)(%r15)
  66         stmg    %r2,%r14,(STACK_PTREGS_GPRS+2*8)(%r15)
  67         .endm
  68
  69 SYM_CODE_START(ftrace_regs_caller)
  70         ftrace_regs_entry       1
  71         j       ftrace_common
  72 SYM_CODE_END(ftrace_regs_caller)
  73
  74 SYM_CODE_START(ftrace_caller)
  75         ftrace_regs_entry       0
  76         j       ftrace_common
  77 SYM_CODE_END(ftrace_caller)
  78
  79 SYM_CODE_START(ftrace_common)
  80 #ifdef CONFIG_HAVE_MARCH_Z196_FEATURES
  81         aghik   %r2,%r0,-MCOUNT_INSN_SIZE
  82         lgrl    %r4,function_trace_op
  83         lgrl    %r1,ftrace_func
  84 #else
  85         lgr     %r2,%r0
  86         aghi    %r2,-MCOUNT_INSN_SIZE
  87         larl    %r4,function_trace_op
  88         lg      %r4,0(%r4)
  89         larl    %r1,ftrace_func
  90         lg      %r1,0(%r1)
  91 #endif
  92         lgr     %r3,%r14
  93         la      %r5,STACK_PTREGS(%r15)
  94         BASR_EX %r14,%r1
  95 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
  96 # The j instruction gets runtime patched to a nop instruction.
  97 # See ftrace_enable_ftrace_graph_caller.
  98 SYM_INNER_LABEL(ftrace_graph_caller, SYM_L_GLOBAL)
  99         j       .Lftrace_graph_caller_end
 100         lmg     %r2,%r3,(STACK_PTREGS_GPRS+14*8)(%r15)
 101         lg      %r4,(STACK_PTREGS_PSW+8)(%r15)
 102         brasl   %r14,prepare_ftrace_return
 103         stg     %r2,(STACK_PTREGS_GPRS+14*8)(%r15)
 104 .Lftrace_graph_caller_end:
 105 #endif
 106         lg      %r0,(STACK_PTREGS_PSW+8)(%r15)
 107 #ifdef CONFIG_HAVE_MARCH_Z196_FEATURES
 108         ltg     %r1,STACK_PTREGS_ORIG_GPR2(%r15)
 109         locgrz  %r1,%r0
 110 #else
 111         lg      %r1,STACK_PTREGS_ORIG_GPR2(%r15)
 112         ltgr    %r1,%r1
 113         jnz     0f
 114         lgr     %r1,%r0
 115 #endif
 116 0:      lmg     %r2,%r15,(STACK_PTREGS_GPRS+2*8)(%r15)
 117         BR_EX   %r1
 118 SYM_CODE_END(ftrace_common)
 119
 120 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 121
 122 SYM_FUNC_START(return_to_handler)
 123         stmg    %r2,%r5,32(%r15)
 124         lgr     %r1,%r15
 125         aghi    %r15,-STACK_FRAME_OVERHEAD
 126         stg     %r1,__SF_BACKCHAIN(%r15)
 127         brasl   %r14,ftrace_return_to_handler
 128         aghi    %r15,STACK_FRAME_OVERHEAD
 129         lgr     %r14,%r2
 130         lmg     %r2,%r5,32(%r15)
 131         BR_EX   %r14
 132 SYM_FUNC_END(return_to_handler)
 133
 134 #endif