arch/x86/kernel/entry_64.S

   1 /*
   2  *  linux/arch/x86_64/entry.S
   3  *
   4  *  Copyright (C) 1991, 1992  Linus Torvalds
   5  *  Copyright (C) 2000, 2001, 2002  Andi Kleen SuSE Labs
   6  *  Copyright (C) 2000  Pavel Machek <[email protected]>
   7  */
   8
   9 /*
  10  * entry.S contains the system-call and fault low-level handling routines.
  11  *
  12  * Some of this is documented in Documentation/x86/entry_64.txt
  13  *
  14  * NOTE: This code handles signal-recognition, which happens every time
  15  * after an interrupt and after each system call.
  16  *
  17  * Normal syscalls and interrupts don't save a full stack frame, this is
  18  * only done for syscall tracing, signals or fork/exec et.al.
  19  *
  20  * A note on terminology:
  21  * - top of stack: Architecture defined interrupt frame from SS to RIP
  22  * at the top of the kernel process stack.
  23  * - partial stack frame: partially saved registers up to R11.
  24  * - full stack frame: Like partial stack frame, but all register saved.
  25  *
  26  * Some macro usage:
  27  * - CFI macros are used to generate dwarf2 unwind information for better
  28  * backtraces. They don't change any code.
  29  * - SAVE_ALL/RESTORE_ALL - Save/restore all registers
  30  * - SAVE_ARGS/RESTORE_ARGS - Save/restore registers that C functions modify.
  31  * There are unfortunately lots of special cases where some registers
  32  * not touched. The macro is a big mess that should be cleaned up.
  33  * - SAVE_REST/RESTORE_REST - Handle the registers not saved by SAVE_ARGS.
  34  * Gives a full stack frame.
  35  * - ENTRY/END Define functions in the symbol table.
  36  * - FIXUP_TOP_OF_STACK/RESTORE_TOP_OF_STACK - Fix up the hardware stack
  37  * frame that is otherwise undefined after a SYSCALL
  38  * - TRACE_IRQ_* - Trace hard interrupt state for lock debugging.
  39  * - errorentry/paranoidentry/zeroentry - Define exception entry points.
  40  */
  41
  42 #include <linux/linkage.h>
  43 #include <asm/segment.h>
  44 #include <asm/cache.h>
  45 #include <asm/errno.h>
  46 #include <asm/dwarf2.h>
  47 #include <asm/calling.h>
  48 #include <asm/asm-offsets.h>
  49 #include <asm/msr.h>
  50 #include <asm/unistd.h>
  51 #include <asm/thread_info.h>
  52 #include <asm/hw_irq.h>
  53 #include <asm/page_types.h>
  54 #include <asm/irqflags.h>
  55 #include <asm/paravirt.h>
  56 #include <asm/ftrace.h>
  57 #include <asm/percpu.h>
  58 #include <asm/asm.h>
  59 #include <linux/err.h>
  60
  61 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this.  */
  62 #include <linux/elf-em.h>
  63 #define AUDIT_ARCH_X86_64       (EM_X86_64|__AUDIT_ARCH_64BIT|__AUDIT_ARCH_LE)
  64 #define __AUDIT_ARCH_64BIT 0x80000000
  65 #define __AUDIT_ARCH_LE    0x40000000
  66
  67         .code64
  68         .section .entry.text, "ax"
  69
  70 #ifdef CONFIG_FUNCTION_TRACER
  71 #ifdef CONFIG_DYNAMIC_FTRACE
  72 ENTRY(mcount)
  73         retq
  74 END(mcount)
  75
  76 ENTRY(ftrace_caller)
  77         cmpl $0, function_trace_stop
  78         jne  ftrace_stub
  79
  80         MCOUNT_SAVE_FRAME
  81
  82         movq 0x38(%rsp), %rdi
  83         movq 8(%rbp), %rsi
  84         subq $MCOUNT_INSN_SIZE, %rdi
  85
  86 GLOBAL(ftrace_call)
  87         call ftrace_stub
  88
  89         MCOUNT_RESTORE_FRAME
  90
  91 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
  92 GLOBAL(ftrace_graph_call)
  93         jmp ftrace_stub
  94 #endif
  95
  96 GLOBAL(ftrace_stub)
  97         retq
  98 END(ftrace_caller)
  99
 100 #else /* ! CONFIG_DYNAMIC_FTRACE */
 101 ENTRY(mcount)
 102         cmpl $0, function_trace_stop
 103         jne  ftrace_stub
 104
 105         cmpq $ftrace_stub, ftrace_trace_function
 106         jnz trace
 107
 108 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 109         cmpq $ftrace_stub, ftrace_graph_return
 110         jnz ftrace_graph_caller
 111
 112         cmpq $ftrace_graph_entry_stub, ftrace_graph_entry
 113         jnz ftrace_graph_caller
 114 #endif
 115
 116 GLOBAL(ftrace_stub)
 117         retq
 118
 119 trace:
 120         MCOUNT_SAVE_FRAME
 121
 122         movq 0x38(%rsp), %rdi
 123         movq 8(%rbp), %rsi
 124         subq $MCOUNT_INSN_SIZE, %rdi
 125
 126         call   *ftrace_trace_function
 127
 128         MCOUNT_RESTORE_FRAME
 129
 130         jmp ftrace_stub
 131 END(mcount)
 132 #endif /* CONFIG_DYNAMIC_FTRACE */
 133 #endif /* CONFIG_FUNCTION_TRACER */
 134
 135 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 136 ENTRY(ftrace_graph_caller)
 137         cmpl $0, function_trace_stop
 138         jne ftrace_stub
 139
 140         MCOUNT_SAVE_FRAME
 141
 142         leaq 8(%rbp), %rdi
 143         movq 0x38(%rsp), %rsi
 144         movq (%rbp), %rdx
 145         subq $MCOUNT_INSN_SIZE, %rsi
 146
 147         call    prepare_ftrace_return
 148
 149         MCOUNT_RESTORE_FRAME
 150
 151         retq
 152 END(ftrace_graph_caller)
 153
 154 GLOBAL(return_to_handler)
 155         subq  $24, %rsp
 156
 157         /* Save the return values */
 158         movq %rax, (%rsp)
 159         movq %rdx, 8(%rsp)
 160         movq %rbp, %rdi
 161
 162         call ftrace_return_to_handler
 163
 164         movq %rax, %rdi
 165         movq 8(%rsp), %rdx
 166         movq (%rsp), %rax
 167         addq $24, %rsp
 168         jmp *%rdi
 169 #endif
 170
 171
 172 #ifndef CONFIG_PREEMPT
 173 #define retint_kernel retint_restore_args
 174 #endif
 175
 176 #ifdef CONFIG_PARAVIRT
 177 ENTRY(native_usergs_sysret64)
 178         swapgs
 179         sysretq
 180 ENDPROC(native_usergs_sysret64)
 181 #endif /* CONFIG_PARAVIRT */
 182
 183
 184 .macro TRACE_IRQS_IRETQ offset=ARGOFFSET
 185 #ifdef CONFIG_TRACE_IRQFLAGS
 186         bt   $9,EFLAGS-\offset(%rsp)    /* interrupts off? */
 187         jnc  1f
 188         TRACE_IRQS_ON
 189 1:
 190 #endif
 191 .endm
 192
 193 /*
 194  * When dynamic function tracer is enabled it will add a breakpoint
 195  * to all locations that it is about to modify, sync CPUs, update
 196  * all the code, sync CPUs, then remove the breakpoints. In this time
 197  * if lockdep is enabled, it might jump back into the debug handler
 198  * outside the updating of the IST protection. (TRACE_IRQS_ON/OFF).
 199  *
 200  * We need to change the IDT table before calling TRACE_IRQS_ON/OFF to
 201  * make sure the stack pointer does not get reset back to the top
 202  * of the debug stack, and instead just reuses the current stack.
 203  */
 204 #if defined(CONFIG_DYNAMIC_FTRACE) && defined(CONFIG_TRACE_IRQFLAGS)
 205
 206 .macro TRACE_IRQS_OFF_DEBUG
 207         call debug_stack_set_zero
 208         TRACE_IRQS_OFF
 209         call debug_stack_reset
 210 .endm
 211
 212 .macro TRACE_IRQS_ON_DEBUG
 213         call debug_stack_set_zero
 214         TRACE_IRQS_ON
 215         call debug_stack_reset
 216 .endm
 217
 218 .macro TRACE_IRQS_IRETQ_DEBUG offset=ARGOFFSET
 219         bt   $9,EFLAGS-\offset(%rsp)    /* interrupts off? */
 220         jnc  1f
 221         TRACE_IRQS_ON_DEBUG
 222 1:
 223 .endm
 224
 225 #else
 226 # define TRACE_IRQS_OFF_DEBUG           TRACE_IRQS_OFF
 227 # define TRACE_IRQS_ON_DEBUG            TRACE_IRQS_ON
 228 # define TRACE_IRQS_IRETQ_DEBUG         TRACE_IRQS_IRETQ
 229 #endif
 230
 231 /*
 232  * C code is not supposed to know about undefined top of stack. Every time
 233  * a C function with an pt_regs argument is called from the SYSCALL based
 234  * fast path FIXUP_TOP_OF_STACK is needed.
 235  * RESTORE_TOP_OF_STACK syncs the syscall state after any possible ptregs
 236  * manipulation.
 237  */
 238
 239         /* %rsp:at FRAMEEND */
 240         .macro FIXUP_TOP_OF_STACK tmp offset=0
 241         movq PER_CPU_VAR(old_rsp),\tmp
 242         movq \tmp,RSP+\offset(%rsp)
 243         movq $__USER_DS,SS+\offset(%rsp)
 244         movq $__USER_CS,CS+\offset(%rsp)
 245         movq $-1,RCX+\offset(%rsp)
 246         movq R11+\offset(%rsp),\tmp  /* get eflags */
 247         movq \tmp,EFLAGS+\offset(%rsp)
 248         .endm
 249
 250         .macro RESTORE_TOP_OF_STACK tmp offset=0
 251         movq RSP+\offset(%rsp),\tmp
 252         movq \tmp,PER_CPU_VAR(old_rsp)
 253         movq EFLAGS+\offset(%rsp),\tmp
 254         movq \tmp,R11+\offset(%rsp)
 255         .endm
 256
 257         .macro FAKE_STACK_FRAME child_rip
 258         /* push in order ss, rsp, eflags, cs, rip */
 259         xorl %eax, %eax
 260         pushq_cfi $__KERNEL_DS /* ss */
 261         /*CFI_REL_OFFSET        ss,0*/
 262         pushq_cfi %rax /* rsp */
 263         CFI_REL_OFFSET  rsp,0
 264         pushq_cfi $(X86_EFLAGS_IF|X86_EFLAGS_BIT1) /* eflags - interrupts on */
 265         /*CFI_REL_OFFSET        rflags,0*/
 266         pushq_cfi $__KERNEL_CS /* cs */
 267         /*CFI_REL_OFFSET        cs,0*/
 268         pushq_cfi \child_rip /* rip */
 269         CFI_REL_OFFSET  rip,0
 270         pushq_cfi %rax /* orig rax */
 271         .endm
 272
 273         .macro UNFAKE_STACK_FRAME
 274         addq $8*6, %rsp
 275         CFI_ADJUST_CFA_OFFSET   -(6*8)
 276         .endm
 277
 278 /*
 279  * initial frame state for interrupts (and exceptions without error code)
 280  */
 281         .macro EMPTY_FRAME start=1 offset=0
 282         .if \start
 283         CFI_STARTPROC simple
 284         CFI_SIGNAL_FRAME
 285         CFI_DEF_CFA rsp,8+\offset
 286         .else
 287         CFI_DEF_CFA_OFFSET 8+\offset
 288         .endif
 289         .endm
 290
 291 /*
 292  * initial frame state for interrupts (and exceptions without error code)
 293  */
 294         .macro INTR_FRAME start=1 offset=0
 295         EMPTY_FRAME \start, SS+8+\offset-RIP
 296         /*CFI_REL_OFFSET ss, SS+\offset-RIP*/
 297         CFI_REL_OFFSET rsp, RSP+\offset-RIP
 298         /*CFI_REL_OFFSET rflags, EFLAGS+\offset-RIP*/
 299         /*CFI_REL_OFFSET cs, CS+\offset-RIP*/
 300         CFI_REL_OFFSET rip, RIP+\offset-RIP
 301         .endm
 302
 303 /*
 304  * initial frame state for exceptions with error code (and interrupts
 305  * with vector already pushed)
 306  */
 307         .macro XCPT_FRAME start=1 offset=0
 308         INTR_FRAME \start, RIP+\offset-ORIG_RAX
 309         /*CFI_REL_OFFSET orig_rax, ORIG_RAX-ORIG_RAX*/
 310         .endm
 311
 312 /*
 313  * frame that enables calling into C.
 314  */
 315         .macro PARTIAL_FRAME start=1 offset=0
 316         XCPT_FRAME \start, ORIG_RAX+\offset-ARGOFFSET
 317         CFI_REL_OFFSET rdi, RDI+\offset-ARGOFFSET
 318         CFI_REL_OFFSET rsi, RSI+\offset-ARGOFFSET
 319         CFI_REL_OFFSET rdx, RDX+\offset-ARGOFFSET
 320         CFI_REL_OFFSET rcx, RCX+\offset-ARGOFFSET
 321         CFI_REL_OFFSET rax, RAX+\offset-ARGOFFSET
 322         CFI_REL_OFFSET r8, R8+\offset-ARGOFFSET
 323         CFI_REL_OFFSET r9, R9+\offset-ARGOFFSET
 324         CFI_REL_OFFSET r10, R10+\offset-ARGOFFSET
 325         CFI_REL_OFFSET r11, R11+\offset-ARGOFFSET
 326         .endm
 327
 328 /*
 329  * frame that enables passing a complete pt_regs to a C function.
 330  */
 331         .macro DEFAULT_FRAME start=1 offset=0
 332         PARTIAL_FRAME \start, R11+\offset-R15
 333         CFI_REL_OFFSET rbx, RBX+\offset
 334         CFI_REL_OFFSET rbp, RBP+\offset
 335         CFI_REL_OFFSET r12, R12+\offset
 336         CFI_REL_OFFSET r13, R13+\offset
 337         CFI_REL_OFFSET r14, R14+\offset
 338         CFI_REL_OFFSET r15, R15+\offset
 339         .endm
 340
 341 /* save partial stack frame */
 342         .macro SAVE_ARGS_IRQ
 343         cld
 344         /* start from rbp in pt_regs and jump over */
 345         movq_cfi rdi, RDI-RBP
 346         movq_cfi rsi, RSI-RBP
 347         movq_cfi rdx, RDX-RBP
 348         movq_cfi rcx, RCX-RBP
 349         movq_cfi rax, RAX-RBP
 350         movq_cfi  r8,  R8-RBP
 351         movq_cfi  r9,  R9-RBP
 352         movq_cfi r10, R10-RBP
 353         movq_cfi r11, R11-RBP
 354
 355         /* Save rbp so that we can unwind from get_irq_regs() */
 356         movq_cfi rbp, 0
 357
 358         /* Save previous stack value */
 359         movq %rsp, %rsi
 360
 361         leaq -RBP(%rsp),%rdi    /* arg1 for handler */
 362         testl $3, CS-RBP(%rsi)
 363         je 1f
 364         SWAPGS
 365         /*
 366          * irq_count is used to check if a CPU is already on an interrupt stack
 367          * or not. While this is essentially redundant with preempt_count it is
 368          * a little cheaper to use a separate counter in the PDA (short of
 369          * moving irq_enter into assembly, which would be too much work)
 370          */
 371 1:      incl PER_CPU_VAR(irq_count)
 372         cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
 373         CFI_DEF_CFA_REGISTER    rsi
 374
 375         /* Store previous stack value */
 376         pushq %rsi
 377         CFI_ESCAPE      0x0f /* DW_CFA_def_cfa_expression */, 6, \
 378                         0x77 /* DW_OP_breg7 */, 0, \
 379                         0x06 /* DW_OP_deref */, \
 380                         0x08 /* DW_OP_const1u */, SS+8-RBP, \
 381                         0x22 /* DW_OP_plus */
 382         /* We entered an interrupt context - irqs are off: */
 383         TRACE_IRQS_OFF
 384         .endm
 385
 386 ENTRY(save_rest)
 387         PARTIAL_FRAME 1 REST_SKIP+8
 388         movq 5*8+16(%rsp), %r11 /* save return address */
 389         movq_cfi rbx, RBX+16
 390         movq_cfi rbp, RBP+16
 391         movq_cfi r12, R12+16
 392         movq_cfi r13, R13+16
 393         movq_cfi r14, R14+16
 394         movq_cfi r15, R15+16
 395         movq %r11, 8(%rsp)      /* return address */
 396         FIXUP_TOP_OF_STACK %r11, 16
 397         ret
 398         CFI_ENDPROC
 399 END(save_rest)
 400
 401 /* save complete stack frame */
 402         .pushsection .kprobes.text, "ax"
 403 ENTRY(save_paranoid)
 404         XCPT_FRAME 1 RDI+8
 405         cld
 406         movq_cfi rdi, RDI+8
 407         movq_cfi rsi, RSI+8
 408         movq_cfi rdx, RDX+8
 409         movq_cfi rcx, RCX+8
 410         movq_cfi rax, RAX+8
 411         movq_cfi r8, R8+8
 412         movq_cfi r9, R9+8
 413         movq_cfi r10, R10+8
 414         movq_cfi r11, R11+8
 415         movq_cfi rbx, RBX+8
 416         movq_cfi rbp, RBP+8
 417         movq_cfi r12, R12+8
 418         movq_cfi r13, R13+8
 419         movq_cfi r14, R14+8
 420         movq_cfi r15, R15+8
 421         movl $1,%ebx
 422         movl $MSR_GS_BASE,%ecx
 423         rdmsr
 424         testl %edx,%edx
 425         js 1f   /* negative -> in kernel */
 426         SWAPGS
 427         xorl %ebx,%ebx
 428 1:      ret
 429         CFI_ENDPROC
 430 END(save_paranoid)
 431         .popsection
 432
 433 /*
 434  * A newly forked process directly context switches into this address.
 435  *
 436  * rdi: prev task we switched from
 437  */
 438 ENTRY(ret_from_fork)
 439         DEFAULT_FRAME
 440
 441         LOCK ; btr $TIF_FORK,TI_flags(%r8)
 442
 443         pushq_cfi kernel_eflags(%rip)
 444         popfq_cfi                               # reset kernel eflags
 445
 446         call schedule_tail                      # rdi: 'prev' task parameter
 447
 448         GET_THREAD_INFO(%rcx)
 449
 450         RESTORE_REST
 451
 452         testl $3, CS-ARGOFFSET(%rsp)            # from kernel_thread?
 453         jz   1f
 454
 455         testl $_TIF_IA32, TI_flags(%rcx)        # 32-bit compat task needs IRET
 456         jnz  int_ret_from_sys_call
 457
 458         RESTORE_TOP_OF_STACK %rdi, -ARGOFFSET
 459         jmp ret_from_sys_call                   # go to the SYSRET fastpath
 460
 461 1:
 462         subq $REST_SKIP, %rsp   # leave space for volatiles
 463         CFI_ADJUST_CFA_OFFSET   REST_SKIP
 464         movq %rbp, %rdi
 465         call *%rbx
 466         movl $0, RAX(%rsp)
 467         RESTORE_REST
 468         jmp int_ret_from_sys_call
 469         CFI_ENDPROC
 470 END(ret_from_fork)
 471
 472 /*
 473  * System call entry. Up to 6 arguments in registers are supported.
 474  *
 475  * SYSCALL does not save anything on the stack and does not change the
 476  * stack pointer.
 477  */
 478
 479 /*
 480  * Register setup:
 481  * rax  system call number
 482  * rdi  arg0
 483  * rcx  return address for syscall/sysret, C arg3
 484  * rsi  arg1
 485  * rdx  arg2
 486  * r10  arg3    (--> moved to rcx for C)
 487  * r8   arg4
 488  * r9   arg5
 489  * r11  eflags for syscall/sysret, temporary for C
 490  * r12-r15,rbp,rbx saved by C code, not touched.
 491  *
 492  * Interrupts are off on entry.
 493  * Only called from user space.
 494  *
 495  * XXX  if we had a free scratch register we could save the RSP into the stack frame
 496  *      and report it properly in ps. Unfortunately we haven't.
 497  *
 498  * When user can change the frames always force IRET. That is because
 499  * it deals with uncanonical addresses better. SYSRET has trouble
 500  * with them due to bugs in both AMD and Intel CPUs.
 501  */
 502
 503 ENTRY(system_call)
 504         CFI_STARTPROC   simple
 505         CFI_SIGNAL_FRAME
 506         CFI_DEF_CFA     rsp,KERNEL_STACK_OFFSET
 507         CFI_REGISTER    rip,rcx
 508         /*CFI_REGISTER  rflags,r11*/
 509         SWAPGS_UNSAFE_STACK
 510         /*
 511          * A hypervisor implementation might want to use a label
 512          * after the swapgs, so that it can do the swapgs
 513          * for the guest and jump here on syscall.
 514          */
 515 GLOBAL(system_call_after_swapgs)
 516
 517         movq    %rsp,PER_CPU_VAR(old_rsp)
 518         movq    PER_CPU_VAR(kernel_stack),%rsp
 519         /*
 520          * No need to follow this irqs off/on section - it's straight
 521          * and short:
 522          */
 523         ENABLE_INTERRUPTS(CLBR_NONE)
 524         SAVE_ARGS 8,0
 525         movq  %rax,ORIG_RAX-ARGOFFSET(%rsp)
 526         movq  %rcx,RIP-ARGOFFSET(%rsp)
 527         CFI_REL_OFFSET rip,RIP-ARGOFFSET
 528         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET)
 529         jnz tracesys
 530 system_call_fastpath:
 531 #if __SYSCALL_MASK == ~0
 532         cmpq $__NR_syscall_max,%rax
 533 #else
 534         andl $__SYSCALL_MASK,%eax
 535         cmpl $__NR_syscall_max,%eax
 536 #endif
 537         ja badsys
 538         movq %r10,%rcx
 539         call *sys_call_table(,%rax,8)  # XXX:    rip relative
 540         movq %rax,RAX-ARGOFFSET(%rsp)
 541 /*
 542  * Syscall return path ending with SYSRET (fast path)
 543  * Has incomplete stack frame and undefined top of stack.
 544  */
 545 ret_from_sys_call:
 546         movl $_TIF_ALLWORK_MASK,%edi
 547         /* edi: flagmask */
 548 sysret_check:
 549         LOCKDEP_SYS_EXIT
 550         DISABLE_INTERRUPTS(CLBR_NONE)
 551         TRACE_IRQS_OFF
 552         movl TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET),%edx
 553         andl %edi,%edx
 554         jnz  sysret_careful
 555         CFI_REMEMBER_STATE
 556         /*
 557          * sysretq will re-enable interrupts:
 558          */
 559         TRACE_IRQS_ON
 560         movq RIP-ARGOFFSET(%rsp),%rcx
 561         CFI_REGISTER    rip,rcx
 562         RESTORE_ARGS 1,-ARG_SKIP,0
 563         /*CFI_REGISTER  rflags,r11*/
 564         movq    PER_CPU_VAR(old_rsp), %rsp
 565         USERGS_SYSRET64
 566
 567         CFI_RESTORE_STATE
 568         /* Handle reschedules */
 569         /* edx: work, edi: workmask */
 570 sysret_careful:
 571         bt $TIF_NEED_RESCHED,%edx
 572         jnc sysret_signal
 573         TRACE_IRQS_ON
 574         ENABLE_INTERRUPTS(CLBR_NONE)
 575         pushq_cfi %rdi
 576         call schedule
 577         popq_cfi %rdi
 578         jmp sysret_check
 579
 580         /* Handle a signal */
 581 sysret_signal:
 582         TRACE_IRQS_ON
 583         ENABLE_INTERRUPTS(CLBR_NONE)
 584 #ifdef CONFIG_AUDITSYSCALL
 585         bt $TIF_SYSCALL_AUDIT,%edx
 586         jc sysret_audit
 587 #endif
 588         /*
 589          * We have a signal, or exit tracing or single-step.
 590          * These all wind up with the iret return path anyway,
 591          * so just join that path right now.
 592          */
 593         FIXUP_TOP_OF_STACK %r11, -ARGOFFSET
 594         jmp int_check_syscall_exit_work
 595
 596 badsys:
 597         movq $-ENOSYS,RAX-ARGOFFSET(%rsp)
 598         jmp ret_from_sys_call
 599
 600 #ifdef CONFIG_AUDITSYSCALL
 601         /*
 602          * Fast path for syscall audit without full syscall trace.
 603          * We just call __audit_syscall_entry() directly, and then
 604          * jump back to the normal fast path.
 605          */
 606 auditsys:
 607         movq %r10,%r9                   /* 6th arg: 4th syscall arg */
 608         movq %rdx,%r8                   /* 5th arg: 3rd syscall arg */
 609         movq %rsi,%rcx                  /* 4th arg: 2nd syscall arg */
 610         movq %rdi,%rdx                  /* 3rd arg: 1st syscall arg */
 611         movq %rax,%rsi                  /* 2nd arg: syscall number */
 612         movl $AUDIT_ARCH_X86_64,%edi    /* 1st arg: audit arch */
 613         call __audit_syscall_entry
 614         LOAD_ARGS 0             /* reload call-clobbered registers */
 615         jmp system_call_fastpath
 616
 617         /*
 618          * Return fast path for syscall audit.  Call __audit_syscall_exit()
 619          * directly and then jump back to the fast path with TIF_SYSCALL_AUDIT
 620          * masked off.
 621          */
 622 sysret_audit:
 623         movq RAX-ARGOFFSET(%rsp),%rsi   /* second arg, syscall return value */
 624         cmpq $-MAX_ERRNO,%rsi   /* is it < -MAX_ERRNO? */
 625         setbe %al               /* 1 if so, 0 if not */
 626         movzbl %al,%edi         /* zero-extend that into %edi */
 627         call __audit_syscall_exit
 628         movl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT),%edi
 629         jmp sysret_check
 630 #endif  /* CONFIG_AUDITSYSCALL */
 631
 632         /* Do syscall tracing */
 633 tracesys:
 634 #ifdef CONFIG_AUDITSYSCALL
 635         testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET)
 636         jz auditsys
 637 #endif
 638         SAVE_REST
 639         movq $-ENOSYS,RAX(%rsp) /* ptrace can change this for a bad syscall */
 640         FIXUP_TOP_OF_STACK %rdi
 641         movq %rsp,%rdi
 642         call syscall_trace_enter
 643         /*
 644          * Reload arg registers from stack in case ptrace changed them.
 645          * We don't reload %rax because syscall_trace_enter() returned
 646          * the value it wants us to use in the table lookup.
 647          */
 648         LOAD_ARGS ARGOFFSET, 1
 649         RESTORE_REST
 650 #if __SYSCALL_MASK == ~0
 651         cmpq $__NR_syscall_max,%rax
 652 #else
 653         andl $__SYSCALL_MASK,%eax
 654         cmpl $__NR_syscall_max,%eax
 655 #endif
 656         ja   int_ret_from_sys_call      /* RAX(%rsp) set to -ENOSYS above */
 657         movq %r10,%rcx  /* fixup for C */
 658         call *sys_call_table(,%rax,8)
 659         movq %rax,RAX-ARGOFFSET(%rsp)
 660         /* Use IRET because user could have changed frame */
 661
 662 /*
 663  * Syscall return path ending with IRET.
 664  * Has correct top of stack, but partial stack frame.
 665  */
 666 GLOBAL(int_ret_from_sys_call)
 667         DISABLE_INTERRUPTS(CLBR_NONE)
 668         TRACE_IRQS_OFF
 669         movl $_TIF_ALLWORK_MASK,%edi
 670         /* edi: mask to check */
 671 GLOBAL(int_with_check)
 672         LOCKDEP_SYS_EXIT_IRQ
 673         GET_THREAD_INFO(%rcx)
 674         movl TI_flags(%rcx),%edx
 675         andl %edi,%edx
 676         jnz   int_careful
 677         andl    $~TS_COMPAT,TI_status(%rcx)
 678         jmp   retint_swapgs
 679
 680         /* Either reschedule or signal or syscall exit tracking needed. */
 681         /* First do a reschedule test. */
 682         /* edx: work, edi: workmask */
 683 int_careful:
 684         bt $TIF_NEED_RESCHED,%edx
 685         jnc  int_very_careful
 686         TRACE_IRQS_ON
 687         ENABLE_INTERRUPTS(CLBR_NONE)
 688         pushq_cfi %rdi
 689         call schedule
 690         popq_cfi %rdi
 691         DISABLE_INTERRUPTS(CLBR_NONE)
 692         TRACE_IRQS_OFF
 693         jmp int_with_check
 694
 695         /* handle signals and tracing -- both require a full stack frame */
 696 int_very_careful:
 697         TRACE_IRQS_ON
 698         ENABLE_INTERRUPTS(CLBR_NONE)
 699 int_check_syscall_exit_work:
 700         SAVE_REST
 701         /* Check for syscall exit trace */
 702         testl $_TIF_WORK_SYSCALL_EXIT,%edx
 703         jz int_signal
 704         pushq_cfi %rdi
 705         leaq 8(%rsp),%rdi       # &ptregs -> arg1
 706         call syscall_trace_leave
 707         popq_cfi %rdi
 708         andl $~(_TIF_WORK_SYSCALL_EXIT|_TIF_SYSCALL_EMU),%edi
 709         jmp int_restore_rest
 710
 711 int_signal:
 712         testl $_TIF_DO_NOTIFY_MASK,%edx
 713         jz 1f
 714         movq %rsp,%rdi          # &ptregs -> arg1
 715         xorl %esi,%esi          # oldset -> arg2
 716         call do_notify_resume
 717 1:      movl $_TIF_WORK_MASK,%edi
 718 int_restore_rest:
 719         RESTORE_REST
 720         DISABLE_INTERRUPTS(CLBR_NONE)
 721         TRACE_IRQS_OFF
 722         jmp int_with_check
 723         CFI_ENDPROC
 724 END(system_call)
 725
 726 /*
 727  * Certain special system calls that need to save a complete full stack frame.
 728  */
 729         .macro PTREGSCALL label,func,arg
 730 ENTRY(\label)
 731         PARTIAL_FRAME 1 8               /* offset 8: return address */
 732         subq $REST_SKIP, %rsp
 733         CFI_ADJUST_CFA_OFFSET REST_SKIP
 734         call save_rest
 735         DEFAULT_FRAME 0 8               /* offset 8: return address */
 736         leaq 8(%rsp), \arg      /* pt_regs pointer */
 737         call \func
 738         jmp ptregscall_common
 739         CFI_ENDPROC
 740 END(\label)
 741         .endm
 742
 743         PTREGSCALL stub_clone, sys_clone, %r8
 744         PTREGSCALL stub_fork, sys_fork, %rdi
 745         PTREGSCALL stub_vfork, sys_vfork, %rdi
 746         PTREGSCALL stub_sigaltstack, sys_sigaltstack, %rdx
 747         PTREGSCALL stub_iopl, sys_iopl, %rsi
 748
 749 ENTRY(ptregscall_common)
 750         DEFAULT_FRAME 1 8       /* offset 8: return address */
 751         RESTORE_TOP_OF_STACK %r11, 8
 752         movq_cfi_restore R15+8, r15
 753         movq_cfi_restore R14+8, r14
 754         movq_cfi_restore R13+8, r13
 755         movq_cfi_restore R12+8, r12
 756         movq_cfi_restore RBP+8, rbp
 757         movq_cfi_restore RBX+8, rbx
 758         ret $REST_SKIP          /* pop extended registers */
 759         CFI_ENDPROC
 760 END(ptregscall_common)
 761
 762 ENTRY(stub_execve)
 763         CFI_STARTPROC
 764         addq $8, %rsp
 765         PARTIAL_FRAME 0
 766         SAVE_REST
 767         FIXUP_TOP_OF_STACK %r11
 768         call sys_execve
 769         RESTORE_TOP_OF_STACK %r11
 770         movq %rax,RAX(%rsp)
 771         RESTORE_REST
 772         jmp int_ret_from_sys_call
 773         CFI_ENDPROC
 774 END(stub_execve)
 775
 776 /*
 777  * sigreturn is special because it needs to restore all registers on return.
 778  * This cannot be done with SYSRET, so use the IRET return path instead.
 779  */
 780 ENTRY(stub_rt_sigreturn)
 781         CFI_STARTPROC
 782         addq $8, %rsp
 783         PARTIAL_FRAME 0
 784         SAVE_REST
 785         movq %rsp,%rdi
 786         FIXUP_TOP_OF_STACK %r11
 787         call sys_rt_sigreturn
 788         movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
 789         RESTORE_REST
 790         jmp int_ret_from_sys_call
 791         CFI_ENDPROC
 792 END(stub_rt_sigreturn)
 793
 794 #ifdef CONFIG_X86_X32_ABI
 795         PTREGSCALL stub_x32_sigaltstack, sys32_sigaltstack, %rdx
 796
 797 ENTRY(stub_x32_rt_sigreturn)
 798         CFI_STARTPROC
 799         addq $8, %rsp
 800         PARTIAL_FRAME 0
 801         SAVE_REST
 802         movq %rsp,%rdi
 803         FIXUP_TOP_OF_STACK %r11
 804         call sys32_x32_rt_sigreturn
 805         movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
 806         RESTORE_REST
 807         jmp int_ret_from_sys_call
 808         CFI_ENDPROC
 809 END(stub_x32_rt_sigreturn)
 810
 811 ENTRY(stub_x32_execve)
 812         CFI_STARTPROC
 813         addq $8, %rsp
 814         PARTIAL_FRAME 0
 815         SAVE_REST
 816         FIXUP_TOP_OF_STACK %r11
 817         call compat_sys_execve
 818         RESTORE_TOP_OF_STACK %r11
 819         movq %rax,RAX(%rsp)
 820         RESTORE_REST
 821         jmp int_ret_from_sys_call
 822         CFI_ENDPROC
 823 END(stub_x32_execve)
 824
 825 #endif
 826
 827 /*
 828  * Build the entry stubs and pointer table with some assembler magic.
 829  * We pack 7 stubs into a single 32-byte chunk, which will fit in a
 830  * single cache line on all modern x86 implementations.
 831  */
 832         .section .init.rodata,"a"
 833 ENTRY(interrupt)
 834         .section .entry.text
 835         .p2align 5
 836         .p2align CONFIG_X86_L1_CACHE_SHIFT
 837 ENTRY(irq_entries_start)
 838         INTR_FRAME
 839 vector=FIRST_EXTERNAL_VECTOR
 840 .rept (NR_VECTORS-FIRST_EXTERNAL_VECTOR+6)/7
 841         .balign 32
 842   .rept 7
 843     .if vector < NR_VECTORS
 844       .if vector <> FIRST_EXTERNAL_VECTOR
 845         CFI_ADJUST_CFA_OFFSET -8
 846       .endif
 847 1:      pushq_cfi $(~vector+0x80)       /* Note: always in signed byte range */
 848       .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
 849         jmp 2f
 850       .endif
 851       .previous
 852         .quad 1b
 853       .section .entry.text
 854 vector=vector+1
 855     .endif
 856   .endr
 857 2:      jmp common_interrupt
 858 .endr
 859         CFI_ENDPROC
 860 END(irq_entries_start)
 861
 862 .previous
 863 END(interrupt)
 864 .previous
 865
 866 /*
 867  * Interrupt entry/exit.
 868  *
 869  * Interrupt entry points save only callee clobbered registers in fast path.
 870  *
 871  * Entry runs with interrupts off.
 872  */
 873
 874 /* 0(%rsp): ~(interrupt number) */
 875         .macro interrupt func
 876         /* reserve pt_regs for scratch regs and rbp */
 877         subq $ORIG_RAX-RBP, %rsp
 878         CFI_ADJUST_CFA_OFFSET ORIG_RAX-RBP
 879         SAVE_ARGS_IRQ
 880         call \func
 881         .endm
 882
 883 /*
 884  * Interrupt entry/exit should be protected against kprobes
 885  */
 886         .pushsection .kprobes.text, "ax"
 887         /*
 888          * The interrupt stubs push (~vector+0x80) onto the stack and
 889          * then jump to common_interrupt.
 890          */
 891         .p2align CONFIG_X86_L1_CACHE_SHIFT
 892 common_interrupt:
 893         XCPT_FRAME
 894         addq $-0x80,(%rsp)              /* Adjust vector to [-256,-1] range */
 895         interrupt do_IRQ
 896         /* 0(%rsp): old_rsp-ARGOFFSET */
 897 ret_from_intr:
 898         DISABLE_INTERRUPTS(CLBR_NONE)
 899         TRACE_IRQS_OFF
 900         decl PER_CPU_VAR(irq_count)
 901
 902         /* Restore saved previous stack */
 903         popq %rsi
 904         CFI_DEF_CFA rsi,SS+8-RBP        /* reg/off reset after def_cfa_expr */
 905         leaq ARGOFFSET-RBP(%rsi), %rsp
 906         CFI_DEF_CFA_REGISTER    rsp
 907         CFI_ADJUST_CFA_OFFSET   RBP-ARGOFFSET
 908
 909 exit_intr:
 910         GET_THREAD_INFO(%rcx)
 911         testl $3,CS-ARGOFFSET(%rsp)
 912         je retint_kernel
 913
 914         /* Interrupt came from user space */
 915         /*
 916          * Has a correct top of stack, but a partial stack frame
 917          * %rcx: thread info. Interrupts off.
 918          */
 919 retint_with_reschedule:
 920         movl $_TIF_WORK_MASK,%edi
 921 retint_check:
 922         LOCKDEP_SYS_EXIT_IRQ
 923         movl TI_flags(%rcx),%edx
 924         andl %edi,%edx
 925         CFI_REMEMBER_STATE
 926         jnz  retint_careful
 927
 928 retint_swapgs:          /* return to user-space */
 929         /*
 930          * The iretq could re-enable interrupts:
 931          */
 932         DISABLE_INTERRUPTS(CLBR_ANY)
 933         TRACE_IRQS_IRETQ
 934         SWAPGS
 935         jmp restore_args
 936
 937 retint_restore_args:    /* return to kernel space */
 938         DISABLE_INTERRUPTS(CLBR_ANY)
 939         /*
 940          * The iretq could re-enable interrupts:
 941          */
 942         TRACE_IRQS_IRETQ
 943 restore_args:
 944         RESTORE_ARGS 1,8,1
 945
 946 irq_return:
 947         INTERRUPT_RETURN
 948         _ASM_EXTABLE(irq_return, bad_iret)
 949
 950 #ifdef CONFIG_PARAVIRT
 951 ENTRY(native_iret)
 952         iretq
 953         _ASM_EXTABLE(native_iret, bad_iret)
 954 #endif
 955
 956         .section .fixup,"ax"
 957 bad_iret:
 958         /*
 959          * The iret traps when the %cs or %ss being restored is bogus.
 960          * We've lost the original trap vector and error code.
 961          * #GPF is the most likely one to get for an invalid selector.
 962          * So pretend we completed the iret and took the #GPF in user mode.
 963          *
 964          * We are now running with the kernel GS after exception recovery.
 965          * But error_entry expects us to have user GS to match the user %cs,
 966          * so swap back.
 967          */
 968         pushq $0
 969
 970         SWAPGS
 971         jmp general_protection
 972
 973         .previous
 974
 975         /* edi: workmask, edx: work */
 976 retint_careful:
 977         CFI_RESTORE_STATE
 978         bt    $TIF_NEED_RESCHED,%edx
 979         jnc   retint_signal
 980         TRACE_IRQS_ON
 981         ENABLE_INTERRUPTS(CLBR_NONE)
 982         pushq_cfi %rdi
 983         call  schedule
 984         popq_cfi %rdi
 985         GET_THREAD_INFO(%rcx)
 986         DISABLE_INTERRUPTS(CLBR_NONE)
 987         TRACE_IRQS_OFF
 988         jmp retint_check
 989
 990 retint_signal:
 991         testl $_TIF_DO_NOTIFY_MASK,%edx
 992         jz    retint_swapgs
 993         TRACE_IRQS_ON
 994         ENABLE_INTERRUPTS(CLBR_NONE)
 995         SAVE_REST
 996         movq $-1,ORIG_RAX(%rsp)
 997         xorl %esi,%esi          # oldset
 998         movq %rsp,%rdi          # &pt_regs
 999         call do_notify_resume
