arch/parisc/kernel/vmlinux.lds.S

   1 /*    Kernel link layout for various "sections"
   2  *
   3  *    Copyright (C) 1999-2003 Matthew Wilcox <willy at parisc-linux.org>
   4  *    Copyright (C) 2000-2003 Paul Bame <bame at parisc-linux.org>
   5  *    Copyright (C) 2000 John Marvin <jsm at parisc-linux.org>
   6  *    Copyright (C) 2000 Michael Ang <mang with subcarrier.org>
   7  *    Copyright (C) 2002 Randolph Chung <tausq with parisc-linux.org>
   8  *    Copyright (C) 2003 James Bottomley <jejb with parisc-linux.org>
   9  *    Copyright (C) 2006-2013 Helge Deller <[email protected]>
  10  */
  11
  12 /*
  13  * Put page table entries (swapper_pg_dir) as the first thing in .bss. This
  14  * will ensure that it has .bss alignment (PAGE_SIZE).
  15  */
  16 #define BSS_FIRST_SECTIONS      *(.data..vm0.pmd) \
  17                                 *(.data..vm0.pgd) \
  18                                 *(.data..vm0.pte)
  19
  20 #include <asm-generic/vmlinux.lds.h>
  21
  22 /* needed for the processor specific cache alignment size */
  23 #include <asm/cache.h>
  24 #include <asm/page.h>
  25 #include <asm/asm-offsets.h>
  26 #include <asm/thread_info.h>
  27
  28 /* ld script to make hppa Linux kernel */
  29 #ifndef CONFIG_64BIT
  30 OUTPUT_FORMAT("elf32-hppa-linux")
  31 OUTPUT_ARCH(hppa)
  32 #else
  33 OUTPUT_FORMAT("elf64-hppa-linux")
  34 OUTPUT_ARCH(hppa:hppa2.0w)
  35 #endif
  36
  37 ENTRY(parisc_kernel_start)
  38 #ifndef CONFIG_64BIT
  39 jiffies = jiffies_64 + 4;
  40 #else
  41 jiffies = jiffies_64;
  42 #endif
  43 SECTIONS
  44 {
  45         . = KERNEL_BINARY_TEXT_START;
  46
  47         __init_begin = .;
  48         HEAD_TEXT_SECTION
  49         INIT_TEXT_SECTION(8)
  50
  51         . = ALIGN(PAGE_SIZE);
  52         INIT_DATA_SECTION(PAGE_SIZE)
  53         /* we have to discard exit text and such at runtime, not link time */
  54         .exit.text :
  55         {
  56                 EXIT_TEXT
  57         }
  58         .exit.data :
  59         {
  60                 EXIT_DATA
  61         }
  62         PERCPU_SECTION(8)
  63         . = ALIGN(HUGEPAGE_SIZE);
  64         __init_end = .;
  65         /* freed after init ends here */
  66
  67         _text = .;              /* Text and read-only data */
  68         _stext = .;
  69         .text ALIGN(PAGE_SIZE) : {
  70                 TEXT_TEXT
  71                 SCHED_TEXT
  72                 CPUIDLE_TEXT
  73                 LOCK_TEXT
  74                 KPROBES_TEXT
  75                 IRQENTRY_TEXT
  76                 SOFTIRQENTRY_TEXT
  77                 *(.text.do_softirq)
  78                 *(.text.sys_exit)
  79                 *(.text.do_sigaltstack)
  80                 *(.text.do_fork)
  81                 *(.text.div)
  82                 *($$*)                  /* millicode routines */
  83                 *(.text.*)
  84                 *(.fixup)
  85                 *(.lock.text)           /* out-of-line lock text */
  86                 *(.gnu.warning)
  87         }
  88         . = ALIGN(PAGE_SIZE);
  89         _etext = .;
  90         /* End of text section */
  91
  92         /* Start of data section */
  93         _sdata = .;
  94
  95         /* Architecturally we need to keep __gp below 0x1000000 and thus
  96          * in front of RO_DATA_SECTION() which stores lots of tracepoint
  97          * and ftrace symbols. */
  98 #ifdef CONFIG_64BIT
  99         . = ALIGN(16);
 100         /* Linkage tables */
 101         .opd : {
 102                 *(.opd)
 103         } PROVIDE (__gp = .);
 104         .plt : {
 105                 *(.plt)
 106         }
 107         .dlt : {
 108                 *(.dlt)
 109         }
 110 #endif
 111
 112         RO_DATA_SECTION(8)
 113
 114         /* RO because of BUILDTIME_EXTABLE_SORT */
 115         EXCEPTION_TABLE(8)
 116         NOTES
 117
 118         /* unwind info */
 119         .PARISC.unwind : {
 120                 __start___unwind = .;
 121                 *(.PARISC.unwind)
 122                 __stop___unwind = .;
 123         }
 124
 125         /* writeable */
 126         /* Make sure this is page aligned so
 127          * that we can properly leave these
 128          * as writable
 129          */
 130         . = ALIGN(HUGEPAGE_SIZE);
 131         data_start = .;
 132
 133         /* Data */
 134         RW_DATA_SECTION(L1_CACHE_BYTES, PAGE_SIZE, PAGE_SIZE)
 135
 136         /* PA-RISC locks requires 16-byte alignment */
 137         . = ALIGN(16);
 138         .data..lock_aligned : {
 139                 *(.data..lock_aligned)
 140         }
 141
 142         /* End of data section */
 143         _edata = .;
 144
 145         /* BSS */
 146         BSS_SECTION(PAGE_SIZE, PAGE_SIZE, PAGE_SIZE)
 147
 148         . = ALIGN(HUGEPAGE_SIZE);
 149         _end = . ;
 150
 151         STABS_DEBUG
 152         .note 0 : { *(.note) }
 153
 154         /* Sections to be discarded */
 155         DISCARDS
 156         /DISCARD/ : {
 157 #ifdef CONFIG_64BIT
 158                 /* temporary hack until binutils is fixed to not emit these
 159                  * for static binaries
 160                  */
 161                 *(.interp)
 162                 *(.dynsym)
 163                 *(.dynstr)
 164                 *(.dynamic)
 165                 *(.hash)
 166                 *(.gnu.hash)
 167 #endif
 168         }
 169 }