gprof/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_PREREQ(2.5)dnl
   3 AC_INIT(gprof.c)
   4
   5 AC_ARG_ENABLE(shared,
   6 [  --enable-shared         build shared BFD library],
   7 [case "${enableval}" in
   8   yes) shared=true ;;
   9   no)  shared=false ;;
  10   *bfd*) shared=true ;;
  11   *) shared=false ;;
  12 esac])dnl
  13
  14 AC_PROG_CC
  15 AC_PROG_INSTALL
  16
  17 AC_ISC_POSIX
  18
  19 AC_CANONICAL_SYSTEM
  20 AC_ARG_PROGRAM
  21
  22 case "${target}" in
  23 alpha-*-*)      MY_TARGET=alpha ;;
  24 changequote(,)dnl
  25 i[3456]86-*-*)  MY_TARGET=i386 ;;
  26 changequote([,])dnl
  27 sparc-*-*)      MY_TARGET=sparc ;;
  28 tahoe-*-*)      MY_TARGET=tahoe ;;
  29 vax-*-*)        MY_TARGET=vax ;;
  30 ns32k-*-*)      MY_TARGET=ns532;;
  31 *-*-*)          MY_TARGET=dummy ;;
  32 esac
  33
  34 AC_SUBST(MY_TARGET)
  35
  36 BFDLIB='-L../bfd -lbfd'
  37
  38 # We need to handle some special cases if BFD was built shared.
  39 case "${host}" in
  40   *-*-sunos*)
  41   # On SunOS, we must link against the name we are going to install,
  42   # not -lbfd, since SunOS does not support SONAME.
  43   if test "${shared}" = "true"; then
  44     BFDLIB='-L../bfd -l`echo bfd | sed '"'"'$(program_transform_name)'"'"'`'
  45   fi
  46   ;;
  47 alpha*-*-osf*)
  48   # On Alpha OSF/1, the native linker searches all the -L
  49   # directories for any LIB.so files, and only then searches for any
  50   # LIB.a files.  That means that if there is an installed
  51   # libbfd.so, but this build is not done with --enable-shared, the
  52   # link will wind up being against the install libbfd.so rather
  53   # than the newly built libbfd.  To avoid this, we must explicitly
  54   # link against libbfd.a when --enable-shared is not used.
  55   if test "${shared}" != "true"; then
  56     BFDLIB='../bfd/libbfd.a'
  57   fi
  58   ;;
  59 esac
  60 AC_SUBST(BFDLIB)
  61
  62 HLDFLAGS=
  63 HLDENV=
  64 # If we have shared libraries, try to set rpath reasonably.
  65 if test "${shared}" = "true"; then
  66   case "${host}" in
  67   *-*-hpux*)
  68     HLDFLAGS='-Wl,+s,+b,$(libdir)'
  69     ;;
  70   *-*-irix5*)
  71     HLDFLAGS='-Wl,-rpath,$(libdir)'
  72     ;;
  73   *-*-linux*aout*)
  74     ;;
  75   *-*-linux*)
  76     HLDFLAGS='-Wl,-rpath,$(libdir)'
  77     ;;
  78   *-*-solaris*)
  79     HLDFLAGS='-R $(libdir)'
  80     ;;
  81   *-*-sysv4*)
  82     HLDENV='if test -z "$${LD_RUN_PATH}"; then LD_RUN_PATH=$(libdir); else LD_RUN_PATH=$${LD_RUN_PATH}:$(libdir); fi; export LD_RUN_PATH;'
  83     ;;
  84   esac
  85 fi
  86
  87 # On SunOS, if the linker supports the -rpath option, use it to
  88 # prevent ../bfd and ../opcodes from being included in the run time
  89 # search path.
  90 case "${host}" in
  91   *-*-sunos*)
  92     echo 'main () { }' > conftest.c
  93     ${CC} -o conftest -Wl,-rpath= conftest.c >/dev/null 2>conftest.t
  94     if grep 'unrecognized' conftest.t >/dev/null 2>&1; then
  95       :
  96     elif grep 'No such file' conftest.t >/dev/null 2>&1; then
  97       :
  98     elif grep 'do not mix' conftest.t >/dev/null 2>&1; then
  99       :
 100     elif test "${shared}" = "true"; then
 101       HLDFLAGS='-Wl,-rpath=$(libdir)'
 102     else
 103       HLDFLAGS='-Wl,-rpath='
 104     fi
 105     rm -f conftest.t conftest.c conftest
 106     ;;
 107 esac
 108 AC_SUBST(HLDFLAGS)
 109 AC_SUBST(HLDENV)
 110
 111 AC_OUTPUT(Makefile)