1000         RESTORE_REST
1001         DISABLE_INTERRUPTS(CLBR_NONE)
1002         TRACE_IRQS_OFF
1003         GET_THREAD_INFO(%rcx)
1004         jmp retint_with_reschedule
1005
1006 #ifdef CONFIG_PREEMPT
1007         /* Returning to kernel space. Check if we need preemption */
1008         /* rcx:  threadinfo. interrupts off. */
1009 ENTRY(retint_kernel)
1010         cmpl $0,TI_preempt_count(%rcx)
1011         jnz  retint_restore_args
1012         bt  $TIF_NEED_RESCHED,TI_flags(%rcx)
1013         jnc  retint_restore_args
1014         bt   $9,EFLAGS-ARGOFFSET(%rsp)  /* interrupts off? */
1015         jnc  retint_restore_args
1016         call preempt_schedule_irq
1017         jmp exit_intr
1018 #endif
1019
1020         CFI_ENDPROC
1021 END(common_interrupt)
1022 /*
1023  * End of kprobes section
1024  */
1025        .popsection
1026
1027 /*
1028  * APIC interrupts.
1029  */
1030 .macro apicinterrupt num sym do_sym
1031 ENTRY(\sym)
1032         INTR_FRAME
1033         pushq_cfi $~(\num)
1034 .Lcommon_\sym:
1035         interrupt \do_sym
1036         jmp ret_from_intr
1037         CFI_ENDPROC
1038 END(\sym)
1039 .endm
1040
1041 #ifdef CONFIG_SMP
1042 apicinterrupt IRQ_MOVE_CLEANUP_VECTOR \
1043         irq_move_cleanup_interrupt smp_irq_move_cleanup_interrupt
1044 apicinterrupt REBOOT_VECTOR \
1045         reboot_interrupt smp_reboot_interrupt
1046 #endif
1047
1048 #ifdef CONFIG_X86_UV
1049 apicinterrupt UV_BAU_MESSAGE \
1050         uv_bau_message_intr1 uv_bau_message_interrupt
1051 #endif
1052 apicinterrupt LOCAL_TIMER_VECTOR \
1053         apic_timer_interrupt smp_apic_timer_interrupt
1054 apicinterrupt X86_PLATFORM_IPI_VECTOR \
1055         x86_platform_ipi smp_x86_platform_ipi
1056
1057 apicinterrupt THRESHOLD_APIC_VECTOR \
1058         threshold_interrupt smp_threshold_interrupt
1059 apicinterrupt THERMAL_APIC_VECTOR \
1060         thermal_interrupt smp_thermal_interrupt
1061
1062 #ifdef CONFIG_SMP
1063 apicinterrupt CALL_FUNCTION_SINGLE_VECTOR \
1064         call_function_single_interrupt smp_call_function_single_interrupt
1065 apicinterrupt CALL_FUNCTION_VECTOR \
1066         call_function_interrupt smp_call_function_interrupt
1067 apicinterrupt RESCHEDULE_VECTOR \
1068         reschedule_interrupt smp_reschedule_interrupt
1069 #endif
1070
1071 apicinterrupt ERROR_APIC_VECTOR \
1072         error_interrupt smp_error_interrupt
1073 apicinterrupt SPURIOUS_APIC_VECTOR \
1074         spurious_interrupt smp_spurious_interrupt
1075
1076 #ifdef CONFIG_IRQ_WORK
1077 apicinterrupt IRQ_WORK_VECTOR \
1078         irq_work_interrupt smp_irq_work_interrupt
1079 #endif
1080
1081 /*
1082  * Exception entry points.
1083  */
1084 .macro zeroentry sym do_sym
1085 ENTRY(\sym)
1086         INTR_FRAME
1087         PARAVIRT_ADJUST_EXCEPTION_FRAME
1088         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1089         subq $ORIG_RAX-R15, %rsp
1090         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1091         call error_entry
1092         DEFAULT_FRAME 0
1093         movq %rsp,%rdi          /* pt_regs pointer */
1094         xorl %esi,%esi          /* no error code */
1095         call \do_sym
1096         jmp error_exit          /* %ebx: no swapgs flag */
1097         CFI_ENDPROC
1098 END(\sym)
1099 .endm
1100
1101 .macro paranoidzeroentry sym do_sym
1102 ENTRY(\sym)
1103         INTR_FRAME
1104         PARAVIRT_ADJUST_EXCEPTION_FRAME
1105         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1106         subq $ORIG_RAX-R15, %rsp
1107         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1108         call save_paranoid
1109         TRACE_IRQS_OFF
1110         movq %rsp,%rdi          /* pt_regs pointer */
1111         xorl %esi,%esi          /* no error code */
1112         call \do_sym
1113         jmp paranoid_exit       /* %ebx: no swapgs flag */
1114         CFI_ENDPROC
1115 END(\sym)
1116 .endm
1117
1118 #define INIT_TSS_IST(x) PER_CPU_VAR(init_tss) + (TSS_ist + ((x) - 1) * 8)
1119 .macro paranoidzeroentry_ist sym do_sym ist
1120 ENTRY(\sym)
1121         INTR_FRAME
1122         PARAVIRT_ADJUST_EXCEPTION_FRAME
1123         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1124         subq $ORIG_RAX-R15, %rsp
1125         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1126         call save_paranoid
1127         TRACE_IRQS_OFF_DEBUG
1128         movq %rsp,%rdi          /* pt_regs pointer */
1129         xorl %esi,%esi          /* no error code */
1130         subq $EXCEPTION_STKSZ, INIT_TSS_IST(\ist)
1131         call \do_sym
1132         addq $EXCEPTION_STKSZ, INIT_TSS_IST(\ist)
1133         jmp paranoid_exit       /* %ebx: no swapgs flag */
1134         CFI_ENDPROC
1135 END(\sym)
1136 .endm
1137
1138 .macro errorentry sym do_sym
1139 ENTRY(\sym)
1140         XCPT_FRAME
1141         PARAVIRT_ADJUST_EXCEPTION_FRAME
1142         subq $ORIG_RAX-R15, %rsp
1143         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1144         call error_entry
1145         DEFAULT_FRAME 0
1146         movq %rsp,%rdi                  /* pt_regs pointer */
1147         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1148         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1149         call \do_sym
1150         jmp error_exit                  /* %ebx: no swapgs flag */
1151         CFI_ENDPROC
1152 END(\sym)
1153 .endm
1154
1155         /* error code is on the stack already */
1156 .macro paranoiderrorentry sym do_sym
1157 ENTRY(\sym)
1158         XCPT_FRAME
1159         PARAVIRT_ADJUST_EXCEPTION_FRAME
1160         subq $ORIG_RAX-R15, %rsp
1161         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1162         call save_paranoid
1163         DEFAULT_FRAME 0
1164         TRACE_IRQS_OFF
1165         movq %rsp,%rdi                  /* pt_regs pointer */
1166         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1167         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1168         call \do_sym
1169         jmp paranoid_exit               /* %ebx: no swapgs flag */
1170         CFI_ENDPROC
1171 END(\sym)
1172 .endm
1173
1174 zeroentry divide_error do_divide_error
1175 zeroentry overflow do_overflow
1176 zeroentry bounds do_bounds
1177 zeroentry invalid_op do_invalid_op
1178 zeroentry device_not_available do_device_not_available
1179 paranoiderrorentry double_fault do_double_fault
1180 zeroentry coprocessor_segment_overrun do_coprocessor_segment_overrun
1181 errorentry invalid_TSS do_invalid_TSS
1182 errorentry segment_not_present do_segment_not_present
1183 zeroentry spurious_interrupt_bug do_spurious_interrupt_bug
1184 zeroentry coprocessor_error do_coprocessor_error
1185 errorentry alignment_check do_alignment_check
1186 zeroentry simd_coprocessor_error do_simd_coprocessor_error
1187
1188
1189         /* Reload gs selector with exception handling */
1190         /* edi:  new selector */
1191 ENTRY(native_load_gs_index)
1192         CFI_STARTPROC
1193         pushfq_cfi
1194         DISABLE_INTERRUPTS(CLBR_ANY & ~CLBR_RDI)
1195         SWAPGS
1196 gs_change:
1197         movl %edi,%gs
1198 2:      mfence          /* workaround */
1199         SWAPGS
1200         popfq_cfi
1201         ret
1202         CFI_ENDPROC
1203 END(native_load_gs_index)
1204
1205         _ASM_EXTABLE(gs_change,bad_gs)
1206         .section .fixup,"ax"
1207         /* running with kernelgs */
1208 bad_gs:
1209         SWAPGS                  /* switch back to user gs */
1210         xorl %eax,%eax
1211         movl %eax,%gs
1212         jmp  2b
1213         .previous
1214
1215 /* Call softirq on interrupt stack. Interrupts are off. */
1216 ENTRY(call_softirq)
1217         CFI_STARTPROC
1218         pushq_cfi %rbp
1219         CFI_REL_OFFSET rbp,0
1220         mov  %rsp,%rbp
1221         CFI_DEF_CFA_REGISTER rbp
1222         incl PER_CPU_VAR(irq_count)
1223         cmove PER_CPU_VAR(irq_stack_ptr),%rsp
1224         push  %rbp                      # backlink for old unwinder
1225         call __do_softirq
1226         leaveq
1227         CFI_RESTORE             rbp
1228         CFI_DEF_CFA_REGISTER    rsp
1229         CFI_ADJUST_CFA_OFFSET   -8
1230         decl PER_CPU_VAR(irq_count)
1231         ret
1232         CFI_ENDPROC
1233 END(call_softirq)
1234
1235 #ifdef CONFIG_XEN
1236 zeroentry xen_hypervisor_callback xen_do_hypervisor_callback
1237
1238 /*
1239  * A note on the "critical region" in our callback handler.
1240  * We want to avoid stacking callback handlers due to events occurring
1241  * during handling of the last event. To do this, we keep events disabled
1242  * until we've done all processing. HOWEVER, we must enable events before
1243  * popping the stack frame (can't be done atomically) and so it would still
1244  * be possible to get enough handler activations to overflow the stack.
1245  * Although unlikely, bugs of that kind are hard to track down, so we'd
1246  * like to avoid the possibility.
1247  * So, on entry to the handler we detect whether we interrupted an
1248  * existing activation in its critical region -- if so, we pop the current
1249  * activation and restart the handler using the previous one.
1250  */
1251 ENTRY(xen_do_hypervisor_callback)   # do_hypervisor_callback(struct *pt_regs)
1252         CFI_STARTPROC
1253 /*
1254  * Since we don't modify %rdi, evtchn_do_upall(struct *pt_regs) will
1255  * see the correct pointer to the pt_regs
1256  */
1257         movq %rdi, %rsp            # we don't return, adjust the stack frame
1258         CFI_ENDPROC
1259         DEFAULT_FRAME
1260 11:     incl PER_CPU_VAR(irq_count)
1261         movq %rsp,%rbp
1262         CFI_DEF_CFA_REGISTER rbp
1263         cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
1264         pushq %rbp                      # backlink for old unwinder
1265         call xen_evtchn_do_upcall
1266         popq %rsp
1267         CFI_DEF_CFA_REGISTER rsp
1268         decl PER_CPU_VAR(irq_count)
1269         jmp  error_exit
1270         CFI_ENDPROC
1271 END(xen_do_hypervisor_callback)
1272
1273 /*
1274  * Hypervisor uses this for application faults while it executes.
1275  * We get here for two reasons:
1276  *  1. Fault while reloading DS, ES, FS or GS
1277  *  2. Fault while executing IRET
1278  * Category 1 we do not need to fix up as Xen has already reloaded all segment
1279  * registers that could be reloaded and zeroed the others.
1280  * Category 2 we fix up by killing the current process. We cannot use the
1281  * normal Linux return path in this case because if we use the IRET hypercall
1282  * to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1283  * We distinguish between categories by comparing each saved segment register
1284  * with its current contents: any discrepancy means we in category 1.
1285  */
1286 ENTRY(xen_failsafe_callback)
1287         INTR_FRAME 1 (6*8)
1288         /*CFI_REL_OFFSET gs,GS*/
1289         /*CFI_REL_OFFSET fs,FS*/
1290         /*CFI_REL_OFFSET es,ES*/
1291         /*CFI_REL_OFFSET ds,DS*/
1292         CFI_REL_OFFSET r11,8
1293         CFI_REL_OFFSET rcx,0
1294         movw %ds,%cx
1295         cmpw %cx,0x10(%rsp)
1296         CFI_REMEMBER_STATE
1297         jne 1f
1298         movw %es,%cx
1299         cmpw %cx,0x18(%rsp)
1300         jne 1f
1301         movw %fs,%cx
1302         cmpw %cx,0x20(%rsp)
1303         jne 1f
1304         movw %gs,%cx
1305         cmpw %cx,0x28(%rsp)
1306         jne 1f
1307         /* All segments match their saved values => Category 2 (Bad IRET). */
1308         movq (%rsp),%rcx
1309         CFI_RESTORE rcx
1310         movq 8(%rsp),%r11
1311         CFI_RESTORE r11
1312         addq $0x30,%rsp
1313         CFI_ADJUST_CFA_OFFSET -0x30
1314         pushq_cfi $0    /* RIP */
1315         pushq_cfi %r11
1316         pushq_cfi %rcx
1317         jmp general_protection
1318         CFI_RESTORE_STATE
1319 1:      /* Segment mismatch => Category 1 (Bad segment). Retry the IRET. */
1320         movq (%rsp),%rcx
1321         CFI_RESTORE rcx
1322         movq 8(%rsp),%r11
1323         CFI_RESTORE r11
1324         addq $0x30,%rsp
1325         CFI_ADJUST_CFA_OFFSET -0x30
1326         pushq_cfi $0
1327         SAVE_ALL
1328         jmp error_exit
1329         CFI_ENDPROC
1330 END(xen_failsafe_callback)
1331
1332 apicinterrupt XEN_HVM_EVTCHN_CALLBACK \
1333         xen_hvm_callback_vector xen_evtchn_do_upcall
1334
1335 #endif /* CONFIG_XEN */
1336
1337 /*
1338  * Some functions should be protected against kprobes
1339  */
1340         .pushsection .kprobes.text, "ax"
1341
1342 paranoidzeroentry_ist debug do_debug DEBUG_STACK
1343 paranoidzeroentry_ist int3 do_int3 DEBUG_STACK
1344 paranoiderrorentry stack_segment do_stack_segment
1345 #ifdef CONFIG_XEN
1346 zeroentry xen_debug do_debug
1347 zeroentry xen_int3 do_int3
1348 errorentry xen_stack_segment do_stack_segment
1349 #endif
1350 errorentry general_protection do_general_protection
1351 errorentry page_fault do_page_fault
1352 #ifdef CONFIG_KVM_GUEST
1353 errorentry async_page_fault do_async_page_fault
1354 #endif
1355 #ifdef CONFIG_X86_MCE
1356 paranoidzeroentry machine_check *machine_check_vector(%rip)
1357 #endif
1358
1359         /*
1360          * "Paranoid" exit path from exception stack.
1361          * Paranoid because this is used by NMIs and cannot take
1362          * any kernel state for granted.
1363          * We don't do kernel preemption checks here, because only
1364          * NMI should be common and it does not enable IRQs and
1365          * cannot get reschedule ticks.
1366          *
1367          * "trace" is 0 for the NMI handler only, because irq-tracing
1368          * is fundamentally NMI-unsafe. (we cannot change the soft and
1369          * hard flags at once, atomically)
1370          */
1371
1372         /* ebx: no swapgs flag */
1373 ENTRY(paranoid_exit)
1374         DEFAULT_FRAME
1375         DISABLE_INTERRUPTS(CLBR_NONE)
1376         TRACE_IRQS_OFF_DEBUG
1377         testl %ebx,%ebx                         /* swapgs needed? */
1378         jnz paranoid_restore
1379         testl $3,CS(%rsp)
1380         jnz   paranoid_userspace
1381 paranoid_swapgs:
1382         TRACE_IRQS_IRETQ 0
1383         SWAPGS_UNSAFE_STACK
1384         RESTORE_ALL 8
1385         jmp irq_return
1386 paranoid_restore:
1387         TRACE_IRQS_IRETQ_DEBUG 0
1388         RESTORE_ALL 8
1389         jmp irq_return
1390 paranoid_userspace:
1391         GET_THREAD_INFO(%rcx)
1392         movl TI_flags(%rcx),%ebx
1393         andl $_TIF_WORK_MASK,%ebx
1394         jz paranoid_swapgs
1395         movq %rsp,%rdi                  /* &pt_regs */
1396         call sync_regs
1397         movq %rax,%rsp                  /* switch stack for scheduling */
1398         testl $_TIF_NEED_RESCHED,%ebx
1399         jnz paranoid_schedule
1400         movl %ebx,%edx                  /* arg3: thread flags */
1401         TRACE_IRQS_ON
1402         ENABLE_INTERRUPTS(CLBR_NONE)
1403         xorl %esi,%esi                  /* arg2: oldset */
1404         movq %rsp,%rdi                  /* arg1: &pt_regs */
1405         call do_notify_resume
1406         DISABLE_INTERRUPTS(CLBR_NONE)
1407         TRACE_IRQS_OFF
1408         jmp paranoid_userspace
1409 paranoid_schedule:
1410         TRACE_IRQS_ON
1411         ENABLE_INTERRUPTS(CLBR_ANY)
1412         call schedule
1413         DISABLE_INTERRUPTS(CLBR_ANY)
1414         TRACE_IRQS_OFF
1415         jmp paranoid_userspace
1416         CFI_ENDPROC
1417 END(paranoid_exit)
1418
1419 /*
1420  * Exception entry point. This expects an error code/orig_rax on the stack.
1421  * returns in "no swapgs flag" in %ebx.
1422  */
1423 ENTRY(error_entry)
1424         XCPT_FRAME
1425         CFI_ADJUST_CFA_OFFSET 15*8
1426         /* oldrax contains error code */
1427         cld
1428         movq_cfi rdi, RDI+8
1429         movq_cfi rsi, RSI+8
1430         movq_cfi rdx, RDX+8
1431         movq_cfi rcx, RCX+8
1432         movq_cfi rax, RAX+8
1433         movq_cfi  r8,  R8+8
1434         movq_cfi  r9,  R9+8
1435         movq_cfi r10, R10+8
1436         movq_cfi r11, R11+8
1437         movq_cfi rbx, RBX+8
1438         movq_cfi rbp, RBP+8
1439         movq_cfi r12, R12+8
1440         movq_cfi r13, R13+8
1441         movq_cfi r14, R14+8
1442         movq_cfi r15, R15+8
1443         xorl %ebx,%ebx
1444         testl $3,CS+8(%rsp)
1445         je error_kernelspace
1446 error_swapgs:
1447         SWAPGS
1448 error_sti:
1449         TRACE_IRQS_OFF
1450         ret
1451
1452 /*
1453  * There are two places in the kernel that can potentially fault with
1454  * usergs. Handle them here. The exception handlers after iret run with
1455  * kernel gs again, so don't set the user space flag. B stepping K8s
1456  * sometimes report an truncated RIP for IRET exceptions returning to
1457  * compat mode. Check for these here too.
1458  */
1459 error_kernelspace:
1460         incl %ebx
1461         leaq irq_return(%rip),%rcx
1462         cmpq %rcx,RIP+8(%rsp)
1463         je error_swapgs
1464         movl %ecx,%eax  /* zero extend */
1465         cmpq %rax,RIP+8(%rsp)
1466         je bstep_iret
1467         cmpq $gs_change,RIP+8(%rsp)
1468         je error_swapgs
1469         jmp error_sti
1470
1471 bstep_iret:
1472         /* Fix truncated RIP */
1473         movq %rcx,RIP+8(%rsp)
1474         jmp error_swapgs
1475         CFI_ENDPROC
1476 END(error_entry)
1477
1478
1479 /* ebx: no swapgs flag (1: don't need swapgs, 0: need it) */
1480 ENTRY(error_exit)
1481         DEFAULT_FRAME
1482         movl %ebx,%eax
1483         RESTORE_REST
1484         DISABLE_INTERRUPTS(CLBR_NONE)
1485         TRACE_IRQS_OFF
1486         GET_THREAD_INFO(%rcx)
1487         testl %eax,%eax
1488         jne retint_kernel
1489         LOCKDEP_SYS_EXIT_IRQ
1490         movl TI_flags(%rcx),%edx
1491         movl $_TIF_WORK_MASK,%edi
1492         andl %edi,%edx
1493         jnz retint_careful
1494         jmp retint_swapgs
1495         CFI_ENDPROC
1496 END(error_exit)
1497
1498 /*
1499  * Test if a given stack is an NMI stack or not.
1500  */
1501         .macro test_in_nmi reg stack nmi_ret normal_ret
1502         cmpq %\reg, \stack
1503         ja \normal_ret
1504         subq $EXCEPTION_STKSZ, %\reg
1505         cmpq %\reg, \stack
1506         jb \normal_ret
1507         jmp \nmi_ret
1508         .endm
1509
1510         /* runs on exception stack */
1511 ENTRY(nmi)
1512         INTR_FRAME
1513         PARAVIRT_ADJUST_EXCEPTION_FRAME
1514         /*
1515          * We allow breakpoints in NMIs. If a breakpoint occurs, then
1516          * the iretq it performs will take us out of NMI context.
1517          * This means that we can have nested NMIs where the next
1518          * NMI is using the top of the stack of the previous NMI. We
1519          * can't let it execute because the nested NMI will corrupt the
1520          * stack of the previous NMI. NMI handlers are not re-entrant
1521          * anyway.
1522          *
1523          * To handle this case we do the following:
1524          *  Check the a special location on the stack that contains
1525          *  a variable that is set when NMIs are executing.
1526          *  The interrupted task's stack is also checked to see if it
1527          *  is an NMI stack.
1528          *  If the variable is not set and the stack is not the NMI
1529          *  stack then:
1530          *    o Set the special variable on the stack
1531          *    o Copy the interrupt frame into a "saved" location on the stack
1532          *    o Copy the interrupt frame into a "copy" location on the stack
1533          *    o Continue processing the NMI
1534          *  If the variable is set or the previous stack is the NMI stack:
1535          *    o Modify the "copy" location to jump to the repeate_nmi
1536          *    o return back to the first NMI
1537          *
1538          * Now on exit of the first NMI, we first clear the stack variable
1539          * The NMI stack will tell any nested NMIs at that point that it is
1540          * nested. Then we pop the stack normally with iret, and if there was
1541          * a nested NMI that updated the copy interrupt stack frame, a
1542          * jump will be made to the repeat_nmi code that will handle the second
1543          * NMI.
1544          */
1545
1546         /* Use %rdx as out temp variable throughout */
1547         pushq_cfi %rdx
1548         CFI_REL_OFFSET rdx, 0
1549
1550         /*
1551          * If %cs was not the kernel segment, then the NMI triggered in user
1552          * space, which means it is definitely not nested.
1553          */
1554         cmpl $__KERNEL_CS, 16(%rsp)
1555         jne first_nmi
1556
1557         /*
1558          * Check the special variable on the stack to see if NMIs are
1559          * executing.
1560          */
1561         cmpl $1, -8(%rsp)
1562         je nested_nmi
1563
1564         /*
1565          * Now test if the previous stack was an NMI stack.
1566          * We need the double check. We check the NMI stack to satisfy the
1567          * race when the first NMI clears the variable before returning.
1568          * We check the variable because the first NMI could be in a
1569          * breakpoint routine using a breakpoint stack.
1570          */
1571         lea 6*8(%rsp), %rdx
1572         test_in_nmi rdx, 4*8(%rsp), nested_nmi, first_nmi
1573         CFI_REMEMBER_STATE
1574
1575 nested_nmi:
1576         /*
1577          * Do nothing if we interrupted the fixup in repeat_nmi.
1578          * It's about to repeat the NMI handler, so we are fine
1579          * with ignoring this one.
1580          */
1581         movq $repeat_nmi, %rdx
1582         cmpq 8(%rsp), %rdx
1583         ja 1f
1584         movq $end_repeat_nmi, %rdx
1585         cmpq 8(%rsp), %rdx
1586         ja nested_nmi_out
1587
1588 1:
1589         /* Set up the interrupted NMIs stack to jump to repeat_nmi */
1590         leaq -6*8(%rsp), %rdx
1591         movq %rdx, %rsp
1592         CFI_ADJUST_CFA_OFFSET 6*8
1593         pushq_cfi $__KERNEL_DS
1594         pushq_cfi %rdx
1595         pushfq_cfi
1596         pushq_cfi $__KERNEL_CS
1597         pushq_cfi $repeat_nmi
1598
1599         /* Put stack back */
1600         addq $(11*8), %rsp
1601         CFI_ADJUST_CFA_OFFSET -11*8
1602
1603 nested_nmi_out:
1604         popq_cfi %rdx
1605         CFI_RESTORE rdx
1606
1607         /* No need to check faults here */
1608         INTERRUPT_RETURN
1609
1610         CFI_RESTORE_STATE
1611 first_nmi:
1612         /*
1613          * Because nested NMIs will use the pushed location that we
1614          * stored in rdx, we must keep that space available.
1615          * Here's what our stack frame will look like:
1616          * +-------------------------+
1617          * | original SS             |
1618          * | original Return RSP     |
1619          * | original RFLAGS         |
1620          * | original CS             |
1621          * | original RIP            |
1622          * +-------------------------+
1623          * | temp storage for rdx    |
1624          * +-------------------------+
1625          * | NMI executing variable  |
1626          * +-------------------------+
1627          * | Saved SS                |
1628          * | Saved Return RSP        |
1629          * | Saved RFLAGS            |
1630          * | Saved CS                |
1631          * | Saved RIP               |
1632          * +-------------------------+
1633          * | copied SS               |
1634          * | copied Return RSP       |
1635          * | copied RFLAGS           |
1636          * | copied CS               |
1637          * | copied RIP              |
1638          * +-------------------------+
1639          * | pt_regs                 |
1640          * +-------------------------+
1641          *
1642          * The saved stack frame is used to fix up the copied stack frame
1643          * that a nested NMI may change to make the interrupted NMI iret jump
1644          * to the repeat_nmi. The original stack frame and the temp storage
1645          * is also used by nested NMIs and can not be trusted on exit.
1646          */
1647         /* Do not pop rdx, nested NMIs will corrupt that part of the stack */
1648         movq (%rsp), %rdx
1649         CFI_RESTORE rdx
1650
1651         /* Set the NMI executing variable on the stack. */
1652         pushq_cfi $1
1653
1654         /* Copy the stack frame to the Saved frame */
1655         .rept 5
1656         pushq_cfi 6*8(%rsp)
1657         .endr
1658         CFI_DEF_CFA_OFFSET SS+8-RIP
1659
1660         /* Everything up to here is safe from nested NMIs */
1661
1662         /*
1663          * If there was a nested NMI, the first NMI's iret will return
1664          * here. But NMIs are still enabled and we can take another
1665          * nested NMI. The nested NMI checks the interrupted RIP to see
1666          * if it is between repeat_nmi and end_repeat_nmi, and if so
1667          * it will just return, as we are about to repeat an NMI anyway.
1668          * This makes it safe to copy to the stack frame that a nested
1669          * NMI will update.
1670          */
1671 repeat_nmi:
1672         /*
1673          * Update the stack variable to say we are still in NMI (the update
1674          * is benign for the non-repeat case, where 1 was pushed just above
1675          * to this very stack slot).
1676          */
1677         movq $1, 5*8(%rsp)
1678
1679         /* Make another copy, this one may be modified by nested NMIs */
1680         .rept 5
1681         pushq_cfi 4*8(%rsp)
1682         .endr
1683         CFI_DEF_CFA_OFFSET SS+8-RIP
1684 end_repeat_nmi:
1685
1686         /*
1687          * Everything below this point can be preempted by a nested
1688          * NMI if the first NMI took an exception and reset our iret stack
1689          * so that we repeat another NMI.
1690          */
1691         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1692         subq $ORIG_RAX-R15, %rsp
1693         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1694         /*
1695          * Use save_paranoid to handle SWAPGS, but no need to use paranoid_exit
1696          * as we should not be calling schedule in NMI context.
1697          * Even with normal interrupts enabled. An NMI should not be
1698          * setting NEED_RESCHED or anything that normal interrupts and
1699          * exceptions might do.
1700          */
1701         call save_paranoid
1702         DEFAULT_FRAME 0
1703
1704         /*
1705          * Save off the CR2 register. If we take a page fault in the NMI then
1706          * it could corrupt the CR2 value. If the NMI preempts a page fault
1707          * handler before it was able to read the CR2 register, and then the
1708          * NMI itself takes a page fault, the page fault that was preempted
1709          * will read the information from the NMI page fault and not the
1710          * origin fault. Save it off and restore it if it changes.
1711          * Use the r12 callee-saved register.
1712          */
1713         movq %cr2, %r12
1714
1715         /* paranoidentry do_nmi, 0; without TRACE_IRQS_OFF */
1716         movq %rsp,%rdi
1717         movq $-1,%rsi
1718         call do_nmi
1719
1720         /* Did the NMI take a page fault? Restore cr2 if it did */
1721         movq %cr2, %rcx
1722         cmpq %rcx, %r12
1723         je 1f
1724         movq %r12, %cr2
1725 1:
1726
1727         testl %ebx,%ebx                         /* swapgs needed? */
1728         jnz nmi_restore
1729 nmi_swapgs:
1730         SWAPGS_UNSAFE_STACK
1731 nmi_restore:
1732         RESTORE_ALL 8
1733         /* Clear the NMI executing stack variable */
1734         movq $0, 10*8(%rsp)
1735         jmp irq_return
1736         CFI_ENDPROC
1737 END(nmi)
1738
1739 ENTRY(ignore_sysret)
1740         CFI_STARTPROC
1741         mov $-ENOSYS,%eax
1742         sysret
1743         CFI_ENDPROC
1744 END(ignore_sysret)
1745
1746 /*
1747  * End of kprobes section
1748  */
1749         .popsection