arch/arm/kernel/entry-common.S

   1 /* SPDX-License-Identifier: GPL-2.0-only */
   2 /*
   3  *  linux/arch/arm/kernel/entry-common.S
   4  *
   5  *  Copyright (C) 2000 Russell King
   6  */
   7
   8 #include <asm/assembler.h>
   9 #include <asm/unistd.h>
  10 #include <asm/ftrace.h>
  11 #include <asm/unwind.h>
  12 #include <asm/memory.h>
  13 #ifdef CONFIG_AEABI
  14 #include <asm/unistd-oabi.h>
  15 #endif
  16
  17         .equ    NR_syscalls, __NR_syscalls
  18
  19 #include "entry-header.S"
  20
  21 saved_psr       .req    r8
  22 #if defined(CONFIG_TRACE_IRQFLAGS) || defined(CONFIG_CONTEXT_TRACKING_USER)
  23 saved_pc        .req    r9
  24 #define TRACE(x...) x
  25 #else
  26 saved_pc        .req    lr
  27 #define TRACE(x...)
  28 #endif
  29
  30         .section .entry.text,"ax",%progbits
  31         .align  5
  32 #if !(IS_ENABLED(CONFIG_TRACE_IRQFLAGS) || IS_ENABLED(CONFIG_CONTEXT_TRACKING_USER) || \
  33         IS_ENABLED(CONFIG_DEBUG_RSEQ))
  34 /*
  35  * This is the fast syscall return path.  We do as little as possible here,
  36  * such as avoiding writing r0 to the stack.  We only use this path if we
  37  * have tracing, context tracking and rseq debug disabled - the overheads
  38  * from those features make this path too inefficient.
  39  */
  40 ret_fast_syscall:
  41 __ret_fast_syscall:
  42  UNWIND(.fnstart        )
  43  UNWIND(.cantunwind     )
  44         disable_irq_notrace                     @ disable interrupts
  45         ldr     r1, [tsk, #TI_FLAGS]            @ re-check for syscall tracing
  46         movs    r1, r1, lsl #16
  47         bne     fast_work_pending
  48
  49         restore_user_regs fast = 1, offset = S_OFF
  50  UNWIND(.fnend          )
  51 ENDPROC(ret_fast_syscall)
  52
  53         /* Ok, we need to do extra processing, enter the slow path. */
  54 fast_work_pending:
  55         str     r0, [sp, #S_R0+S_OFF]!          @ returned r0
  56         /* fall through to work_pending */
  57 #else
  58 /*
  59  * The "replacement" ret_fast_syscall for when tracing, context tracking,
  60  * or rseq debug is enabled.  As we will need to call out to some C functions,
  61  * we save r0 first to avoid needing to save registers around each C function
  62  * call.
  63  */
  64 ret_fast_syscall:
  65 __ret_fast_syscall:
  66  UNWIND(.fnstart        )
  67  UNWIND(.cantunwind     )
  68         str     r0, [sp, #S_R0 + S_OFF]!        @ save returned r0
  69 #if IS_ENABLED(CONFIG_DEBUG_RSEQ)
  70         /* do_rseq_syscall needs interrupts enabled. */
  71         mov     r0, sp                          @ 'regs'
  72         bl      do_rseq_syscall
  73 #endif
  74         disable_irq_notrace                     @ disable interrupts
  75         ldr     r1, [tsk, #TI_FLAGS]            @ re-check for syscall tracing
  76         movs    r1, r1, lsl #16
  77         beq     no_work_pending
  78  UNWIND(.fnend          )
  79 ENDPROC(ret_fast_syscall)
  80
  81         /* Slower path - fall through to work_pending */
  82 #endif
  83
  84         tst     r1, #_TIF_SYSCALL_WORK
  85         bne     __sys_trace_return_nosave
  86 slow_work_pending:
  87         mov     r0, sp                          @ 'regs'
  88         mov     r2, why                         @ 'syscall'
  89         bl      do_work_pending
  90         cmp     r0, #0
  91         beq     no_work_pending
  92         movlt   scno, #(__NR_restart_syscall - __NR_SYSCALL_BASE)
  93         ldmia   sp, {r0 - r6}                   @ have to reload r0 - r6
  94         b       local_restart                   @ ... and off we go
  95 ENDPROC(ret_fast_syscall)
  96
  97 /*
  98  * "slow" syscall return path.  "why" tells us if this was a real syscall.
  99  * IRQs may be enabled here, so always disable them.  Note that we use the
 100  * "notrace" version to avoid calling into the tracing code unnecessarily.
 101  * do_work_pending() will update this state if necessary.
 102  */
 103 ENTRY(ret_to_user)
 104 ret_slow_syscall:
 105 #if IS_ENABLED(CONFIG_DEBUG_RSEQ)
 106         /* do_rseq_syscall needs interrupts enabled. */
 107         enable_irq_notrace                      @ enable interrupts
 108         mov     r0, sp                          @ 'regs'
 109         bl      do_rseq_syscall
 110 #endif
 111         disable_irq_notrace                     @ disable interrupts
 112 ENTRY(ret_to_user_from_irq)
 113         ldr     r1, [tsk, #TI_FLAGS]
 114         movs    r1, r1, lsl #16
 115         bne     slow_work_pending
 116 no_work_pending:
 117         asm_trace_hardirqs_on save = 0
 118
 119         ct_user_enter save = 0
 120
 121         restore_user_regs fast = 0, offset = 0
 122 ENDPROC(ret_to_user_from_irq)
 123 ENDPROC(ret_to_user)
 124
 125 /*
 126  * This is how we return from a fork.
 127  */
 128 ENTRY(ret_from_fork)
 129         bl      schedule_tail
 130         cmp     r5, #0
 131         movne   r0, r4
 132         badrne  lr, 1f
 133         retne   r5
 134 1:      get_thread_info tsk
 135         b       ret_slow_syscall
 136 ENDPROC(ret_from_fork)
 137
 138 /*=============================================================================
 139  * SWI handler
 140  *-----------------------------------------------------------------------------
 141  */
 142
 143         .align  5
 144 #ifdef CONFIG_HARDEN_BRANCH_HISTORY
 145 ENTRY(vector_bhb_loop8_swi)
 146         sub     sp, sp, #PT_REGS_SIZE
 147         stmia   sp, {r0 - r12}
 148         mov     r8, #8
 149 1:      b       2f
 150 2:      subs    r8, r8, #1
 151         bne     1b
 152         dsb     nsh
 153         isb
 154         b       3f
 155 ENDPROC(vector_bhb_loop8_swi)
 156
 157         .align  5
 158 ENTRY(vector_bhb_bpiall_swi)
 159         sub     sp, sp, #PT_REGS_SIZE
 160         stmia   sp, {r0 - r12}
 161         mcr     p15, 0, r8, c7, c5, 6   @ BPIALL
 162         isb
 163         b       3f
 164 ENDPROC(vector_bhb_bpiall_swi)
 165 #endif
 166         .align  5
 167 ENTRY(vector_swi)
 168 #ifdef CONFIG_CPU_V7M
 169         v7m_exception_entry
 170 #else
 171         sub     sp, sp, #PT_REGS_SIZE
 172         stmia   sp, {r0 - r12}                  @ Calling r0 - r12
 173 3:
 174  ARM(   add     r8, sp, #S_PC           )
 175  ARM(   stmdb   r8, {sp, lr}^           )       @ Calling sp, lr
 176  THUMB( mov     r8, sp                  )
 177  THUMB( store_user_sp_lr r8, r10, S_SP  )       @ calling sp, lr
 178         mrs     saved_psr, spsr                 @ called from non-FIQ mode, so ok.
 179  TRACE( mov     saved_pc, lr            )
 180         str     saved_pc, [sp, #S_PC]           @ Save calling PC
 181         str     saved_psr, [sp, #S_PSR]         @ Save CPSR
 182         str     r0, [sp, #S_OLD_R0]             @ Save OLD_R0
 183 #endif
 184         reload_current r10, ip
 185         zero_fp
 186         alignment_trap r10, ip, cr_alignment
 187         asm_trace_hardirqs_on save=0
 188         enable_irq_notrace
 189         ct_user_exit save=0
 190
 191         /*
 192          * Get the system call number.
 193          */
 194
 195 #if defined(CONFIG_OABI_COMPAT)
 196
 197         /*
 198          * If we have CONFIG_OABI_COMPAT then we need to look at the swi
 199          * value to determine if it is an EABI or an old ABI call.
 200          */
 201 #ifdef CONFIG_ARM_THUMB
 202         tst     saved_psr, #PSR_T_BIT
 203         movne   r10, #0                         @ no thumb OABI emulation
 204  USER(  ldreq   r10, [saved_pc, #-4]    )       @ get SWI instruction
 205 #else
 206  USER(  ldr     r10, [saved_pc, #-4]    )       @ get SWI instruction
 207 #endif
 208  ARM_BE8(rev    r10, r10)                       @ little endian instruction
 209
 210 #elif defined(CONFIG_AEABI)
 211
 212         /*
 213          * Pure EABI user space always put syscall number into scno (r7).
 214          */
 215 #elif defined(CONFIG_ARM_THUMB)
 216         /* Legacy ABI only, possibly thumb mode. */
 217         tst     saved_psr, #PSR_T_BIT           @ this is SPSR from save_user_regs
 218         addne   scno, r7, #__NR_SYSCALL_BASE    @ put OS number in
 219  USER(  ldreq   scno, [saved_pc, #-4]   )
 220
 221 #else
 222         /* Legacy ABI only. */
 223  USER(  ldr     scno, [saved_pc, #-4]   )       @ get SWI instruction
 224 #endif
 225
 226         /* saved_psr and saved_pc are now dead */
 227
 228         uaccess_disable tbl
 229         get_thread_info tsk
 230
 231         adr     tbl, sys_call_table             @ load syscall table pointer
 232
 233 #if defined(CONFIG_OABI_COMPAT)
 234         /*
 235          * If the swi argument is zero, this is an EABI call and we do nothing.
 236          *
 237          * If this is an old ABI call, get the syscall number into scno and
 238          * get the old ABI syscall table address.
 239          */
 240         bics    r10, r10, #0xff000000
 241         strne   r10, [tsk, #TI_ABI_SYSCALL]
 242         streq   scno, [tsk, #TI_ABI_SYSCALL]
 243         eorne   scno, r10, #__NR_OABI_SYSCALL_BASE
 244         ldrne   tbl, =sys_oabi_call_table
 245 #elif !defined(CONFIG_AEABI)
 246         bic     scno, scno, #0xff000000         @ mask off SWI op-code
 247         str     scno, [tsk, #TI_ABI_SYSCALL]
 248         eor     scno, scno, #__NR_SYSCALL_BASE  @ check OS number
 249 #else
 250         str     scno, [tsk, #TI_ABI_SYSCALL]
 251 #endif
 252         /*
 253          * Reload the registers that may have been corrupted on entry to
 254          * the syscall assembly (by tracing or context tracking.)
 255          */
 256  TRACE( ldmia   sp, {r0 - r3}           )
 257
 258 local_restart:
 259         ldr     r10, [tsk, #TI_FLAGS]           @ check for syscall tracing
 260         stmdb   sp!, {r4, r5}                   @ push fifth and sixth args
 261
 262         tst     r10, #_TIF_SYSCALL_WORK         @ are we tracing syscalls?
 263         bne     __sys_trace
 264
 265         invoke_syscall tbl, scno, r10, __ret_fast_syscall
 266
 267         add     r1, sp, #S_OFF
 268 2:      cmp     scno, #(__ARM_NR_BASE - __NR_SYSCALL_BASE)
 269         eor     r0, scno, #__NR_SYSCALL_BASE    @ put OS number back
 270         bcs     arm_syscall
 271         mov     why, #0                         @ no longer a real syscall
 272         b       sys_ni_syscall                  @ not private func
 273
 274 #if defined(CONFIG_OABI_COMPAT) || !defined(CONFIG_AEABI)
 275         /*
 276          * We failed to handle a fault trying to access the page
 277          * containing the swi instruction, but we're not really in a
 278          * position to return -EFAULT. Instead, return back to the
 279          * instruction and re-enter the user fault handling path trying
 280          * to page it in. This will likely result in sending SEGV to the
 281          * current task.
 282          */
 283 9001:
 284         sub     lr, saved_pc, #4
 285         str     lr, [sp, #S_PC]
 286         get_thread_info tsk
 287         b       ret_fast_syscall
 288 #endif
 289 ENDPROC(vector_swi)
 290         .ltorg
 291
 292         /*
 293          * This is the really slow path.  We're going to be doing
 294          * context switches, and waiting for our parent to respond.
 295          */
 296 __sys_trace:
 297         add     r0, sp, #S_OFF
 298         bl      syscall_trace_enter
 299         mov     scno, r0
 300         invoke_syscall tbl, scno, r10, __sys_trace_return, reload=1
 301         cmp     scno, #-1                       @ skip the syscall?
 302         bne     2b
 303         add     sp, sp, #S_OFF                  @ restore stack
 304
 305 __sys_trace_return_nosave:
 306         enable_irq_notrace
 307         mov     r0, sp
 308         bl      syscall_trace_exit
 309         b       ret_slow_syscall
 310
 311 __sys_trace_return:
 312         str     r0, [sp, #S_R0 + S_OFF]!        @ save returned r0
 313         mov     r0, sp
 314         bl      syscall_trace_exit
 315         b       ret_slow_syscall
 316
 317         .macro  syscall_table_start, sym
 318         .equ    __sys_nr, 0
 319         .type   \sym, #object
 320 ENTRY(\sym)
 321         .endm
 322
 323         .macro  syscall, nr, func
 324         .ifgt   __sys_nr - \nr
 325         .error  "Duplicated/unorded system call entry"
 326         .endif
 327         .rept   \nr - __sys_nr
 328         .long   sys_ni_syscall
 329         .endr
 330         .long   \func
 331         .equ    __sys_nr, \nr + 1
 332         .endm
 333
 334         .macro  syscall_table_end, sym
 335         .ifgt   __sys_nr - __NR_syscalls
 336         .error  "System call table too big"
 337         .endif
 338         .rept   __NR_syscalls - __sys_nr
 339         .long   sys_ni_syscall
 340         .endr
 341         .size   \sym, . - \sym
 342         .endm
 343
 344 #define __SYSCALL_WITH_COMPAT(nr, native, compat)       __SYSCALL(nr, native)
 345 #define __SYSCALL(nr, func) syscall nr, func
 346
 347 /*
 348  * This is the syscall table declaration for native ABI syscalls.
 349  * With EABI a couple syscalls are obsolete and defined as sys_ni_syscall.
 350  */
 351         syscall_table_start sys_call_table
 352 #ifdef CONFIG_AEABI
 353 #include <calls-eabi.S>
 354 #else
 355 #include <calls-oabi.S>
 356 #endif
 357         syscall_table_end sys_call_table
 358
 359 /*============================================================================
 360  * Special system call wrappers
 361  */
 362 @ r0 = syscall number
 363 @ r8 = syscall table
 364 sys_syscall:
 365                 bic     scno, r0, #__NR_OABI_SYSCALL_BASE
 366                 cmp     scno, #__NR_syscall - __NR_SYSCALL_BASE
 367                 cmpne   scno, #NR_syscalls      @ check range
 368 #ifdef CONFIG_CPU_SPECTRE
 369                 movhs   scno, #0
 370                 csdb
 371 #endif
 372                 stmialo sp, {r5, r6}            @ shuffle args
 373                 movlo   r0, r1
 374                 movlo   r1, r2
 375                 movlo   r2, r3
 376                 movlo   r3, r4
 377                 ldrlo   pc, [tbl, scno, lsl #2]
 378                 b       sys_ni_syscall
 379 ENDPROC(sys_syscall)
 380
 381 sys_sigreturn_wrapper:
 382                 add     r0, sp, #S_OFF
 383                 mov     why, #0         @ prevent syscall restart handling
 384                 b       sys_sigreturn
 385 ENDPROC(sys_sigreturn_wrapper)
 386
 387 sys_rt_sigreturn_wrapper:
 388                 add     r0, sp, #S_OFF
 389                 mov     why, #0         @ prevent syscall restart handling
 390                 b       sys_rt_sigreturn
 391 ENDPROC(sys_rt_sigreturn_wrapper)
 392
 393 sys_statfs64_wrapper:
 394                 teq     r1, #88
 395                 moveq   r1, #84
 396                 b       sys_statfs64
 397 ENDPROC(sys_statfs64_wrapper)
 398
 399 sys_fstatfs64_wrapper:
 400                 teq     r1, #88
 401                 moveq   r1, #84
 402                 b       sys_fstatfs64
 403 ENDPROC(sys_fstatfs64_wrapper)
 404
 405 /*
 406  * Note: off_4k (r5) is always units of 4K.  If we can't do the requested
 407  * offset, we return EINVAL.
 408  */
 409 sys_mmap2:
 410                 str     r5, [sp, #4]
 411                 b       sys_mmap_pgoff
 412 ENDPROC(sys_mmap2)
 413
 414 #ifdef CONFIG_OABI_COMPAT
 415
 416 /*
 417  * These are syscalls with argument register differences
 418  */
 419
 420 sys_oabi_pread64:
 421                 stmia   sp, {r3, r4}
 422                 b       sys_pread64
 423 ENDPROC(sys_oabi_pread64)
 424
 425 sys_oabi_pwrite64:
 426                 stmia   sp, {r3, r4}
 427                 b       sys_pwrite64
 428 ENDPROC(sys_oabi_pwrite64)
 429
 430 sys_oabi_truncate64:
 431                 mov     r3, r2
 432                 mov     r2, r1
 433                 b       sys_truncate64
 434 ENDPROC(sys_oabi_truncate64)
 435
 436 sys_oabi_ftruncate64:
 437                 mov     r3, r2
 438                 mov     r2, r1
 439                 b       sys_ftruncate64
 440 ENDPROC(sys_oabi_ftruncate64)
 441
 442 sys_oabi_readahead:
 443                 str     r3, [sp]
 444                 mov     r3, r2
 445                 mov     r2, r1
 446                 b       sys_readahead
 447 ENDPROC(sys_oabi_readahead)
 448
 449 /*
 450  * Let's declare a second syscall table for old ABI binaries
 451  * using the compatibility syscall entries.
 452  */
 453         syscall_table_start sys_oabi_call_table
 454 #undef __SYSCALL_WITH_COMPAT
 455 #define __SYSCALL_WITH_COMPAT(nr, native, compat)       __SYSCALL(nr, compat)
 456 #include <calls-oabi.S>
 457         syscall_table_end sys_oabi_call_table
 458
 459 #endif
 460