gdb/configure.in

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright 1995, 1996, 1997, 1998 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 2 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program; if not, write to the Free Software
  18 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  19
  20 dnl Process this file with autoconf to produce a configure script.
  21
  22 AC_PREREQ(2.5)dnl
  23 AC_INIT(main.c)
  24 AC_CONFIG_HEADER(config.h:config.in)
  25
  26 AC_PROG_CC
  27 AC_AIX
  28 AC_ISC_POSIX
  29
  30 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  31 AC_CANONICAL_SYSTEM
  32
  33 dnl gdb doesn't use gettext, but bfd does.  We call this to ensure we
  34 dnl link with the correct libraries.
  35 ALL_LINGUAS=
  36 CY_GNU_GETTEXT
  37
  38 dnl List of object files added by configure.
  39
  40 CONFIG_OBS=
  41 CONFIG_DEPS=
  42 CONFIG_SRCS=
  43
  44 configdirs="doc testsuite"
  45
  46 dnl
  47 changequote(,)dnl
  48
  49 . ${srcdir}/configure.host
  50
  51 . ${srcdir}/configure.tgt
  52
  53 dnl
  54 changequote([,])dnl
  55
  56 AC_PROG_INSTALL
  57 AC_CHECK_TOOL(AR, ar)
  58 AC_CHECK_TOOL(RANLIB, ranlib, :)
  59 AC_PROG_YACC
  60
  61 AC_ARG_PROGRAM
  62
  63 AC_TYPE_SIGNAL
  64
  65 AC_HEADER_STDC
  66 AC_CHECK_HEADERS(ctype.h curses.h endian.h libintl.h link.h \
  67                  memory.h objlist.h ptrace.h sgtty.h stddef.h stdlib.h \
  68                  string.h sys/procfs.h sys/ptrace.h sys/reg.h \
  69                  term.h termio.h termios.h unistd.h wait.h sys/wait.h \
  70                  wchar.h wctype.h asm/debugreg.h)
  71
  72 AC_HEADER_STAT
  73
  74 AC_C_CONST
  75
  76 AC_CHECK_FUNCS(setpgid sbrk sigaction isascii bzero bcopy btowc)
  77 AC_FUNC_ALLOCA
  78
  79 BFD_NEED_DECLARATION(malloc)
  80 BFD_NEED_DECLARATION(realloc)
  81 BFD_NEED_DECLARATION(free)
  82 BFD_NEED_DECLARATION(strerror)
  83 BFD_NEED_DECLARATION(strdup)
  84
  85 # If we are configured native on GNU/Linux, work around problems with sys/procfs.h
  86 if test "${target}" = "${host}"; then
  87   case "${host}" in
  88   i[[3456]]86-*-linux*)
  89         AC_DEFINE(START_INFERIOR_TRAPS_EXPECTED,2)
  90         AC_DEFINE(sys_quotactl)
  91         ;;
  92   esac
  93 fi
  94
  95 AC_MSG_CHECKING([for gregset_t type])
  96 AC_CACHE_VAL(gdb_cv_have_gregset_t,
  97 [AC_TRY_LINK([#include <sys/procfs.h>],[gregset_t *gregsetp = 0],
  98 gdb_cv_have_gregset_t=yes, gdb_cv_have_gregset_t=no)])
  99 AC_MSG_RESULT($gdb_cv_have_gregset_t)
 100 if test $gdb_cv_have_gregset_t = yes; then
 101   AC_DEFINE(HAVE_GREGSET_T)
 102 fi
 103
 104 AC_MSG_CHECKING([for fpregset_t type])
 105 AC_CACHE_VAL(gdb_cv_have_fpregset_t,
 106 [AC_TRY_LINK([#include <sys/procfs.h>],[fpregset_t *fpregsetp = 0],
 107 gdb_cv_have_fpregset_t=yes, gdb_cv_have_fpregset_t=no)])
 108 AC_MSG_RESULT($gdb_cv_have_fpregset_t)
 109 if test $gdb_cv_have_fpregset_t = yes; then
 110   AC_DEFINE(HAVE_FPREGSET_T)
 111 fi
 112
 113 dnl See if host has libm.  This is usually needed by simulators.
 114 AC_CHECK_LIB(m, main)
 115
 116 dnl Solaris puts wctype in /usr/lib/libw.a before Solaris 2.6.
 117 dnl
 118 dnl A bug in GNU ld 2.9.1 causes a problem if we link in -lw
 119 dnl under Solaris 2.6 because it is some funky empty library.
 120 dnl So only link in libw if we have to.
 121 AC_CHECK_LIB(c, wctype,: ,AC_CHECK_LIB(w, wctype))
 122
 123 dnl See if compiler supports "long long" type.
 124
 125 AC_MSG_CHECKING(for long long support in compiler)
 126 AC_CACHE_VAL(gdb_cv_c_long_long,
 127 [AC_TRY_COMPILE(, [
 128   extern long long foo;
 129   switch (foo & 2) { case 0: return 1; }
 130 ],
 131 gdb_cv_c_long_long=yes, gdb_cv_c_long_long=no)])
 132 AC_MSG_RESULT($gdb_cv_c_long_long)
 133 if test $gdb_cv_c_long_long = yes; then
 134   AC_DEFINE(CC_HAS_LONG_LONG)
 135 fi
 136
 137 dnl See if the compiler and runtime support printing long long
 138
 139 AC_MSG_CHECKING(for long long support in printf)
 140 AC_CACHE_VAL(gdb_cv_printf_has_long_long,
 141 [AC_TRY_RUN([
 142 int main () {
 143   char buf[32];
 144   long long l = 0;
 145   l = (l << 16) + 0x0123;
 146   l = (l << 16) + 0x4567;
 147   l = (l << 16) + 0x89ab;
 148   l = (l << 16) + 0xcdef;
 149   sprintf (buf, "0x%016llx", l);
 150   return (strcmp ("0x0123456789abcdef", buf));
 151 }],
 152 gdb_cv_printf_has_long_long=yes,
 153 gdb_cv_printf_has_long_long=no,
 154 gdb_cv_printf_has_long_long=no)])
 155 if test $gdb_cv_printf_has_long_long = yes; then
 156   AC_DEFINE(PRINTF_HAS_LONG_LONG)
 157 fi
 158 AC_MSG_RESULT($gdb_cv_printf_has_long_long)
 159
 160 dnl See if compiler supports "long double" type.  Can't use AC_C_LONG_DOUBLE
 161 dnl because autoconf complains about cross-compilation issues.  However, this
 162 dnl code uses the same variables as the macro for compatibility.
 163
 164 AC_MSG_CHECKING(for long double support in compiler)
 165 AC_CACHE_VAL(ac_cv_c_long_double,
 166 [AC_TRY_COMPILE(, [long double foo;],
 167 ac_cv_c_long_double=yes, ac_cv_c_long_double=no)])
 168 AC_MSG_RESULT($ac_cv_c_long_double)
 169 if test $ac_cv_c_long_double = yes; then
 170   AC_DEFINE(HAVE_LONG_DOUBLE)
 171 fi
 172
 173 dnl See if the compiler and runtime support printing long doubles
 174
 175 AC_MSG_CHECKING(for long double support in printf)
 176 AC_CACHE_VAL(gdb_cv_printf_has_long_double,
 177 [AC_TRY_RUN([
 178 int main () {
 179   char buf[16];
 180   long double f = 3.141592653;
 181   sprintf (buf, "%Lg", f);
 182   return (strncmp ("3.14159", buf, 7));
 183 }],
 184 gdb_cv_printf_has_long_double=yes,
 185 gdb_cv_printf_has_long_double=no,
 186 gdb_cv_printf_has_long_double=no)])
 187 if test $gdb_cv_printf_has_long_double = yes; then
 188   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE)
 189 fi
 190 AC_MSG_RESULT($gdb_cv_printf_has_long_double)
 191
 192 dnl See if the compiler and runtime support scanning long doubles
 193
 194 AC_MSG_CHECKING(for long double support in scanf)
 195 AC_CACHE_VAL(gdb_cv_scanf_has_long_double,
 196 [AC_TRY_RUN([
 197 int main () {
 198   char *buf = "3.141592653";
 199   long double f = 0;
 200   sscanf (buf, "%Lg", &f);
 201   return !(f > 3.14159 && f < 3.14160);
 202 }],
 203 gdb_cv_scanf_has_long_double=yes,
 204 gdb_cv_scanf_has_long_double=no,
 205 gdb_cv_scanf_has_long_double=no)])
 206 if test $gdb_cv_scanf_has_long_double = yes; then
 207   AC_DEFINE(SCANF_HAS_LONG_DOUBLE)
 208 fi
 209 AC_MSG_RESULT($gdb_cv_scanf_has_long_double)
 210
 211 AC_FUNC_MMAP
 212
 213 dnl See if thread_db library is around for Solaris thread debugging.  Note that
 214 dnl we must explicitly test for version 1 of the library because version 0
 215 dnl (present on Solaris 2.4 or earlier) doesn't have the same API.
 216
 217 dnl Note that we only want this if we are both native (host == target), and
 218 dnl not doing a canadian cross build (build == host).
 219
 220 if test ${build} = ${host} -a ${host} = ${target} ; then
 221    case ${host_os} in
 222    hpux*)
 223       AC_MSG_CHECKING(for HPUX/OSF thread support)
 224       if test -f /usr/include/dce/cma_config.h ; then
 225          if test "$GCC" = "yes" ; then
 226             AC_MSG_RESULT(yes)
 227             AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT)
 228             CONFIG_OBS="${CONFIG_OJS} hpux-thread.o"
 229             CONFIG_SRCS="${CONFIG_SRCS} hpux-thread.c"
 230          else
 231             AC_MSG_RESULT(no (suppressed because you are not using GCC))
 232          fi
 233       else
 234          AC_MSG_RESULT(no)
 235       fi
 236       ;;
 237    solaris*)
 238       AC_MSG_CHECKING(for Solaris thread debugging library)
 239       if test -f /usr/lib/libthread_db.so.1 ; then
 240          AC_MSG_RESULT(yes)
 241          AC_DEFINE(HAVE_THREAD_DB_LIB)
 242          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
 243          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
 244          AC_CHECK_LIB(dl, dlopen)
 245          if test "$GCC" = "yes" ; then
 246             # The GNU linker requires the -export-dynamic option to make
 247             # all symbols visible in the dynamic symbol table.
 248             hold_ldflags=$LDFLAGS
 249             AC_MSG_CHECKING(for the ld -export-dynamic flag)
 250             LDFLAGS="${LDFLAGS} -Wl,-export-dynamic"
 251             AC_TRY_LINK(, [int i;], found=yes, found=no)
 252             LDFLAGS=$hold_ldflags
 253             AC_MSG_RESULT($found)
 254             if test $found = yes; then
 255                CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Wl,-export-dynamic"
 256             fi
 257          fi
 258          # Sun randomly tweaked the prototypes in <proc_service.h>
 259          # at one point.
 260          AC_MSG_CHECKING(if <proc_service.h> is old)
 261          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
 262             AC_TRY_COMPILE([
 263                 #include <proc_service.h>
 264                 ps_err_e ps_pdwrite
 265                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
 266             ],, gdb_cv_proc_service_is_old=no,
 267                 gdb_cv_proc_service_is_old=yes)
 268          ])
 269          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
 270          if test $gdb_cv_proc_service_is_old = yes; then
 271             AC_DEFINE(PROC_SERVICE_IS_OLD)
 272          fi
 273       else
 274          AC_MSG_RESULT(no)
 275       fi
 276       ;;
 277    esac
 278    AC_SUBST(CONFIG_LDFLAGS)
 279 fi
 280
 281 dnl Handle optional features that can be enabled.
 282 ENABLE_CFLAGS=
 283
 284 AC_ARG_ENABLE(netrom,
 285 [  --enable-netrom ],
 286 [case "${enableval}" in
 287 yes)    enable_netrom=yes ;;
 288 no)     enable_netrom=no ;;
 289 *)      AC_MSG_ERROR(bad value ${enableval} given for netrom option) ;;
 290 esac])
 291
 292 if test "${enable_netrom}" = "yes"; then
 293         CONFIG_OBS="${CONFIG_OBS} remote-nrom.o"
 294         CONFIG_SRCS="${CONFIG_SRCS} remote-nrom.c"
 295 fi
 296
 297 AC_ARG_ENABLE(build-warnings,
 298 [  --enable-build-warnings              Enable build-time compiler warnings if gcc is used],
 299 [build_warnings="-Wall -Wpointer-arith -Wstrict-prototypes -Wmissing-prototypes -Wmissing-declarations"
 300 case "${enableval}" in
 301   yes)  ;;
 302   no)   build_warnings="-w";;
 303 dnl  ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
 304 dnl        build_warnings="${build_warnings} ${t}";;
 305 dnl  *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
 306 dnl        build_warnings="${t} ${build_warnings}";;
 307 dnl  *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
 308   *)    ;;
 309 esac],[build_warnings=""])dnl
 310
 311 if test "x${build_warnings}" != x -a "x$GCC" = xyes
 312 then
 313    WARN_CFLAGS="${build_warnings}"
 314 else
 315    WARN_CFLAGS=""
 316 fi
 317 AC_SUBST(WARN_CFLAGS)
 318
 319 MMALLOC_CFLAGS=
 320 MMALLOC=
 321 AC_SUBST(MMALLOC_CFLAGS)
 322 AC_SUBST(MMALLOC)
 323
 324 AC_ARG_WITH(mmalloc,
 325 [  --with-mmalloc          Use memory mapped malloc package],
 326 [case "${withval}" in
 327   yes)  want_mmalloc=true ;;
 328   no)   want_mmalloc=false;;
 329   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-mmalloc option) ;;
 330 esac],[want_mmalloc=false])dnl
 331
 332 if test x$want_mmalloc = xtrue; then
 333    AC_DEFINE(USE_MMALLOC)
 334    AC_DEFINE(MMCHECK_FORCE)
 335    MMALLOC_CFLAGS="-I$srcdir/../mmalloc"
 336    MMALLOC='../mmalloc/libmmalloc.a'
 337 fi
 338
 339 # start-sanitize-carp
 340 # The below takes an educated guess at the targets that
 341 # should be built.  It is an interum version that provides
 342 # significant backward compatibility.
 343
 344 AC_ARG_ENABLE(carp,
 345 [  --enable-carp        Configure alternative readaptive paradigm ],
 346 [case "${enableval}" in
 347   yes) enable_carp=yes ;;
 348   no)  enable_carp=no ;;
 349   *)   AC_MSG_ERROR([bad value ${enableval} for carp option]) ;;
 350 esac],[enable_carp=no])dnl
 351
 352 AC_ARG_ENABLE(targets,
 353 [  --enable-targets        alternative target configurations],
 354 [case "${enableval}" in
 355   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 356             ;;
 357   no)       enable_targets= ;;
 358   *)        enable_targets="$enableval" ;;
 359 esac])dnl
 360
 361 # Canonicalize the secondary target names.
 362 all_targets=false
 363 if test -n "$enable_targets" ; then
 364     if test "$enable_targets" = all ; then
 365         all_targets=true
 366     else
 367         for targ in `echo $enable_targets | sed 's/,/ /g'`
 368         do
 369             result=`${CONFIG_SHELL-/bin/sh} $ac_config_sub $targ 2>/dev/null`
 370             if test -n "$result" ; then
 371                 canon_targets="$canon_targets $result"
 372             fi
 373         done
 374     fi
 375 fi
 376
 377 # Convert the target names into GDB [*]-tdep.c names
 378 changequote(,)dnl
 379 selarchs=
 380 for targ in $target $canon_targets
 381 do
 382     if test "x$targ" = "xall" ; then
 383         all_targets=true
 384     else
 385         t_cpu=`echo $targ    | sed 's/^\([^-]*\)-\([^-]*\)-\(.*\)$/\1/'`
 386         t_vendor=`echo $targ | sed 's/^\([^-]*\)-\([^-]*\)-\(.*\)$/\2/'`
 387         t_os=`echo $targ     | sed 's/^\([^-]*\)-\([^-]*\)-\(.*\)$/\3/'`
 388         mt=`
 389 target=$targ
 390 target_cpu=$t_cpu
 391 target_vendor=$t_vendor
 392 target_os=$t_os
 393 . ${srcdir}/configure.tgt
 394 echo ${srcdir}/config/${gdb_target_cpu}/${gdb_target}.mt`
 395         if test -r ${mt} ; then
 396             # This gets confused over .mt files that have multiple -tdep.o
 397             tdep=`sed -n '
 398 s/^.*[  =]\([^  ]*\)-tdep.o.*/\1/p
 399 ' $mt`
 400             selarchs="$selarchs $tdep"
 401         fi
 402     fi
 403 done
 404 changequote([,])dnl
 405
 406 # We don't do any links based on the target system, just makefile config.
 407
 408 if test x${all_targets} = xfalse ; then
 409
 410     # Target architecture .o files.
 411     ta=
 412
 413     for arch in $selarchs
 414     do
 415         archdefs="$archdefs -DARCH_$arch"
 416         ta="$ta ${arch}-tdep.o"
 417         # Special cases
 418         case "$arch" in
 419             dvp)  ta="$ta mips-tdep.o dvp-tdep.o" ;;
 420         esac
 421     done
 422
 423     # Weed out duplicate .o files.
 424     f=""
 425     for i in $ta ; do
 426         case " $f " in
 427             *" $i "*) ;;
 428             *) f="$f $i" ;;
 429         esac
 430     done
 431     ta="$f"
 432
 433     # And duplicate -D flags.
 434     f=""
 435     for i in $archdefs ; do
 436         case " $f " in
 437             *" $i "*) ;;
 438             *) f="$f $i" ;;
 439         esac
 440     done
 441     archdefs="$f"
 442
 443     MACHINE_OBS="$ta"
 444
 445 else    # all_targets is true
 446     archdefs=-DARCH_all
 447     MACHINE_OBS='$(ALL_MACHINES)'
 448 fi
 449
 450 dnl Don't define an archdefs list
 451 dnl AC_SUBST(archdefs)
 452 dnl XXXX this name will change several more times
 453 if test "${enable_carp}" = yes ; then
 454     gdb_target=carp
 455     gdb_target_cpu=carp
 456 else
 457     MACHINE_OBS="# $MACHINE_OBS"
 458 fi
 459 AC_SUBST(MACHINE_OBS)
 460
 461 # end-sanitize-carp
 462 # start-sanitize-gdbtk
 463 # start-sanitize-ide
 464 ENABLE_IDE=
 465 AC_ARG_ENABLE(ide, [  --enable-ide            Enable IDE support])
 466 if test "$enable_ide" = yes; then
 467    enable_ide=yes
 468    ENABLE_IDE=1
 469 else
 470    enable_ide=no
 471 fi
 472 AC_SUBST(ENABLE_IDE)
 473
 474 AC_ARG_WITH(foundry-libs,
 475 [  --with-foundry-libs=DIR Use the Foundry SDK in DIR],
 476 [FOUNDRY_LIB_BASE=${withval}])
 477 AC_SUBST(FOUNDRY_LIB_BASE)
 478
 479 #
 480 # This is the Foundry SDK
 481 #
 482 # These variables are used to determine where the Foundry libs and
 483 # header files are located.
 484 #
 485 if test "$FOUNDRY_LIB_BASE" != ""; then
 486     LIBGUI="${FOUNDRY_LIB_BASE}/lib/libgui.a"
 487     GUI_CFLAGS_X="-I${FOUNDRY_LIB_BASE}/include"
 488     if test x$enable_ide = xyes; then
 489         IDE_CFLAGS_X="-I${FOUNDRY_LIB_BASE}/include -DIDE"
 490         IDE_X="-L${FOUNDRY_LIB_BASE}/lib -lilu-Tk -lilu-c -lilu"
 491     else
 492         IDE_CFLAGS_X="-I${FOUNDRY_LIB_BASE}/include"
 493     fi
 494     LIBIDETCL="${FOUNDRY_LIB_BASE}/lib/libidetcl.a"
 495     LIBIDE="${FOUNDRY_LIB_BASE}/lib/libide.a"
 496     IDE_DEPS="${FOUNDRY_LIB_BASE}/lib/libilu-Tk.a ${FOUNDRY_LIB_BASE}/lib/libilu-c.a ${FOUNDRY_LIB_BASE}/lib/libilu.a"
 497 else
 498     LIBGUI="../libgui/src/libgui.a"
 499     GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
 500     if test x$enable_ide = xyes; then
 501         IDE_CFLAGS_X="-I${srcdir}/../libidetcl/src -I${srcdir}/../libide/src -DIDE -I${srcdir}/../ilu/runtime/mainloop"
 502         IDE_X="-L../ilu/runtime/mainloop -lilu-Tk -L../ilu/runtime/c -lilu-c -L../ilu/runtime/kernel -lilu"
 503     else
 504         IDE_CFLAGS_X="-I${srcdir}/../libidetcl/src -I${srcdir}/../libide/src"
 505     fi
 506     LIBIDETCL="../libidetcl/src/libidetcl.a"
 507     LIBIDE="../libide/src/libide.a"
 508     IDE_DEPS="../ilu/runtime/mainloop/libilu-Tk.a ../ilu/runtime/c/libilu-c.a ../ilu/runtime/kernel/libilu.a"
 509 fi
 510 AC_SUBST(LIBGUI)
 511 AC_SUBST(GUI_CFLAGS_X)
 512 AC_SUBST(IDE_CFLAGS_X)
 513 AC_SUBST(IDE_X)
 514 AC_SUBST(LIBIDETCL)
 515 AC_SUBST(LIBIDE)
 516 AC_SUBST(IDE_DEPS)
 517 # end-sanitize-ide
 518
 519 ENABLE_GDBTK=
 520
 521 AC_ARG_ENABLE(gdbtk,
 522 [  --enable-gdbtk          Enable GDBTK GUI front end],
 523 [case "${enableval}" in
 524     yes)
 525         case "$host" in
 526         *go32*)
 527             AC_MSG_WARN([GDB does not support GDBtk on host ${host}.  GDBtk will be disabled.])
 528             enable_gdbtk=no ;;
 529         *windows*)
 530             AC_MSG_WARN([GDB does not support GDBtk on host ${host}.  GDBtk will be disabled.])
 531             enable_gdbtk=no ;;
 532         *)
 533             enable_gdbtk=yes ;;
 534         esac ;;
 535     no)
 536         enable_gdbtk=no  ;;
 537     *)
 538         AC_MSG_ERROR(bad value ${enableval} given for gdbtk option) ;;
 539 esac],
 540 [
 541 # Default is on for everything but go32 and cygwin32
 542 case "$host" in
 543     *go32* | *windows*)
 544         ;;
 545     *)
 546         enable_gdbtk=yes ;;
 547     esac
 548 ])
 549
 550 # In the cygwin32 environment, we need some additional flags.
 551 AC_CACHE_CHECK([for cygwin32], gdb_cv_os_cygwin32,
 552 [AC_EGREP_CPP(lose, [
 553 #ifdef __CYGWIN32__
 554 lose
 555 #endif],[gdb_cv_os_cygwin32=yes],[gdb_cv_os_cygwin32=no])])
 556
 557 WIN32LIBS=
 558 WIN32LDAPP=
 559 AC_SUBST(WIN32LIBS)
 560 AC_SUBST(WIN32LDAPP)
 561
 562 DLLTOOL=${DLLTOOL-dlltool}
 563 WINDRES=${WINDRES-windres}
 564 AC_SUBST(DLLTOOL)
 565 AC_SUBST(WINDRES)
 566
 567 if test x$gdb_cv_os_cygwin32 = xyes; then
 568     if test x$enable_ide = xyes; then
 569         WIN32LIBS="-ladvapi32"
 570     fi
 571 fi
 572
 573 configdir="unix"
 574
 575 GDBTKLIBS=
 576 if test "${enable_gdbtk}" = "yes"; then
 577
 578     CY_AC_PATH_TCLCONFIG
 579     if test -z "${no_tcl}"; then
 580         CY_AC_LOAD_TCLCONFIG
 581         CY_AC_PATH_TKCONFIG
 582
 583         # If $no_tk is nonempty, then we can't do Tk, and there is no
 584         # point to doing Tcl.
 585         if test -z "${no_tk}"; then
 586            CY_AC_LOAD_TKCONFIG
 587            CY_AC_PATH_TCLH
 588            CY_AC_PATH_TKH
 589            CY_AC_PATH_ITCLH
 590            CY_AC_PATH_TIX
 591
 592            # now look for tix library stuff
 593            TIXVERSION=4.1.8.0
 594            . ${ac_cv_c_tclconfig}/tclConfig.sh
 595            case "${host}" in
 596            *-*-cygwin32*)
 597                 tixdir=../tix/win/tcl8.0
 598                 ;;
 599            *)
 600                 tixdir=../tix/unix/tk8.0
 601                 ;;
 602            esac
 603            if test "${TCL_SHARED_BUILD}" = "1"; then
 604                 TIX_LIB_EXT="${TCL_SHLIB_SUFFIX}"
 605
 606                 # Can't win them all: SunOS 4 (others?) appends a version
 607                 # number after the ".so"
 608                 case "${host}" in
 609                 *-*-sunos4*)
 610                     TIX_LIB_EXT="${TIX_LIB_EXT}.1.0" ;;
 611                 esac
 612
 613            else
 614                 TIX_LIB_EXT=".a"
 615            fi
 616
 617            if test "${TCL_LIB_VERSIONS_OK}" = "ok"; then
 618                 TIXLIB="-L${tixdir} -ltix${TIXVERSION}"
 619                 TIX_DEPS="${tixdir}/libtix${TIXVERSION}${TIX_LIB_EXT}"
 620            else
 621                 TIXLIB="-L${tixdir} -ltix`echo ${TIXVERSION} | tr -d .`"
 622                 TIX_DEPS="${tixdir}/libtix`echo ${TIXVERSION} | tr -d .`${TIX_LIB_EXT}"
 623            fi
 624
 625            ENABLE_GDBTK=1
 626            ENABLE_CFLAGS="${ENABLE_CFLAGS} -DGDBTK"
 627
 628            # Include some libraries that Tcl and Tk want.
 629            if test "${enable_ide}" = "yes"; then
 630               TCL_LIBS='$(LIBIDETCL) $(LIBIDE) $(LIBGUI) $(IDE) $(ITCL) $(TIX) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
 631               CONFIG_DEPS='$(LIBIDETCL) $(LIBIDE) $(LIBGUI) $(IDE_DEPS) $(ITCL_DEPS) $(TIX_DEPS) $(TK_DEPS) $(TCL_DEPS)'
 632            else
 633               TCL_LIBS='$(LIBGUI) $(ITCL) $(TIX) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
 634               CONFIG_DEPS='$(LIBGUI) $(ITCL_DEPS) $(TIX_DEPS) $(TK_DEPS) $(TCL_DEPS)'
 635            fi
 636            # Yes, the ordering seems wrong here.  But it isn't.
 637            # TK_LIBS is the list of libraries that need to be linked
 638            # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
 639            # were in LIBS then any link tests after this point would
 640            # try to include things like `$(LIBGUI)', which wouldn't work.
 641            GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
 642            CONFIG_OBS="${CONFIG_OBS} gdbtk.o gdbtk-cmds.o gdbtk-hooks.o"
 643
 644            if test x$gdb_cv_os_cygwin32 = xyes; then
 645               WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32 -luser32"
 646               WIN32LDAPP="-Wl,--subsystem,console"
 647               CONFIG_OBS="${CONFIG_OBS} gdbres.o"
 648            fi
 649         fi
 650     fi
 651 fi
 652
 653 AC_SUBST(ENABLE_GDBTK)
 654 AC_SUBST(X_CFLAGS)
 655 AC_SUBST(X_LDFLAGS)
 656 AC_SUBST(X_LIBS)
 657 AC_SUBST(TIXLIB)
 658 AC_SUBST(TIX_DEPS)
 659 AC_SUBST(GDBTKLIBS)
 660 # end-sanitize-gdbtk
 661
 662 AC_PATH_X
 663 # start-sanitize-sky
 664 # Enable GPU2 library for MIPS simulator
 665 AC_ARG_WITH(sim-gpu2,
 666 [  --with-sim-gpu2=DIR     Use GPU2 library under given DIR],
 667 [case "${target}" in
 668   mips*-sky-*)
 669     if test -d "${withval}"
 670     then
 671       LIBS="${LIBS} -L${withval}/lib -lgpu2 -L${x_libraries} -lX11 -lXext"
 672     else
 673       AC_MSG_WARN([Directory ${withval} does not exist.])
 674     fi ;;
 675   *)  AC_MSG_WARN([--with-sim-gpu2 option invalid for target ${target}])
 676 esac])dnl
 677
 678 # Enable target accurate FP library
 679 AC_ARG_WITH(sim-funit,
 680 [  --with-sim-funit=DIR    Use target FP lib under given DIR],
 681 [case "${target}" in
 682   mips*-sky-*)
 683     if test -d "${withval}"
 684     then
 685       LIBS="${LIBS} -L${withval}/lib -lfunit"
 686     else
 687       AC_MSG_WARN([Directory ${withval} does not exist.])
 688     fi ;;
 689   *)  AC_MSG_WARN([--with-sim-funit option invalid for target ${target}])
 690 esac])dnl
 691 # end-sanitize-sky
 692
 693 AC_SUBST(ENABLE_CFLAGS)
 694
 695 AC_SUBST(CONFIG_OBS)
 696 AC_SUBST(CONFIG_DEPS)
 697 AC_SUBST(CONFIG_SRCS)
 698
 699 # Begin stuff to support --enable-shared
 700 AC_ARG_ENABLE(shared,
 701 [  --enable-shared         Use shared libraries],
 702 [case "${enableval}" in
 703   yes) shared=true ;;
 704   no)  shared=false ;;
 705   *) shared=true ;;
 706 esac])dnl
 707
 708 HLDFLAGS=
 709 HLDENV=
 710 # If we have shared libraries, try to set rpath reasonably.
 711 if test "${shared}" = "true"; then
 712   case "${host}" in
 713   *-*-hpux*)
 714     HLDFLAGS='-Wl,+s,+b,$(libdir)'
 715     ;;
 716   *-*-irix5* | *-*-irix6*)
 717     HLDFLAGS='-Wl,-rpath,$(libdir)'
 718     ;;
 719   *-*-linux*aout*)
 720     ;;
 721   *-*-linux* | *-pc-linux-gnu)
 722     HLDFLAGS='-Wl,-rpath,$(libdir)'
 723     ;;
 724   *-*-solaris*)
 725     HLDFLAGS='-R $(libdir)'
 726     ;;
 727   *-*-sysv4*)
 728     HLDENV='if test -z "$${LD_RUN_PATH}"; then LD_RUN_PATH=$(libdir); else LD_RUN_PATH=$${LD_RUN_PATH}:$(libdir); fi; export LD_RUN_PATH;'
 729     ;;
 730   esac
 731 fi
 732
 733 # On SunOS, if the linker supports the -rpath option, use it to
 734 # prevent ../bfd and ../opcodes from being included in the run time
 735 # search path.
 736 case "${host}" in
 737   *-*-sunos*)
 738     echo 'main () { }' > conftest.c
 739     ${CC} -o conftest -Wl,-rpath= conftest.c >/dev/null 2>conftest.t
 740     if grep 'unrecognized' conftest.t >/dev/null 2>&1; then
 741       :
 742     elif grep 'No such file' conftest.t >/dev/null 2>&1; then
 743       :
 744     elif grep 'do not mix' conftest.t >/dev/null 2>&1; then
 745       :
 746     elif grep 'some text already loaded' conftest.t >/dev/null 2>&1; then
 747       :
 748     elif test "${shared}" = "true"; then
 749       HLDFLAGS='-Wl,-rpath=$(libdir)'
 750     else
 751       HLDFLAGS='-Wl,-rpath='
 752     fi
 753     rm -f conftest.t conftest.c conftest
 754     ;;
 755 esac
 756 AC_SUBST(HLDFLAGS)
 757 AC_SUBST(HLDENV)
 758 # End stuff to support --enable-shared
 759
 760 # target_subdir is used by the testsuite to find the target libraries.
 761 target_subdir=
 762 if test "${host}" != "${target}"; then
 763     target_subdir="${target_alias}/"
 764 fi
 765 AC_SUBST(target_subdir)
 766
 767 frags=
 768 host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
 769 if test ! -f ${host_makefile_frag}; then
 770 AC_MSG_ERROR("*** Gdb does not support host ${host}")
 771 fi
 772 frags="$frags $host_makefile_frag"
 773
 774 target_makefile_frag=${srcdir}/config/${gdb_target_cpu}/${gdb_target}.mt
 775 if test ! -f ${target_makefile_frag}; then
 776 AC_MSG_ERROR("*** Gdb does not support target ${target}")
 777 fi
 778 frags="$frags $target_makefile_frag"
 779
 780 AC_SUBST_FILE(host_makefile_frag)
 781 AC_SUBST_FILE(target_makefile_frag)
 782 AC_SUBST(frags)
 783
 784 changequote(,)dnl
 785 hostfile=`sed -n '
 786 s/XM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
 787 ' ${host_makefile_frag}`
 788
 789 targetfile=`sed -n '
 790 s/TM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
 791 ' ${target_makefile_frag}`
 792
 793 # these really aren't orthogonal true/false values of the same condition,
 794 # but shells are slow enough that I like to reuse the test conditions
 795 # whenever possible
 796 if test "${target}" = "${host}"; then
 797 nativefile=`sed -n '
 798 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
 799 ' ${host_makefile_frag}`
 800 # else
 801 # GDBserver is only useful in a "native" enviroment
 802 # configdirs=`echo $configdirs | sed 's/gdbserver//'`
 803 fi
 804 changequote([,])
 805
 806 # If hostfile (XM_FILE) and/or targetfile (TM_FILE) and/or nativefile
 807 # (NAT_FILE) is not set in config/*/*.m[ht] files, we don't make the
 808 # corresponding links.  But we have to remove the xm.h files and tm.h
 809 # files anyway, e.g. when switching from "configure host" to
 810 # "configure none".
 811
 812 files=
 813 links=
 814 rm -f xm.h
 815 if test "${hostfile}" != ""; then
 816 files="${files} config/${gdb_host_cpu}/${hostfile}"
 817 links="${links} xm.h"
 818 fi
 819 rm -f tm.h
 820 if test "${targetfile}" != ""; then
 821 files="${files} config/${gdb_target_cpu}/${targetfile}"
 822 links="${links} tm.h"
 823 fi
 824 rm -f nm.h
 825 if test "${nativefile}" != ""; then
 826 files="${files} config/${gdb_host_cpu}/${nativefile}"
 827 links="${links} nm.h"
 828 else
 829 # A cross-only configuration.
 830 files="${files} config/nm-empty.h"
 831 links="${links} nm.h"
 832 fi
 833 # start-sanitize-gdbtk
 834 AC_PROG_LN_S
 835 # Make it possible to use the GUI without doing a full install
 836 if test "${enable_gdbtk}" = "yes" -a ! -d gdbtcl2 ; then
 837   if test "$LN_S" = "ln -s" -a ! -f gdbtcl2 ; then
 838   echo linking $srcdir/gdbtcl2 to gdbtcl2
 839   $LN_S $srcdir/gdbtcl2 gdbtcl2
 840   else
 841   echo Warning: Unable to link $srcdir/gdbtcl2 to gdbtcl2.  You will need to do a
 842   echo "         " make install before you are able to run the GUI.
 843   fi
 844 fi
 845 # end-sanitize-gdbtk
 846
 847 AC_LINK_FILES($files, $links)
 848
 849 dnl Check for exe extension set on certain hosts (e.g. Win32)
 850 AC_EXEEXT
 851
 852 AC_CONFIG_SUBDIRS($configdirs)
 853 AC_OUTPUT(Makefile .gdbinit:gdbinit.in,
 854 [
 855 dnl Autoconf doesn't provide a mechanism for modifying definitions
 856 dnl provided by makefile fragments.
 857 dnl
 858 if test "${nativefile}" = ""; then
 859 sed -e '/^NATDEPFILES[[         ]]*=[[  ]]*/s//# NATDEPFILES=/' \
 860         < Makefile > Makefile.tem
 861 mv -f Makefile.tem Makefile
 862 fi
 863
 864 changequote(,)dnl
 865 sed -e '/^TM_FILE[      ]*=/s,^TM_FILE[         ]*=[    ]*,&config/'"${gdb_target_cpu}"'/,
 866 /^XM_FILE[      ]*=/s,^XM_FILE[         ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,
 867 /^NAT_FILE[     ]*=/s,^NAT_FILE[        ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp
 868 mv -f Makefile.tmp Makefile
 869 changequote([,])dnl
 870
 871 case x$CONFIG_HEADERS in
 872 xconfig.h:config.in)
 873 echo > stamp-h ;;
 874 esac
 875 ],
 876 [
 877 gdb_host_cpu=$gdb_host_cpu
 878 gdb_target_cpu=$gdb_target_cpu
 879 nativefile=$nativefile
 880 ])
 881
 882 exit 0