configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011, 2012,
   3 #   2014, 2015, 2016, 2019, 2020 Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include(config/debuginfod.m4)
  27 m4_include([libtool.m4])
  28 m4_include([ltoptions.m4])
  29 m4_include([ltsugar.m4])
  30 m4_include([ltversion.m4])
  31 m4_include([lt~obsolete.m4])
  32 m4_include([config/isl.m4])
  33
  34 AC_INIT(move-if-change)
  35 AC_DISABLE_OPTION_CHECKING
  36
  37 progname=$0
  38 # if PWD already has a value, it is probably wrong.
  39 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  40
  41 # Export original configure arguments for use by sub-configures.
  42 # Quote arguments with shell meta charatcers.
  43 TOPLEVEL_CONFIGURE_ARGUMENTS=
  44 set -- "$progname" "$@"
  45 for ac_arg
  46 do
  47   case "$ac_arg" in
  48   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  49     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  50     # if the argument is of the form -foo=baz, quote the baz part only
  51     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  52   *) ;;
  53   esac
  54   # Add the quoted argument to the list.
  55   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  56 done
  57 if test "$silent" = yes; then
  58   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  59 fi
  60 # Remove the initial space we just introduced and, as these will be
  61 # expanded by make, quote '$'.
  62 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  63 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  64
  65 # Find the build, host, and target systems.
  66 ACX_NONCANONICAL_BUILD
  67 ACX_NONCANONICAL_HOST
  68 ACX_NONCANONICAL_TARGET
  69
  70 dnl Autoconf 2.5x and later will set a default program prefix if
  71 dnl --target was used, even if it was the same as --host.  Disable
  72 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  73 dnl to take effect.
  74 test "$host_noncanonical" = "$target_noncanonical" &&
  75   test "$program_prefix$program_suffix$program_transform_name" = \
  76     NONENONEs,x,x, &&
  77   program_transform_name=s,y,y,
  78
  79 AC_CANONICAL_SYSTEM
  80 AC_ARG_PROGRAM
  81
  82 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  83 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  84
  85 # Get 'install' or 'install-sh' and its variants.
  86 AC_PROG_INSTALL
  87 ACX_PROG_LN
  88 AC_PROG_LN_S
  89 AC_PROG_SED
  90 AC_PROG_AWK
  91
  92 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
  93
  94 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
  95 # a relative path.
  96 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
  97   INSTALL="${srcpwd}/install-sh -c"
  98 fi
  99
 100 # Set srcdir to "." if that's what it is.
 101 # This is important for multilib support.
 102 pwd=`${PWDCMD-pwd}`
 103 if test "${pwd}" = "${srcpwd}" ; then
 104   srcdir=.
 105 fi
 106
 107 topsrcdir=$srcpwd
 108
 109 extra_host_args=
 110
 111 ### To add a new directory to the tree, first choose whether it is a target
 112 ### or a host dependent tool.  Then put it into the appropriate list
 113 ### (library or tools, host or target), doing a dependency sort.
 114
 115 # Subdirs will be configured in the order listed in build_configdirs,
 116 # configdirs, or target_configdirs; see the serialization section below.
 117
 118 # Dependency sorting is only needed when *configuration* must be done in
 119 # a particular order.  In all cases a dependency should be specified in
 120 # the Makefile, whether or not it's implicitly specified here.
 121
 122 # Double entries in build_configdirs, configdirs, or target_configdirs may
 123 # cause circular dependencies and break everything horribly.
 124
 125 # these library is used by various programs built for the build
 126 # environment
 127 #
 128 build_libs="build-libiberty build-libcpp"
 129
 130 # these tools are built for the build environment
 131 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
 132
 133 # these libraries are used by various programs built for the host environment
 134 #f
 135 host_libs="intl libiberty opcodes bfd readline tcl tk itcl libgui zlib libbacktrace libcpp libdecnumber gmp mpfr mpc isl libelf libiconv libctf"
 136
 137 # these tools are built for the host environment
 138 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 139 # know that we are building the simulator.
 140 # binutils, gas and ld appear in that order because it makes sense to run
 141 # "make check" in that particular order.
 142 # If --enable-gold is used, "gold" may replace "ld".
 143 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gdbserver gprof etc expect dejagnu m4 utils guile fastjar gnattools libcc1 gotools"
 144
 145 # these libraries are built for the target environment, and are built after
 146 # the host libraries and the host tools (which may be a cross compiler)
 147 # Note that libiberty is not a target library.
 148 target_libraries="target-libgcc \
 149                 target-libbacktrace \
 150                 target-libgloss \
 151                 target-newlib \
 152                 target-libgomp \
 153                 target-liboffloadmic \
 154                 target-libhsail-rt \
 155                 target-libatomic \
 156                 target-libitm \
 157                 target-libstdc++-v3 \
 158                 target-libsanitizer \
 159                 target-libvtv \
 160                 target-libssp \
 161                 target-libquadmath \
 162                 target-libgfortran \
 163                 target-libffi \
 164                 target-libobjc \
 165                 target-libada \
 166                 target-libgo"
 167
 168 # these tools are built using the target libraries, and are intended to
 169 # run only in the target environment
 170 #
 171 # note: any program that *uses* libraries that are in the "target_libraries"
 172 # list belongs in this list.
 173 #
 174 target_tools="target-rda"
 175
 176 ################################################################################
 177
 178 ## All tools belong in one of the four categories, and are assigned above
 179 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 180 ## is important because configure will choke if they ever get through.
 181 ## ${configdirs} is directories we build using the host tools.
 182 ## ${target_configdirs} is directories we build using the target tools.
 183 configdirs=`echo ${host_libs} ${host_tools}`
 184 target_configdirs=`echo ${target_libraries} ${target_tools}`
 185 build_configdirs=`echo ${build_libs} ${build_tools}`
 186
 187 m4_divert_text([PARSE_ARGS],
 188 [case $srcdir in
 189   *" "*)
 190 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 191     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 192 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 193     ;;
 194 esac
 195 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 196 ])
 197
 198 ################################################################################
 199
 200 srcname="gnu development package"
 201
 202 # This gets set non-empty for some net releases of packages.
 203 appdirs=""
 204
 205 # Define is_cross_compiler to save on calls to 'test'.
 206 is_cross_compiler=
 207 if test x"${host}" = x"${target}" ; then
 208   is_cross_compiler=no
 209 else
 210   is_cross_compiler=yes
 211 fi
 212
 213 # Find the build and target subdir names.
 214 GCC_TOPLEV_SUBDIRS
 215 # Be sure to cover against remnants of an in-tree build.
 216 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 217   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 218 Use a pristine source tree when building in a separate tree])
 219 fi
 220
 221 # Skipdirs are removed silently.
 222 skipdirs=
 223 # Noconfigdirs are removed loudly.
 224 noconfigdirs=""
 225
 226 use_gnu_ld=
 227 # Make sure we don't let GNU ld be added if we didn't want it.
 228 if test x$with_gnu_ld = xno ; then
 229   use_gnu_ld=no
 230   noconfigdirs="$noconfigdirs ld gold"
 231 fi
 232
 233 use_gnu_as=
 234 # Make sure we don't let GNU as be added if we didn't want it.
 235 if test x$with_gnu_as = xno ; then
 236   use_gnu_as=no
 237   noconfigdirs="$noconfigdirs gas"
 238 fi
 239
 240 use_included_zlib=
 241 AC_ARG_WITH(system-zlib,
 242 [AS_HELP_STRING([--with-system-zlib], [use installed libz])])
 243 # Make sure we don't let ZLIB be added if we didn't want it.
 244 if test x$with_system_zlib = xyes ; then
 245   use_included_zlib=no
 246   noconfigdirs="$noconfigdirs zlib"
 247 fi
 248
 249 # Don't compile the bundled readline/libreadline.a if --with-system-readline
 250 # is provided.
 251 if test x$with_system_readline = xyes ; then
 252   noconfigdirs="$noconfigdirs readline"
 253 fi
 254
 255 # some tools are so dependent upon X11 that if we're not building with X,
 256 # it's not even worth trying to configure, much less build, that tool.
 257
 258 case ${with_x} in
 259   yes | "") ;; # the default value for this tree is that X11 is available
 260   no)
 261     skipdirs="${skipdirs} tk itcl libgui"
 262     # We won't be able to build gdbtk without X.
 263     enable_gdbtk=no
 264     ;;
 265   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 266 esac
 267
 268 # Some are only suitable for cross toolchains.
 269 # Remove these if host=target.
 270 cross_only="target-libgloss target-newlib target-opcodes"
 271
 272 case $is_cross_compiler in
 273   no) skipdirs="${skipdirs} ${cross_only}" ;;
 274 esac
 275
 276 # If both --with-headers and --with-libs are specified, default to
 277 # --without-newlib.
 278 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 279    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 280   if test x"${with_newlib}" = x ; then
 281     with_newlib=no
 282   fi
 283 fi
 284
 285 # Recognize --with-newlib/--without-newlib.
 286 case ${with_newlib} in
 287   no) skipdirs="${skipdirs} target-newlib" ;;
 288   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 289 esac
 290
 291 AC_ARG_ENABLE(as-accelerator-for,
 292 [AS_HELP_STRING([--enable-as-accelerator-for=ARG],
 293                 [build as offload target compiler.
 294                 Specify offload host triple by ARG])])
 295
 296 AC_ARG_ENABLE(offload-targets,
 297 [AS_HELP_STRING([--enable-offload-targets=LIST],
 298                 [enable offloading to devices from comma-separated LIST of
 299                 TARGET[=DIR]. Use optional path to find offload target compiler
 300                 during the build])],
 301 [
 302   if test x"$enable_offload_targets" = x; then
 303     AC_MSG_ERROR([no offload targets specified])
 304   fi
 305 ], [enable_offload_targets=])
 306
 307 # Handle --enable-gold, --enable-ld.
 308 # --disable-gold [--enable-ld]
 309 #     Build only ld.  Default option.
 310 # --enable-gold [--enable-ld]
 311 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 312 #     as "ld.bfd" and "ld".
 313 # --enable-gold=default [--enable-ld]
 314 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 315 #     install ld as "ld.bfd".
 316 # --enable-gold[=default] --disable-ld
 317 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 318 # --enable-gold --enable-ld=default
 319 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 320 #     and ld.bfd).
 321 #     In other words, ld is default
 322 # --enable-gold=default --enable-ld=default
 323 #     Error.
 324
 325 default_ld=
 326 AC_ARG_ENABLE(gold,
 327 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 328                 [build gold @<:@ARG={default,yes,no}@:>@])],
 329 ENABLE_GOLD=$enableval,
 330 ENABLE_GOLD=no)
 331 case "${ENABLE_GOLD}" in
 332   yes|default)
 333     # Check for ELF target.
 334     is_elf=no
 335     case "${target}" in
 336       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 337       | *-*-linux* | *-*-gnu* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 338       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 339       | *-*-solaris2* | *-*-nto* | *-*-nacl*)
 340         case "${target}" in
 341           *-*-linux*aout* | *-*-linux*oldld*)
 342             ;;
 343           *)
 344             is_elf=yes
 345             ;;
 346         esac
 347     esac
 348
 349     if test "$is_elf" = "yes"; then
 350       # Check for target supported by gold.
 351       case "${target}" in
 352         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-* \
 353         | aarch64*-*-* | tilegx*-*-* | mips*-*-* | s390*-*-*)
 354           configdirs="$configdirs gold"
 355           if test x${ENABLE_GOLD} = xdefault; then
 356             default_ld=gold
 357           fi
 358           ENABLE_GOLD=yes
 359           ;;
 360       esac
 361     fi
 362     ;;
 363   no)
 364     ;;
 365   *)
 366     AC_MSG_ERROR([invalid --enable-gold argument])
 367     ;;
 368 esac
 369
 370 AC_ARG_ENABLE(ld,
 371 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 372                 [build ld @<:@ARG={default,yes,no}@:>@])],
 373 ENABLE_LD=$enableval,
 374 ENABLE_LD=yes)
 375
 376 case "${ENABLE_LD}" in
 377   default)
 378     if test x${default_ld} != x; then
 379       AC_MSG_ERROR([either gold or ld can be the default ld])
 380     fi
 381     ;;
 382   yes)
 383     ;;
 384   no)
 385     if test x${ENABLE_GOLD} != xyes; then
 386       AC_MSG_WARN([neither ld nor gold are enabled])
 387     fi
 388     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 389     ;;
 390   *)
 391     AC_MSG_ERROR([invalid --enable-ld argument])
 392     ;;
 393 esac
 394
 395 # PR gas/19109
 396 # Decide the default method for compressing debug sections.
 397 # Provide a configure time option to override our default.
 398 AC_ARG_ENABLE(compressed_debug_sections,
 399 [AS_HELP_STRING([--enable-compressed-debug-sections={all,gas,gold,ld,none}],
 400                 [Enable compressed debug sections for gas, gold or ld by
 401                  default])],
 402 [
 403   if test x"$enable_compressed_debug_sections" = xyes; then
 404     AC_MSG_ERROR([no program with compressed debug sections specified])
 405   fi
 406 ], [enable_compressed_debug_sections=])
 407
 408 # Configure extra directories which are host specific
 409
 410 case "${host}" in
 411   *-cygwin*)
 412     configdirs="$configdirs libtermcap" ;;
 413 esac
 414
 415 # A target can indicate whether a language isn't supported for some reason.
 416 # Only spaces may be used in this macro; not newlines or tabs.
 417 unsupported_languages=
 418
 419 # Remove more programs from consideration, based on the host or
 420 # target this usually means that a port of the program doesn't
 421 # exist yet.
 422
 423 case "${host}" in
 424   i[[3456789]]86-*-msdosdjgpp*)
 425     noconfigdirs="$noconfigdirs tcl tk itcl"
 426     ;;
 427 esac
 428
 429
 430 AC_ARG_ENABLE(libquadmath,
 431 AS_HELP_STRING([--disable-libquadmath],
 432   [do not build libquadmath directory]),
 433 ENABLE_LIBQUADMATH=$enableval,
 434 ENABLE_LIBQUADMATH=yes)
 435 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 436   noconfigdirs="$noconfigdirs target-libquadmath"
 437 fi
 438
 439
 440 AC_ARG_ENABLE(libquadmath-support,
 441 AS_HELP_STRING([--disable-libquadmath-support],
 442   [disable libquadmath support for Fortran]),
 443 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 444 ENABLE_LIBQUADMATH_SUPPORT=yes)
 445 enable_libquadmath_support=
 446 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 447   enable_libquadmath_support=no
 448 fi
 449
 450
 451 AC_ARG_ENABLE(libada,
 452 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 453 ENABLE_LIBADA=$enableval,
 454 ENABLE_LIBADA=yes)
 455 if test "${ENABLE_LIBADA}" != "yes" ; then
 456   noconfigdirs="$noconfigdirs gnattools"
 457 fi
 458
 459 AC_ARG_ENABLE(libssp,
 460 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 461 ENABLE_LIBSSP=$enableval,
 462 ENABLE_LIBSSP=yes)
 463
 464 AC_ARG_ENABLE(libstdcxx,
 465 AS_HELP_STRING([--disable-libstdcxx],
 466   [do not build libstdc++-v3 directory]),
 467 ENABLE_LIBSTDCXX=$enableval,
 468 ENABLE_LIBSTDCXX=default)
 469 [if test "${ENABLE_LIBSTDCXX}" = "no" ; then
 470   noconfigdirs="$noconfigdirs target-libstdc++-v3"
 471 fi]
 472
 473 # If this is accelerator compiler and its target is intelmic we enable
 474 # target liboffloadmic by default.  If this is compiler with offloading
 475 # for intelmic we enable host liboffloadmic by default.  Otherwise
 476 # liboffloadmic is disabled by default.
 477 AC_ARG_ENABLE([liboffloadmic],
 478 AC_HELP_STRING([[--enable-liboffloadmic[=ARG]]],
 479                [build liboffloadmic @<:@ARG={no,host,target}@:>@]),
 480 [case "$enableval" in
 481   no | host | target)
 482     enable_liboffloadmic=$enableval ;;
 483   *)
 484     AC_MSG_ERROR([--enable-liboffloadmic=no/host/target]) ;;
 485 esac],
 486 [if test x"$enable_as_accelerator_for" != x; then
 487   case "${target}" in
 488     *-intelmic-* | *-intelmicemul-*)
 489       enable_liboffloadmic=target
 490       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=target"
 491       ;;
 492     *)
 493       enable_liboffloadmic=no
 494       ;;
 495   esac
 496 else
 497   case "${enable_offload_targets}" in
 498     *-intelmic-* | *-intelmicemul-*)
 499       enable_liboffloadmic=host
 500       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=host"
 501       ;;
 502     *)
 503       enable_liboffloadmic=no
 504       ;;
 505     esac
 506 fi])
 507 AC_SUBST(extra_liboffloadmic_configure_flags)
 508
 509 # Enable libgomp by default on hosted POSIX systems, and a few others.
 510 if test x$enable_libgomp = x ; then
 511     case "${target}" in
 512     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 513         ;;
 514     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 515         ;;
 516     *-*-solaris2* | *-*-hpux11*)
 517         ;;
 518     *-*-darwin* | *-*-aix*)
 519         ;;
 520     nvptx*-*-*)
 521         ;;
 522     *)
 523         noconfigdirs="$noconfigdirs target-libgomp"
 524         ;;
 525     esac
 526 fi
 527
 528 # Disable libatomic on unsupported systems.
 529 if test -d ${srcdir}/libatomic; then
 530     if test x$enable_libatomic = x; then
 531         AC_MSG_CHECKING([for libatomic support])
 532         if (srcdir=${srcdir}/libatomic; \
 533                 . ${srcdir}/configure.tgt; \
 534                 test -n "$UNSUPPORTED")
 535         then
 536             AC_MSG_RESULT([no])
 537             noconfigdirs="$noconfigdirs target-libatomic"
 538         else
 539             AC_MSG_RESULT([yes])
 540         fi
 541     fi
 542 fi
 543
 544 # Disable liboffloadmic on unsupported systems.
 545 if test -d ${srcdir}/liboffloadmic; then
 546     if test x$enable_liboffloadmic != xno; then
 547         AC_MSG_CHECKING([for liboffloadmic support])
 548         if (srcdir=${srcdir}/liboffloadmic; \
 549                 . ${srcdir}/configure.tgt; \
 550                 test -n "$UNSUPPORTED")
 551         then
 552             AC_MSG_RESULT([no])
 553             noconfigdirs="$noconfigdirs target-liboffloadmic"
 554         else
 555             AC_MSG_RESULT([yes])
 556         fi
 557     fi
 558 fi
 559
 560 # Disable libitm on unsupported systems.
 561 if test -d ${srcdir}/libitm; then
 562     if test x$enable_libitm = x; then
 563         AC_MSG_CHECKING([for libitm support])
 564         if (srcdir=${srcdir}/libitm; \
 565                 . ${srcdir}/configure.tgt; \
 566                 test -n "$UNSUPPORTED")
 567         then
 568             AC_MSG_RESULT([no])
 569             noconfigdirs="$noconfigdirs target-libitm"
 570         else
 571             AC_MSG_RESULT([yes])
 572         fi
 573     fi
 574 fi
 575
 576 # Disable libsanitizer on unsupported systems.
 577 if test -d ${srcdir}/libsanitizer; then
 578     if test x$enable_libsanitizer = x; then
 579         AC_MSG_CHECKING([for libsanitizer support])
 580         if (srcdir=${srcdir}/libsanitizer; \
 581                 . ${srcdir}/configure.tgt; \
 582                 test -n "$UNSUPPORTED")
 583         then
 584             AC_MSG_RESULT([no])
 585             noconfigdirs="$noconfigdirs target-libsanitizer"
 586         else
 587             AC_MSG_RESULT([yes])
 588         fi
 589     fi
 590 fi
 591
 592 # Disable libvtv on unsupported systems.
 593 if test -d ${srcdir}/libvtv; then
 594     if test x$enable_libvtv = x; then
 595         AC_MSG_CHECKING([for libvtv support])
 596         if (srcdir=${srcdir}/libvtv; \
 597                 . ${srcdir}/configure.tgt; \
 598                 test "$VTV_SUPPORTED" != "yes")
 599         then
 600             AC_MSG_RESULT([no])
 601             noconfigdirs="$noconfigdirs target-libvtv"
 602         else
 603             AC_MSG_RESULT([yes])
 604         fi
 605     fi
 606 fi
 607
 608
 609 # Disable libhsail-rt on unsupported systems.
 610 if test -d ${srcdir}/libhsail-rt; then
 611     if test x$enable_libhsail_rt = x; then
 612         AC_MSG_CHECKING([for libhsail-rt support])
 613         if (srcdir=${srcdir}/libhsail-rt; \
 614                 . ${srcdir}/configure.tgt; \
 615                 test -n "$UNSUPPORTED")
 616         then
 617             AC_MSG_RESULT([no])
 618             unsupported_languages="$unsupported_languages brig"
 619             # This implicitly disables also target-libhsail-rt as it won't
 620             # get added to the build without BRIG FE.
 621         else
 622             AC_MSG_RESULT([yes])
 623         fi
 624     fi
 625 fi
 626
 627
 628 # Disable libquadmath for some systems.
 629 case "${target}" in
 630   avr-*-*)
 631     noconfigdirs="$noconfigdirs target-libquadmath"
 632     ;;
 633   # libquadmath is unused on AIX and libquadmath build process use of
 634   # LD_LIBRARY_PATH can break AIX bootstrap.
 635   powerpc-*-aix* | rs6000-*-aix*)
 636     noconfigdirs="$noconfigdirs target-libquadmath"
 637     ;;
 638 esac
 639
 640 # Disable libssp for some systems.
 641 case "${target}" in
 642   avr-*-*)
 643     # No hosted I/O support.
 644     noconfigdirs="$noconfigdirs target-libssp"
 645     ;;
 646   powerpc-*-aix* | rs6000-*-aix*)
 647     noconfigdirs="$noconfigdirs target-libssp"
 648     ;;
 649   rl78-*-*)
 650     # libssp uses a misaligned load to trigger a fault, but the RL78
 651     # doesn't fault for those - instead, it gives a build-time error
 652     # for explicit misaligned loads.
 653     noconfigdirs="$noconfigdirs target-libssp"
 654     ;;
 655   visium-*-*)
 656     # No hosted I/O support.
 657     noconfigdirs="$noconfigdirs target-libssp"
 658     ;;
 659 esac
 660
 661 # Disable libstdc++-v3 for some systems.
 662 # Allow user to override this if they pass --enable-libstdc++-v3
 663 if test "${ENABLE_LIBSTDCXX}" = "default" ; then
 664   case "${target}" in
 665     *-*-vxworks*)
 666       # VxWorks uses the Dinkumware C++ library.
 667       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 668       ;;
 669     arm*-wince-pe*)
 670       # the C++ libraries don't build on top of CE's C libraries
 671       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 672       ;;
 673     avr-*-*)
 674       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 675       ;;
 676     ft32-*-*)
 677       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 678       ;;
 679   esac
 680 fi
 681
 682 # Disable Fortran for some systems.
 683 case "${target}" in
 684   mmix-*-*)
 685     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 686     unsupported_languages="$unsupported_languages fortran"
 687     ;;
 688 esac
 689
 690 # Disable libffi for some systems.
 691 case "${target}" in
 692   powerpc-*-darwin*)
 693     ;;
 694   i[[3456789]]86-*-darwin*)
 695     ;;
 696   x86_64-*-darwin[[912]]*)
 697     ;;
 698   *-*-darwin*)
 699     noconfigdirs="$noconfigdirs target-libffi"
 700     ;;
 701   *-*-netware*)
 702     noconfigdirs="$noconfigdirs target-libffi"
 703     ;;
 704   *-*-phoenix*)
 705     noconfigdirs="$noconfigdirs target-libffi"
 706     ;;
 707   *-*-rtems*)
 708     noconfigdirs="$noconfigdirs target-libffi"
 709     ;;
 710   *-*-tpf*)
 711     noconfigdirs="$noconfigdirs target-libffi"
 712     ;;
 713   *-*-uclinux*)
 714     noconfigdirs="$noconfigdirs target-libffi"
 715     ;;
 716   *-*-vxworks*)
 717     noconfigdirs="$noconfigdirs target-libffi"
 718     ;;
 719   aarch64*-*-freebsd*)
 720     noconfigdirs="$noconfigdirs target-libffi"
 721     ;;
 722   alpha*-*-*vms*)
 723     noconfigdirs="$noconfigdirs target-libffi"
 724     ;;
 725   arm*-*-freebsd*)
 726     noconfigdirs="$noconfigdirs target-libffi"
 727     ;;
 728   arm-wince-pe)
 729     noconfigdirs="$noconfigdirs target-libffi"
 730     ;;
 731   arm*-*-symbianelf*)
 732     noconfigdirs="$noconfigdirs target-libffi"
 733     ;;
 734   cris-*-* | crisv32-*-*)
 735     case "${target}" in
 736       *-*-linux*)
 737         ;;
 738       *) # See PR46792 regarding target-libffi.
 739         noconfigdirs="$noconfigdirs target-libffi";;
 740     esac
 741     ;;
 742   hppa*64*-*-hpux*)
 743     noconfigdirs="$noconfigdirs target-libffi"
 744     ;;
 745   hppa*-hp-hpux11*)
 746     ;;
 747   hppa*-*-hpux*)
 748     noconfigdirs="$noconfigdirs target-libffi"
 749     ;;
 750   ia64*-*-*vms*)
 751     noconfigdirs="$noconfigdirs target-libffi"
 752     ;;
 753   i[[3456789]]86-w64-mingw*)
 754     noconfigdirs="$noconfigdirs target-libffi"
 755     ;;
 756   i[[3456789]]86-*-mingw*)
 757     noconfigdirs="$noconfigdirs target-libffi"
 758     ;;
 759   x86_64-*-mingw*)
 760     noconfigdirs="$noconfigdirs target-libffi"
 761     ;;
 762   mmix-*-*)
 763     noconfigdirs="$noconfigdirs target-libffi"
 764     ;;
 765   powerpc-*-aix*)
 766     ;;
 767   rs6000-*-aix*)
 768     ;;
 769   ft32-*-*)
 770     noconfigdirs="$noconfigdirs target-libffi"
 771     ;;
 772   *-*-lynxos*)
 773     noconfigdirs="$noconfigdirs target-libffi"
 774     ;;
 775 esac
 776
 777 # Disable the go frontend on systems where it is known to not work. Please keep
 778 # this in sync with contrib/config-list.mk.
 779 case "${target}" in
 780 *-*-darwin* | *-*-cygwin* | *-*-mingw*)
 781     unsupported_languages="$unsupported_languages go"
 782     ;;
 783 esac
 784
 785 # Only allow gdbserver on some systems.
 786 if test -d ${srcdir}/gdbserver; then
 787     if test x$enable_gdbserver = x; then
 788         AC_MSG_CHECKING([for gdbserver support])
 789         if (srcdir=${srcdir}/gdbserver; \
 790                 . ${srcdir}/configure.srv; \
 791                 test -n "$UNSUPPORTED")
 792         then
 793             AC_MSG_RESULT([no])
 794             noconfigdirs="$noconfigdirs gdbserver"
 795         else
 796             AC_MSG_RESULT([yes])
 797         fi
 798     fi
 799 fi
 800
 801 # Disable libgo for some systems where it is known to not work.
 802 # For testing, you can easily override this with --enable-libgo.
 803 if test x$enable_libgo = x; then
 804     case "${target}" in
 805     *-*-darwin*)
 806         # PR 46986
 807         noconfigdirs="$noconfigdirs target-libgo"
 808         ;;
 809     *-*-cygwin* | *-*-mingw*)
 810         noconfigdirs="$noconfigdirs target-libgo"
 811         ;;
 812     esac
 813 fi
 814
 815 # Default libgloss CPU subdirectory.
 816 libgloss_dir="$target_cpu"
 817
 818 case "${target}" in
 819   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 820     libgloss_dir=wince
 821     ;;
 822   aarch64*-*-* )
 823     libgloss_dir=aarch64
 824     ;;
 825   arm*-*-*)
 826     libgloss_dir=arm
 827     ;;
 828   cris-*-* | crisv32-*-*)
 829     libgloss_dir=cris
 830     ;;
 831   hppa*-*-*)
 832     libgloss_dir=pa
 833     ;;
 834   i[[3456789]]86-*-*)
 835     libgloss_dir=i386
 836     ;;
 837   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 838     libgloss_dir=m68hc11
 839     ;;
 840   m68*-*-* | fido-*-*)
 841     libgloss_dir=m68k
 842     ;;
 843   mips*-*-*)
 844     libgloss_dir=mips
 845     ;;
 846   powerpc*-*-*)
 847     libgloss_dir=rs6000
 848     ;;
 849   sparc*-*-*)
 850     libgloss_dir=sparc
 851     ;;
 852 esac
 853
 854 # Disable newlib and libgloss for various target OSes.
 855 case "${target}" in
 856   alpha*-dec-osf*)
 857     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 858     ;;
 859   i[[3456789]]86-*-linux*)
 860     # This section makes it possible to build newlib natively on linux.
 861     # If we are using a cross compiler then don't configure newlib.
 862     if test x${is_cross_compiler} != xno ; then
 863       noconfigdirs="$noconfigdirs target-newlib"
 864     fi
 865     noconfigdirs="$noconfigdirs target-libgloss"
 866     # If we are not using a cross compiler, do configure newlib.
 867     # Note however, that newlib will only be configured in this situation
 868     # if the --with-newlib option has been given, because otherwise
 869     # 'target-newlib' will appear in skipdirs.
 870     ;;
 871   i[[3456789]]86-*-rdos*)
 872     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 873     ;;
 874   sh*-*-pe|mips*-*-pe|arm-wince-pe)
 875     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 876     ;;
 877   sparc-*-sunos4*)
 878     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 879     ;;
 880   *-*-aix*)
 881     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 882     ;;
 883   *-*-beos*)
 884     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 885     ;;
 886   *-*-chorusos)
 887     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 888     ;;
 889   *-*-dragonfly*)
 890     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 891     ;;
 892   *-*-freebsd*)
 893     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 894     ;;
 895   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 896     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 897     ;;
 898   *-*-lynxos*)
 899     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 900     ;;
 901   *-*-mingw*)
 902     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 903     ;;
 904   *-*-netbsd*)
 905     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 906     ;;
 907   *-*-netware*)
 908     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 909     ;;
 910   *-*-tpf*)
 911     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 912     ;;
 913   *-*-uclinux*)
 914     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 915     ;;
 916   *-*-vxworks*)
 917     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 918     ;;
 919 esac
 920
 921 case "${target}" in
 922   *-*-chorusos)
 923     ;;
 924   aarch64-*-darwin*)
 925     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 926     noconfigdirs="$noconfigdirs sim target-rda"
 927     ;;
 928   arm-*-darwin*)
 929     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 930     noconfigdirs="$noconfigdirs sim target-rda"
 931     ;;
 932   powerpc-*-darwin*)
 933     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 934     noconfigdirs="$noconfigdirs sim target-rda"
 935     ;;
 936   i[[3456789]]86-*-darwin*)
 937     noconfigdirs="$noconfigdirs ld gprof"
 938     noconfigdirs="$noconfigdirs sim target-rda"
 939     ;;
 940   x86_64-*-darwin[[912]]*)
 941     noconfigdirs="$noconfigdirs ld gas gprof"
 942     noconfigdirs="$noconfigdirs sim target-rda"
 943     ;;
 944   *-*-darwin*)
 945     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 946     noconfigdirs="$noconfigdirs sim target-rda"
 947     ;;
 948   *-*-dragonfly*)
 949     ;;
 950   *-*-freebsd*)
 951     if test "x$with_gmp" = x && test "x$with_gmp_dir" = x \
 952         && test -f /usr/local/include/gmp.h; then
 953       with_gmp=/usr/local
 954     fi
 955     ;;
 956   *-*-kaos*)
 957     # Remove unsupported stuff on all kaOS configurations.
 958     noconfigdirs="$noconfigdirs target-libgloss"
 959     ;;
 960   *-*-netbsd*)
 961     ;;
 962   *-*-netware*)
 963     ;;
 964   *-*-phoenix*)
 965     noconfigdirs="$noconfigdirs target-libgloss"
 966     ;;
 967   *-*-rtems*)
 968     noconfigdirs="$noconfigdirs target-libgloss"
 969     ;;
 970     # The tpf target doesn't support gdb yet.
 971   *-*-tpf*)
 972     noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl"
 973     ;;
 974   *-*-uclinux*)
 975     noconfigdirs="$noconfigdirs target-rda"
 976     ;;
 977   *-*-vxworks*)
 978     ;;
 979   alpha*-dec-osf*)
 980     # ld works, but does not support shared libraries.
 981     # gas doesn't generate exception information.
 982     noconfigdirs="$noconfigdirs gas ld"
 983     ;;
 984   alpha*-*-*vms*)
 985     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
 986     ;;
 987   alpha*-*-*)
 988     # newlib is not 64 bit ready
 989     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 990     ;;
 991   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 992     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
 993     ;;
 994   arc*-*-*)
 995     noconfigdirs="$noconfigdirs sim"
 996     ;;
 997   arm-*-pe*)
 998     noconfigdirs="$noconfigdirs target-libgloss"
 999     ;;
