tools/perf/util/parse-events.y

   1 %pure-parser
   2 %parse-param {void *_data}
   3 %parse-param {void *scanner}
   4 %lex-param {void* scanner}
   5 %locations
   6
   7 %{
   8
   9 #define YYDEBUG 1
  10
  11 #include <linux/compiler.h>
  12 #include <linux/list.h>
  13 #include <linux/types.h>
  14 #include "util.h"
  15 #include "parse-events.h"
  16 #include "parse-events-bison.h"
  17
  18 #define ABORT_ON(val) \
  19 do { \
  20         if (val) \
  21                 YYABORT; \
  22 } while (0)
  23
  24 #define ALLOC_LIST(list) \
  25 do { \
  26         list = malloc(sizeof(*list)); \
  27         ABORT_ON(!list);              \
  28         INIT_LIST_HEAD(list);         \
  29 } while (0)
  30
  31 static inc_group_count(struct list_head *list,
  32                        struct parse_events_evlist *data)
  33 {
  34         /* Count groups only have more than 1 members */
  35         if (!list_is_last(list->next, list))
  36                 data->nr_groups++;
  37 }
  38
  39 %}
  40
  41 %token PE_START_EVENTS PE_START_TERMS
  42 %token PE_VALUE PE_VALUE_SYM_HW PE_VALUE_SYM_SW PE_RAW PE_TERM
  43 %token PE_EVENT_NAME
  44 %token PE_NAME
  45 %token PE_MODIFIER_EVENT PE_MODIFIER_BP
  46 %token PE_NAME_CACHE_TYPE PE_NAME_CACHE_OP_RESULT
  47 %token PE_PREFIX_MEM PE_PREFIX_RAW PE_PREFIX_GROUP
  48 %token PE_ERROR
  49 %token PE_PMU_EVENT_PRE PE_PMU_EVENT_SUF PE_KERNEL_PMU_EVENT
  50 %type <num> PE_VALUE
  51 %type <num> PE_VALUE_SYM_HW
  52 %type <num> PE_VALUE_SYM_SW
  53 %type <num> PE_RAW
  54 %type <num> PE_TERM
  55 %type <str> PE_NAME
  56 %type <str> PE_NAME_CACHE_TYPE
  57 %type <str> PE_NAME_CACHE_OP_RESULT
  58 %type <str> PE_MODIFIER_EVENT
  59 %type <str> PE_MODIFIER_BP
  60 %type <str> PE_EVENT_NAME
  61 %type <str> PE_PMU_EVENT_PRE PE_PMU_EVENT_SUF PE_KERNEL_PMU_EVENT
  62 %type <num> value_sym
  63 %type <head> event_config
  64 %type <term> event_term
  65 %type <head> event_pmu
  66 %type <head> event_legacy_symbol
  67 %type <head> event_legacy_cache
  68 %type <head> event_legacy_mem
  69 %type <head> event_legacy_tracepoint
  70 %type <head> event_legacy_numeric
  71 %type <head> event_legacy_raw
  72 %type <head> event_def
  73 %type <head> event_mod
  74 %type <head> event_name
  75 %type <head> event
  76 %type <head> events
  77 %type <head> group_def
  78 %type <head> group
  79 %type <head> groups
  80
  81 %union
  82 {
  83         char *str;
  84         u64 num;
  85         struct list_head *head;
  86         struct parse_events_term *term;
  87 }
  88 %%
  89
  90 start:
  91 PE_START_EVENTS start_events
  92 |
  93 PE_START_TERMS  start_terms
  94
  95 start_events: groups
  96 {
  97         struct parse_events_evlist *data = _data;
  98
  99         parse_events_update_lists($1, &data->list);
 100 }
 101
 102 groups:
 103 groups ',' group
 104 {
 105         struct list_head *list  = $1;
 106         struct list_head *group = $3;
 107
 108         parse_events_update_lists(group, list);
 109         $$ = list;
 110 }
 111 |
 112 groups ',' event
 113 {
 114         struct list_head *list  = $1;
 115         struct list_head *event = $3;
 116
 117         parse_events_update_lists(event, list);
 118         $$ = list;
 119 }
 120 |
 121 group
 122 |
 123 event
 124
 125 group:
 126 group_def ':' PE_MODIFIER_EVENT
 127 {
 128         struct list_head *list = $1;
 129
 130         ABORT_ON(parse_events__modifier_group(list, $3));
 131         $$ = list;
 132 }
 133 |
 134 group_def
 135
 136 group_def:
 137 PE_NAME '{' events '}'
 138 {
 139         struct list_head *list = $3;
 140
 141         inc_group_count(list, _data);
 142         parse_events__set_leader($1, list);
 143         $$ = list;
 144 }
 145 |
 146 '{' events '}'
 147 {
 148         struct list_head *list = $2;
 149
 150         inc_group_count(list, _data);
 151         parse_events__set_leader(NULL, list);
 152         $$ = list;
 153 }
 154
 155 events:
 156 events ',' event
 157 {
 158         struct list_head *event = $3;
 159         struct list_head *list  = $1;
 160
 161         parse_events_update_lists(event, list);
 162         $$ = list;
 163 }
 164 |
 165 event
 166
 167 event: event_mod
 168
 169 event_mod:
 170 event_name PE_MODIFIER_EVENT
 171 {
 172         struct list_head *list = $1;
 173
 174         /*
 175          * Apply modifier on all events added by single event definition
 176          * (there could be more events added for multiple tracepoint
 177          * definitions via '*?'.
 178          */
 179         ABORT_ON(parse_events__modifier_event(list, $2, false));
 180         $$ = list;
 181 }
 182 |
 183 event_name
 184
 185 event_name:
 186 PE_EVENT_NAME event_def
 187 {
 188         ABORT_ON(parse_events_name($2, $1));
 189         free($1);
 190         $$ = $2;
 191 }
 192 |
 193 event_def
 194
 195 event_def: event_pmu |
 196            event_legacy_symbol |
 197            event_legacy_cache sep_dc |
 198            event_legacy_mem |
 199            event_legacy_tracepoint sep_dc |
 200            event_legacy_numeric sep_dc |
 201            event_legacy_raw sep_dc
 202
 203 event_pmu:
 204 PE_NAME '/' event_config '/'
 205 {
 206         struct parse_events_evlist *data = _data;
 207         struct list_head *list;
 208
 209         ALLOC_LIST(list);
 210         ABORT_ON(parse_events_add_pmu(list, &data->idx, $1, $3));
 211         parse_events__free_terms($3);
 212         $$ = list;
 213 }
 214 |
 215 PE_NAME '/' '/'
 216 {
 217         struct parse_events_evlist *data = _data;
 218         struct list_head *list;
 219
 220         ALLOC_LIST(list);
 221         ABORT_ON(parse_events_add_pmu(list, &data->idx, $1, NULL));
 222         $$ = list;
 223 }
 224 |
 225 PE_KERNEL_PMU_EVENT sep_dc
 226 {
 227         struct parse_events_evlist *data = _data;
 228         struct list_head *head;
 229         struct parse_events_term *term;
 230         struct list_head *list;
 231
 232         ALLOC_LIST(head);
 233         ABORT_ON(parse_events_term__num(&term, PARSE_EVENTS__TERM_TYPE_USER,
 234                                         $1, 1));
 235         list_add_tail(&term->list, head);
 236
 237         ALLOC_LIST(list);
 238         ABORT_ON(parse_events_add_pmu(list, &data->idx, "cpu", head));
 239         parse_events__free_terms(head);
 240         $$ = list;
 241 }
 242 |
 243 PE_PMU_EVENT_PRE '-' PE_PMU_EVENT_SUF sep_dc
 244 {
 245         struct parse_events_evlist *data = _data;
 246         struct list_head *head;
 247         struct parse_events_term *term;
 248         struct list_head *list;
 249         char pmu_name[128];
 250         snprintf(&pmu_name, 128, "%s-%s", $1, $3);
 251
 252         ALLOC_LIST(head);
 253         ABORT_ON(parse_events_term__num(&term, PARSE_EVENTS__TERM_TYPE_USER,
 254                                         &pmu_name, 1));
 255         list_add_tail(&term->list, head);
 256
 257         ALLOC_LIST(list);
 258         ABORT_ON(parse_events_add_pmu(list, &data->idx, "cpu", head));
 259         parse_events__free_terms(head);
 260         $$ = list;
 261 }
 262
 263 value_sym:
 264 PE_VALUE_SYM_HW
 265 |
 266 PE_VALUE_SYM_SW
 267
 268 event_legacy_symbol:
 269 value_sym '/' event_config '/'
 270 {
 271         struct parse_events_evlist *data = _data;
 272         struct list_head *list;
 273         int type = $1 >> 16;
 274         int config = $1 & 255;
 275
 276         ALLOC_LIST(list);
 277         ABORT_ON(parse_events_add_numeric(list, &data->idx,
 278                                           type, config, $3));
 279         parse_events__free_terms($3);
 280         $$ = list;
 281 }
 282 |
 283 value_sym sep_slash_dc
 284 {
 285         struct parse_events_evlist *data = _data;
 286         struct list_head *list;
 287         int type = $1 >> 16;
 288         int config = $1 & 255;
 289
 290         ALLOC_LIST(list);
 291         ABORT_ON(parse_events_add_numeric(list, &data->idx,
 292                                           type, config, NULL));
 293         $$ = list;
 294 }
 295
 296 event_legacy_cache:
 297 PE_NAME_CACHE_TYPE '-' PE_NAME_CACHE_OP_RESULT '-' PE_NAME_CACHE_OP_RESULT
 298 {
 299         struct parse_events_evlist *data = _data;
 300         struct list_head *list;
 301
 302         ALLOC_LIST(list);
 303         ABORT_ON(parse_events_add_cache(list, &data->idx, $1, $3, $5));
 304         $$ = list;
 305 }
 306 |
 307 PE_NAME_CACHE_TYPE '-' PE_NAME_CACHE_OP_RESULT
 308 {
 309         struct parse_events_evlist *data = _data;
 310         struct list_head *list;
 311
 312         ALLOC_LIST(list);
 313         ABORT_ON(parse_events_add_cache(list, &data->idx, $1, $3, NULL));
 314         $$ = list;
 315 }
 316 |
 317 PE_NAME_CACHE_TYPE
 318 {
 319         struct parse_events_evlist *data = _data;
 320         struct list_head *list;
 321
 322         ALLOC_LIST(list);
 323         ABORT_ON(parse_events_add_cache(list, &data->idx, $1, NULL, NULL));
 324         $$ = list;
 325 }
 326
 327 event_legacy_mem:
 328 PE_PREFIX_MEM PE_VALUE '/' PE_VALUE ':' PE_MODIFIER_BP sep_dc
 329 {
 330         struct parse_events_evlist *data = _data;
 331         struct list_head *list;
 332
 333         ALLOC_LIST(list);
 334         ABORT_ON(parse_events_add_breakpoint(list, &data->idx,
 335                                              (void *) $2, $6, $4));
 336         $$ = list;
 337 }
 338 |
 339 PE_PREFIX_MEM PE_VALUE '/' PE_VALUE sep_dc
 340 {
 341         struct parse_events_evlist *data = _data;
 342         struct list_head *list;
 343
 344         ALLOC_LIST(list);
 345         ABORT_ON(parse_events_add_breakpoint(list, &data->idx,
 346                                              (void *) $2, NULL, $4));
 347         $$ = list;
 348 }
 349 |
 350 PE_PREFIX_MEM PE_VALUE ':' PE_MODIFIER_BP sep_dc
 351 {
 352         struct parse_events_evlist *data = _data;
 353         struct list_head *list;
 354
 355         ALLOC_LIST(list);
 356         ABORT_ON(parse_events_add_breakpoint(list, &data->idx,
 357                                              (void *) $2, $4, 0));
 358         $$ = list;
 359 }
 360 |
 361 PE_PREFIX_MEM PE_VALUE sep_dc
 362 {
 363         struct parse_events_evlist *data = _data;
 364         struct list_head *list;
 365
 366         ALLOC_LIST(list);
 367         ABORT_ON(parse_events_add_breakpoint(list, &data->idx,
 368                                              (void *) $2, NULL, 0));
 369         $$ = list;
 370 }
 371
 372 event_legacy_tracepoint:
 373 PE_NAME '-' PE_NAME ':' PE_NAME
 374 {
 375         struct parse_events_evlist *data = _data;
 376         struct list_head *list;
 377         char sys_name[128];
 378         snprintf(&sys_name, 128, "%s-%s", $1, $3);
 379
 380         ALLOC_LIST(list);
 381         ABORT_ON(parse_events_add_tracepoint(list, &data->idx, &sys_name, $5));
 382         $$ = list;
 383 }
 384 |
 385 PE_NAME ':' PE_NAME
 386 {
 387         struct parse_events_evlist *data = _data;
 388         struct list_head *list;
 389
 390         ALLOC_LIST(list);
 391         ABORT_ON(parse_events_add_tracepoint(list, &data->idx, $1, $3));
 392         $$ = list;
 393 }
 394
 395 event_legacy_numeric:
 396 PE_VALUE ':' PE_VALUE
 397 {
 398         struct parse_events_evlist *data = _data;
 399         struct list_head *list;
 400
 401         ALLOC_LIST(list);
 402         ABORT_ON(parse_events_add_numeric(list, &data->idx, (u32)$1, $3, NULL));
 403         $$ = list;
 404 }
 405
 406 event_legacy_raw:
 407 PE_RAW
 408 {
 409         struct parse_events_evlist *data = _data;
 410         struct list_head *list;
 411
 412         ALLOC_LIST(list);
 413         ABORT_ON(parse_events_add_numeric(list, &data->idx,
 414                                           PERF_TYPE_RAW, $1, NULL));
 415         $$ = list;
 416 }
 417
 418 start_terms: event_config
 419 {
 420         struct parse_events_terms *data = _data;
 421         data->terms = $1;
 422 }
 423
 424 event_config:
 425 event_config ',' event_term
 426 {
 427         struct list_head *head = $1;
 428         struct parse_events_term *term = $3;
 429
 430         ABORT_ON(!head);
 431         list_add_tail(&term->list, head);
 432         $$ = $1;
 433 }
 434 |
 435 event_term
 436 {
 437         struct list_head *head = malloc(sizeof(*head));
 438         struct parse_events_term *term = $1;
 439
 440         ABORT_ON(!head);
 441         INIT_LIST_HEAD(head);
 442         list_add_tail(&term->list, head);
 443         $$ = head;
 444 }
 445
 446 event_term:
 447 PE_NAME '=' PE_NAME
 448 {
 449         struct parse_events_term *term;
 450
 451         ABORT_ON(parse_events_term__str(&term, PARSE_EVENTS__TERM_TYPE_USER,
 452                                         $1, $3));
 453         $$ = term;
 454 }
 455 |
 456 PE_NAME '=' PE_VALUE
 457 {
 458         struct parse_events_term *term;
 459
 460         ABORT_ON(parse_events_term__num(&term, PARSE_EVENTS__TERM_TYPE_USER,
 461                                         $1, $3));
 462         $$ = term;
 463 }
 464 |
 465 PE_NAME '=' PE_VALUE_SYM_HW
 466 {
 467         struct parse_events_term *term;
 468         int config = $3 & 255;
 469
 470         ABORT_ON(parse_events_term__sym_hw(&term, $1, config));
 471         $$ = term;
 472 }
 473 |
 474 PE_NAME
 475 {
 476         struct parse_events_term *term;
 477
 478         ABORT_ON(parse_events_term__num(&term, PARSE_EVENTS__TERM_TYPE_USER,
 479                                         $1, 1));
 480         $$ = term;
 481 }
 482 |
 483 PE_VALUE_SYM_HW
 484 {
 485         struct parse_events_term *term;
 486         int config = $1 & 255;
 487
 488         ABORT_ON(parse_events_term__sym_hw(&term, NULL, config));
 489         $$ = term;
 490 }
 491 |
 492 PE_TERM '=' PE_NAME
 493 {
 494         struct parse_events_term *term;
 495
 496         ABORT_ON(parse_events_term__str(&term, (int)$1, NULL, $3));
 497         $$ = term;
 498 }
 499 |
 500 PE_TERM '=' PE_VALUE
 501 {
 502         struct parse_events_term *term;
 503
 504         ABORT_ON(parse_events_term__num(&term, (int)$1, NULL, $3));
 505         $$ = term;
 506 }
 507 |
 508 PE_TERM
 509 {
 510         struct parse_events_term *term;
 511
 512         ABORT_ON(parse_events_term__num(&term, (int)$1, NULL, 1));
 513         $$ = term;
 514 }
 515
 516 sep_dc: ':' |
 517
 518 sep_slash_dc: '/' | ':' |
 519
 520 %%
 521
 522 void parse_events_error(YYLTYPE *loc, void *data,
 523                         void *scanner __maybe_unused,
 524                         char const *msg __maybe_unused)
 525 {
 526         parse_events_evlist_error(data, loc->last_column, "parser error");
 527 }