scripts/sphinx-pre-install

   1 #!/usr/bin/env perl
   2 # SPDX-License-Identifier: GPL-2.0-or-later
   3 use strict;
   4
   5 # Copyright (c) 2017-2020 Mauro Carvalho Chehab <[email protected]>
   6 #
   7
   8 my $prefix = "./";
   9 $prefix = "$ENV{'srctree'}/" if ($ENV{'srctree'});
  10
  11 my $conf = $prefix . "Documentation/conf.py";
  12 my $requirement_file = $prefix . "Documentation/sphinx/requirements.txt";
  13 my $virtenv_prefix = "sphinx_";
  14
  15 #
  16 # Static vars
  17 #
  18
  19 my %missing;
  20 my $system_release;
  21 my $need = 0;
  22 my $optional = 0;
  23 my $need_symlink = 0;
  24 my $need_sphinx = 0;
  25 my $need_pip = 0;
  26 my $need_virtualenv = 0;
  27 my $rec_sphinx_upgrade = 0;
  28 my $verbose_warn_install = 1;
  29 my $install = "";
  30 my $virtenv_dir = "";
  31 my $python_cmd = "";
  32 my $activate_cmd;
  33 my $min_version;
  34 my $cur_version;
  35 my $rec_version = "3.4.3";
  36 my $latest_avail_ver;
  37
  38 #
  39 # Command line arguments
  40 #
  41
  42 my $pdf = 1;
  43 my $virtualenv = 1;
  44 my $version_check = 0;
  45
  46 #
  47 # List of required texlive packages on Fedora and OpenSuse
  48 #
  49
  50 my %texlive = (
  51         'amsfonts.sty'       => 'texlive-amsfonts',
  52         'amsmath.sty'        => 'texlive-amsmath',
  53         'amssymb.sty'        => 'texlive-amsfonts',
  54         'amsthm.sty'         => 'texlive-amscls',
  55         'anyfontsize.sty'    => 'texlive-anyfontsize',
  56         'atbegshi.sty'       => 'texlive-oberdiek',
  57         'bm.sty'             => 'texlive-tools',
  58         'capt-of.sty'        => 'texlive-capt-of',
  59         'cmap.sty'           => 'texlive-cmap',
  60         'ecrm1000.tfm'       => 'texlive-ec',
  61         'eqparbox.sty'       => 'texlive-eqparbox',
  62         'eu1enc.def'         => 'texlive-euenc',
  63         'fancybox.sty'       => 'texlive-fancybox',
  64         'fancyvrb.sty'       => 'texlive-fancyvrb',
  65         'float.sty'          => 'texlive-float',
  66         'fncychap.sty'       => 'texlive-fncychap',
  67         'footnote.sty'       => 'texlive-mdwtools',
  68         'framed.sty'         => 'texlive-framed',
  69         'luatex85.sty'       => 'texlive-luatex85',
  70         'multirow.sty'       => 'texlive-multirow',
  71         'needspace.sty'      => 'texlive-needspace',
  72         'palatino.sty'       => 'texlive-psnfss',
  73         'parskip.sty'        => 'texlive-parskip',
  74         'polyglossia.sty'    => 'texlive-polyglossia',
  75         'tabulary.sty'       => 'texlive-tabulary',
  76         'threeparttable.sty' => 'texlive-threeparttable',
  77         'titlesec.sty'       => 'texlive-titlesec',
  78         'ucs.sty'            => 'texlive-ucs',
  79         'upquote.sty'        => 'texlive-upquote',
  80         'wrapfig.sty'        => 'texlive-wrapfig',
  81         'ctexhook.sty'       => 'texlive-ctex',
  82 );
  83
  84 #
  85 # Subroutines that checks if a feature exists
  86 #
  87
  88 sub check_missing(%)
  89 {
  90         my %map = %{$_[0]};
  91
  92         foreach my $prog (sort keys %missing) {
  93                 my $is_optional = $missing{$prog};
  94
  95                 # At least on some LTS distros like CentOS 7, texlive doesn't
  96                 # provide all packages we need. When such distros are
  97                 # detected, we have to disable PDF output.
  98                 #
  99                 # So, we need to ignore the packages that distros would
 100                 # need for LaTeX to work
 101                 if ($is_optional == 2 && !$pdf) {
 102                         $optional--;
 103                         next;
 104                 }
 105
 106                 if ($verbose_warn_install) {
 107                         if ($is_optional) {
 108                                 print "Warning: better to also install \"$prog\".\n";
 109                         } else {
 110                                 print "ERROR: please install \"$prog\", otherwise, build won't work.\n";
 111                         }
 112                 }
 113                 if (defined($map{$prog})) {
 114                         $install .= " " . $map{$prog};
 115                 } else {
 116                         $install .= " " . $prog;
 117                 }
 118         }
 119
 120         $install =~ s/^\s//;
 121 }
 122
 123 sub add_package($$)
 124 {
 125         my $package = shift;
 126         my $is_optional = shift;
 127
 128         $missing{$package} = $is_optional;
 129         if ($is_optional) {
 130                 $optional++;
 131         } else {
 132                 $need++;
 133         }
 134 }
 135
 136 sub check_missing_file($$$)
 137 {
 138         my $files = shift;
 139         my $package = shift;
 140         my $is_optional = shift;
 141
 142         for (@$files) {
 143                 return if(-e $_);
 144         }
 145
 146         add_package($package, $is_optional);
 147 }
 148
 149 sub findprog($)
 150 {
 151         foreach(split(/:/, $ENV{PATH})) {
 152                 return "$_/$_[0]" if(-x "$_/$_[0]");
 153         }
 154 }
 155
 156 sub find_python_no_venv()
 157 {
 158         my $prog = shift;
 159
 160         my $cur_dir = qx(pwd);
 161         $cur_dir =~ s/\s+$//;
 162
 163         foreach my $dir (split(/:/, $ENV{PATH})) {
 164                 next if ($dir =~ m,($cur_dir)/sphinx,);
 165                 return "$dir/python3" if(-x "$dir/python3");
 166         }
 167         foreach my $dir (split(/:/, $ENV{PATH})) {
 168                 next if ($dir =~ m,($cur_dir)/sphinx,);
 169                 return "$dir/python" if(-x "$dir/python");
 170         }
 171         return "python";
 172 }
 173
 174 sub check_program($$)
 175 {
 176         my $prog = shift;
 177         my $is_optional = shift;
 178
 179         return $prog if findprog($prog);
 180
 181         add_package($prog, $is_optional);
 182 }
 183
 184 sub check_perl_module($$)
 185 {
 186         my $prog = shift;
 187         my $is_optional = shift;
 188
 189         my $err = system("perl -M$prog -e 1 2>/dev/null /dev/null");
 190         return if ($err == 0);
 191
 192         add_package($prog, $is_optional);
 193 }
 194
 195 sub check_python_module($$)
 196 {
 197         my $prog = shift;
 198         my $is_optional = shift;
 199
 200         return if (!$python_cmd);
 201
 202         my $err = system("$python_cmd -c 'import $prog' 2>/dev/null /dev/null");
 203         return if ($err == 0);
 204
 205         add_package($prog, $is_optional);
 206 }
 207
 208 sub check_rpm_missing($$)
 209 {
 210         my @pkgs = @{$_[0]};
 211         my $is_optional = $_[1];
 212
 213         foreach my $prog(@pkgs) {
 214                 my $err = system("rpm -q '$prog' 2>/dev/null >/dev/null");
 215                 add_package($prog, $is_optional) if ($err);
 216         }
 217 }
 218
 219 sub check_pacman_missing($$)
 220 {
 221         my @pkgs = @{$_[0]};
 222         my $is_optional = $_[1];
 223
 224         foreach my $prog(@pkgs) {
 225                 my $err = system("pacman -Q '$prog' 2>/dev/null >/dev/null");
 226                 add_package($prog, $is_optional) if ($err);
 227         }
 228 }
 229
 230 sub check_missing_tex($)
 231 {
 232         my $is_optional = shift;
 233         my $kpsewhich = findprog("kpsewhich");
 234
 235         foreach my $prog(keys %texlive) {
 236                 my $package = $texlive{$prog};
 237                 if (!$kpsewhich) {
 238                         add_package($package, $is_optional);
 239                         next;
 240                 }
 241                 my $file = qx($kpsewhich $prog);
 242                 add_package($package, $is_optional) if ($file =~ /^\s*$/);
 243         }
 244 }
 245
 246 sub get_sphinx_fname()
 247 {
 248         my $fname = "sphinx-build";
 249         return $fname if findprog($fname);
 250
 251         $fname = "sphinx-build-3";
 252         if (findprog($fname)) {
 253                 $need_symlink = 1;
 254                 return $fname;
 255         }
 256
 257         return "";
 258 }
 259
 260 sub get_sphinx_version($)
 261 {
 262         my $cmd = shift;
 263         my $ver;
 264
 265         open IN, "$cmd --version 2>&1 |";
 266         while (<IN>) {
 267                 if (m/^\s*sphinx-build\s+([\d\.]+)((\+\/[\da-f]+)|(b\d+))?$/) {
 268                         $ver=$1;
 269                         last;
 270                 }
 271                 # Sphinx 1.2.x uses a different format
 272                 if (m/^\s*Sphinx.*\s+([\d\.]+)$/) {
 273                         $ver=$1;
 274                         last;
 275                 }
 276         }
 277         close IN;
 278         return $ver;
 279 }
 280
 281 sub check_sphinx()
 282 {
 283         open IN, $conf or die "Can't open $conf";
 284         while (<IN>) {
 285                 if (m/^\s*needs_sphinx\s*=\s*[\'\"]([\d\.]+)[\'\"]/) {
 286                         $min_version=$1;
 287                         last;
 288                 }
 289         }
 290         close IN;
 291
 292         die "Can't get needs_sphinx version from $conf" if (!$min_version);
 293
 294         $virtenv_dir = $virtenv_prefix . "latest";
 295
 296         my $sphinx = get_sphinx_fname();
 297         if ($sphinx eq "") {
 298                 $need_sphinx = 1;
 299                 return;
 300         }
 301
 302         $cur_version = get_sphinx_version($sphinx);
 303         die ("$sphinx returned an error") if (!$cur_version);
 304
 305         die "$sphinx didn't return its version" if (!$cur_version);
 306
 307         if ($cur_version lt $min_version) {
 308                 printf "ERROR: Sphinx version is %s. It should be >= %s\n",
 309                        $cur_version, $min_version;
 310                 $need_sphinx = 1;
 311                 return;
 312         }
 313
 314         return if ($cur_version lt $rec_version);
 315
 316         # On version check mode, just assume Sphinx has all mandatory deps
 317         exit (0) if ($version_check);
 318 }
 319
 320 #
 321 # Ancillary subroutines
 322 #
 323
 324 sub catcheck($)
 325 {
 326   my $res = "";
 327   $res = qx(cat $_[0]) if (-r $_[0]);
 328   return $res;
 329 }
 330
 331 sub which($)
 332 {
 333         my $file = shift;
 334         my @path = split ":", $ENV{PATH};
 335
 336         foreach my $dir(@path) {
 337                 my $name = $dir.'/'.$file;
 338                 return $name if (-x $name );
 339         }
 340         return undef;
 341 }
 342
 343 #
 344 # Subroutines that check distro-specific hints
 345 #
 346
 347 sub give_debian_hints()
 348 {
 349         my %map = (
 350                 "python-sphinx"         => "python3-sphinx",
 351                 "yaml"                  => "python3-yaml",
 352                 "ensurepip"             => "python3-venv",
 353                 "virtualenv"            => "virtualenv",
 354                 "dot"                   => "graphviz",
 355                 "convert"               => "imagemagick",
 356                 "Pod::Usage"            => "perl-modules",
 357                 "xelatex"               => "texlive-xetex",
 358                 "rsvg-convert"          => "librsvg2-bin",
 359         );
 360
 361         if ($pdf) {
 362                 check_missing_file(["/usr/share/texlive/texmf-dist/tex/latex/ctex/ctexhook.sty"],
 363                                    "texlive-lang-chinese", 2);
 364
 365                 check_missing_file(["/usr/share/fonts/truetype/dejavu/DejaVuSans.ttf"],
 366                                    "fonts-dejavu", 2);
 367
 368                 check_missing_file(["/usr/share/fonts/noto-cjk/NotoSansCJK-Regular.ttc",
 369                                     "/usr/share/fonts/opentype/noto/NotoSansCJK-Regular.ttc",
 370                                     "/usr/share/fonts/opentype/noto/NotoSerifCJK-Regular.ttc"],
 371                                    "fonts-noto-cjk", 2);
 372         }
 373
 374         check_program("dvipng", 2) if ($pdf);
 375         check_missing(\%map);
 376
 377         return if (!$need && !$optional);
 378         printf("You should run:\n") if ($verbose_warn_install);
 379         printf("\n\tsudo apt-get install $install\n");
 380 }
 381
 382 sub give_redhat_hints()
 383 {
 384         my %map = (
 385                 "python-sphinx"         => "python3-sphinx",
 386                 "yaml"                  => "python3-pyyaml",
 387                 "virtualenv"            => "python3-virtualenv",
 388                 "dot"                   => "graphviz",
 389                 "convert"               => "ImageMagick",
 390                 "Pod::Usage"            => "perl-Pod-Usage",
 391                 "xelatex"               => "texlive-xetex-bin",
 392                 "rsvg-convert"          => "librsvg2-tools",
 393         );
 394
 395         my @fedora26_opt_pkgs = (
 396                 "graphviz-gd",          # Fedora 26: needed for PDF support
 397         );
 398
 399         my @fedora_tex_pkgs = (
 400                 "texlive-collection-fontsrecommended",
 401                 "texlive-collection-latex",
 402                 "texlive-xecjk",
 403                 "dejavu-sans-fonts",
 404                 "dejavu-serif-fonts",
 405                 "dejavu-sans-mono-fonts",
 406         );
 407
 408         #
 409         # Checks valid for RHEL/CentOS version 7.x.
 410         #
 411         my $old = 0;
 412         my $rel;
 413         my $noto_sans_redhat = "google-noto-sans-cjk-ttc-fonts";
 414         $rel = $1 if ($system_release =~ /release\s+(\d+)/);
 415
 416         if (!($system_release =~ /Fedora/)) {
 417                 $map{"virtualenv"} = "python-virtualenv";
 418
 419                 if ($rel && $rel < 8) {
 420                         $old = 1;
 421                         $pdf = 0;
 422
 423                         printf("Note: texlive packages on RHEL/CENTOS <= 7 are incomplete. Can't support PDF output\n");
 424                         printf("If you want to build PDF, please read:\n");
 425                         printf("\thttps://www.systutorials.com/241660/how-to-install-tex-live-on-centos-7-linux/\n");
 426                 }
 427         } else {
 428                 if ($rel && $rel < 26) {
 429                         $old = 1;
 430                 }
 431                 if ($rel && $rel >= 38) {
 432                         $noto_sans_redhat = "google-noto-sans-cjk-fonts";
 433                 }
 434         }
 435         if (!$rel) {
 436                 printf("Couldn't identify release number\n");
 437                 $old = 1;
 438                 $pdf = 0;
 439         }
 440
 441         if ($pdf) {
 442                 check_missing_file(["/usr/share/fonts/google-noto-cjk/NotoSansCJK-Regular.ttc",
 443                                     "/usr/share/fonts/google-noto-sans-cjk-fonts/NotoSansCJK-Regular.ttc"],
 444                                    $noto_sans_redhat, 2);
 445         }
 446
 447         check_rpm_missing(\@fedora26_opt_pkgs, 2) if ($pdf && !$old);
 448         check_rpm_missing(\@fedora_tex_pkgs, 2) if ($pdf);
 449         check_missing_tex(2) if ($pdf);
 450         check_missing(\%map);
 451
 452         return if (!$need && !$optional);
 453
 454         if (!$old) {
 455                 # dnf, for Fedora 18+
 456                 printf("You should run:\n") if ($verbose_warn_install);
 457                 printf("\n\tsudo dnf install -y $install\n");
 458         } else {
 459                 # yum, for RHEL (and clones) or Fedora version < 18
 460                 printf("You should run:\n") if ($verbose_warn_install);
 461                 printf("\n\tsudo yum install -y $install\n");
 462         }
 463 }
 464
 465 sub give_opensuse_hints()
 466 {
 467         my %map = (
 468                 "python-sphinx"         => "python3-sphinx",
 469                 "yaml"                  => "python3-pyyaml",
 470                 "virtualenv"            => "python3-virtualenv",
 471                 "dot"                   => "graphviz",
 472                 "convert"               => "ImageMagick",
 473                 "Pod::Usage"            => "perl-Pod-Usage",
 474                 "xelatex"               => "texlive-xetex-bin",
 475         );
 476
 477         # On Tumbleweed, this package is also named rsvg-convert
 478         $map{"rsvg-convert"} = "rsvg-view" if (!($system_release =~ /Tumbleweed/));
 479
 480         my @suse_tex_pkgs = (
 481                 "texlive-babel-english",
 482                 "texlive-caption",
 483                 "texlive-colortbl",
 484                 "texlive-courier",
 485                 "texlive-dvips",
 486                 "texlive-helvetic",
 487                 "texlive-makeindex",
 488                 "texlive-metafont",
 489                 "texlive-metapost",
 490                 "texlive-palatino",
 491                 "texlive-preview",
 492                 "texlive-times",
 493                 "texlive-zapfchan",
 494                 "texlive-zapfding",
 495         );
 496
 497         $map{"latexmk"} = "texlive-latexmk-bin";
 498
 499         # FIXME: add support for installing CJK fonts
 500         #
 501         # I tried hard, but was unable to find a way to install
 502         # "Noto Sans CJK SC" on openSUSE
 503
 504         check_rpm_missing(\@suse_tex_pkgs, 2) if ($pdf);
 505         check_missing_tex(2) if ($pdf);
 506         check_missing(\%map);
 507
 508         return if (!$need && !$optional);
 509         printf("You should run:\n") if ($verbose_warn_install);
 510         printf("\n\tsudo zypper install --no-recommends $install\n");
 511 }
 512
 513 sub give_mageia_hints()
 514 {
 515         my %map = (
 516                 "python-sphinx"         => "python3-sphinx",
 517                 "yaml"                  => "python3-yaml",
 518                 "virtualenv"            => "python3-virtualenv",
 519                 "dot"                   => "graphviz",
 520                 "convert"               => "ImageMagick",
 521                 "Pod::Usage"            => "perl-Pod-Usage",
 522                 "xelatex"               => "texlive",
 523                 "rsvg-convert"          => "librsvg2",
 524         );
 525
 526         my @tex_pkgs = (
 527                 "texlive-fontsextra",
 528         );
 529
 530         $map{"latexmk"} = "texlive-collection-basic";
 531
 532         my $packager_cmd;
 533         my $noto_sans;
 534         if ($system_release =~ /OpenMandriva/) {
 535                 $packager_cmd = "dnf install";
 536                 $noto_sans = "noto-sans-cjk-fonts";
 537                 @tex_pkgs = ( "texlive-collection-fontsextra" );
 538         } else {
 539                 $packager_cmd = "urpmi";
 540                 $noto_sans = "google-noto-sans-cjk-ttc-fonts";
 541         }
 542
 543
 544         if ($pdf) {
 545                 check_missing_file(["/usr/share/fonts/google-noto-cjk/NotoSansCJK-Regular.ttc",
 546                                     "/usr/share/fonts/TTF/NotoSans-Regular.ttf"],
 547                                    $noto_sans, 2);
 548         }
 549
 550         check_rpm_missing(\@tex_pkgs, 2) if ($pdf);
 551         check_missing(\%map);
 552
 553         return if (!$need && !$optional);
 554         printf("You should run:\n") if ($verbose_warn_install);
 555         printf("\n\tsudo $packager_cmd $install\n");
 556 }
 557
 558 sub give_arch_linux_hints()
 559 {
 560         my %map = (
 561                 "yaml"                  => "python-yaml",
 562                 "virtualenv"            => "python-virtualenv",
 563                 "dot"                   => "graphviz",
 564                 "convert"               => "imagemagick",
 565                 "xelatex"               => "texlive-xetex",
 566                 "latexmk"               => "texlive-core",
 567                 "rsvg-convert"          => "extra/librsvg",
 568         );
 569
 570         my @archlinux_tex_pkgs = (
 571                 "texlive-core",
 572                 "texlive-latexextra",
 573                 "ttf-dejavu",
 574         );
 575         check_pacman_missing(\@archlinux_tex_pkgs, 2) if ($pdf);
 576
 577         if ($pdf) {
 578                 check_missing_file(["/usr/share/fonts/noto-cjk/NotoSansCJK-Regular.ttc"],
 579                                    "noto-fonts-cjk", 2);
 580         }
 581
 582         check_missing(\%map);
 583
 584         return if (!$need && !$optional);
 585         printf("You should run:\n") if ($verbose_warn_install);
 586         printf("\n\tsudo pacman -S $install\n");
 587 }
 588
 589 sub give_gentoo_hints()
 590 {
 591         my %map = (
 592                 "yaml"                  => "dev-python/pyyaml",
 593                 "virtualenv"            => "dev-python/virtualenv",
 594                 "dot"                   => "media-gfx/graphviz",
 595                 "convert"               => "media-gfx/imagemagick",
 596                 "xelatex"               => "dev-texlive/texlive-xetex media-fonts/dejavu",
 597                 "rsvg-convert"          => "gnome-base/librsvg",
 598         );
 599
 600         check_missing_file(["/usr/share/fonts/dejavu/DejaVuSans.ttf"],
 601                            "media-fonts/dejavu", 2) if ($pdf);
 602
 603         if ($pdf) {
 604                 check_missing_file(["/usr/share/fonts/noto-cjk/NotoSansCJKsc-Regular.otf",
 605                                     "/usr/share/fonts/noto-cjk/NotoSerifCJK-Regular.ttc"],
 606                                    "media-fonts/noto-cjk", 2);
 607         }
 608
 609         check_missing(\%map);
 610
 611         return if (!$need && !$optional);
 612
 613         printf("You should run:\n") if ($verbose_warn_install);
 614         printf("\n");
 615
 616         my $imagemagick = "media-gfx/imagemagick svg png";
 617         my $cairo = "media-gfx/graphviz cairo pdf";
 618         my $portage_imagemagick = "/etc/portage/package.use/imagemagick";
 619         my $portage_cairo = "/etc/portage/package.use/graphviz";
 620
 621         if (qx(grep imagemagick $portage_imagemagick 2>/dev/null) eq "") {
 622                 printf("\tsudo su -c 'echo \"$imagemagick\" > $portage_imagemagick'\n")
 623         }
 624         if (qx(grep graphviz $portage_cairo 2>/dev/null) eq  "") {
 625                 printf("\tsudo su -c 'echo \"$cairo\" > $portage_cairo'\n");
 626         }
 627
 628         printf("\tsudo emerge --ask $install\n");
 629
 630 }
 631
 632 sub check_distros()
 633 {
 634         # Distro-specific hints
 635         if ($system_release =~ /Red Hat Enterprise Linux/) {
 636                 give_redhat_hints;
 637                 return;
 638         }
 639         if ($system_release =~ /CentOS/) {
 640                 give_redhat_hints;
 641                 return;
 642         }
 643         if ($system_release =~ /Scientific Linux/) {
 644                 give_redhat_hints;
 645                 return;
 646         }
 647         if ($system_release =~ /Oracle Linux Server/) {
 648                 give_redhat_hints;
 649                 return;
 650         }
 651         if ($system_release =~ /Fedora/) {
 652                 give_redhat_hints;
 653                 return;
 654         }
 655         if ($system_release =~ /Ubuntu/) {
 656                 give_debian_hints;
 657                 return;
 658         }
 659         if ($system_release =~ /Debian/) {
 660                 give_debian_hints;
 661                 return;
 662         }
 663         if ($system_release =~ /openSUSE/) {
 664                 give_opensuse_hints;
 665                 return;
 666         }
 667         if ($system_release =~ /Mageia/) {
 668                 give_mageia_hints;
 669                 return;
 670         }
 671         if ($system_release =~ /OpenMandriva/) {
 672                 give_mageia_hints;
 673                 return;
 674         }
 675         if ($system_release =~ /Arch Linux/) {
 676                 give_arch_linux_hints;
 677                 return;
 678         }
 679         if ($system_release =~ /Gentoo/) {
 680                 give_gentoo_hints;
 681                 return;
 682         }
 683
 684         #
 685         # Fall-back to generic hint code for other distros
 686         # That's far from ideal, specially for LaTeX dependencies.
 687         #
 688         my %map = (
 689                 "sphinx-build" => "sphinx"
 690         );
 691         check_missing_tex(2) if ($pdf);
 692         check_missing(\%map);
 693         print "I don't know distro $system_release.\n";
 694         print "So, I can't provide you a hint with the install procedure.\n";
 695         print "There are likely missing dependencies.\n";
 696 }
 697
 698 #
 699 # Common dependencies
 700 #
 701
 702 sub deactivate_help()
 703 {
 704         printf "\n    If you want to exit the virtualenv, you can use:\n";
 705         printf "\tdeactivate\n";
 706 }
 707
 708 sub get_virtenv()
 709 {
 710         my $ver;
 711         my $min_activate = "$ENV{'PWD'}/${virtenv_prefix}${min_version}/bin/activate";
 712         my @activates = glob "$ENV{'PWD'}/${virtenv_prefix}*/bin/activate";
 713
 714         @activates = sort {$b cmp $a} @activates;
 715
 716         foreach my $f (@activates) {
 717                 next if ($f lt $min_activate);
 718
 719                 my $sphinx_cmd = $f;
 720                 $sphinx_cmd =~ s/activate/sphinx-build/;
 721                 next if (! -f $sphinx_cmd);
 722
 723                 my $ver = get_sphinx_version($sphinx_cmd);
 724
 725                 if (!$ver) {
 726                         $f =~ s#/bin/activate##;
 727                         print("Warning: virtual environment $f is not working.\nPython version upgrade? Remove it with:\n\n\trm -rf $f\n\n");
 728                 }
 729
 730                 if ($need_sphinx && ($ver ge $min_version)) {
 731                         return ($f, $ver);
 732                 } elsif ($ver gt $cur_version) {
 733                         return ($f, $ver);
 734                 }
 735         }
 736         return ("", "");
 737 }
 738
 739 sub recommend_sphinx_upgrade()
 740 {
 741         my $venv_ver;
 742
 743         # Avoid running sphinx-builds from venv if $cur_version is good
 744         if ($cur_version && ($cur_version ge $rec_version)) {
 745                 $latest_avail_ver = $cur_version;
 746                 return;
 747         }
 748
 749         # Get the highest version from sphinx_*/bin/sphinx-build and the
 750         # corresponding command to activate the venv/virtenv
 751         ($activate_cmd, $venv_ver) = get_virtenv();
 752
 753         # Store the highest version from Sphinx existing virtualenvs
 754         if (($activate_cmd ne "") && ($venv_ver gt $cur_version)) {
 755                 $latest_avail_ver = $venv_ver;
 756         } else {
 757                 $latest_avail_ver = $cur_version if ($cur_version);
 758         }
 759
 760         # As we don't know package version of Sphinx, and there's no
 761         # virtual environments, don't check if upgrades are needed
 762         if (!$virtualenv) {
 763                 return if (!$latest_avail_ver);
 764         }
 765
 766         # Either there are already a virtual env or a new one should be created
 767         $need_pip = 1;
 768
 769         return if (!$latest_avail_ver);
 770
 771         # Return if the reason is due to an upgrade or not
 772         if ($latest_avail_ver lt $rec_version) {
 773                 $rec_sphinx_upgrade = 1;
 774         }
 775
 776         return $latest_avail_ver;
 777 }
 778
 779 #
 780 # The logic here is complex, as it have to deal with different versions:
 781 #       - minimal supported version;
 782 #       - minimal PDF version;
 783 #       - recommended version.
 784 # It also needs to work fine with both distro's package and venv/virtualenv
 785 sub recommend_sphinx_version($)
 786 {
 787         my $virtualenv_cmd = shift;
 788
 789         # Version is OK. Nothing to do.
 790         if ($cur_version && ($cur_version ge $rec_version)) {
 791                 return;
 792         };
 793
 794         if (!$need_sphinx) {
 795                 # sphinx-build is present and its version is >= $min_version
 796
 797                 #only recommend enabling a newer virtenv version if makes sense.
 798                 if ($latest_avail_ver gt $cur_version) {
 799                         printf "\nYou may also use the newer Sphinx version $latest_avail_ver with:\n";
 800                         printf "\tdeactivate\n"  if ($ENV{'PWD'} =~ /${virtenv_prefix}/);
 801                         printf "\t. $activate_cmd\n";
 802                         deactivate_help();
 803
 804                         return;
 805                 }
 806                 return if ($latest_avail_ver ge $rec_version);
 807         }
 808
 809         if (!$virtualenv) {
 810                 # No sphinx either via package or via virtenv. As we can't
 811                 # Compare the versions here, just return, recommending the
 812                 # user to install it from the package distro.
 813                 return if (!$latest_avail_ver);
 814
 815                 # User doesn't want a virtenv recommendation, but he already
 816                 # installed one via virtenv with a newer version.
 817                 # So, print commands to enable it
 818                 if ($latest_avail_ver gt $cur_version) {
 819                         printf "\nYou may also use the Sphinx virtualenv version $latest_avail_ver with:\n";
 820                         printf "\tdeactivate\n"  if ($ENV{'PWD'} =~ /${virtenv_prefix}/);
 821                         printf "\t. $activate_cmd\n";
 822                         deactivate_help();
 823
 824                         return;
 825                 }
 826                 print "\n";
 827         } else {
 828                 $need++ if ($need_sphinx);
 829         }
 830
 831         # Suggest newer versions if current ones are too old
 832         if ($latest_avail_ver && $latest_avail_ver ge $min_version) {
 833                 # If there's a good enough version, ask the user to enable it
 834                 if ($latest_avail_ver ge $rec_version) {
 835                         printf "\nNeed to activate Sphinx (version $latest_avail_ver) on virtualenv with:\n";
 836                         printf "\t. $activate_cmd\n";
 837                         deactivate_help();
 838
 839                         return;
 840                 }
 841
 842                 # Version is above the minimal required one, but may be
 843                 # below the recommended one. So, print warnings/notes
 844
 845                 if ($latest_avail_ver lt $rec_version) {
 846                         print "Warning: It is recommended at least Sphinx version $rec_version.\n";
 847                 }
 848         }
 849
 850         # At this point, either it needs Sphinx or upgrade is recommended,
 851         # both via pip
 852
 853         if ($rec_sphinx_upgrade) {
 854                 if (!$virtualenv) {
 855                         print "Instead of install/upgrade Python Sphinx pkg, you could use pip/pypi with:\n\n";
 856                 } else {
 857                         print "To upgrade Sphinx, use:\n\n";
 858                 }
 859         } else {
 860                 print "\nSphinx needs to be installed either:\n1) via pip/pypi with:\n\n";
 861         }
 862
 863         $python_cmd = find_python_no_venv();
 864
 865         printf "\t$virtualenv_cmd $virtenv_dir\n";
 866
 867         printf "\t. $virtenv_dir/bin/activate\n";
 868         printf "\tpip install -r $requirement_file\n";
 869         deactivate_help();
 870
 871         printf "\n2) As a package with:\n";
 872
 873         my $old_need = $need;
 874         my $old_optional = $optional;
 875         %missing = ();
 876         $pdf = 0;
 877         $optional = 0;
 878         $install = "";
 879         $verbose_warn_install = 0;
 880
 881         add_package("python-sphinx", 0);
 882
 883         check_distros();
 884
 885         $need = $old_need;
 886         $optional = $old_optional;
 887
 888         printf "\n    Please note that Sphinx >= 3.0 will currently produce false-positive\n";
 889         printf "   warning when the same name is used for more than one type (functions,\n";
 890         printf "   structs, enums,...). This is known Sphinx bug. For more details, see:\n";
 891         printf "\thttps://github.com/sphinx-doc/sphinx/pull/8313\n";
 892 }
 893
 894 sub check_needs()
 895 {
 896         # Check if Sphinx is already accessible from current environment
 897         check_sphinx();
 898
 899         if ($system_release) {
 900                 print "Detected OS: $system_release.\n";
 901         } else {
 902                 print "Unknown OS\n";
 903         }
 904         printf "Sphinx version: %s\n\n", $cur_version if ($cur_version);
 905
 906         # Check python command line, trying first python3
 907         $python_cmd = findprog("python3");
 908         $python_cmd = check_program("python", 0) if (!$python_cmd);
 909
 910         # Check the type of virtual env, depending on Python version
 911         if ($python_cmd) {
 912                 if ($virtualenv) {
 913                         my $tmp = qx($python_cmd --version 2>&1);
 914                         if ($tmp =~ m/(\d+\.)(\d+\.)/) {
 915                                 if ($1 < 3) {
 916                                         # Fail if it finds python2 (or worse)
 917                                         die "Python 3 is required to build the kernel docs\n";
 918                                 }
 919                                 if ($1 == 3 && $2 < 3) {
 920                                         # Need Python 3.3 or upper for venv
 921                                         $need_virtualenv = 1;
 922                                 }
 923                         } else {
 924                                 die "Warning: couldn't identify $python_cmd version!";
 925                         }
 926                 } else {
 927                         add_package("python-sphinx", 0);
 928                 }
 929         }
 930
 931         my $venv_ver = recommend_sphinx_upgrade();
 932
 933         my $virtualenv_cmd;
 934
 935         if ($need_pip) {
 936                 # Set virtualenv command line, if python < 3.3
 937                 if ($need_virtualenv) {
 938                         $virtualenv_cmd = findprog("virtualenv-3");
 939                         $virtualenv_cmd = findprog("virtualenv-3.5") if (!$virtualenv_cmd);
 940                         if (!$virtualenv_cmd) {
 941                                 check_program("virtualenv", 0);
 942                                 $virtualenv_cmd = "virtualenv";
 943                         }
 944                 } else {
 945                         $virtualenv_cmd = "$python_cmd -m venv";
 946                         check_python_module("ensurepip", 0);
 947                 }
 948         }
 949
 950         # Check for needed programs/tools
 951         check_perl_module("Pod::Usage", 0);
 952         check_python_module("yaml", 0);
 953         check_program("make", 0);
 954         check_program("gcc", 0);
 955         check_program("dot", 1);
 956         check_program("convert", 1);
 957
 958         # Extra PDF files - should use 2 for is_optional
 959         check_program("xelatex", 2) if ($pdf);
 960         check_program("rsvg-convert", 2) if ($pdf);
 961         check_program("latexmk", 2) if ($pdf);
 962
 963         # Do distro-specific checks and output distro-install commands
 964         check_distros();
 965
 966         if (!$python_cmd) {
 967                 if ($need == 1) {
 968                         die "Can't build as $need mandatory dependency is missing";
 969                 } elsif ($need) {
 970                         die "Can't build as $need mandatory dependencies are missing";
 971                 }
 972         }
 973
 974         # Check if sphinx-build is called sphinx-build-3
 975         if ($need_symlink) {
 976                 printf "\tsudo ln -sf %s /usr/bin/sphinx-build\n\n",
 977                        which("sphinx-build-3");
 978         }
 979
 980         recommend_sphinx_version($virtualenv_cmd);
 981         printf "\n";
 982
 983         print "All optional dependencies are met.\n" if (!$optional);
 984
 985         if ($need == 1) {
 986                 die "Can't build as $need mandatory dependency is missing";
 987         } elsif ($need) {
 988                 die "Can't build as $need mandatory dependencies are missing";
 989         }
 990
 991         print "Needed package dependencies are met.\n";
 992 }
 993
 994 #
 995 # Main
 996 #
 997
 998 while (@ARGV) {
 999         my $arg = shift(@ARGV);
1000
1001         if ($arg eq "--no-virtualenv") {
1002                 $virtualenv = 0;
1003         } elsif ($arg eq "--no-pdf"){
1004                 $pdf = 0;
1005         } elsif ($arg eq "--version-check"){
1006                 $version_check = 1;
1007         } else {
1008                 print "Usage:\n\t$0 <--no-virtualenv> <--no-pdf> <--version-check>\n\n";
1009                 print "Where:\n";
1010                 print "\t--no-virtualenv\t- Recommend installing Sphinx instead of using a virtualenv\n";
1011                 print "\t--version-check\t- if version is compatible, don't check for missing dependencies\n";
1012                 print "\t--no-pdf\t- don't check for dependencies required to build PDF docs\n\n";
1013                 exit -1;
1014         }
1015 }
1016
1017 #
1018 # Determine the system type. There's no standard unique way that would
1019 # work with all distros with a minimal package install. So, several
1020 # methods are used here.
1021 #
1022 # By default, it will use lsb_release function. If not available, it will
1023 # fail back to reading the known different places where the distro name
1024 # is stored
1025 #
1026
1027 $system_release = qx(lsb_release -d) if which("lsb_release");
1028 $system_release =~ s/Description:\s*// if ($system_release);
1029 $system_release = catcheck("/etc/system-release") if !$system_release;
1030 $system_release = catcheck("/etc/redhat-release") if !$system_release;
1031 $system_release = catcheck("/etc/lsb-release") if !$system_release;
1032 $system_release = catcheck("/etc/gentoo-release") if !$system_release;
1033
1034 # This seems more common than LSB these days
1035 if (!$system_release) {
1036         my %os_var;
1037         if (open IN, "cat /etc/os-release|") {
1038                 while (<IN>) {
1039                         if (m/^([\w\d\_]+)=\"?([^\"]*)\"?\n/) {
1040                                 $os_var{$1}=$2;
1041                         }
1042                 }
1043                 $system_release = $os_var{"NAME"};
1044                 if (defined($os_var{"VERSION_ID"})) {
1045                         $system_release .= " " . $os_var{"VERSION_ID"} if (defined($os_var{"VERSION_ID"}));
1046                 } else {
1047                         $system_release .= " " . $os_var{"VERSION"};
1048                 }
1049         }
1050 }
1051 $system_release = catcheck("/etc/issue") if !$system_release;
1052 $system_release =~ s/\s+$//;
1053
1054 check_needs;