1000   arm-*-riscix*)
1001     noconfigdirs="$noconfigdirs ld target-libgloss"
1002     ;;
1003   avr-*-*)
1004     if test x${with_avrlibc} != xno; then
1005       noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1006     fi
1007     ;;
1008   c4x-*-* | tic4x-*-*)
1009     noconfigdirs="$noconfigdirs target-libgloss"
1010     ;;
1011   tic54x-*-*)
1012     noconfigdirs="$noconfigdirs target-libgloss gdb"
1013     ;;
1014   d10v-*-*)
1015     noconfigdirs="$noconfigdirs target-libgloss"
1016     ;;
1017   d30v-*-*)
1018     noconfigdirs="$noconfigdirs gdb"
1019     ;;
1020   fr30-*-elf*)
1021     noconfigdirs="$noconfigdirs gdb"
1022     ;;
1023   ft32-*-*)
1024     noconfigdirs="$noconfigdirs target-rda gprof"
1025     ;;
1026   moxie-*-*)
1027     noconfigdirs="$noconfigdirs"
1028     ;;
1029   h8300*-*-*)
1030     noconfigdirs="$noconfigdirs target-libgloss"
1031     ;;
1032   h8500-*-*)
1033     noconfigdirs="$noconfigdirs target-libgloss"
1034     ;;
1035   hppa1.1-*-osf* | hppa1.1-*-bsd* )
1036     ;;
1037   hppa*64*-*-hpux*)
1038     noconfigdirs="$noconfigdirs gdb"
1039     ;;
1040   hppa*-*-hpux11*)
1041     noconfigdirs="$noconfigdirs gdb ld"
1042     ;;
1043   hppa*64*-*-linux*)
1044     ;;
1045   hppa*-*-linux*)
1046     ;;
1047   hppa*-*-*elf* | \
1048   hppa*-*-lites* | \
1049   hppa*-*-openbsd* | \
1050   hppa*64*-*-*)
1051     ;;
1052   hppa*-*-pro*)
1053     ;;
1054   hppa*-*-*)
1055     noconfigdirs="$noconfigdirs ld"
1056     ;;
1057   i960-*-*)
1058     noconfigdirs="$noconfigdirs gdb"
1059     ;;
1060   ia64*-*-elf*)
1061     # No gdb support yet.
1062     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
1063     ;;
1064   ia64*-**-hpux*)
1065     # No ld support yet.
1066     noconfigdirs="$noconfigdirs gdb libgui itcl ld"
1067     ;;
1068   ia64*-*-*vms*)
1069     # No ld support yet.
1070     noconfigdirs="$noconfigdirs libgui itcl ld"
1071     ;;
1072   i[[3456789]]86-w64-mingw*)
1073     ;;
1074   i[[3456789]]86-*-mingw*)
1075     target_configdirs="$target_configdirs target-winsup"
1076     ;;
1077   *-*-cygwin*)
1078     target_configdirs="$target_configdirs target-libtermcap target-winsup"
1079     noconfigdirs="$noconfigdirs target-libgloss"
1080     # always build newlib if winsup directory is present.
1081     if test -d "$srcdir/winsup/cygwin"; then
1082       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1083     elif test -d "$srcdir/newlib"; then
1084       echo "Warning: winsup/cygwin is missing so newlib can't be built."
1085     fi
1086     ;;
1087   i[[3456789]]86-*-pe)
1088     noconfigdirs="$noconfigdirs target-libgloss"
1089     ;;
1090   i[[3456789]]86-*-sco3.2v5*)
1091     # The linker does not yet know about weak symbols in COFF,
1092     # and is not configured to handle mixed ELF and COFF.
1093     noconfigdirs="$noconfigdirs ld target-libgloss"
1094     ;;
1095   i[[3456789]]86-*-sco*)
1096     noconfigdirs="$noconfigdirs gprof target-libgloss"
1097     ;;
1098   i[[3456789]]86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
1099     noconfigdirs="$noconfigdirs target-libgloss"
1100     ;;
1101   i[[3456789]]86-*-sysv4*)
1102     noconfigdirs="$noconfigdirs target-libgloss"
1103     ;;
1104   i[[3456789]]86-*-beos*)
1105     noconfigdirs="$noconfigdirs gdb"
1106     ;;
1107   i[[3456789]]86-*-rdos*)
1108     noconfigdirs="$noconfigdirs gdb"
1109     ;;
1110   mmix-*-*)
1111     noconfigdirs="$noconfigdirs gdb"
1112     ;;
1113   mt-*-*)
1114     noconfigdirs="$noconfigdirs sim"
1115     ;;
1116   nfp-*-*)
1117     noconfigdirs="$noconfigdirs ld gas gdb gprof sim"
1118     noconfigdirs="$noconfigdirs $target_libraries"
1119     ;;
1120   powerpc-*-aix*)
1121     # copied from rs6000-*-* entry
1122     noconfigdirs="$noconfigdirs gprof"
1123     ;;
1124   powerpc*-*-winnt* | powerpc*-*-pe*)
1125     target_configdirs="$target_configdirs target-winsup"
1126     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
1127     # always build newlib.
1128     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1129     ;;
1130     # This is temporary until we can link against shared libraries
1131   powerpcle-*-solaris*)
1132     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
1133     ;;
1134   powerpc-*-beos*)
1135     noconfigdirs="$noconfigdirs gdb"
1136     ;;
1137   rs6000-*-lynxos*)
1138     noconfigdirs="$noconfigdirs gprof"
1139     ;;
1140   rs6000-*-aix*)
1141     noconfigdirs="$noconfigdirs gprof"
1142     ;;
1143   rs6000-*-*)
1144     noconfigdirs="$noconfigdirs gprof"
1145     ;;
1146   m68k-apollo-*)
1147     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
1148     ;;
1149   microblaze*)
1150     noconfigdirs="$noconfigdirs gprof"
1151     ;;
1152   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
1153     if test x$with_newlib = xyes; then
1154       noconfigdirs="$noconfigdirs gprof"
1155     fi
1156     ;;
1157   mips*-*-irix5*)
1158     noconfigdirs="$noconfigdirs gprof target-libgloss"
1159     ;;
1160   mips*-*-irix6*)
1161     noconfigdirs="$noconfigdirs gprof target-libgloss"
1162     ;;
1163   mips*-*-bsd*)
1164     noconfigdirs="$noconfigdirs ld gas gprof target-libgloss"
1165     ;;
1166   mips*-*-linux*)
1167     ;;
1168   mips*-*-ultrix* | mips*-*-osf* | mips*-*-ecoff* | mips*-*-pe* \
1169   | mips*-*-irix* | mips*-*-lnews* | mips*-*-riscos*)
1170     noconfigdirs="$noconfigdirs ld gas gprof"
1171     ;;
1172   mips*-*-*)
1173     noconfigdirs="$noconfigdirs gprof"
1174     ;;
1175   nvptx*-*-*)
1176     noconfigdirs="$noconfigdirs target-libssp target-libstdc++-v3 target-libobjc"
1177     ;;
1178   sh-*-*)
1179     case "${target}" in
1180       sh*-*-elf)
1181          ;;
1182       *)
1183          noconfigdirs="$noconfigdirs target-libgloss" ;;
1184     esac
1185     ;;
1186   sparc-*-sunos4*)
1187     if test x${is_cross_compiler} = xno ; then
1188            use_gnu_ld=no
1189     fi
1190     ;;
1191   tic6x-*-*)
1192     noconfigdirs="$noconfigdirs sim"
1193     ;;
1194   tilepro*-*-* | tilegx*-*-*)
1195     noconfigdirs="$noconfigdirs sim"
1196     ;;
1197   v810-*-*)
1198     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1199     ;;
1200   vax-*-*)
1201     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1202     ;;
1203   wasm32-*-*)
1204     noconfigdirs="$noconfigdirs ld"
1205     ;;
1206 esac
1207
1208 # If we aren't building newlib, then don't build libgloss, since libgloss
1209 # depends upon some newlib header files.
1210 case "${noconfigdirs}" in
1211   *target-libgloss*) ;;
1212   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1213 esac
1214
1215 # Work in distributions that contain no compiler tools, like Autoconf.
1216 host_makefile_frag=/dev/null
1217 if test -d ${srcdir}/config ; then
1218 case "${host}" in
1219   i[[3456789]]86-*-msdosdjgpp*)
1220     host_makefile_frag="config/mh-djgpp"
1221     ;;
1222   *-cygwin*)
1223     ACX_CHECK_CYGWIN_CAT_WORKS
1224     host_makefile_frag="config/mh-cygwin"
1225     ;;
1226   *-mingw*)
1227     host_makefile_frag="config/mh-mingw"
1228     ;;
1229   alpha*-linux*)
1230     host_makefile_frag="config/mh-alpha-linux"
1231     ;;
1232   hppa*-hp-hpux10*)
1233     host_makefile_frag="config/mh-pa-hpux10"
1234     ;;
1235   hppa*-hp-hpux*)
1236     host_makefile_frag="config/mh-pa"
1237     ;;
1238   hppa*-*)
1239     host_makefile_frag="config/mh-pa"
1240     ;;
1241   *-*-darwin*)
1242     host_makefile_frag="config/mh-darwin"
1243     ;;
1244   powerpc-*-aix*)
1245     host_makefile_frag="config/mh-ppc-aix"
1246     ;;
1247   rs6000-*-aix*)
1248     host_makefile_frag="config/mh-ppc-aix"
1249     ;;
1250 esac
1251 fi
1252
1253 if test "${build}" != "${host}" ; then
1254   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1255   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1256   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1257   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1258   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1259   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1260   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1261   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1262   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1263   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1264   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1265   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1266 else
1267   AR_FOR_BUILD="\$(AR)"
1268   AS_FOR_BUILD="\$(AS)"
1269   CC_FOR_BUILD="\$(CC)"
1270   CXX_FOR_BUILD="\$(CXX)"
1271   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1272   GOC_FOR_BUILD="\$(GOC)"
1273   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1274   LD_FOR_BUILD="\$(LD)"
1275   NM_FOR_BUILD="\$(NM)"
1276   RANLIB_FOR_BUILD="\$(RANLIB)"
1277   WINDRES_FOR_BUILD="\$(WINDRES)"
1278   WINDMC_FOR_BUILD="\$(WINDMC)"
1279 fi
1280
1281 AC_PROG_CC
1282 AC_PROG_CXX
1283
1284 # We must set the default linker to the linker used by gcc for the correct
1285 # operation of libtool.  If LD is not defined and we are using gcc, try to
1286 # set the LD default to the ld used by gcc.
1287 if test -z "$LD"; then
1288   if test "$GCC" = yes; then
1289     case $build in
1290     *-*-mingw*)
1291       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1292     *)
1293       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1294     esac
1295     case $gcc_prog_ld in
1296     # Accept absolute paths.
1297     [[\\/]* | [A-Za-z]:[\\/]*)]
1298       LD="$gcc_prog_ld" ;;
1299     esac
1300   fi
1301 fi
1302
1303 # Check whether -static-libstdc++ -static-libgcc is supported.
1304 have_static_libs=no
1305 if test "$GCC" = yes; then
1306   saved_LDFLAGS="$LDFLAGS"
1307
1308   LDFLAGS="$LDFLAGS -static-libstdc++ -static-libgcc"
1309   AC_MSG_CHECKING([whether g++ accepts -static-libstdc++ -static-libgcc])
1310   AC_LANG_PUSH(C++)
1311   AC_LINK_IFELSE([AC_LANG_SOURCE([
1312 #if (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 5)
1313 #error -static-libstdc++ not implemented
1314 #endif
1315 int main() {}])],
1316     [AC_MSG_RESULT([yes]); have_static_libs=yes],
1317     [AC_MSG_RESULT([no])])
1318   AC_LANG_POP(C++)
1319
1320   LDFLAGS="$saved_LDFLAGS"
1321 fi
1322
1323 ACX_PROG_GNAT
1324 ACX_PROG_CMP_IGNORE_INITIAL
1325
1326 AC_ARG_ENABLE([bootstrap],
1327 [AS_HELP_STRING([--enable-bootstrap],
1328                 [enable bootstrapping @<:@yes if native build@:>@])],,
1329 enable_bootstrap=default)
1330
1331 # Issue errors and warnings for invalid/strange bootstrap combinations.
1332 if test -r $srcdir/gcc/configure; then
1333   have_compiler=yes
1334 else
1335   have_compiler=no
1336 fi
1337
1338 case "$have_compiler:$host:$target:$enable_bootstrap" in
1339   *:*:*:no) ;;
1340
1341   # Default behavior.  Enable bootstrap if we have a compiler
1342   # and we are in a native configuration.
1343   yes:$build:$build:default)
1344     enable_bootstrap=yes ;;
1345
1346   *:*:*:default)
1347     enable_bootstrap=no ;;
1348
1349   # We have a compiler and we are in a native configuration, bootstrap is ok
1350   yes:$build:$build:yes)
1351     ;;
1352
1353   # Other configurations, but we have a compiler.  Assume the user knows
1354   # what he's doing.
1355   yes:*:*:yes)
1356     AC_MSG_WARN([trying to bootstrap a cross compiler])
1357     ;;
1358
1359   # No compiler: if they passed --enable-bootstrap explicitly, fail
1360   no:*:*:yes)
1361     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
1362
1363   # Fail if wrong command line
1364   *)
1365     AC_MSG_ERROR([invalid option for --enable-bootstrap])
1366     ;;
1367 esac
1368
1369 # When bootstrapping with GCC, build stage 1 in C++98 mode to ensure that a
1370 # C++98 compiler can still start the bootstrap.
1371 if test "$enable_bootstrap:$GXX" = "yes:yes"; then
1372   CXX="$CXX -std=gnu++98"
1373 fi
1374
1375 # Used for setting $lt_cv_objdir
1376 _LT_CHECK_OBJDIR
1377
1378 # Check for GMP, MPFR and MPC
1379 gmplibs="-lmpc -lmpfr -lgmp"
1380 gmpinc=
1381 have_gmp=no
1382
1383 # Check for debuginfod
1384 AC_DEBUGINFOD
1385
1386 # Specify a location for mpc
1387 # check for this first so it ends up on the link line before mpfr.
1388 AC_ARG_WITH(mpc,
1389 [AS_HELP_STRING([--with-mpc=PATH],
1390                 [specify prefix directory for installed MPC package.
1391                  Equivalent to --with-mpc-include=PATH/include
1392                  plus --with-mpc-lib=PATH/lib])])
1393 AC_ARG_WITH(mpc-include,
1394 [AS_HELP_STRING([--with-mpc-include=PATH],
1395                 [specify directory for installed MPC include files])])
1396 AC_ARG_WITH(mpc-lib,
1397 [AS_HELP_STRING([--with-mpc-lib=PATH],
1398                 [specify directory for the installed MPC library])])
1399
1400 if test "x$with_mpc" != x; then
1401   gmplibs="-L$with_mpc/lib $gmplibs"
1402   gmpinc="-I$with_mpc/include $gmpinc"
1403 fi
1404 if test "x$with_mpc_include" != x; then
1405   gmpinc="-I$with_mpc_include $gmpinc"
1406 fi
1407 if test "x$with_mpc_lib" != x; then
1408   gmplibs="-L$with_mpc_lib $gmplibs"
1409 fi
1410 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1411   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1412   gmpinc='-I$$s/mpc/src '"$gmpinc"
1413   # Do not test the mpc version.  Assume that it is sufficient, since
1414   # it is in the source tree, and the library has not been built yet
1415   # but it would be included on the link line in the version check below
1416   # hence making the test fail.
1417   have_gmp=yes
1418 fi
1419
1420 # Specify a location for mpfr
1421 # check for this first so it ends up on the link line before gmp.
1422 AC_ARG_WITH(mpfr-dir,
1423 [AS_HELP_STRING([--with-mpfr-dir=PATH], [this option has been REMOVED])],
1424 [AC_MSG_ERROR([The --with-mpfr-dir=PATH option has been removed.
1425 Use --with-mpfr=PATH or --with-mpfr-include=PATH plus --with-mpfr-lib=PATH])])
1426
1427 AC_ARG_WITH(mpfr,
1428 [AS_HELP_STRING([--with-mpfr=PATH],
1429                 [specify prefix directory for installed MPFR package.
1430                  Equivalent to --with-mpfr-include=PATH/include
1431                  plus --with-mpfr-lib=PATH/lib])])
1432 AC_ARG_WITH(mpfr-include,
1433 [AS_HELP_STRING([--with-mpfr-include=PATH],
1434                 [specify directory for installed MPFR include files])])
1435 AC_ARG_WITH(mpfr-lib,
1436 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1437                 [specify directory for the installed MPFR library])])
1438
1439 if test "x$with_mpfr" != x; then
1440   gmplibs="-L$with_mpfr/lib $gmplibs"
1441   gmpinc="-I$with_mpfr/include $gmpinc"
1442 fi
1443 if test "x$with_mpfr_include" != x; then
1444   gmpinc="-I$with_mpfr_include $gmpinc"
1445 fi
1446 if test "x$with_mpfr_lib" != x; then
1447   gmplibs="-L$with_mpfr_lib $gmplibs"
1448 fi
1449 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1450   # MPFR v3.1.0 moved the sources into a src sub-directory.
1451   if ! test -d ${srcdir}/mpfr/src; then
1452     AC_MSG_ERROR([dnl
1453 Building GCC with MPFR in the source tree is only handled for MPFR 3.1.0+.])
1454   fi
1455   gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir $gmplibs"
1456   gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr/src -I$$s/mpfr/src '"$gmpinc"
1457   extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr/src --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir"
1458   # Do not test the mpfr version.  Assume that it is sufficient, since
1459   # it is in the source tree, and the library has not been built yet
1460   # but it would be included on the link line in the version check below
1461   # hence making the test fail.
1462   have_gmp=yes
1463 fi
1464
1465 # Specify a location for gmp
1466 AC_ARG_WITH(gmp-dir,
1467 [AS_HELP_STRING([--with-gmp-dir=PATH], [this option has been REMOVED])],
1468 [AC_MSG_ERROR([The --with-gmp-dir=PATH option has been removed.
1469 Use --with-gmp=PATH or --with-gmp-include=PATH plus --with-gmp-lib=PATH])])
1470
1471 AC_ARG_WITH(gmp,
1472 [AS_HELP_STRING([--with-gmp=PATH],
1473                 [specify prefix directory for the installed GMP package.
1474                  Equivalent to --with-gmp-include=PATH/include
1475                  plus --with-gmp-lib=PATH/lib])])
1476 AC_ARG_WITH(gmp-include,
1477 [AS_HELP_STRING([--with-gmp-include=PATH],
1478                 [specify directory for installed GMP include files])])
1479 AC_ARG_WITH(gmp-lib,
1480 [AS_HELP_STRING([--with-gmp-lib=PATH],
1481                 [specify directory for the installed GMP library])])
1482
1483
1484 if test "x$with_gmp" != x; then
1485   gmplibs="-L$with_gmp/lib $gmplibs"
1486   gmpinc="-I$with_gmp/include $gmpinc"
1487 fi
1488 if test "x$with_gmp_include" != x; then
1489   gmpinc="-I$with_gmp_include $gmpinc"
1490 fi
1491 if test "x$with_gmp_lib" != x; then
1492   gmplibs="-L$with_gmp_lib $gmplibs"
1493 fi
1494 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1495   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1496   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1497   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1498   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1499   extra_isl_gmp_configure_flags='--with-gmp-builddir=$$r/$(HOST_SUBDIR)/gmp'
1500   # Do not test the gmp version.  Assume that it is sufficient, since
1501   # it is in the source tree, and the library has not been built yet
1502   # but it would be included on the link line in the version check below
1503   # hence making the test fail.
1504   have_gmp=yes
1505 fi
1506
1507 if test -d ${srcdir}/gcc && test "x$have_gmp" = xno; then
1508   have_gmp=yes
1509   saved_CFLAGS="$CFLAGS"
1510   CFLAGS="$CFLAGS $gmpinc"
1511   # Check for the recommended and required versions of GMP.
1512   AC_MSG_CHECKING([for the correct version of gmp.h])
1513   AC_TRY_COMPILE([#include "gmp.h"],[
1514   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1515   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1516   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,3)
1517   choke me
1518   #endif
1519   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1520   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1521   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1522   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1523   choke me
1524   #endif
1525   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1526    [AC_MSG_RESULT([no]); have_gmp=no])
1527
1528   # If we have GMP, check the MPFR version.
1529   if test x"$have_gmp" = xyes; then
1530     # Check for the recommended and required versions of MPFR.
1531     AC_MSG_CHECKING([for the correct version of mpfr.h])
1532     AC_TRY_COMPILE([#include <gmp.h>
1533     #include <mpfr.h>],[
1534     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,0)
1535     choke me
1536     #endif
1537     ], [AC_TRY_COMPILE([#include <gmp.h>
1538     #include <mpfr.h>],[
1539     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,2)
1540     choke me
1541     #endif
1542     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1543      [AC_MSG_RESULT([no]); have_gmp=no])
1544   fi
1545
1546   # Check for the MPC header version.
1547   if test x"$have_gmp" = xyes ; then
1548     # Check for the recommended and required versions of MPC.
1549     AC_MSG_CHECKING([for the correct version of mpc.h])
1550     AC_TRY_COMPILE([#include <mpc.h>],[
1551     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1552     choke me
1553     #endif
1554     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1555     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1556     choke me
1557     #endif
1558     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1559      [AC_MSG_RESULT([no]); have_gmp=no])
1560   fi
1561
1562   # Now check the MPFR library.
1563   if test x"$have_gmp" = xyes; then
1564     saved_LIBS="$LIBS"
1565     LIBS="$LIBS $gmplibs"
1566     AC_MSG_CHECKING([for the correct version of the gmp/mpfr/mpc libraries])
1567     AC_TRY_LINK([#include <mpc.h>],[
1568     mpfr_t n;
1569     mpfr_t x;
1570     mpc_t c;
1571     int t;
1572     mpfr_init (n);
1573     mpfr_init (x);
1574     mpfr_atan2 (n, n, x, GMP_RNDN);
1575     mpfr_erfc (n, x, GMP_RNDN);
1576     mpfr_subnormalize (x, t, GMP_RNDN);
1577     mpfr_clear(n);
1578     mpfr_clear(x);
1579     mpc_init2 (c, 53);
1580     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1581     mpc_cosh (c, c, MPC_RNDNN);
1582     mpc_pow (c, c, c, MPC_RNDNN);
1583     mpc_acosh (c, c, MPC_RNDNN);
1584     mpc_clear (c);
1585     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1586     LIBS="$saved_LIBS"
1587   fi
1588
1589   CFLAGS="$saved_CFLAGS"
1590
1591 # The library versions listed in the error message below should match
1592 # the HARD-minimums enforced above.
1593   if test x$have_gmp != xyes; then
1594     AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 2.4.0+ and MPC 0.8.0+.
1595 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1596 their locations.  Source code for these libraries can be found at
1597 their respective hosting sites as well as at
1598 ftp://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1599 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1600 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1601 make sure that you have installed both the libraries and the header
1602 files.  They may be located in separate packages.])
1603   fi
1604 fi
1605
1606 # Flags needed for both GMP, MPFR and/or MPC.
1607 AC_SUBST(gmplibs)
1608 AC_SUBST(gmpinc)
1609 AC_SUBST(extra_mpfr_configure_flags)
1610 AC_SUBST(extra_mpc_gmp_configure_flags)
1611 AC_SUBST(extra_mpc_mpfr_configure_flags)
1612 AC_SUBST(extra_isl_gmp_configure_flags)
1613
1614 # Libraries to use for stage1 or when not bootstrapping.
1615 AC_ARG_WITH(stage1-libs,
1616 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1617 [if test "$withval" = "no" -o "$withval" = "yes"; then
1618    stage1_libs=
1619  else
1620    stage1_libs=$withval
1621  fi],
1622 [stage1_libs=])
1623 AC_SUBST(stage1_libs)
1624
1625 # Whether or not to use -static-libstdc++ and -static-libgcc.  The
1626 # default is yes if gcc is being built; no otherwise.  The reason for
1627 # this default is that gdb is sometimes linked against GNU Source
1628 # Highlight, which is a shared library that uses C++ exceptions.  In
1629 # this case, -static-libstdc++ will cause crashes.
1630 AC_ARG_WITH(static-standard-libraries,
1631 [AS_HELP_STRING([--with-static-standard-libraries],
1632                 [use -static-libstdc++ and -static-libgcc (default=auto)])],
1633 [], [with_static_standard_libraries=auto])
1634 if test "$with_static_standard_libraries" = auto; then
1635   with_static_standard_libraries=$have_compiler
1636 fi
1637
1638 # Linker flags to use for stage1 or when not bootstrapping.
1639 AC_ARG_WITH(stage1-ldflags,
1640 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1641 [if test "$withval" = "no" -o "$withval" = "yes"; then
1642    stage1_ldflags=
1643  else
1644    stage1_ldflags=$withval
1645  fi],
1646 [stage1_ldflags=
1647  # In stage 1, default to linking libstdc++ and libgcc statically with GCC
1648  # if supported.  But if the user explicitly specified the libraries to use,
1649  # trust that they are doing what they want.
1650  if test "$with_static_standard_libraries" = yes -a "$stage1_libs" = "" \
1651      -a "$have_static_libs" = yes; then
1652    stage1_ldflags="-static-libstdc++ -static-libgcc"
1653  fi])
1654 AC_SUBST(stage1_ldflags)
1655
1656 # Libraries to use for stage2 and later builds.
1657 AC_ARG_WITH(boot-libs,
1658 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1659 [if test "$withval" = "no" -o "$withval" = "yes"; then
1660    poststage1_libs=
1661  else
1662    poststage1_libs=$withval
1663  fi],
1664 [poststage1_libs=])
1665 AC_SUBST(poststage1_libs)
1666
1667 # Linker flags to use for stage2 and later builds.
1668 AC_ARG_WITH(boot-ldflags,
1669 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1670                 [linker flags for stage2 and later])],
1671 [if test "$withval" = "no" -o "$withval" = "yes"; then
1672    poststage1_ldflags=
1673  else
1674    poststage1_ldflags=$withval
1675  fi],
1676 [poststage1_ldflags=
1677  # In stages 2 and 3, default to linking libstdc++ and libgcc
1678  # statically.  But if the user explicitly specified the libraries to
1679  # use, trust that they are doing what they want.
1680  if test "$poststage1_libs" = ""; then
1681    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1682  fi])
1683 AC_SUBST(poststage1_ldflags)
1684
1685 # GCC GRAPHITE dependency isl.
1686 # Basic setup is inlined here, actual checks are in config/isl.m4
1687
1688 AC_ARG_WITH(isl,
1689   [AS_HELP_STRING(
1690    [--with-isl=PATH],
1691    [Specify prefix directory for the installed isl package.
1692     Equivalent to --with-isl-include=PATH/include
1693     plus --with-isl-lib=PATH/lib])])
1694
1695 # Treat --without-isl as a request to disable
1696 # GRAPHITE support and skip all following checks.
1697 if test "x$with_isl" != "xno"; then
1698   # Check for isl
1699   dnl Provide configure switches and initialize islinc & isllibs
1700   dnl with user input.
1701   ISL_INIT_FLAGS
1702   dnl The versions of isl that work for Graphite
1703   ISL_CHECK_VERSION()
1704   dnl Only execute fail-action, if isl has been requested.
1705   ISL_IF_FAILED([
1706     AC_MSG_ERROR([Unable to find a usable isl.  See config.log for details.])])
1707 fi
1708
1709 # If the isl check failed, disable builds of in-tree variant of isl
1710 if test "x$with_isl" = xno ||
1711    test "x$gcc_cv_isl" = xno; then
1712   noconfigdirs="$noconfigdirs isl"
1713   islinc=
1714 fi
1715
1716 AC_SUBST(isllibs)
1717 AC_SUBST(islinc)
1718
1719 # Check for LTO support.
1720 AC_ARG_ENABLE(lto,
1721 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1722 enable_lto=$enableval,
1723 enable_lto=yes; default_enable_lto=yes)
1724
1725 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1726   build_lto_plugin=yes
1727 ],[if test x"$default_enable_lto" = x"yes" ; then
1728     case $target in
1729       *-apple-darwin[[912]]* | *-cygwin* | *-mingw* | *djgpp*) ;;
1730       # On other non-ELF platforms, LTO has yet to be validated.
1731       *) enable_lto=no ;;
1732     esac
1733   else
1734   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1735   # It would also be nice to check the binutils support, but we don't
1736   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1737   # warn during gcc/ subconfigure; unless you're bootstrapping with
1738   # -flto it won't be needed until after installation anyway.
1739     case $target in
1740       *-cygwin* | *-mingw* | *-apple-darwin* | *djgpp*) ;;
1741       *) if test x"$enable_lto" = x"yes"; then
1742         AC_MSG_ERROR([LTO support is not enabled for this target.])
1743         fi
1744       ;;
1745     esac
1746   fi
1747   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1748   # Build it unless LTO was explicitly disabled.
1749   case $target in
1750     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1751     *) ;;
1752   esac
1753 ])
1754
1755 AC_ARG_ENABLE(linker-plugin-configure-flags,
1756   [AS_HELP_STRING([[--enable-linker-plugin-configure-flags=FLAGS]],
1757     [additional flags for configuring linker plugins @<:@none@:>@])],
1758   extra_linker_plugin_configure_flags=$enableval,
1759   extra_linker_plugin_configure_flags=)
1760 AC_SUBST(extra_linker_plugin_configure_flags)
1761 AC_ARG_ENABLE(linker-plugin-flags,
1762   [AS_HELP_STRING([[--enable-linker-plugin-flags=FLAGS]],
1763     [additional flags for configuring and building linker plugins @<:@none@:>@])],
1764   extra_linker_plugin_flags=$enableval,
1765   extra_linker_plugin_flags=)
1766 AC_SUBST(extra_linker_plugin_flags)
1767
1768 # Enable --enable-host-shared.
1769 # Checked early to determine whether jit is an 'all' language
1770 AC_ARG_ENABLE(host-shared,
1771 [AS_HELP_STRING([--enable-host-shared],
1772                 [build host code as shared libraries])],
1773 [host_shared=$enableval], [host_shared=no])
1774 AC_SUBST(host_shared)
1775
1776 # By default, C and C++ are the only stage 1 languages.
1777 stage1_languages=,c,
1778
1779 # Target libraries that we bootstrap.
1780 bootstrap_target_libs=,target-libgcc,
1781
1782 # Figure out what language subdirectories are present.
1783 # Look if the user specified --enable-languages="..."; if not, use
1784 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1785 # go away some day.
1786 # NB:  embedded tabs in this IF block -- do not untabify
1787 if test -d ${srcdir}/gcc; then
1788   if test x"${enable_languages+set}" != xset; then
1789     if test x"${LANGUAGES+set}" = xset; then
1790       enable_languages="${LANGUAGES}"
1791         echo configure.ac: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
1792     else
1793       enable_languages=default
1794     fi
1795   else
1796     if test x"${enable_languages}" = x ||
1797        test x"${enable_languages}" = xyes;
1798        then
1799       echo configure.ac: --enable-languages needs at least one language argument 1>&2
1800       exit 1
1801     fi
1802   fi
1803   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
1804
1805   # 'f95' is the old name for the 'fortran' language. We issue a warning
1806   # and make the substitution.
1807   case ,${enable_languages}, in
1808     *,f95,*)
1809       echo configure.ac: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
1810       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
1811       ;;
1812   esac
1813
1814   # If bootstrapping, C++ must be enabled.
1815   case ",$enable_languages,:$enable_bootstrap" in
1816     *,c++,*:*) ;;
1817     *:yes)
1818       if test -f ${srcdir}/gcc/cp/config-lang.in; then
1819         enable_languages="${enable_languages},c++"
1820       else
1821         AC_MSG_ERROR([bootstrapping requires c++ sources])
1822       fi
1823       ;;
1824   esac
1825
1826   # First scan to see if an enabled language requires some other language.
1827   # We assume that a given config-lang.in will list all the language
1828   # front ends it requires, even if some are required indirectly.
1829   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1830     case ${lang_frag} in
1831       ..) ;;
1832       # The odd quoting in the next line works around
1833       # an apparent bug in bash 1.12 on linux.
1834       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1835       *)
1836         # From the config-lang.in, get $language, $lang_requires, and
1837         # $lang_requires_boot_languages.
1838         language=
1839         lang_requires=
1840         lang_requires_boot_languages=
1841         # set srcdir during sourcing lang_frag to the gcc dir.
1842         # Sadly overriding srcdir on the . line doesn't work in plain sh as it
1843         # polutes this shell
1844         saved_srcdir=${srcdir}
1845         srcdir=${srcdir}/gcc . ${lang_frag}
1846         srcdir=${saved_srcdir}
1847         for other in ${lang_requires} ${lang_requires_boot_languages}; do
1848           case ,${enable_languages}, in
1849             *,$other,*) ;;
1850             *,default,*) ;;
1851             *,all,*) ;;
1852             *,$language,*)
1853               echo " \`$other' language required by \`$language'; enabling" 1>&2
1854               enable_languages="${enable_languages},${other}"
1855               ;;
1856           esac
1857         done
1858         for other in ${lang_requires_boot_languages} ; do
1859           if test "$other" != "c"; then
1860             case ,${enable_stage1_languages}, in
1861               *,$other,*) ;;
1862               *,default,*) ;;
1863               *,all,*) ;;
1864               *)
1865                 case ,${enable_languages}, in
1866                   *,$language,*)
1867                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
1868                     enable_stage1_languages="$enable_stage1_languages,${other}"
1869                     ;;
1870                 esac
1871                 ;;
1872             esac
1873           fi
1874         done
1875         ;;
1876     esac
1877   done
1878
1879   new_enable_languages=,c,
1880
1881   # If LTO is enabled, add the LTO front end.
1882   if test "$enable_lto" = "yes" ; then
1883     case ,${enable_languages}, in
1884       *,lto,*) ;;
1885       *) enable_languages="${enable_languages},lto" ;;
1886     esac
1887     if test "${build_lto_plugin}" = "yes" ; then
1888       configdirs="$configdirs lto-plugin"
1889     fi
1890   fi
1891
1892   # If we're building an offloading compiler, add the LTO front end.
1893   if test x"$enable_as_accelerator_for" != x ; then
1894     case ,${enable_languages}, in
1895       *,lto,*) ;;
1896       *) enable_languages="${enable_languages},lto" ;;
1897     esac
1898   fi
1899
1900   missing_languages=`echo ",$enable_languages," | sed -e s/,default,/,/ -e s/,all,/,/ -e s/,c,/,/ `
1901   potential_languages=,c,
1902
1903   enabled_target_libs=
1904   disabled_target_libs=
1905
1906   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1907     case ${lang_frag} in
1908       ..) ;;
1909       # The odd quoting in the next line works around
1910       # an apparent bug in bash 1.12 on linux.
1911       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1912       *)
1913         # From the config-lang.in, get $language, $target_libs,
1914         # $lang_dirs, $boot_language, and $build_by_default
1915         language=
1916         target_libs=
1917         lang_dirs=
1918         subdir_requires=
1919         boot_language=no
1920         build_by_default=yes
1921         # set srcdir during sourcing.  See above about save & restore
1922         saved_srcdir=${srcdir}
1923         srcdir=${srcdir}/gcc . ${lang_frag}
1924         srcdir=${saved_srcdir}
1925         if test x${language} = x; then
1926           echo "${lang_frag} doesn't set \$language." 1>&2
1927           exit 1
1928         fi
1929
1930         if test "$language" = "c++"; then
1931           boot_language=yes
1932         fi
1933
1934         add_this_lang=no
1935         # C is always enabled, so no need to add it again
1936         if test "$language" != "c"; then
1937           case ,${enable_languages}, in
1938             *,${language},*)
1939               # Language was explicitly selected; include it
1940               add_this_lang=yes
1941               ;;
1942             *,all,*)
1943               # All languages are enabled
1944               add_this_lang=all
1945               ;;
1946             *,default,*)
1947               # 'default' was selected, select it if it is a default language
1948               add_this_lang=${build_by_default}
1949               ;;
1950           esac
1951         fi
1952
1953         # Disable languages that need other directories if these aren't available.
1954         for i in $subdir_requires; do
1955           test -f "$srcdir/gcc/$i/config-lang.in" && continue
1956           case ${add_this_lang} in
1957             yes)
1958               # Specifically requested language; tell them.
1959               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
1960               ;;
1961             all)
1962               AC_MSG_WARN([The gcc/$i directory contains parts of $language but is missing])
1963               add_this_lang=unsupported
1964               ;;
1965             *)
1966               # Silently disable.
1967               add_this_lang=unsupported
1968               ;;
1969           esac
1970         done
1971
1972         # Disable Ada if no preexisting GNAT is available.
1973         case ${add_this_lang}:${language}:${have_gnat} in
1974           yes:ada:no)
1975             # Specifically requested language; tell them.
1976             AC_MSG_ERROR([GNAT is required to build $language])
1977             ;;
1978           all:ada:no)
1979             AC_MSG_WARN([GNAT is required to build $language])
1980             add_this_lang=unsupported
1981             ;;
1982           *:ada:no)
1983             # Silently disable.
1984             add_this_lang=unsupported
1985             ;;
1986         esac
1987
1988         # Disable jit if -enable-host-shared not specified
1989         case ${add_this_lang}:${language}:${host_shared} in
1990           yes:jit:no)
1991             # PR jit/64780: explicitly specify --enable-host-shared
1992             AC_MSG_ERROR([
1993 Enabling language "jit" requires --enable-host-shared.
1994
1995 --enable-host-shared typically slows the rest of the compiler down by
1996 a few %, so you must explicitly enable it.
1997
1998 If you want to build both the jit and the regular compiler, it is often
1999 best to do this via two separate configure/builds, in separate
2000 directories, to avoid imposing the performance cost of
2001 --enable-host-shared on the regular compiler.])
2002             ;;
2003           all:jit:no)
2004             AC_MSG_WARN([--enable-host-shared required to build $language])
2005             add_this_lang=unsupported
2006             ;;
2007           *:jit:no)
2008             # Silently disable.
2009             add_this_lang=unsupported
2010             ;;
2011         esac
2012
2013         # Disable a language that is unsupported by the target.
2014         case "${add_this_lang}: $unsupported_languages " in
2015           no:*) ;;
2016           unsupported:*) ;;
2017           *:*" $language "*)
2018             AC_MSG_WARN([${language} not supported for this target])
2019             add_this_lang=unsupported
2020             ;;
2021         esac
2022
2023         case $add_this_lang in
2024           unsupported)
2025             # Remove language-dependent dirs.
2026             disabled_target_libs="$disabled_target_libs $target_libs"
2027             noconfigdirs="$noconfigdirs $lang_dirs"
2028             ;;
2029           no)
2030             # Remove language-dependent dirs; still show language as supported.
2031             disabled_target_libs="$disabled_target_libs $target_libs"
2032             noconfigdirs="$noconfigdirs $lang_dirs"
2033             potential_languages="${potential_languages}${language},"
2034             ;;
2035           all|yes)
2036             new_enable_languages="${new_enable_languages}${language},"
2037             potential_languages="${potential_languages}${language},"
2038             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
2039             enabled_target_libs="$enabled_target_libs $target_libs"
2040             case "${boot_language}:,$enable_stage1_languages," in
2041               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
2042                 # Add to (comma-separated) list of stage 1 languages.
2043                 case ",$stage1_languages," in
2044                   *,$language,* | ,yes, | ,all,) ;;
2045                   *) stage1_languages="${stage1_languages}${language}," ;;
2046                 esac
2047                 # We need to bootstrap any supporting libraries.
2048                 bootstrap_target_libs="${bootstrap_target_libs}${target_libs},"
2049                 ;;
2050             esac
2051             ;;
2052         esac
2053         ;;
2054     esac
2055   done
2056
2057   # Add target libraries which are only needed for disabled languages
2058   # to noconfigdirs.
2059   if test -n "$disabled_target_libs"; then
2060     for dir in $disabled_target_libs; do
2061       case " $enabled_target_libs " in
2062       *" ${dir} "*) ;;
2063       *) noconfigdirs="$noconfigdirs $dir" ;;
2064       esac
2065     done
2066   fi
2067
2068   AC_ARG_ENABLE(stage1-languages,
2069   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
2070                   [choose additional languages to build during
2071                   stage1.  Mostly useful for compiler development])],
2072   [case ,${enable_stage1_languages}, in
2073     ,no,|,,)
2074       # Set it to something that will have no effect in the loop below
2075       enable_stage1_languages=c ;;
2076     ,yes,)
2077       enable_stage1_languages=`echo $new_enable_languages | \
2078         sed -e "s/^,//" -e "s/,$//" ` ;;
2079     *,all,*)
2080       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
2081         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
2082   esac
2083
2084   # Add "good" languages from enable_stage1_languages to stage1_languages,
2085   # while "bad" languages go in missing_languages.  Leave no duplicates.
2086   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
2087     case $potential_languages in
2088       *,$i,*)
2089         case $stage1_languages in
2090           *,$i,*) ;;
2091           *) stage1_languages="$stage1_languages$i," ;;
2092         esac ;;
2093       *)
2094         case $missing_languages in
2095           *,$i,*) ;;
2096           *) missing_languages="$missing_languages$i," ;;
2097         esac ;;
2098      esac
2099   done])
2100
2101   # Remove leading/trailing commas that were added for simplicity
2102   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
2103   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
2104   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
2105   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
2106
2107   if test "x$missing_languages" != x; then
2108     AC_MSG_ERROR([
2109 The following requested languages could not be built: ${missing_languages}
2110 Supported languages are: ${potential_languages}])
2111   fi
2112   if test "x$new_enable_languages" != "x$enable_languages"; then
2113     echo The following languages will be built: ${new_enable_languages}
2114     enable_languages="$new_enable_languages"
2115   fi
2116
2117   AC_SUBST(stage1_languages)
2118   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
2119 fi
2120
2121 # Handle --disable-<component> generically.
2122 for dir in $configdirs $build_configdirs $target_configdirs ; do
2123   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
2124   varname=`echo $dirname | sed -e s/+/_/g`
2125   if eval test x\${enable_${varname}} "=" xno ; then
2126     noconfigdirs="$noconfigdirs $dir"
2127   fi
2128 done
2129
2130 # Check for Boehm's garbage collector
2131 AC_ARG_ENABLE(objc-gc,
2132 [AS_HELP_STRING([--enable-objc-gc],
2133                 [enable use of Boehm's garbage collector with the
2134                  GNU Objective-C runtime])])
2135 AC_ARG_WITH([target-bdw-gc],
2136 [AS_HELP_STRING([--with-target-bdw-gc=PATHLIST],
2137                 [specify prefix directory for installed bdw-gc package.
2138                  Equivalent to --with-target-bdw-gc-include=PATH/include
2139                  plus --with-target-bdw-gc-lib=PATH/lib])])
2140 AC_ARG_WITH([target-bdw-gc-include],
2141 [AS_HELP_STRING([--with-target-bdw-gc-include=PATHLIST],
2142                 [specify directories for installed bdw-gc include files])])
2143 AC_ARG_WITH([target-bdw-gc-lib],
2144 [AS_HELP_STRING([--with-target-bdw-gc-lib=PATHLIST],
2145                 [specify directories for installed bdw-gc library])])
2146
2147 case ,${enable_languages},:${enable_objc_gc} in *,objc,*:yes|*,objc,*:auto)
2148   AC_MSG_CHECKING([for bdw garbage collector])
2149   if test "x$with_target_bdw_gc$with_target_bdw_gc_include$with_target_bdw_gc_lib" = x; then
2150     dnl no bdw-gw options, assume default locations
2151     AC_MSG_RESULT([using bdw-gc in default locations])
2152   else
2153     dnl bdw-gw options, first error checking, complete checking in libobjc
2154     if test "x$with_target_bdw_gc_include" = x && test "x$with_target_bdw_gc_lib" != x; then
2155       AC_MSG_ERROR([found --with-target-bdw-gc-lib but --with-target-bdw-gc-include missing])
2156     elif test "x$with_target_bdw_gc_include" != x && test "x$with_target_bdw_gc_lib" = x; then
2157       AC_MSG_ERROR([found --with-target-bdw-gc-include but --with-target-bdw-gc-lib missing])
2158     else
2159       AC_MSG_RESULT([using paths configured with --with-target-bdw-gc options])
2160     fi
2161   fi
2162 esac
2163
2164 # Disable libitm, libsanitizer, libvtv, liboffloadmic if we're not building C++
2165 case ,${enable_languages}, in
2166   *,c++,*)
2167     # Disable libitm, libsanitizer if we're not building libstdc++
2168     case "${noconfigdirs}" in
2169       *target-libstdc++-v3*)
2170         noconfigdirs="$noconfigdirs target-libitm target-libsanitizer"
2171         ;;
2172       *) ;;
2173     esac
2174     ;;
2175   *)
2176     noconfigdirs="$noconfigdirs target-liboffloadmic target-libitm target-libsanitizer target-libvtv"
2177     ;;
2178 esac
2179
2180 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
2181 # $build_configdirs and $target_configdirs.
2182 # If we have the source for $noconfigdirs entries, add them to $notsupp.
2183
2184 notsupp=""
2185 for dir in . $skipdirs $noconfigdirs ; do
2186   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
2187   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2188     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
2189     if test -r $srcdir/$dirname/configure ; then
2190       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2191         true
2192       else
2193         notsupp="$notsupp $dir"
2194       fi
2195     fi
2196   fi
2197   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2198     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
2199     if test -r $srcdir/$dirname/configure ; then
2200       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2201         true
2202       else
2203         notsupp="$notsupp $dir"
2204       fi
2205     fi
2206   fi
2207   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2208     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
2209     if test -r $srcdir/$dirname/configure ; then
2210       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2211         true
2212       else
2213         notsupp="$notsupp $dir"
2214       fi
2215     fi
2216   fi
2217 done
2218
2219 # Quietly strip out all directories which aren't configurable in this tree.
2220 # This relies on all configurable subdirectories being autoconfiscated, which
2221 # is now the case.
2222 build_configdirs_all="$build_configdirs"
2223 build_configdirs=
2224 for i in ${build_configdirs_all} ; do
2225   j=`echo $i | sed -e s/build-//g`
2226   if test -f ${srcdir}/$j/configure ; then
2227     build_configdirs="${build_configdirs} $i"
2228   fi
2229 done
2230
2231 configdirs_all="$configdirs"
2232 configdirs=
2233 for i in ${configdirs_all} ; do
2234   if test -f ${srcdir}/$i/configure ; then
2235     configdirs="${configdirs} $i"
2236   fi
2237 done
2238
2239 target_configdirs_all="$target_configdirs"
2240 target_configdirs=
2241 for i in ${target_configdirs_all} ; do
2242   j=`echo $i | sed -e s/target-//g`
2243   if test -f ${srcdir}/$j/configure ; then
2244     target_configdirs="${target_configdirs} $i"
2245   fi
2246 done
2247
2248 # libiberty-linker-plugin is special: it doesn't have its own source directory,
2249 # so we have to add it after the preceding checks.
2250 if test x"$extra_linker_plugin_flags$extra_linker_plugin_configure_flags" != x
2251 then
2252   case " $configdirs " in
2253     *" libiberty "*)
2254       # If we can build libiberty, we can also build libiberty-linker-plugin.
2255       configdirs="$configdirs libiberty-linker-plugin"
2256       extra_linker_plugin_configure_flags="$extra_linker_plugin_configure_flags \
2257         --with-libiberty=../libiberty-linker-plugin";;
2258     *)
2259       AC_MSG_ERROR([libiberty missing]);;
2260   esac
2261 fi
2262
2263 # Sometimes we have special requirements for the host libiberty.
2264 extra_host_libiberty_configure_flags=
2265 extra_host_zlib_configure_flags=
2266 case " $configdirs " in
2267   *" lto-plugin "* | *" libcc1 "*)
2268     # When these are to be built as shared libraries, the same applies to
2269     # libiberty.
2270     extra_host_libiberty_configure_flags=--enable-shared
2271     ;;
2272   *" bfd "*)
2273     # When bfd is to be built as a shared library, the same applies to
2274     # zlib.
2275     if test "$enable_shared" = "yes"; then
2276       extra_host_zlib_configure_flags=--enable-host-shared
2277     fi
2278     ;;
2279 esac
2280 AC_SUBST(extra_host_libiberty_configure_flags)
2281 AC_SUBST(extra_host_zlib_configure_flags)
2282
2283 # Produce a warning message for the subdirs we can't configure.
2284 # This isn't especially interesting in the Cygnus tree, but in the individual
2285 # FSF releases, it's important to let people know when their machine isn't
2286 # supported by the one or two programs in a package.
2287
2288 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2289   # If $appdirs is non-empty, at least one of those directories must still
2290   # be configured, or we error out.  (E.g., if the gas release supports a
2291   # specified target in some subdirs but not the gas subdir, we shouldn't
2292   # pretend that all is well.)
2293   if test -n "$appdirs" ; then
2294     for dir in $appdirs ; do
2295       if test -r $dir/Makefile.in ; then
2296         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2297           appdirs=""
2298           break
2299         fi
2300         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2301           appdirs=""
2302           break
2303         fi
2304       fi
2305     done
2306     if test -n "$appdirs" ; then
2307       echo "*** This configuration is not supported by this package." 1>&2
2308       exit 1
2309     fi
2310   fi
2311   # Okay, some application will build, or we don't care to check.  Still
2312   # notify of subdirs not getting built.
2313   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2314   echo "    ${notsupp}" 1>&2
2315   echo "    (Any other directories should still work fine.)" 1>&2
2316 fi
2317
2318 case "$host" in
2319   *msdosdjgpp*)
2320     enable_gdbtk=no ;;
2321 esac
2322
2323 # To find our prefix, in gcc_cv_tool_prefix.
2324 ACX_TOOL_DIRS
2325
2326 copy_dirs=
2327
2328 AC_ARG_WITH([build-sysroot],
2329   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2330                   [use sysroot as the system root during the build])],
2331   [if test x"$withval" != x ; then
2332      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2333    fi],
2334   [SYSROOT_CFLAGS_FOR_TARGET=])
2335 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2336
2337 AC_ARG_WITH([debug-prefix-map],
2338   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2339                   [map A to B, C to D ... in debug information])],
2340   [if test x"$withval" != x; then
2341      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2342      for debug_map in $withval; do
2343        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2344      done
2345    fi],
2346   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2347 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2348
2349 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2350 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2351 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2352 # We want to ensure that TARGET libraries (which we know are built with
2353 # gcc) are built with "-O2 -g", so include those options when setting
2354 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2355 if test "x$CFLAGS_FOR_TARGET" = x; then
2356   if test "x${is_cross_compiler}" = xyes; then
2357     CFLAGS_FOR_TARGET="-g -O2"
2358   else
2359     CFLAGS_FOR_TARGET=$CFLAGS
2360     case " $CFLAGS " in
2361       *" -O2 "*) ;;
2362       *) CFLAGS_FOR_TARGET="-O2 $CFLAGS_FOR_TARGET" ;;
2363     esac
2364     case " $CFLAGS " in
2365       *" -g "* | *" -g3 "*) ;;
2366       *) CFLAGS_FOR_TARGET="-g $CFLAGS_FOR_TARGET" ;;
2367     esac
2368   fi
2369 fi
2370 AC_SUBST(CFLAGS_FOR_TARGET)
2371
2372 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2373   if test "x${is_cross_compiler}" = xyes; then
2374     CXXFLAGS_FOR_TARGET="-g -O2"
2375   else
2376     CXXFLAGS_FOR_TARGET=$CXXFLAGS
2377     case " $CXXFLAGS " in
2378       *" -O2 "*) ;;
2379       *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS_FOR_TARGET" ;;
2380     esac
2381     case " $CXXFLAGS " in
2382       *" -g "* | *" -g3 "*) ;;
2383       *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS_FOR_TARGET" ;;
2384     esac
2385   fi
2386 fi
2387 AC_SUBST(CXXFLAGS_FOR_TARGET)
2388
2389 AC_SUBST(LDFLAGS_FOR_TARGET)
2390
2391 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2392 # the named directory are copied to $(tooldir)/sys-include.
2393 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2394   if test x${is_cross_compiler} = xno ; then
2395     echo 1>&2 '***' --with-headers is only supported when cross compiling
2396     exit 1
2397   fi
2398   if test x"${with_headers}" != xyes ; then
2399     x=${gcc_cv_tool_prefix}
2400     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2401   fi
2402 fi
2403
2404 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2405 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2406 # are permitted.
2407 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2408   if test x${is_cross_compiler} = xno ; then
2409     echo 1>&2 '***' --with-libs is only supported when cross compiling
2410     exit 1
2411   fi
2412   if test x"${with_libs}" != xyes ; then
2413     # Copy the libraries in reverse order, so that files in the first named
2414     # library override files in subsequent libraries.
2415     x=${gcc_cv_tool_prefix}
2416     for l in ${with_libs}; do
2417       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2418     done
2419   fi
2420 fi
2421
2422 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2423 #
2424 # This is done by determining whether or not the appropriate directory
2425 # is available, and by checking whether or not specific configurations
2426 # have requested that this magic not happen.
2427 #
2428 # The command line options always override the explicit settings in
2429 # configure.ac, and the settings in configure.ac override this magic.
2430 #
2431 # If the default for a toolchain is to use GNU as and ld, and you don't
2432 # want to do that, then you should use the --without-gnu-as and
2433 # --without-gnu-ld options for the configure script.  Similarly, if
2434 # the default is to use the included zlib and you don't want to do that,
2435 # you should use the --with-system-zlib option for the configure script.
2436
2437 if test x${use_gnu_as} = x &&
2438    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2439   with_gnu_as=yes
2440   extra_host_args="$extra_host_args --with-gnu-as"
2441 fi
2442
2443 if test x${use_gnu_ld} = x &&
2444    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2445   with_gnu_ld=yes
2446   extra_host_args="$extra_host_args --with-gnu-ld"
2447 fi
2448
2449 if test x${use_included_zlib} = x &&
2450    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2451   :
2452 else
2453   with_system_zlib=yes
2454   extra_host_args="$extra_host_args --with-system-zlib"
2455 fi
2456
2457 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2458 # can detect this case.
2459
2460 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2461   with_newlib=yes
2462   extra_host_args="$extra_host_args --with-newlib"
2463 fi
2464
2465 # Handle ${copy_dirs}
2466 set fnord ${copy_dirs}
2467 shift
2468 while test $# != 0 ; do
2469   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2470     :
2471   else
2472     echo Copying $1 to $2
2473
2474     # Use the install script to create the directory and all required
2475     # parent directories.
2476     if test -d $2 ; then
2477       :
2478     else
2479       echo >config.temp
2480       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2481     fi
2482
2483     # Copy the directory, assuming we have tar.
2484     # FIXME: Should we use B in the second tar?  Not all systems support it.
2485     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2486
2487     # It is the responsibility of the user to correctly adjust all
2488     # symlinks.  If somebody can figure out how to handle them correctly
2489     # here, feel free to add the code.
2490
2491     echo $1 > $2/COPIED
2492   fi
2493   shift; shift
2494 done
2495
2496 # Determine a target-dependent exec_prefix that the installed
2497 # gcc will search in.  Keep this list sorted by triplet, with
2498 # the *-*-osname triplets last.
2499 md_exec_prefix=
2500 case "${target}" in
2501   i[[34567]]86-pc-msdosdjgpp*)
2502     md_exec_prefix=/dev/env/DJDIR/bin
2503     ;;
2504   *-*-hpux* | \
2505   *-*-nto-qnx* | \
2506   *-*-solaris2*)
2507     md_exec_prefix=/usr/ccs/bin
2508     ;;
2509 esac
2510
2511 extra_arflags_for_target=
2512 extra_nmflags_for_target=
2513 extra_ranlibflags_for_target=
2514 target_makefile_frag=/dev/null
2515 case "${target}" in
2516   spu-*-*)
2517     target_makefile_frag="config/mt-spu"
2518     ;;
2519   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
2520     target_makefile_frag="config/mt-sde"
2521     ;;
2522   mipsisa*-*-elfoabi*)
2523     target_makefile_frag="config/mt-mips-elfoabi"
2524     ;;
2525   mips*-*-*linux* | mips*-*-gnu*)
2526     target_makefile_frag="config/mt-mips-gnu"
2527     ;;
2528   nios2-*-elf*)
2529     target_makefile_frag="config/mt-nios2-elf"
2530     ;;
2531   *-*-linux-android*)
2532     target_makefile_frag="config/mt-android"
2533     ;;
2534   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2535     target_makefile_frag="config/mt-gnu"
2536     ;;
2537   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2538     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2539     # commands to handle both 32-bit and 64-bit objects.  These flags are
2540     # harmless if we're using GNU nm or ar.
2541     extra_arflags_for_target=" -X32_64"
2542     extra_nmflags_for_target=" -B -X32_64"
2543     ;;
2544 esac
2545
2546 alphaieee_frag=/dev/null
2547 case $target in
2548   alpha*-*-*)
2549     # This just makes sure to use the -mieee option to build target libs.
2550     # This should probably be set individually by each library.
2551     alphaieee_frag="config/mt-alphaieee"
2552     ;;
2553 esac
2554
2555 # If --enable-target-optspace always use -Os instead of -O2 to build
2556 # the target libraries, similarly if it is not specified, use -Os
2557 # on selected platforms.
2558 ospace_frag=/dev/null
2559 case "${enable_target_optspace}:${target}" in
2560   yes:*)
2561     ospace_frag="config/mt-ospace"
2562     ;;
2563   :d30v-*)
2564     ospace_frag="config/mt-d30v"
2565     ;;
2566   :m32r-* | :d10v-* | :fr30-* | :i?86*-*-elfiamcu)
2567     ospace_frag="config/mt-ospace"
2568     ;;
2569   no:* | :*)
2570     ;;
2571   *)
2572     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2573     ;;
2574 esac
2575
2576 # Some systems (e.g., one of the i386-aix systems the gas testers are
2577 # using) don't handle "\$" correctly, so don't use it here.
2578 tooldir='${exec_prefix}'/${target_noncanonical}
2579 build_tooldir=${tooldir}
2580
2581 # Create a .gdbinit file which runs the one in srcdir
2582 # and tells GDB to look there for source files.
2583
2584 if test -r ${srcdir}/.gdbinit ; then
2585   case ${srcdir} in
2586     .) ;;
2587     *) cat > ./.gdbinit <<EOF
2588 # ${NO_EDIT}
2589 dir ${srcdir}
2590 dir .
2591 source ${srcdir}/.gdbinit
2592 EOF
2593     ;;
2594   esac
2595 fi
2596
2597 # Make sure that the compiler is able to generate an executable.  If it
2598 # can't, we are probably in trouble.  We don't care whether we can run the
2599 # executable--we might be using a cross compiler--we only care whether it
2600 # can be created.  At this point the main configure script has set CC.
2601 we_are_ok=no
2602 echo "int main () { return 0; }" > conftest.c
2603 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2604 if test $? = 0 ; then
2605   if test -s conftest || test -s conftest.exe ; then
2606     we_are_ok=yes
2607   fi
2608 fi
2609 case $we_are_ok in
2610   no)
2611     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2612     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2613     rm -f conftest*
2614     exit 1
2615     ;;
2616 esac
2617 rm -f conftest*
2618
2619 # Decide which environment variable is used to find dynamic libraries.
2620 case "${host}" in
2621   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2622   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2623   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2624   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2625 esac
2626
2627 # On systems where the dynamic library environment variable is PATH,
2628 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2629 # built executables to PATH.
2630 if test "$RPATH_ENVVAR" = PATH; then
2631   GCC_SHLIB_SUBDIR=/shlib
2632 else
2633   GCC_SHLIB_SUBDIR=
2634 fi
2635
2636 # Adjust the toplevel makefile according to whether bootstrap was selected.
2637 case $enable_bootstrap in
2638   yes)
2639     bootstrap_suffix=bootstrap
2640     BUILD_CONFIG=bootstrap-debug
2641     ;;
2642   no)
2643     bootstrap_suffix=no-bootstrap
2644     BUILD_CONFIG=
2645     ;;
2646 esac
2647
2648 AC_MSG_CHECKING(for default BUILD_CONFIG)
2649
2650 AC_ARG_WITH([build-config],
2651   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2652                   [use config/NAME.mk build configuration])],
2653   [case $with_build_config in
2654    yes) with_build_config= ;;
2655    no) with_build_config= BUILD_CONFIG= ;;
2656    esac])
2657
2658 if test "x${with_build_config}" != x; then
2659   BUILD_CONFIG=$with_build_config
2660 else
2661   case $BUILD_CONFIG in
2662   bootstrap-debug)
2663     if echo "int f (void) { return 0; }" > conftest.c &&
2664        ${CC} -c conftest.c &&
2665        mv conftest.o conftest.o.g0 &&
2666        ${CC} -c -g conftest.c &&
2667        mv conftest.o conftest.o.g &&
2668        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
2669       :
2670     else
2671       BUILD_CONFIG=
2672     fi
2673     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2674     ;;
2675   esac
2676 fi
2677 AC_MSG_RESULT($BUILD_CONFIG)
2678 AC_SUBST(BUILD_CONFIG)
2679
2680 # Use same top-level configure hooks in libgcc/libstdc++/libvtv.
2681 AC_MSG_CHECKING([for --enable-vtable-verify])
2682 AC_ARG_ENABLE(vtable-verify,
2683 [AS_HELP_STRING([--enable-vtable-verify],
2684                 [Enable vtable verification feature])],
2685 [case "$enableval" in
2686  yes) enable_vtable_verify=yes ;;
2687  no)  enable_vtable_verify=no ;;
2688  *)   enable_vtable_verify=no;;
2689  esac],
2690 [enable_vtable_verify=no])
2691 AC_MSG_RESULT($enable_vtable_verify)
2692
2693 # Record target_configdirs and the configure arguments for target and
2694 # build configuration in Makefile.
2695 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
2696 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
2697 bootstrap_fixincludes=no
2698
2699 # If we are building libgomp, bootstrap it.
2700 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
2701   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
2702 fi
2703
2704 # If we are building libsanitizer and $BUILD_CONFIG contains bootstrap-asan
2705 # or bootstrap-ubsan, bootstrap it.
2706 if echo " ${target_configdirs} " | grep " libsanitizer " > /dev/null 2>&1; then
2707   case "$BUILD_CONFIG" in
2708     *bootstrap-asan* | *bootstrap-ubsan* )
2709       bootstrap_target_libs=${bootstrap_target_libs}target-libsanitizer,
2710       bootstrap_fixincludes=yes
2711       ;;
2712   esac
2713 fi
2714
2715 # If we are building libvtv and --enable-vtable-verify, bootstrap it.
2716 if echo " ${target_configdirs} " | grep " libvtv " > /dev/null 2>&1 &&
2717    test "$enable_vtable_verify" != no; then
2718   bootstrap_target_libs=${bootstrap_target_libs}target-libvtv,
2719 fi
2720
2721 # Determine whether gdb needs tk/tcl or not.
2722 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
2723 # and in that case we want gdb to be built without tk.  Ugh!
2724 # In fact I believe gdb is the *only* package directly dependent on tk,
2725 # so we should be able to put the 'maybe's in unconditionally and
2726 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
2727 # 100% sure that that's safe though.
2728
2729 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
2730 case "$enable_gdbtk" in
2731   no)
2732     GDB_TK="" ;;
2733   yes)
2734     GDB_TK="${gdb_tk}" ;;
2735   *)
2736     # Only add the dependency on gdbtk when GDBtk is part of the gdb
2737     # distro.  Eventually someone will fix this and move Insight, nee
2738     # gdbtk to a separate directory.
2739     if test -d ${srcdir}/gdb/gdbtk ; then
2740       GDB_TK="${gdb_tk}"
2741     else
2742       GDB_TK=""
2743     fi
2744     ;;
2745 esac
2746 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
2747 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
2748
2749 # gdb and gdbserver depend on gnulib and gdbsupport, but as nothing
2750 # else does, only include them if one of these is built.  The Makefile
2751 # provides the ordering, so it's enough here to add to the list.
2752 case " ${configdirs} " in
2753   *\ gdb\ *)
2754     configdirs="${configdirs} gnulib gdbsupport"
2755     ;;
2756   *\ gdbserver\ *)
2757     configdirs="${configdirs} gnulib gdbsupport"
2758     ;;
2759 esac
2760
2761 # Strip out unwanted targets.
2762
2763 # While at that, we remove Makefiles if we were started for recursive
2764 # configuration, so that the top-level Makefile reconfigures them,
2765 # like we used to do when configure itself was recursive.
2766
2767 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
2768 # but now we're fixing up the Makefile ourselves with the additional
2769 # commands passed to AC_CONFIG_FILES.  Use separate variables
2770 # extrasub-{build,host,target} not because there is any reason to split
2771 # the substitutions up that way, but only to remain below the limit of
2772 # 99 commands in a script, for HP-UX sed.
2773
2774 # Do not nest @if/@endif or @unless/@endunless pairs, because
2775 # configure will not warn you at all.
2776
2777 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
2778   yes:yes:*\ gold\ *:*,c++,*) ;;
2779   yes:yes:*\ gold\ *:*)
2780     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
2781     ;;
2782 esac
2783
2784 extrasub_build=
2785 for module in ${build_configdirs} ; do
2786   if test -z "${no_recursion}" \
2787      && test -f ${build_subdir}/${module}/Makefile; then
2788     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
2789     rm -f ${build_subdir}/${module}/Makefile
2790   fi
2791   extrasub_build="$extrasub_build
2792 /^@if build-$module\$/d
2793 /^@endif build-$module\$/d
2794 /^@unless build-$module\$/,/^@endunless build-$module\$/d
2795 /^@if build-$module-$bootstrap_suffix\$/d
2796 /^@endif build-$module-$bootstrap_suffix\$/d
2797 /^@unless build-$module-$bootstrap_suffix\$/,/^@endunless build-$module-$bootstrap_suffix\$/d"
2798 done
2799 extrasub_host=
2800 for module in ${configdirs} ; do
2801   if test -z "${no_recursion}"; then
2802     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
2803       if test -f ${file}; then
2804         echo 1>&2 "*** removing ${file} to force reconfigure"
2805         rm -f ${file}
2806       fi
2807     done
2808   fi
2809   case ${module},${bootstrap_fixincludes} in
2810     fixincludes,no) host_bootstrap_suffix=no-bootstrap ;;
2811     *) host_bootstrap_suffix=$bootstrap_suffix ;;
2812   esac
2813   extrasub_host="$extrasub_host
2814 /^@if $module\$/d
2815 /^@endif $module\$/d
2816 /^@unless $module\$/,/^@endunless $module\$/d
2817 /^@if $module-$host_bootstrap_suffix\$/d
2818 /^@endif $module-$host_bootstrap_suffix\$/d
2819 /^@unless $module-$host_bootstrap_suffix\$/,/^@endunless $module-$host_bootstrap_suffix\$/d"
2820 done
2821 extrasub_target=
2822 for module in ${target_configdirs} ; do
2823   if test -z "${no_recursion}" \
2824      && test -f ${target_subdir}/${module}/Makefile; then
2825     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
2826     rm -f ${target_subdir}/${module}/Makefile
2827   fi
2828
2829   # We only bootstrap target libraries listed in bootstrap_target_libs.
2830   case $bootstrap_target_libs in
2831     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
2832     *) target_bootstrap_suffix=no-bootstrap ;;
2833   esac
2834
2835   extrasub_target="$extrasub_target
2836 /^@if target-$module\$/d
2837 /^@endif target-$module\$/d
2838 /^@unless target-$module\$/,/^@endunless target-$module\$/d
2839 /^@if target-$module-$target_bootstrap_suffix\$/d
2840 /^@endif target-$module-$target_bootstrap_suffix\$/d
2841 /^@unless target-$module-$target_bootstrap_suffix\$/,/^@endunless target-$module-$target_bootstrap_suffix\$/d"
2842 done
2843
2844 # Do the final fixup along with target modules.
2845 extrasub_target="$extrasub_target
2846 /^@if /,/^@endif /d
2847 /^@unless /d
2848 /^@endunless /d"
2849
2850 # Create the serialization dependencies.  This uses a temporary file.
2851
2852 AC_ARG_ENABLE([serial-configure],
2853 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
2854                 [force sequential configuration of
2855                  sub-packages for the host, target or build
2856                  machine, or all sub-packages])])
2857
2858 case ${enable_serial_configure} in
2859   yes)
2860     enable_serial_build_configure=yes
2861     enable_serial_host_configure=yes
2862     enable_serial_target_configure=yes
2863     ;;
2864 esac
2865
2866 # These force 'configure's to be done one at a time, to avoid problems
2867 # with contention over a shared config.cache.
2868 rm -f serdep.tmp
2869 echo '# serdep.tmp' > serdep.tmp
2870 olditem=
2871 test "x${enable_serial_build_configure}" = xyes &&
2872 for item in ${build_configdirs} ; do
2873   case ${olditem} in
2874     "") ;;
2875     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
2876   esac
2877   olditem=${item}
2878 done
2879 olditem=
2880 test "x${enable_serial_host_configure}" = xyes &&
2881 for item in ${configdirs} ; do
2882   case ${olditem} in
2883     "") ;;
2884     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
2885   esac
2886   olditem=${item}
2887 done
2888 olditem=
2889 test "x${enable_serial_target_configure}" = xyes &&
2890 for item in ${target_configdirs} ; do
2891   case ${olditem} in
2892     "") ;;
2893     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
2894   esac
2895   olditem=${item}
2896 done
2897 serialization_dependencies=serdep.tmp
2898 AC_SUBST_FILE(serialization_dependencies)
2899
2900 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
2901 # target, nonopt, and variable assignments.  These are the ones we
2902 # might not want to pass down to subconfigures.  The exception being
2903 # --cache-file=/dev/null, which is used to turn off the use of cache
2904 # files altogether, and which should be passed on to subconfigures.
2905 # Also strip program-prefix, program-suffix, and program-transform-name,
2906 # so that we can pass down a consistent program-transform-name.
2907 baseargs=
2908 tbaseargs=
2909 keep_next=no
2910 skip_next=no
2911 eval "set -- $ac_configure_args"
2912 for ac_arg
2913 do
2914   if test X"$skip_next" = X"yes"; then
2915     skip_next=no
2916     continue
2917   fi
2918   if test X"$keep_next" = X"yes"; then
2919     case $ac_arg in
2920       *\'*)
2921         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2922     esac
2923     baseargs="$baseargs '$ac_arg'"
2924     tbaseargs="$tbaseargs '$ac_arg'"
2925     keep_next=no
2926     continue
2927   fi
2928
2929   # Handle separated arguments.  Based on the logic generated by
2930   # autoconf 2.59.
2931   case $ac_arg in
2932     *=* | --config-cache | -C | -disable-* | --disable-* \
2933       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
2934       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
2935       | -with-* | --with-* | -without-* | --without-* | --x)
2936       separate_arg=no
2937       ;;
2938     -*)
2939       separate_arg=yes
2940       ;;
2941     *)
2942       separate_arg=no
2943       ;;
2944   esac
2945
2946   skip_targ=no
2947   case $ac_arg in
2948 changequote(,)
2949   --with-* | --without-*)
2950     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
2951
2952     case $libopt in
2953     *[-_]include)
2954       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
2955       ;;
2956     *[-_]lib)
2957       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
2958       ;;
2959     *)
2960       lib=$libopt
2961       ;;
2962     esac
2963 changequote([,])
2964
2965     case $lib in
2966     mpc | mpfr | gmp | isl)
2967       # If we're processing --with-$lib, --with-$lib-include or
2968       # --with-$lib-lib, for one of the libs above, and target is
2969       # different from host, don't pass the current argument to any
2970       # target library's configure.
2971       if test x$is_cross_compiler = xyes; then
2972         skip_targ=yes
2973       fi
2974       ;;
2975     esac
2976     ;;
2977   esac
2978
2979   case "$ac_arg" in
2980     --cache-file=/dev/null | \
2981     -cache-file=/dev/null )
2982       # Handled here to avoid the test to skip args below.
2983       baseargs="$baseargs '$ac_arg'"
2984       tbaseargs="$tbaseargs '$ac_arg'"
2985       # Assert: $separate_arg should always be no.
2986       keep_next=$separate_arg
2987       ;;
2988     --no*)
2989       continue
2990       ;;
2991     --c* | \
2992     --sr* | \
2993     --ho* | \
2994     --bu* | \
2995     --t* | \
2996     --program-* | \
2997     -cache_file* | \
2998     -srcdir* | \
2999     -host* | \
3000     -build* | \
3001     -target* | \
3002     -program-prefix* | \
3003     -program-suffix* | \
3004     -program-transform-name* )
3005       skip_next=$separate_arg
3006       continue
3007       ;;
3008     -*)
3009       # An option.  Add it.
3010       case $ac_arg in
3011         *\'*)
3012           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
3013       esac
3014       baseargs="$baseargs '$ac_arg'"
3015       if test X"$skip_targ" = Xno; then
3016         tbaseargs="$tbaseargs '$ac_arg'"
3017       fi
3018       keep_next=$separate_arg
3019       ;;
3020     *)
3021       # Either a variable assignment, or a nonopt (triplet).  Don't
3022       # pass it down; let the Makefile handle this.
3023       continue
3024       ;;
3025   esac
3026 done
3027 # Remove the initial space we just introduced and, as these will be
3028 # expanded by make, quote '$'.
3029 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
3030
3031 # Add in --program-transform-name, after --program-prefix and
3032 # --program-suffix have been applied to it.  Autoconf has already
3033 # doubled dollar signs and backslashes in program_transform_name; we want
3034 # the backslashes un-doubled, and then the entire thing wrapped in single
3035 # quotes, because this will be expanded first by make and then by the shell.
3036 # Also, because we want to override the logic in subdir configure scripts to
3037 # choose program_transform_name, replace any s,x,x, with s,y,y,.
3038 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
3039 ${program_transform_name}
3040 EOF_SED
3041 gcc_transform_name=`cat conftestsed.out`
3042 rm -f conftestsed.out
3043 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
3044 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
3045 if test "$silent" = yes; then
3046   baseargs="$baseargs --silent"
3047   tbaseargs="$tbaseargs --silent"
3048 fi
3049 baseargs="$baseargs --disable-option-checking"
3050 tbaseargs="$tbaseargs --disable-option-checking"
3051
3052 # Record and document user additions to sub configure arguments.
3053 AC_ARG_VAR([build_configargs],
3054            [additional configure arguments for build directories])
3055 AC_ARG_VAR([host_configargs],
3056            [additional configure arguments for host directories])
3057 AC_ARG_VAR([target_configargs],
3058            [additional configure arguments for target directories])
3059
3060 # For the build-side libraries, we just need to pretend we're native,
3061 # and not use the same cache file.  Multilibs are neither needed nor
3062 # desired.  We can't even use the same cache file for all build-side
3063 # libraries, as they're compiled differently; some with C, some with
3064 # C++ or with different feature-enabling options.
3065 build_configargs="$build_configargs --cache-file=./config.cache ${baseargs}"
3066
3067 # For host modules, accept cache file option, or specification as blank.
3068 case "${cache_file}" in
3069 "") # empty
3070   cache_file_option="" ;;
3071 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
3072   cache_file_option="--cache-file=${cache_file}" ;;
3073 *) # relative path
3074   cache_file_option="--cache-file=../${cache_file}" ;;
3075 esac
3076
3077 # Host dirs don't like to share a cache file either, horribly enough.
3078 # This seems to be due to autoconf 2.5x stupidity.
3079 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}"
3080
3081 target_configargs="$target_configargs ${tbaseargs}"
3082
3083 # Passing a --with-cross-host argument lets the target libraries know
3084 # whether they are being built with a cross-compiler or being built
3085 # native.  However, it would be better to use other mechanisms to make the
3086 # sorts of decisions they want to make on this basis.  Please consider
3087 # this option to be deprecated.  FIXME.
3088 if test x${is_cross_compiler} = xyes ; then
3089   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
3090 fi
3091
3092 # Special user-friendly check for native x86_64-linux build, if
3093 # multilib is not explicitly enabled.
3094 case "$target:$have_compiler:$host:$target:$enable_multilib" in
3095   x86_64-*linux*:yes:$build:$build:)
3096     # Make sure we have a development environment that handles 32-bit
3097     dev64=no
3098     echo "int main () { return 0; }" > conftest.c
3099     ${CC} -m32 -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
3100     if test $? = 0 ; then
3101       if test -s conftest || test -s conftest.exe ; then
3102         dev64=yes
3103       fi
3104     fi
3105     rm -f conftest*
3106     if test x${dev64} != xyes ; then
3107       AC_MSG_ERROR([I suspect your system does not have 32-bit development libraries (libc and headers). If you have them, rerun configure with --enable-multilib. If you do not have them, and want to build a 64-bit-only compiler, rerun configure with --disable-multilib.])
3108     fi
3109     ;;
3110 esac
3111
3112 # Default to --enable-multilib.
3113 if test x${enable_multilib} = x ; then
3114   target_configargs="--enable-multilib ${target_configargs}"
3115 fi
3116
3117 # Pass --with-newlib if appropriate.  Note that target_configdirs has
3118 # changed from the earlier setting of with_newlib.
3119 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
3120   target_configargs="--with-newlib ${target_configargs}"
3121 fi
3122
3123 # Different target subdirs use different values of certain variables
3124 # (notably CXX).  Worse, multilibs use *lots* of different values.
3125 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
3126 # it doesn't automatically accept command-line overrides of them.
3127 # This means it's not safe for target subdirs to share a cache file,
3128 # which is disgusting, but there you have it.  Hopefully this can be
3129 # fixed in future.  It's still worthwhile to use a cache file for each
3130 # directory.  I think.
3131
3132 # Pass the appropriate --build, --host, --target and --cache-file arguments.
3133 # We need to pass --target, as newer autoconf's requires consistency
3134 # for target_alias and gcc doesn't manage it consistently.
3135 target_configargs="--cache-file=./config.cache ${target_configargs}"
3136
3137 FLAGS_FOR_TARGET=
3138 case " $target_configdirs " in
3139  *" newlib "*)
3140   case " $target_configargs " in
3141   *" --with-newlib "*)
3142    case "$target" in
3143     *-cygwin*)
3144       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -isystem $$s/winsup/cygwin/include'
3145       ;;
3146    esac
3147
3148    # If we're not building GCC, don't discard standard headers.
3149    if test -d ${srcdir}/gcc; then
3150      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
3151
3152      if test "${build}" != "${host}"; then
3153        # On Canadian crosses, CC_FOR_TARGET will have already been set
3154        # by `configure', so we won't have an opportunity to add -Bgcc/
3155        # to it.  This is right: we don't want to search that directory
3156        # for binaries, but we want the header files in there, so add
3157        # them explicitly.
3158        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
3159
3160        # Someone might think of using the pre-installed headers on
3161        # Canadian crosses, in case the installed compiler is not fully
3162        # compatible with the compiler being built.  In this case, it
3163        # would be better to flag an error than risking having
3164        # incompatible object files being constructed.  We can't
3165        # guarantee that an error will be flagged, but let's hope the
3166        # compiler will do it, when presented with incompatible header
3167        # files.
3168      fi
3169    fi
3170
3171    case "${target}-${is_cross_compiler}" in
3172    i[[3456789]]86-*-linux*-no)
3173       # Here host == target, so we don't need to build gcc,
3174       # so we don't want to discard standard headers.
3175       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
3176       ;;
3177    *)
3178       # If we're building newlib, use its generic headers last, but search
3179       # for any libc-related directories first (so make it the last -B
3180       # switch).
3181       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
3182
3183       # If we're building libgloss, find the startup file, simulator library
3184       # and linker script.
3185       case " $target_configdirs " in
3186         *" libgloss "*)
3187         # Look for startup file, simulator library and maybe linker script.
3188         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
3189         # Look for libnosys.a in case the target needs it.
3190         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
3191         # Most targets have the linker script in the source directory.
3192         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
3193         ;;
3194       esac
3195       ;;
3196    esac
3197    ;;
3198   esac
3199   ;;
3200 esac
3201
3202 case "$target" in
3203   x86_64-*mingw* | *-w64-mingw*)
3204   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
3205   # however, use a symlink named 'mingw' in ${prefix} .
3206     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
3207     ;;
3208   *-mingw*)
3209   # MinGW can't be handled as Cygwin above since it does not use newlib.
3210     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
3211     ;;
3212 esac
3213
3214 # Allow the user to override the flags for
3215 # our build compiler if desired.
3216 if test x"${build}" = x"${host}" ; then
3217   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
3218   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
3219   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
3220 fi
3221
3222 # On Canadian crosses, we'll be searching the right directories for
3223 # the previously-installed cross compiler, so don't bother to add
3224 # flags for directories within the install tree of the compiler
3225 # being built; programs in there won't even run.
3226 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
3227   # Search for pre-installed headers if nothing else fits.
3228   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
3229 fi
3230
3231 if test "x${use_gnu_ld}" = x &&
3232    echo " ${configdirs} " | grep " ld " > /dev/null ; then
3233   # Arrange for us to find uninstalled linker scripts.
3234   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
3235 fi
3236
3237 # Search for other target-specific linker scripts and such.
3238 case "${target}" in
3239   mep*)
3240     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
3241     ;;
3242 esac
3243
3244 # Makefile fragments.
3245 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
3246 do
3247   eval fragval=\$$frag
3248   if test $fragval != /dev/null; then
3249     eval $frag=${srcdir}/$fragval
3250   fi
3251 done
3252 AC_SUBST_FILE(host_makefile_frag)
3253 AC_SUBST_FILE(target_makefile_frag)
3254 AC_SUBST_FILE(alphaieee_frag)
3255 AC_SUBST_FILE(ospace_frag)
3256
3257 # Miscellanea: directories, flags, etc.
3258 AC_SUBST(RPATH_ENVVAR)
3259 AC_SUBST(GCC_SHLIB_SUBDIR)
3260 AC_SUBST(tooldir)
3261 AC_SUBST(build_tooldir)
3262 AC_SUBST(CONFIGURE_GDB_TK)
3263 AC_SUBST(GDB_TK)
3264 AC_SUBST(INSTALL_GDB_TK)
3265
3266 # Build module lists & subconfigure args.
3267 AC_SUBST(build_configargs)
3268 AC_SUBST(build_configdirs)
3269
3270 # Host module lists & subconfigure args.
3271 AC_SUBST(host_configargs)
3272 AC_SUBST(configdirs)
3273 AC_SUBST(target_configdirs)
3274
3275 # Target module lists & subconfigure args.
3276 AC_SUBST(target_configargs)
3277
3278
3279 # Build tools.
3280 AC_SUBST(AR_FOR_BUILD)
3281 AC_SUBST(AS_FOR_BUILD)
3282 AC_SUBST(CC_FOR_BUILD)
3283 AC_SUBST(CFLAGS_FOR_BUILD)
3284 AC_SUBST(CXXFLAGS_FOR_BUILD)
3285 AC_SUBST(CXX_FOR_BUILD)
3286 AC_SUBST(DLLTOOL_FOR_BUILD)
3287 AC_SUBST(GFORTRAN_FOR_BUILD)
3288 AC_SUBST(GOC_FOR_BUILD)
3289 AC_SUBST(LDFLAGS_FOR_BUILD)
3290 AC_SUBST(LD_FOR_BUILD)
3291 AC_SUBST(NM_FOR_BUILD)
3292 AC_SUBST(RANLIB_FOR_BUILD)
3293 AC_SUBST(WINDMC_FOR_BUILD)
3294 AC_SUBST(WINDRES_FOR_BUILD)
3295
3296 # Generate default definitions for YACC, M4, LEX and other programs that run
3297 # on the build machine.  These are used if the Makefile can't locate these
3298 # programs in objdir.
3299 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
3300
3301 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
3302 case " $build_configdirs " in
3303   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
3304 esac
3305
3306 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
3307 case " $build_configdirs " in
3308   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
3309 esac
3310
3311 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
3312 case " $build_configdirs " in
3313   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
3314 esac
3315
3316 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3317 case " $build_configdirs " in
3318   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3319   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
3320 esac
3321
3322 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3323 case " $build_configdirs " in
3324   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3325 esac
3326
3327 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3328 case " $build_configdirs " in
3329   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3330   *)
3331 changequote(,)
3332     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3333     # higher, else we use the "missing" dummy.
3334     if ${MAKEINFO} --version \
3335        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3336       :
3337     else
3338       MAKEINFO="$MISSING makeinfo"
3339     fi
3340     ;;
3341 changequote([,])
3342 esac
3343
3344 # FIXME: expect and dejagnu may become build tools?
3345
3346 AC_CHECK_PROGS(EXPECT, expect, expect)
3347 case " $configdirs " in
3348   *" expect "*)
3349     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3350     ;;
3351 esac
3352
3353 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3354 case " $configdirs " in
3355   *" dejagnu "*)
3356     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3357     ;;
3358 esac
3359
3360
3361 # Host tools.
3362 NCN_STRICT_CHECK_TOOLS(AR, ar)
3363 NCN_STRICT_CHECK_TOOLS(AS, as)
3364 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3365 NCN_STRICT_CHECK_TOOLS(LD, ld)
3366 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3367 NCN_STRICT_CHECK_TOOLS(NM, nm)
3368 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3369 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3370 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3371 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3372 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3373 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3374 NCN_STRICT_CHECK_TOOLS(READELF, readelf)
3375 AC_SUBST(CC)
3376 AC_SUBST(CXX)
3377 AC_SUBST(CFLAGS)
3378 AC_SUBST(CXXFLAGS)
3379
3380 # Target tools.
3381 AC_ARG_WITH([build-time-tools],
3382   [AS_HELP_STRING([--with-build-time-tools=PATH],
3383                   [use given path to find target tools during the build])],
3384   [case x"$withval" in
3385      x/*) ;;
3386      *)
3387        with_build_time_tools=
3388        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3389        ;;
3390    esac],
3391   [with_build_time_tools=])
3392
3393 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3394 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3395 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3396 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3397 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3398
3399 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3400 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3401 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3402 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3403 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3404 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3405 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJCOPY_FOR_TARGET, objcopy)
3406 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3407 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3408 ACX_CHECK_INSTALLED_TARGET_TOOL(READELF_FOR_TARGET, readelf)
3409 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3410 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3411 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3412
3413 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3414
3415 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3416 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3417 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3418 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3419 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3420                 [gcc/xg++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3421                 c++)
3422 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3423                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3424                 c++)
3425 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3426 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3427 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3428                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3429 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3430                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3431 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3432 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3433 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3434 GCC_TARGET_TOOL(objcopy, OBJCOPY_FOR_TARGET, OBJCOPY, [binutils/objcopy])
3435 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3436 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3437 GCC_TARGET_TOOL(readelf, READELF_FOR_TARGET, READELF, [binutils/readelf])
3438 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3439 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3440 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3441
3442 AC_SUBST(FLAGS_FOR_TARGET)
3443 AC_SUBST(RAW_CXX_FOR_TARGET)
3444
3445 # Certain tools may need extra flags.
3446 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3447 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3448 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3449
3450 # When building target libraries, except in a Canadian cross, we use
3451 # the same toolchain as the compiler we just built.
3452 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3453 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3454 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3455 if test $host = $build; then
3456   case " $configdirs " in
3457     *" gcc "*)
3458       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3459       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3460       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3461       ;;
3462   esac
3463 fi
3464
3465 AC_SUBST(COMPILER_AS_FOR_TARGET)
3466 AC_SUBST(COMPILER_LD_FOR_TARGET)
3467 AC_SUBST(COMPILER_NM_FOR_TARGET)
3468
3469 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3470 AC_ARG_ENABLE(maintainer-mode,
3471 [AS_HELP_STRING([--enable-maintainer-mode],
3472                 [enable make rules and dependencies not useful
3473                  (and sometimes confusing) to the casual installer])],
3474       USE_MAINTAINER_MODE=$enableval,
3475       USE_MAINTAINER_MODE=no)
3476 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3477 AC_SUBST(MAINTAINER_MODE_TRUE)
3478 AC_SUBST(MAINTAINER_MODE_FALSE)
3479 if test "$USE_MAINTAINER_MODE" = yes; then
3480   MAINTAINER_MODE_TRUE=
3481   MAINTAINER_MODE_FALSE='#'
3482 else
3483   MAINTAINER_MODE_TRUE='#'
3484   MAINTAINER_MODE_FALSE=
3485 fi
3486 MAINT=$MAINTAINER_MODE_TRUE
3487 AC_SUBST(MAINT)dnl
3488
3489 # ---------------------
3490 # GCC bootstrap support
3491 # ---------------------
3492
3493 # Stage specific cflags for build.
3494 stage1_cflags="-g"
3495 case $build in
3496   vax-*-*)
3497     case ${GCC} in
3498       yes) stage1_cflags="-g -Wa,-J" ;;
3499       *) stage1_cflags="-g -J" ;;
3500     esac ;;
3501 esac
3502
3503 AC_SUBST(stage1_cflags)
3504
3505 # Enable --enable-checking in stage1 of the compiler.
3506 AC_ARG_ENABLE(stage1-checking,
3507 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3508                 [choose additional checking for stage1 of the compiler])],
3509 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3510 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3511   # For --disable-checking or implicit --enable-checking=release, avoid
3512   # setting --enable-checking=gc in the default stage1 checking for LTO
3513   # bootstraps.  See PR62077.
3514   case $BUILD_CONFIG in
3515     *lto*)
3516       stage1_checking=--enable-checking=release,misc,gimple,rtlflag,tree,types;;
3517     *)
3518       stage1_checking=--enable-checking=yes,types;;
3519   esac
3520   if test "x$enable_checking" = x && \
3521      test -d ${srcdir}/gcc && \
3522      test x"`cat ${srcdir}/gcc/DEV-PHASE`" = xexperimental; then
3523     stage1_checking=--enable-checking=yes,types,extra
3524   fi
3525 else
3526   stage1_checking=--enable-checking=$enable_checking,types
3527 fi])
3528 AC_SUBST(stage1_checking)
3529
3530 # Enable -Werror in bootstrap stage2 and later.
3531 AC_ARG_ENABLE(werror,
3532 [AS_HELP_STRING([--enable-werror],
3533                 [enable -Werror in bootstrap stage2 and later])],
3534 [
3535 case ${enable_werror} in
3536   yes) stage2_werror_flag="--enable-werror-always" ;;
3537   *) stage2_werror_flag="" ;;
3538 esac
3539 ],
3540 [
3541 if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3542   case $BUILD_CONFIG in
3543   bootstrap-debug)
3544       stage2_werror_flag="--enable-werror-always" ;;
3545   "")
3546       stage2_werror_flag="--enable-werror-always" ;;
3547   esac
3548 fi
3549 ])
3550
3551 AC_SUBST(stage2_werror_flag)
3552
3553 # Specify what files to not compare during bootstrap.
3554
3555 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3556 case "$target" in
3557   hppa*64*-*-hpux*) ;;
3558   hppa*-*-hpux*) compare_exclusions="gcc/cc*-checksum\$(objext) | */libgcc/lib2funcs* | gcc/ada/*tools/* | gcc/function-tests.o" ;;
3559   powerpc*-ibm-aix*) compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/* | *libgomp*\$(objext)" ;;
3560 esac
3561 AC_SUBST(compare_exclusions)
3562
3563 AC_CONFIG_FILES([Makefile],
3564   [sed "$extrasub_build" Makefile |
3565    sed "$extrasub_host" |
3566    sed "$extrasub_target" > mf$$
3567    mv -f mf$$ Makefile],
3568   [extrasub_build="$extrasub_build"
3569    extrasub_host="$extrasub_host"
3570    extrasub_target="$extrasub_target"])
3571 AC_OUTPUT