arch/x86/lib/retpoline.S

   1 /* SPDX-License-Identifier: GPL-2.0 */
   2
   3 #include <linux/stringify.h>
   4 #include <linux/linkage.h>
   5 #include <asm/dwarf2.h>
   6 #include <asm/cpufeatures.h>
   7 #include <asm/alternative.h>
   8 #include <asm/export.h>
   9 #include <asm/nospec-branch.h>
  10 #include <asm/unwind_hints.h>
  11 #include <asm/frame.h>
  12
  13         .section .text.__x86.indirect_thunk
  14
  15 .macro RETPOLINE reg
  16         ANNOTATE_INTRA_FUNCTION_CALL
  17         call    .Ldo_rop_\@
  18 .Lspec_trap_\@:
  19         UNWIND_HINT_EMPTY
  20         pause
  21         lfence
  22         jmp .Lspec_trap_\@
  23 .Ldo_rop_\@:
  24         mov     %\reg, (%_ASM_SP)
  25         UNWIND_HINT_FUNC
  26         RET
  27 .endm
  28
  29 .macro THUNK reg
  30
  31         .align RETPOLINE_THUNK_SIZE
  32 SYM_INNER_LABEL(__x86_indirect_thunk_\reg, SYM_L_GLOBAL)
  33         UNWIND_HINT_EMPTY
  34
  35         ALTERNATIVE_2 __stringify(ANNOTATE_RETPOLINE_SAFE; jmp *%\reg), \
  36                       __stringify(RETPOLINE \reg), X86_FEATURE_RETPOLINE, \
  37                       __stringify(lfence; ANNOTATE_RETPOLINE_SAFE; jmp *%\reg; int3), X86_FEATURE_RETPOLINE_LFENCE
  38
  39 .endm
  40
  41 /*
  42  * Despite being an assembler file we can't just use .irp here
  43  * because __KSYM_DEPS__ only uses the C preprocessor and would
  44  * only see one instance of "__x86_indirect_thunk_\reg" rather
  45  * than one per register with the correct names. So we do it
  46  * the simple and nasty way...
  47  *
  48  * Worse, you can only have a single EXPORT_SYMBOL per line,
  49  * and CPP can't insert newlines, so we have to repeat everything
  50  * at least twice.
  51  */
  52
  53 #define __EXPORT_THUNK(sym)     _ASM_NOKPROBE(sym); EXPORT_SYMBOL(sym)
  54 #define EXPORT_THUNK(reg)       __EXPORT_THUNK(__x86_indirect_thunk_ ## reg)
  55
  56         .align RETPOLINE_THUNK_SIZE
  57 SYM_CODE_START(__x86_indirect_thunk_array)
  58
  59 #define GEN(reg) THUNK reg
  60 #include <asm/GEN-for-each-reg.h>
  61 #undef GEN
  62
  63         .align RETPOLINE_THUNK_SIZE
  64 SYM_CODE_END(__x86_indirect_thunk_array)
  65
  66 #define GEN(reg) EXPORT_THUNK(reg)
  67 #include <asm/GEN-for-each-reg.h>
  68 #undef GEN