configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011, 2012,
   3 #   2014, 2015, 2016, 2019, 2020 Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include(config/debuginfod.m4)
  27 m4_include([libtool.m4])
  28 m4_include([ltoptions.m4])
  29 m4_include([ltsugar.m4])
  30 m4_include([ltversion.m4])
  31 m4_include([lt~obsolete.m4])
  32 m4_include([config/isl.m4])
  33
  34 AC_INIT(move-if-change)
  35 AC_DISABLE_OPTION_CHECKING
  36
  37 progname=$0
  38 # if PWD already has a value, it is probably wrong.
  39 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  40
  41 # Export original configure arguments for use by sub-configures.
  42 # Quote arguments with shell meta charatcers.
  43 TOPLEVEL_CONFIGURE_ARGUMENTS=
  44 set -- "$progname" "$@"
  45 for ac_arg
  46 do
  47   case "$ac_arg" in
  48   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  49     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  50     # if the argument is of the form -foo=baz, quote the baz part only
  51     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  52   *) ;;
  53   esac
  54   # Add the quoted argument to the list.
  55   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  56 done
  57 if test "$silent" = yes; then
  58   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  59 fi
  60 # Remove the initial space we just introduced and, as these will be
  61 # expanded by make, quote '$'.
  62 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  63 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  64
  65 # Find the build, host, and target systems.
  66 ACX_NONCANONICAL_BUILD
  67 ACX_NONCANONICAL_HOST
  68 ACX_NONCANONICAL_TARGET
  69
  70 dnl Autoconf 2.5x and later will set a default program prefix if
  71 dnl --target was used, even if it was the same as --host.  Disable
  72 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  73 dnl to take effect.
  74 test "$host_noncanonical" = "$target_noncanonical" &&
  75   test "$program_prefix$program_suffix$program_transform_name" = \
  76     NONENONEs,x,x, &&
  77   program_transform_name=s,y,y,
  78
  79 AC_CANONICAL_SYSTEM
  80 AC_ARG_PROGRAM
  81
  82 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  83 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  84
  85 # Get 'install' or 'install-sh' and its variants.
  86 AC_PROG_INSTALL
  87 ACX_PROG_LN
  88 AC_PROG_LN_S
  89 AC_PROG_SED
  90 AC_PROG_AWK
  91
  92 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
  93
  94 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
  95 # a relative path.
  96 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
  97   INSTALL="${srcpwd}/install-sh -c"
  98 fi
  99
 100 # Set srcdir to "." if that's what it is.
 101 # This is important for multilib support.
 102 pwd=`${PWDCMD-pwd}`
 103 if test "${pwd}" = "${srcpwd}" ; then
 104   srcdir=.
 105 fi
 106
 107 topsrcdir=$srcpwd
 108
 109 extra_host_args=
 110
 111 ### To add a new directory to the tree, first choose whether it is a target
 112 ### or a host dependent tool.  Then put it into the appropriate list
 113 ### (library or tools, host or target), doing a dependency sort.
 114
 115 # Subdirs will be configured in the order listed in build_configdirs,
 116 # configdirs, or target_configdirs; see the serialization section below.
 117
 118 # Dependency sorting is only needed when *configuration* must be done in
 119 # a particular order.  In all cases a dependency should be specified in
 120 # the Makefile, whether or not it's implicitly specified here.
 121
 122 # Double entries in build_configdirs, configdirs, or target_configdirs may
 123 # cause circular dependencies and break everything horribly.
 124
 125 # these library is used by various programs built for the build
 126 # environment
 127 #
 128 build_libs="build-libiberty build-libcpp"
 129
 130 # these tools are built for the build environment
 131 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
 132
 133 # these libraries are used by various programs built for the host environment
 134 #f
 135 host_libs="intl libiberty opcodes bfd readline tcl tk itcl libgui zlib libbacktrace libcpp libdecnumber gmp mpfr mpc isl libelf libiconv libctf"
 136
 137 # these tools are built for the host environment
 138 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 139 # know that we are building the simulator.
 140 # binutils, gas and ld appear in that order because it makes sense to run
 141 # "make check" in that particular order.
 142 # If --enable-gold is used, "gold" may replace "ld".
 143 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gdbserver gprof etc expect dejagnu m4 utils guile fastjar gnattools libcc1 gotools"
 144
 145 # these libraries are built for the target environment, and are built after
 146 # the host libraries and the host tools (which may be a cross compiler)
 147 # Note that libiberty is not a target library.
 148 target_libraries="target-libgcc \
 149                 target-libbacktrace \
 150                 target-libgloss \
 151                 target-newlib \
 152                 target-libgomp \
 153                 target-liboffloadmic \
 154                 target-libhsail-rt \
 155                 target-libatomic \
 156                 target-libitm \
 157                 target-libstdc++-v3 \
 158                 target-libsanitizer \
 159                 target-libvtv \
 160                 target-libssp \
 161                 target-libquadmath \
 162                 target-libgfortran \
 163                 target-libffi \
 164                 target-libobjc \
 165                 target-libada \
 166                 target-libgo"
 167
 168 # these tools are built using the target libraries, and are intended to
 169 # run only in the target environment
 170 #
 171 # note: any program that *uses* libraries that are in the "target_libraries"
 172 # list belongs in this list.
 173 #
 174 target_tools="target-rda"
 175
 176 ################################################################################
 177
 178 ## All tools belong in one of the four categories, and are assigned above
 179 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 180 ## is important because configure will choke if they ever get through.
 181 ## ${configdirs} is directories we build using the host tools.
 182 ## ${target_configdirs} is directories we build using the target tools.
 183 configdirs=`echo ${host_libs} ${host_tools}`
 184 target_configdirs=`echo ${target_libraries} ${target_tools}`
 185 build_configdirs=`echo ${build_libs} ${build_tools}`
 186
 187 m4_divert_text([PARSE_ARGS],
 188 [case $srcdir in
 189   *" "*)
 190 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 191     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 192 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 193     ;;
 194 esac
 195 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 196 ])
 197
 198 ################################################################################
 199
 200 srcname="gnu development package"
 201
 202 # This gets set non-empty for some net releases of packages.
 203 appdirs=""
 204
 205 # Define is_cross_compiler to save on calls to 'test'.
 206 is_cross_compiler=
 207 if test x"${host}" = x"${target}" ; then
 208   is_cross_compiler=no
 209 else
 210   is_cross_compiler=yes
 211 fi
 212
 213 # Find the build and target subdir names.
 214 GCC_TOPLEV_SUBDIRS
 215 # Be sure to cover against remnants of an in-tree build.
 216 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 217   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 218 Use a pristine source tree when building in a separate tree])
 219 fi
 220
 221 # Skipdirs are removed silently.
 222 skipdirs=
 223 # Noconfigdirs are removed loudly.
 224 noconfigdirs=""
 225
 226 use_gnu_ld=
 227 # Make sure we don't let GNU ld be added if we didn't want it.
 228 if test x$with_gnu_ld = xno ; then
 229   use_gnu_ld=no
 230   noconfigdirs="$noconfigdirs ld gold"
 231 fi
 232
 233 use_gnu_as=
 234 # Make sure we don't let GNU as be added if we didn't want it.
 235 if test x$with_gnu_as = xno ; then
 236   use_gnu_as=no
 237   noconfigdirs="$noconfigdirs gas"
 238 fi
 239
 240 use_included_zlib=
 241 AC_ARG_WITH(system-zlib,
 242 [AS_HELP_STRING([--with-system-zlib], [use installed libz])])
 243 # Make sure we don't let ZLIB be added if we didn't want it.
 244 if test x$with_system_zlib = xyes ; then
 245   use_included_zlib=no
 246   noconfigdirs="$noconfigdirs zlib"
 247 fi
 248
 249 # Don't compile the bundled readline/libreadline.a if --with-system-readline
 250 # is provided.
 251 if test x$with_system_readline = xyes ; then
 252   noconfigdirs="$noconfigdirs readline"
 253 fi
 254
 255 # some tools are so dependent upon X11 that if we're not building with X,
 256 # it's not even worth trying to configure, much less build, that tool.
 257
 258 case ${with_x} in
 259   yes | "") ;; # the default value for this tree is that X11 is available
 260   no)
 261     skipdirs="${skipdirs} tk itcl libgui"
 262     # We won't be able to build gdbtk without X.
 263     enable_gdbtk=no
 264     ;;
 265   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 266 esac
 267
 268 # Some are only suitable for cross toolchains.
 269 # Remove these if host=target.
 270 cross_only="target-libgloss target-newlib target-opcodes"
 271
 272 case $is_cross_compiler in
 273   no) skipdirs="${skipdirs} ${cross_only}" ;;
 274 esac
 275
 276 # If both --with-headers and --with-libs are specified, default to
 277 # --without-newlib.
 278 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 279    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 280   if test x"${with_newlib}" = x ; then
 281     with_newlib=no
 282   fi
 283 fi
 284
 285 # Recognize --with-newlib/--without-newlib.
 286 case ${with_newlib} in
 287   no) skipdirs="${skipdirs} target-newlib" ;;
 288   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 289 esac
 290
 291 AC_ARG_ENABLE(as-accelerator-for,
 292 [AS_HELP_STRING([--enable-as-accelerator-for=ARG],
 293                 [build as offload target compiler.
 294                 Specify offload host triple by ARG])])
 295
 296 AC_ARG_ENABLE(offload-targets,
 297 [AS_HELP_STRING([--enable-offload-targets=LIST],
 298                 [enable offloading to devices from comma-separated LIST of
 299                 TARGET[=DIR]. Use optional path to find offload target compiler
 300                 during the build])],
 301 [
 302   if test x"$enable_offload_targets" = x; then
 303     AC_MSG_ERROR([no offload targets specified])
 304   fi
 305 ], [enable_offload_targets=])
 306
 307 # Handle --enable-gold, --enable-ld.
 308 # --disable-gold [--enable-ld]
 309 #     Build only ld.  Default option.
 310 # --enable-gold [--enable-ld]
 311 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 312 #     as "ld.bfd" and "ld".
 313 # --enable-gold=default [--enable-ld]
 314 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 315 #     install ld as "ld.bfd".
 316 # --enable-gold[=default] --disable-ld
 317 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 318 # --enable-gold --enable-ld=default
 319 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 320 #     and ld.bfd).
 321 #     In other words, ld is default
 322 # --enable-gold=default --enable-ld=default
 323 #     Error.
 324
 325 default_ld=
 326 AC_ARG_ENABLE(gold,
 327 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 328                 [build gold @<:@ARG={default,yes,no}@:>@])],
 329 ENABLE_GOLD=$enableval,
 330 ENABLE_GOLD=no)
 331 case "${ENABLE_GOLD}" in
 332   yes|default)
 333     # Check for ELF target.
 334     is_elf=no
 335     case "${target}" in
 336       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 337       | *-*-linux* | *-*-gnu* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 338       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 339       | *-*-solaris2* | *-*-nto* | *-*-nacl*)
 340         case "${target}" in
 341           *-*-linux*aout* | *-*-linux*oldld*)
 342             ;;
 343           *)
 344             is_elf=yes
 345             ;;
 346         esac
 347     esac
 348
 349     if test "$is_elf" = "yes"; then
 350       # Check for target supported by gold.
 351       case "${target}" in
 352         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-* \
 353         | aarch64*-*-* | tilegx*-*-* | mips*-*-* | s390*-*-*)
 354           configdirs="$configdirs gold"
 355           if test x${ENABLE_GOLD} = xdefault; then
 356             default_ld=gold
 357           fi
 358           ENABLE_GOLD=yes
 359           ;;
 360       esac
 361     fi
 362     ;;
 363   no)
 364     ;;
 365   *)
 366     AC_MSG_ERROR([invalid --enable-gold argument])
 367     ;;
 368 esac
 369
 370 AC_ARG_ENABLE(ld,
 371 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 372                 [build ld @<:@ARG={default,yes,no}@:>@])],
 373 ENABLE_LD=$enableval,
 374 ENABLE_LD=yes)
 375
 376 case "${ENABLE_LD}" in
 377   default)
 378     if test x${default_ld} != x; then
 379       AC_MSG_ERROR([either gold or ld can be the default ld])
 380     fi
 381     ;;
 382   yes)
 383     ;;
 384   no)
 385     if test x${ENABLE_GOLD} != xyes; then
 386       AC_MSG_WARN([neither ld nor gold are enabled])
 387     fi
 388     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 389     ;;
 390   *)
 391     AC_MSG_ERROR([invalid --enable-ld argument])
 392     ;;
 393 esac
 394
 395 # PR gas/19109
 396 # Decide the default method for compressing debug sections.
 397 # Provide a configure time option to override our default.
 398 AC_ARG_ENABLE(compressed_debug_sections,
 399 [AS_HELP_STRING([--enable-compressed-debug-sections={all,gas,gold,ld,none}],
 400                 [Enable compressed debug sections for gas, gold or ld by
 401                  default])],
 402 [
 403   if test x"$enable_compressed_debug_sections" = xyes; then
 404     AC_MSG_ERROR([no program with compressed debug sections specified])
 405   fi
 406 ], [enable_compressed_debug_sections=])
 407
 408 # Configure extra directories which are host specific
 409
 410 case "${host}" in
 411   *-cygwin*)
 412     configdirs="$configdirs libtermcap" ;;
 413 esac
 414
 415 # A target can indicate whether a language isn't supported for some reason.
 416 # Only spaces may be used in this macro; not newlines or tabs.
 417 unsupported_languages=
 418
 419 # Remove more programs from consideration, based on the host or
 420 # target this usually means that a port of the program doesn't
 421 # exist yet.
 422
 423 case "${host}" in
 424   i[[3456789]]86-*-msdosdjgpp*)
 425     noconfigdirs="$noconfigdirs tcl tk itcl"
 426     ;;
 427 esac
 428
 429
 430 AC_ARG_ENABLE(libquadmath,
 431 AS_HELP_STRING([--disable-libquadmath],
 432   [do not build libquadmath directory]),
 433 ENABLE_LIBQUADMATH=$enableval,
 434 ENABLE_LIBQUADMATH=yes)
 435 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 436   noconfigdirs="$noconfigdirs target-libquadmath"
 437 fi
 438
 439
 440 AC_ARG_ENABLE(libquadmath-support,
 441 AS_HELP_STRING([--disable-libquadmath-support],
 442   [disable libquadmath support for Fortran]),
 443 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 444 ENABLE_LIBQUADMATH_SUPPORT=yes)
 445 enable_libquadmath_support=
 446 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 447   enable_libquadmath_support=no
 448 fi
 449
 450
 451 AC_ARG_ENABLE(libada,
 452 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 453 ENABLE_LIBADA=$enableval,
 454 ENABLE_LIBADA=yes)
 455 if test "${ENABLE_LIBADA}" != "yes" ; then
 456   noconfigdirs="$noconfigdirs gnattools"
 457 fi
 458
 459 AC_ARG_ENABLE(libssp,
 460 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 461 ENABLE_LIBSSP=$enableval,
 462 ENABLE_LIBSSP=yes)
 463
 464 AC_ARG_ENABLE(libstdcxx,
 465 AS_HELP_STRING([--disable-libstdcxx],
 466   [do not build libstdc++-v3 directory]),
 467 ENABLE_LIBSTDCXX=$enableval,
 468 ENABLE_LIBSTDCXX=default)
 469 [if test "${ENABLE_LIBSTDCXX}" = "no" ; then
 470   noconfigdirs="$noconfigdirs target-libstdc++-v3"
 471 fi]
 472
 473 # If this is accelerator compiler and its target is intelmic we enable
 474 # target liboffloadmic by default.  If this is compiler with offloading
 475 # for intelmic we enable host liboffloadmic by default.  Otherwise
 476 # liboffloadmic is disabled by default.
 477 AC_ARG_ENABLE([liboffloadmic],
 478 AC_HELP_STRING([[--enable-liboffloadmic[=ARG]]],
 479                [build liboffloadmic @<:@ARG={no,host,target}@:>@]),
 480 [case "$enableval" in
 481   no | host | target)
 482     enable_liboffloadmic=$enableval ;;
 483   *)
 484     AC_MSG_ERROR([--enable-liboffloadmic=no/host/target]) ;;
 485 esac],
 486 [if test x"$enable_as_accelerator_for" != x; then
 487   case "${target}" in
 488     *-intelmic-* | *-intelmicemul-*)
 489       enable_liboffloadmic=target
 490       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=target"
 491       ;;
 492     *)
 493       enable_liboffloadmic=no
 494       ;;
 495   esac
 496 else
 497   case "${enable_offload_targets}" in
 498     *-intelmic-* | *-intelmicemul-*)
 499       enable_liboffloadmic=host
 500       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=host"
 501       ;;
 502     *)
 503       enable_liboffloadmic=no
 504       ;;
 505     esac
 506 fi])
 507 AC_SUBST(extra_liboffloadmic_configure_flags)
 508
 509 # Enable libgomp by default on hosted POSIX systems, and a few others.
 510 if test x$enable_libgomp = x ; then
 511     case "${target}" in
 512     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 513         ;;
 514     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 515         ;;
 516     *-*-solaris2* | *-*-hpux11*)
 517         ;;
 518     *-*-darwin* | *-*-aix*)
 519         ;;
 520     nvptx*-*-*)
 521         ;;
 522     *)
 523         noconfigdirs="$noconfigdirs target-libgomp"
 524         ;;
 525     esac
 526 fi
 527
 528 # Disable libatomic on unsupported systems.
 529 if test -d ${srcdir}/libatomic; then
 530     if test x$enable_libatomic = x; then
 531         AC_MSG_CHECKING([for libatomic support])
 532         if (srcdir=${srcdir}/libatomic; \
 533                 . ${srcdir}/configure.tgt; \
 534                 test -n "$UNSUPPORTED")
 535         then
 536             AC_MSG_RESULT([no])
 537             noconfigdirs="$noconfigdirs target-libatomic"
 538         else
 539             AC_MSG_RESULT([yes])
 540         fi
 541     fi
 542 fi
 543
 544 # Disable liboffloadmic on unsupported systems.
 545 if test -d ${srcdir}/liboffloadmic; then
 546     if test x$enable_liboffloadmic != xno; then
 547         AC_MSG_CHECKING([for liboffloadmic support])
 548         if (srcdir=${srcdir}/liboffloadmic; \
 549                 . ${srcdir}/configure.tgt; \
 550                 test -n "$UNSUPPORTED")
 551         then
 552             AC_MSG_RESULT([no])
 553             noconfigdirs="$noconfigdirs target-liboffloadmic"
 554         else
 555             AC_MSG_RESULT([yes])
 556         fi
 557     fi
 558 fi
 559
 560 # Disable libitm on unsupported systems.
 561 if test -d ${srcdir}/libitm; then
 562     if test x$enable_libitm = x; then
 563         AC_MSG_CHECKING([for libitm support])
 564         if (srcdir=${srcdir}/libitm; \
 565                 . ${srcdir}/configure.tgt; \
 566                 test -n "$UNSUPPORTED")
 567         then
 568             AC_MSG_RESULT([no])
 569             noconfigdirs="$noconfigdirs target-libitm"
 570         else
 571             AC_MSG_RESULT([yes])
 572         fi
 573     fi
 574 fi
 575
 576 # Disable libsanitizer on unsupported systems.
 577 if test -d ${srcdir}/libsanitizer; then
 578     if test x$enable_libsanitizer = x; then
 579         AC_MSG_CHECKING([for libsanitizer support])
 580         if (srcdir=${srcdir}/libsanitizer; \
 581                 . ${srcdir}/configure.tgt; \
 582                 test -n "$UNSUPPORTED")
 583         then
 584             AC_MSG_RESULT([no])
 585             noconfigdirs="$noconfigdirs target-libsanitizer"
 586         else
 587             AC_MSG_RESULT([yes])
 588         fi
 589     fi
 590 fi
 591
 592 # Disable libvtv on unsupported systems.
 593 if test -d ${srcdir}/libvtv; then
 594     if test x$enable_libvtv = x; then
 595         AC_MSG_CHECKING([for libvtv support])
 596         if (srcdir=${srcdir}/libvtv; \
 597                 . ${srcdir}/configure.tgt; \
 598                 test "$VTV_SUPPORTED" != "yes")
 599         then
 600             AC_MSG_RESULT([no])
 601             noconfigdirs="$noconfigdirs target-libvtv"
 602         else
 603             AC_MSG_RESULT([yes])
 604         fi
 605     fi
 606 fi
 607
 608
 609 # Disable libhsail-rt on unsupported systems.
 610 if test -d ${srcdir}/libhsail-rt; then
 611     if test x$enable_libhsail_rt = x; then
 612         AC_MSG_CHECKING([for libhsail-rt support])
 613         if (srcdir=${srcdir}/libhsail-rt; \
 614                 . ${srcdir}/configure.tgt; \
 615                 test -n "$UNSUPPORTED")
 616         then
 617             AC_MSG_RESULT([no])
 618             unsupported_languages="$unsupported_languages brig"
 619             # This implicitly disables also target-libhsail-rt as it won't
 620             # get added to the build without BRIG FE.
 621         else
 622             AC_MSG_RESULT([yes])
 623         fi
 624     fi
 625 fi
 626
 627
 628 # Disable libquadmath for some systems.
 629 case "${target}" in
 630   avr-*-*)
 631     noconfigdirs="$noconfigdirs target-libquadmath"
 632     ;;
 633   # libquadmath is unused on AIX and libquadmath build process use of
 634   # LD_LIBRARY_PATH can break AIX bootstrap.
 635   powerpc-*-aix* | rs6000-*-aix*)
 636     noconfigdirs="$noconfigdirs target-libquadmath"
 637     ;;
 638 esac
 639
 640 # Disable libssp for some systems.
 641 case "${target}" in
 642   avr-*-*)
 643     # No hosted I/O support.
 644     noconfigdirs="$noconfigdirs target-libssp"
 645     ;;
 646   powerpc-*-aix* | rs6000-*-aix*)
 647     noconfigdirs="$noconfigdirs target-libssp"
 648     ;;
 649   rl78-*-*)
 650     # libssp uses a misaligned load to trigger a fault, but the RL78
 651     # doesn't fault for those - instead, it gives a build-time error
 652     # for explicit misaligned loads.
 653     noconfigdirs="$noconfigdirs target-libssp"
 654     ;;
 655   visium-*-*)
 656     # No hosted I/O support.
 657     noconfigdirs="$noconfigdirs target-libssp"
 658     ;;
 659 esac
 660
 661 # Disable libstdc++-v3 for some systems.
 662 # Allow user to override this if they pass --enable-libstdc++-v3
 663 if test "${ENABLE_LIBSTDCXX}" = "default" ; then
 664   case "${target}" in
 665     *-*-vxworks*)
 666       # VxWorks uses the Dinkumware C++ library.
 667       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 668       ;;
 669     arm*-wince-pe*)
 670       # the C++ libraries don't build on top of CE's C libraries
 671       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 672       ;;
 673     avr-*-*)
 674       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 675       ;;
 676     ft32-*-*)
 677       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 678       ;;
 679   esac
 680 fi
 681
 682 # Disable Fortran for some systems.
 683 case "${target}" in
 684   mmix-*-*)
 685     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 686     unsupported_languages="$unsupported_languages fortran"
 687     ;;
 688 esac
 689
 690 # Disable libffi for some systems.
 691 case "${target}" in
 692   powerpc-*-darwin*)
 693     ;;
 694   i[[3456789]]86-*-darwin*)
 695     ;;
 696   x86_64-*-darwin[[912]]*)
 697     ;;
 698   *-*-darwin*)
 699     noconfigdirs="$noconfigdirs target-libffi"
 700     ;;
 701   *-*-netware*)
 702     noconfigdirs="$noconfigdirs target-libffi"
 703     ;;
 704   *-*-phoenix*)
 705     noconfigdirs="$noconfigdirs target-libffi"
 706     ;;
 707   *-*-rtems*)
 708     noconfigdirs="$noconfigdirs target-libffi"
 709     ;;
 710   *-*-tpf*)
 711     noconfigdirs="$noconfigdirs target-libffi"
 712     ;;
 713   *-*-uclinux*)
 714     noconfigdirs="$noconfigdirs target-libffi"
 715     ;;
 716   *-*-vxworks*)
 717     noconfigdirs="$noconfigdirs target-libffi"
 718     ;;
 719   aarch64*-*-freebsd*)
 720     noconfigdirs="$noconfigdirs target-libffi"
 721     ;;
 722   alpha*-*-*vms*)
 723     noconfigdirs="$noconfigdirs target-libffi"
 724     ;;
 725   arm*-*-freebsd*)
 726     noconfigdirs="$noconfigdirs target-libffi"
 727     ;;
 728   arm-wince-pe)
 729     noconfigdirs="$noconfigdirs target-libffi"
 730     ;;
 731   arm*-*-symbianelf*)
 732     noconfigdirs="$noconfigdirs target-libffi"
 733     ;;
 734   cris-*-* | crisv32-*-*)
 735     case "${target}" in
 736       *-*-linux*)
 737         ;;
 738       *) # See PR46792 regarding target-libffi.
 739         noconfigdirs="$noconfigdirs target-libffi";;
 740     esac
 741     ;;
 742   hppa*64*-*-hpux*)
 743     noconfigdirs="$noconfigdirs target-libffi"
 744     ;;
 745   hppa*-hp-hpux11*)
 746     ;;
 747   hppa*-*-hpux*)
 748     noconfigdirs="$noconfigdirs target-libffi"
 749     ;;
 750   ia64*-*-*vms*)
 751     noconfigdirs="$noconfigdirs target-libffi"
 752     ;;
 753   i[[3456789]]86-w64-mingw*)
 754     noconfigdirs="$noconfigdirs target-libffi"
 755     ;;
 756   i[[3456789]]86-*-mingw*)
 757     noconfigdirs="$noconfigdirs target-libffi"
 758     ;;
 759   x86_64-*-mingw*)
 760     noconfigdirs="$noconfigdirs target-libffi"
 761     ;;
 762   mmix-*-*)
 763     noconfigdirs="$noconfigdirs target-libffi"
 764     ;;
 765   powerpc-*-aix*)
 766     ;;
 767   rs6000-*-aix*)
 768     ;;
 769   ft32-*-*)
 770     noconfigdirs="$noconfigdirs target-libffi"
 771     ;;
 772   *-*-lynxos*)
 773     noconfigdirs="$noconfigdirs target-libffi"
 774     ;;
 775 esac
 776
 777 # Disable the go frontend on systems where it is known to not work. Please keep
 778 # this in sync with contrib/config-list.mk.
 779 case "${target}" in
 780 *-*-darwin* | *-*-cygwin* | *-*-mingw*)
 781     unsupported_languages="$unsupported_languages go"
 782     ;;
 783 esac
 784
 785 # Only allow gdbserver on some systems.
 786 if test -d ${srcdir}/gdbserver; then
 787     if test x$enable_gdbserver = x; then
 788         AC_MSG_CHECKING([for gdbserver support])
 789         if (srcdir=${srcdir}/gdbserver; \
 790                 . ${srcdir}/configure.srv; \
 791                 test -n "$UNSUPPORTED")
 792         then
 793             AC_MSG_RESULT([no])
 794             noconfigdirs="$noconfigdirs gdbserver"
 795         else
 796             AC_MSG_RESULT([yes])
 797         fi
 798     fi
 799 fi
 800
 801 # Disable libgo for some systems where it is known to not work.
 802 # For testing, you can easily override this with --enable-libgo.
 803 if test x$enable_libgo = x; then
 804     case "${target}" in
 805     *-*-darwin*)
 806         # PR 46986
 807         noconfigdirs="$noconfigdirs target-libgo"
 808         ;;
 809     *-*-cygwin* | *-*-mingw*)
 810         noconfigdirs="$noconfigdirs target-libgo"
 811         ;;
 812     esac
 813 fi
 814
 815 # Default libgloss CPU subdirectory.
 816 libgloss_dir="$target_cpu"
 817
 818 case "${target}" in
 819   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 820     libgloss_dir=wince
 821     ;;
 822   aarch64*-*-* )
 823     libgloss_dir=aarch64
 824     ;;
 825   arm*-*-*)
 826     libgloss_dir=arm
 827     ;;
 828   cris-*-* | crisv32-*-*)
 829     libgloss_dir=cris
 830     ;;
 831   hppa*-*-*)
 832     libgloss_dir=pa
 833     ;;
 834   i[[3456789]]86-*-*)
 835     libgloss_dir=i386
 836     ;;
 837   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 838     libgloss_dir=m68hc11
 839     ;;
 840   m68*-*-* | fido-*-*)
 841     libgloss_dir=m68k
 842     ;;
 843   mips*-*-*)
 844     libgloss_dir=mips
 845     ;;
 846   powerpc*-*-*)
 847     libgloss_dir=rs6000
 848     ;;
 849   sparc*-*-*)
 850     libgloss_dir=sparc
 851     ;;
 852 esac
 853
 854 # Disable newlib and libgloss for various target OSes.
 855 case "${target}" in
 856   alpha*-dec-osf*)
 857     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 858     ;;
 859   i[[3456789]]86-*-linux*)
 860     # This section makes it possible to build newlib natively on linux.
 861     # If we are using a cross compiler then don't configure newlib.
 862     if test x${is_cross_compiler} != xno ; then
 863       noconfigdirs="$noconfigdirs target-newlib"
 864     fi
 865     noconfigdirs="$noconfigdirs target-libgloss"
 866     # If we are not using a cross compiler, do configure newlib.
 867     # Note however, that newlib will only be configured in this situation
 868     # if the --with-newlib option has been given, because otherwise
 869     # 'target-newlib' will appear in skipdirs.
 870     ;;
 871   i[[3456789]]86-*-rdos*)
 872     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 873     ;;
 874   sh*-*-pe|mips*-*-pe|arm-wince-pe)
 875     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 876     ;;
 877   sparc-*-sunos4*)
 878     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 879     ;;
 880   *-*-aix*)
 881     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 882     ;;
 883   *-*-beos*)
 884     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 885     ;;
 886   *-*-chorusos)
 887     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 888     ;;
 889   *-*-dragonfly*)
 890     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 891     ;;
 892   *-*-freebsd*)
 893     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 894     ;;
 895   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 896     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 897     ;;
 898   *-*-lynxos*)
 899     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 900     ;;
 901   *-*-mingw*)
 902     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 903     ;;
 904   *-*-netbsd*)
 905     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 906     ;;
 907   *-*-netware*)
 908     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 909     ;;
 910   *-*-tpf*)
 911     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 912     ;;
 913   *-*-uclinux*)
 914     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 915     ;;
 916   *-*-vxworks*)
 917     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 918     ;;
 919 esac
 920
 921 case "${target}" in
 922   *-*-chorusos)
 923     ;;
 924   aarch64-*-darwin*)
 925     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 926     noconfigdirs="$noconfigdirs sim target-rda"
 927     ;;
 928   arm-*-darwin*)
 929     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 930     noconfigdirs="$noconfigdirs sim target-rda"
 931     ;;
 932   powerpc-*-darwin*)
 933     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 934     noconfigdirs="$noconfigdirs sim target-rda"
 935     ;;
 936   i[[3456789]]86-*-darwin*)
 937     noconfigdirs="$noconfigdirs ld gprof"
 938     noconfigdirs="$noconfigdirs sim target-rda"
 939     ;;
 940   x86_64-*-darwin[[912]]*)
 941     noconfigdirs="$noconfigdirs ld gas gprof"
 942     noconfigdirs="$noconfigdirs sim target-rda"
 943     ;;
 944   *-*-darwin*)
 945     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 946     noconfigdirs="$noconfigdirs sim target-rda"
 947     ;;
 948   *-*-dragonfly*)
 949     ;;
 950   *-*-freebsd*)
 951     if test "x$with_gmp" = x && test "x$with_gmp_dir" = x \
 952         && test -f /usr/local/include/gmp.h; then
 953       with_gmp=/usr/local
 954     fi
 955     ;;
 956   *-*-kaos*)
 957     # Remove unsupported stuff on all kaOS configurations.
 958     noconfigdirs="$noconfigdirs target-libgloss"
 959     ;;
 960   *-*-netbsd*)
 961     ;;
 962   *-*-netware*)
 963     ;;
 964   *-*-phoenix*)
 965     noconfigdirs="$noconfigdirs target-libgloss"
 966     ;;
 967   *-*-rtems*)
 968     noconfigdirs="$noconfigdirs target-libgloss"
 969     ;;
 970     # The tpf target doesn't support gdb yet.
 971   *-*-tpf*)
 972     noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl"
 973     ;;
 974   *-*-uclinux*)
 975     noconfigdirs="$noconfigdirs target-rda"
 976     ;;
 977   *-*-vxworks*)
 978     ;;
 979   alpha*-dec-osf*)
 980     # ld works, but does not support shared libraries.
 981     # gas doesn't generate exception information.
 982     noconfigdirs="$noconfigdirs gas ld"
 983     ;;
 984   alpha*-*-*vms*)
 985     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
 986     ;;
 987   alpha*-*-*)
 988     # newlib is not 64 bit ready
 989     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 990     ;;
 991   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 992     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
 993     ;;
 994   arc*-*-*)
 995     noconfigdirs="$noconfigdirs sim"
 996     ;;
 997   arm-*-pe*)
 998     noconfigdirs="$noconfigdirs target-libgloss"
 999     ;;
1000   arm-*-riscix*)
1001     noconfigdirs="$noconfigdirs ld target-libgloss"
1002     ;;
1003   avr-*-*)
1004     if test x${with_avrlibc} != xno; then
1005       noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1006     fi
1007     ;;
1008   c4x-*-* | tic4x-*-*)
1009     noconfigdirs="$noconfigdirs target-libgloss"
1010     ;;
1011   tic54x-*-*)
1012     noconfigdirs="$noconfigdirs target-libgloss gdb"
1013     ;;
1014   d10v-*-*)
1015     noconfigdirs="$noconfigdirs target-libgloss"
1016     ;;
1017   d30v-*-*)
1018     noconfigdirs="$noconfigdirs gdb"
1019     ;;
1020   fr30-*-elf*)
1021     noconfigdirs="$noconfigdirs gdb"
1022     ;;
1023   ft32-*-*)
1024     noconfigdirs="$noconfigdirs target-rda gprof"
1025     ;;
1026   moxie-*-*)
1027     noconfigdirs="$noconfigdirs"
1028     ;;
1029   h8300*-*-*)
1030     noconfigdirs="$noconfigdirs target-libgloss"
1031     ;;
1032   h8500-*-*)
1033     noconfigdirs="$noconfigdirs target-libgloss"
1034     ;;
1035   hppa1.1-*-osf* | hppa1.1-*-bsd* )
1036     ;;
1037   hppa*64*-*-hpux*)
1038     noconfigdirs="$noconfigdirs gdb"
1039     ;;
1040   hppa*-*-hpux11*)
1041     noconfigdirs="$noconfigdirs gdb ld"
1042     ;;
1043   hppa*64*-*-linux*)
1044     ;;
1045   hppa*-*-linux*)
1046     ;;
1047   hppa*-*-*elf* | \
1048   hppa*-*-lites* | \
1049   hppa*-*-openbsd* | \
1050   hppa*64*-*-*)
1051     ;;
1052   hppa*-*-pro*)
1053     ;;
1054   hppa*-*-*)
1055     noconfigdirs="$noconfigdirs ld"
1056     ;;
1057   i960-*-*)
1058     noconfigdirs="$noconfigdirs gdb"
1059     ;;
1060   ia64*-*-elf*)
1061     # No gdb support yet.
1062     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
1063     ;;
1064   ia64*-**-hpux*)
1065     # No ld support yet.
1066     noconfigdirs="$noconfigdirs gdb libgui itcl ld"
1067     ;;
1068   ia64*-*-*vms*)
1069     # No ld support yet.
1070     noconfigdirs="$noconfigdirs libgui itcl ld"
1071     ;;
1072   i[[3456789]]86-w64-mingw*)
1073     ;;
1074   i[[3456789]]86-*-mingw*)
1075     target_configdirs="$target_configdirs target-winsup"
1076     ;;
1077   *-*-cygwin*)
1078     target_configdirs="$target_configdirs target-libtermcap target-winsup"
1079     noconfigdirs="$noconfigdirs target-libgloss"
1080     # always build newlib if winsup directory is present.
1081     if test -d "$srcdir/winsup/cygwin"; then
1082       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1083     elif test -d "$srcdir/newlib"; then
1084       echo "Warning: winsup/cygwin is missing so newlib can't be built."
1085     fi
1086     ;;
1087   i[[3456789]]86-*-pe)
1088     noconfigdirs="$noconfigdirs target-libgloss"
1089     ;;
1090   i[[3456789]]86-*-sco3.2v5*)
1091     # The linker does not yet know about weak symbols in COFF,
1092     # and is not configured to handle mixed ELF and COFF.
1093     noconfigdirs="$noconfigdirs ld target-libgloss"
1094     ;;
1095   i[[3456789]]86-*-sco*)
1096     noconfigdirs="$noconfigdirs gprof target-libgloss"
1097     ;;
1098   i[[3456789]]86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
1099     noconfigdirs="$noconfigdirs target-libgloss"
1100     ;;
1101   i[[3456789]]86-*-sysv4*)
1102     noconfigdirs="$noconfigdirs target-libgloss"
1103     ;;
1104   i[[3456789]]86-*-beos*)
1105     noconfigdirs="$noconfigdirs gdb"
1106     ;;
1107   i[[3456789]]86-*-rdos*)
1108     noconfigdirs="$noconfigdirs gdb"
1109     ;;
1110   mmix-*-*)
1111     noconfigdirs="$noconfigdirs gdb"
1112     ;;
1113   mt-*-*)
1114     noconfigdirs="$noconfigdirs sim"
1115     ;;
1116   nfp-*-*)
1117     noconfigdirs="$noconfigdirs ld gas gdb gprof sim"
1118     noconfigdirs="$noconfigdirs $target_libraries"
1119     ;;
1120   pdp11-*-*)
1121     noconfigdirs="$noconfigdirs gdb gprof"
1122     ;;
1123   powerpc-*-aix*)
1124     # copied from rs6000-*-* entry
1125     noconfigdirs="$noconfigdirs gprof"
1126     ;;
1127   powerpc*-*-winnt* | powerpc*-*-pe*)
1128     target_configdirs="$target_configdirs target-winsup"
1129     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
1130     # always build newlib.
1131     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1132     ;;
1133     # This is temporary until we can link against shared libraries
1134   powerpcle-*-solaris*)
1135     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
1136     ;;
1137   powerpc-*-beos*)
1138     noconfigdirs="$noconfigdirs gdb"
1139     ;;
1140   rs6000-*-lynxos*)
1141     noconfigdirs="$noconfigdirs gprof"
1142     ;;
1143   rs6000-*-aix*)
1144     noconfigdirs="$noconfigdirs gprof"
1145     ;;
1146   rs6000-*-*)
1147     noconfigdirs="$noconfigdirs gprof"
1148     ;;
1149   m68k-apollo-*)
1150     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
1151     ;;
1152   microblaze*)
1153     noconfigdirs="$noconfigdirs gprof"
1154     ;;
1155   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
1156     if test x$with_newlib = xyes; then
1157       noconfigdirs="$noconfigdirs gprof"
1158     fi
1159     ;;
1160   mips*-*-irix5*)
1161     noconfigdirs="$noconfigdirs gprof target-libgloss"
1162     ;;
1163   mips*-*-irix6*)
1164     noconfigdirs="$noconfigdirs gprof target-libgloss"
1165     ;;
1166   mips*-*-bsd*)
1167     noconfigdirs="$noconfigdirs ld gas gprof target-libgloss"
1168     ;;
1169   mips*-*-linux*)
1170     ;;
1171   mips*-*-ultrix* | mips*-*-osf* | mips*-*-ecoff* | mips*-*-pe* \
1172   | mips*-*-irix* | mips*-*-lnews* | mips*-*-riscos*)
1173     noconfigdirs="$noconfigdirs ld gas gprof"
1174     ;;
1175   mips*-*-*)
1176     noconfigdirs="$noconfigdirs gprof"
1177     ;;
1178   nvptx*-*-*)
1179     noconfigdirs="$noconfigdirs target-libssp target-libstdc++-v3 target-libobjc"
1180     ;;
1181   sh-*-*)
1182     case "${target}" in
1183       sh*-*-elf)
1184          ;;
1185       *)
1186          noconfigdirs="$noconfigdirs target-libgloss" ;;
1187     esac
1188     ;;
1189   sparc-*-sunos4*)
1190     if test x${is_cross_compiler} = xno ; then
1191            use_gnu_ld=no
1192     fi
1193     ;;
1194   tic6x-*-*)
1195     noconfigdirs="$noconfigdirs sim"
1196     ;;
1197   tilepro*-*-* | tilegx*-*-*)
1198     noconfigdirs="$noconfigdirs sim"
1199     ;;
1200   v810-*-*)
1201     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1202     ;;
1203   vax-*-*)
1204     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1205     ;;
1206   wasm32-*-*)
1207     noconfigdirs="$noconfigdirs ld"
1208     ;;
1209 esac
1210
1211 # If we aren't building newlib, then don't build libgloss, since libgloss
1212 # depends upon some newlib header files.
1213 case "${noconfigdirs}" in
1214   *target-libgloss*) ;;
1215   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1216 esac
1217
1218 # Work in distributions that contain no compiler tools, like Autoconf.
1219 host_makefile_frag=/dev/null
1220 if test -d ${srcdir}/config ; then
1221 case "${host}" in
1222   i[[3456789]]86-*-msdosdjgpp*)
1223     host_makefile_frag="config/mh-djgpp"
1224     ;;
1225   *-cygwin*)
1226     ACX_CHECK_CYGWIN_CAT_WORKS
1227     host_makefile_frag="config/mh-cygwin"
1228     ;;
1229   *-mingw*)
1230     host_makefile_frag="config/mh-mingw"
1231     ;;
1232   alpha*-linux*)
1233     host_makefile_frag="config/mh-alpha-linux"
1234     ;;
1235   hppa*-hp-hpux10*)
1236     host_makefile_frag="config/mh-pa-hpux10"
1237     ;;
1238   hppa*-hp-hpux*)
1239     host_makefile_frag="config/mh-pa"
1240     ;;
1241   hppa*-*)
1242     host_makefile_frag="config/mh-pa"
1243     ;;
1244   *-*-darwin*)
1245     host_makefile_frag="config/mh-darwin"
1246     ;;
1247   powerpc-*-aix*)
1248     host_makefile_frag="config/mh-ppc-aix"
1249     ;;
1250   rs6000-*-aix*)
1251     host_makefile_frag="config/mh-ppc-aix"
1252     ;;
1253 esac
1254 fi
1255
1256 if test "${build}" != "${host}" ; then
1257   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1258   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1259   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1260   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1261   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1262   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1263   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1264   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1265   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1266   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1267   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1268   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1269 else
1270   AR_FOR_BUILD="\$(AR)"
1271   AS_FOR_BUILD="\$(AS)"
1272   CC_FOR_BUILD="\$(CC)"
1273   CXX_FOR_BUILD="\$(CXX)"
1274   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1275   GOC_FOR_BUILD="\$(GOC)"
1276   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1277   LD_FOR_BUILD="\$(LD)"
1278   NM_FOR_BUILD="\$(NM)"
1279   RANLIB_FOR_BUILD="\$(RANLIB)"
1280   WINDRES_FOR_BUILD="\$(WINDRES)"
1281   WINDMC_FOR_BUILD="\$(WINDMC)"
1282 fi
1283
1284 AC_PROG_CC
1285 AC_PROG_CXX
1286
1287 # We must set the default linker to the linker used by gcc for the correct
1288 # operation of libtool.  If LD is not defined and we are using gcc, try to
1289 # set the LD default to the ld used by gcc.
1290 if test -z "$LD"; then
1291   if test "$GCC" = yes; then
1292     case $build in
1293     *-*-mingw*)
1294       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1295     *)
1296       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1297     esac
1298     case $gcc_prog_ld in
1299     # Accept absolute paths.
1300     [[\\/]* | [A-Za-z]:[\\/]*)]
1301       LD="$gcc_prog_ld" ;;
1302     esac
1303   fi
1304 fi
1305
1306 # Check whether -static-libstdc++ -static-libgcc is supported.
1307 have_static_libs=no
1308 if test "$GCC" = yes; then
1309   saved_LDFLAGS="$LDFLAGS"
1310
1311   LDFLAGS="$LDFLAGS -static-libstdc++ -static-libgcc"
1312   AC_MSG_CHECKING([whether g++ accepts -static-libstdc++ -static-libgcc])
1313   AC_LANG_PUSH(C++)
1314   AC_LINK_IFELSE([AC_LANG_SOURCE([
1315 #if (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 5)
1316 #error -static-libstdc++ not implemented
1317 #endif
1318 int main() {}])],
1319     [AC_MSG_RESULT([yes]); have_static_libs=yes],
1320     [AC_MSG_RESULT([no])])
1321   AC_LANG_POP(C++)
1322
1323   LDFLAGS="$saved_LDFLAGS"
1324 fi
1325
1326 ACX_PROG_GNAT
1327 ACX_PROG_CMP_IGNORE_INITIAL
1328
1329 AC_ARG_ENABLE([bootstrap],
1330 [AS_HELP_STRING([--enable-bootstrap],
1331                 [enable bootstrapping @<:@yes if native build@:>@])],,
1332 enable_bootstrap=default)
1333
1334 # Issue errors and warnings for invalid/strange bootstrap combinations.
1335 if test -r $srcdir/gcc/configure; then
1336   have_compiler=yes
1337 else
1338   have_compiler=no
1339 fi
1340
1341 case "$have_compiler:$host:$target:$enable_bootstrap" in
1342   *:*:*:no) ;;
1343
1344   # Default behavior.  Enable bootstrap if we have a compiler
1345   # and we are in a native configuration.
1346   yes:$build:$build:default)
1347     enable_bootstrap=yes ;;
1348
1349   *:*:*:default)
1350     enable_bootstrap=no ;;
1351
1352   # We have a compiler and we are in a native configuration, bootstrap is ok
1353   yes:$build:$build:yes)
1354     ;;
1355
1356   # Other configurations, but we have a compiler.  Assume the user knows
1357   # what he's doing.
1358   yes:*:*:yes)
1359     AC_MSG_WARN([trying to bootstrap a cross compiler])
1360     ;;
1361
1362   # No compiler: if they passed --enable-bootstrap explicitly, fail
1363   no:*:*:yes)
1364     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
1365
1366   # Fail if wrong command line
1367   *)
1368     AC_MSG_ERROR([invalid option for --enable-bootstrap])
1369     ;;
1370 esac
1371
1372 # When bootstrapping with GCC, build stage 1 in C++98 mode to ensure that a
1373 # C++98 compiler can still start the bootstrap.
1374 if test "$enable_bootstrap:$GXX" = "yes:yes"; then
1375   CXX="$CXX -std=gnu++98"
1376 fi
1377
1378 # Used for setting $lt_cv_objdir
1379 _LT_CHECK_OBJDIR
1380
1381 # Check for GMP, MPFR and MPC
1382 gmplibs="-lmpc -lmpfr -lgmp"
1383 gmpinc=
1384 have_gmp=no
1385
1386 # Check for debuginfod
1387 AC_DEBUGINFOD
1388
1389 # Specify a location for mpc
1390 # check for this first so it ends up on the link line before mpfr.
1391 AC_ARG_WITH(mpc,
1392 [AS_HELP_STRING([--with-mpc=PATH],
1393                 [specify prefix directory for installed MPC package.
1394                  Equivalent to --with-mpc-include=PATH/include
1395                  plus --with-mpc-lib=PATH/lib])])
1396 AC_ARG_WITH(mpc-include,
1397 [AS_HELP_STRING([--with-mpc-include=PATH],
1398                 [specify directory for installed MPC include files])])
1399 AC_ARG_WITH(mpc-lib,
1400 [AS_HELP_STRING([--with-mpc-lib=PATH],
1401                 [specify directory for the installed MPC library])])
1402
1403 if test "x$with_mpc" != x; then
1404   gmplibs="-L$with_mpc/lib $gmplibs"
1405   gmpinc="-I$with_mpc/include $gmpinc"
1406 fi
1407 if test "x$with_mpc_include" != x; then
1408   gmpinc="-I$with_mpc_include $gmpinc"
1409 fi
1410 if test "x$with_mpc_lib" != x; then
1411   gmplibs="-L$with_mpc_lib $gmplibs"
1412 fi
1413 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1414   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1415   gmpinc='-I$$s/mpc/src '"$gmpinc"
1416   # Do not test the mpc version.  Assume that it is sufficient, since
1417   # it is in the source tree, and the library has not been built yet
1418   # but it would be included on the link line in the version check below
1419   # hence making the test fail.
1420   have_gmp=yes
1421 fi
1422
1423 # Specify a location for mpfr
1424 # check for this first so it ends up on the link line before gmp.
1425 AC_ARG_WITH(mpfr-dir,
1426 [AS_HELP_STRING([--with-mpfr-dir=PATH], [this option has been REMOVED])],
1427 [AC_MSG_ERROR([The --with-mpfr-dir=PATH option has been removed.
1428 Use --with-mpfr=PATH or --with-mpfr-include=PATH plus --with-mpfr-lib=PATH])])
1429
1430 AC_ARG_WITH(mpfr,
1431 [AS_HELP_STRING([--with-mpfr=PATH],
1432                 [specify prefix directory for installed MPFR package.
1433                  Equivalent to --with-mpfr-include=PATH/include
1434                  plus --with-mpfr-lib=PATH/lib])])
1435 AC_ARG_WITH(mpfr-include,
1436 [AS_HELP_STRING([--with-mpfr-include=PATH],
1437                 [specify directory for installed MPFR include files])])
1438 AC_ARG_WITH(mpfr-lib,
1439 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1440                 [specify directory for the installed MPFR library])])
1441
1442 if test "x$with_mpfr" != x; then
1443   gmplibs="-L$with_mpfr/lib $gmplibs"
1444   gmpinc="-I$with_mpfr/include $gmpinc"
1445 fi
1446 if test "x$with_mpfr_include" != x; then
1447   gmpinc="-I$with_mpfr_include $gmpinc"
1448 fi
1449 if test "x$with_mpfr_lib" != x; then
1450   gmplibs="-L$with_mpfr_lib $gmplibs"
1451 fi
1452 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1453   # MPFR v3.1.0 moved the sources into a src sub-directory.
1454   if ! test -d ${srcdir}/mpfr/src; then
1455     AC_MSG_ERROR([dnl
1456 Building GCC with MPFR in the source tree is only handled for MPFR 3.1.0+.])
1457   fi
1458   gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir $gmplibs"
1459   gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr/src -I$$s/mpfr/src '"$gmpinc"
1460   extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr/src --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir"
1461   # Do not test the mpfr version.  Assume that it is sufficient, since
1462   # it is in the source tree, and the library has not been built yet
1463   # but it would be included on the link line in the version check below
1464   # hence making the test fail.
1465   have_gmp=yes
1466 fi
1467
1468 # Specify a location for gmp
1469 AC_ARG_WITH(gmp-dir,
1470 [AS_HELP_STRING([--with-gmp-dir=PATH], [this option has been REMOVED])],
1471 [AC_MSG_ERROR([The --with-gmp-dir=PATH option has been removed.
1472 Use --with-gmp=PATH or --with-gmp-include=PATH plus --with-gmp-lib=PATH])])
1473
1474 AC_ARG_WITH(gmp,
1475 [AS_HELP_STRING([--with-gmp=PATH],
1476                 [specify prefix directory for the installed GMP package.
1477                  Equivalent to --with-gmp-include=PATH/include
1478                  plus --with-gmp-lib=PATH/lib])])
1479 AC_ARG_WITH(gmp-include,
1480 [AS_HELP_STRING([--with-gmp-include=PATH],
1481                 [specify directory for installed GMP include files])])
1482 AC_ARG_WITH(gmp-lib,
1483 [AS_HELP_STRING([--with-gmp-lib=PATH],
1484                 [specify directory for the installed GMP library])])
1485
1486
1487 if test "x$with_gmp" != x; then
1488   gmplibs="-L$with_gmp/lib $gmplibs"
1489   gmpinc="-I$with_gmp/include $gmpinc"
1490 fi
1491 if test "x$with_gmp_include" != x; then
1492   gmpinc="-I$with_gmp_include $gmpinc"
1493 fi
1494 if test "x$with_gmp_lib" != x; then
1495   gmplibs="-L$with_gmp_lib $gmplibs"
1496 fi
1497 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1498   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1499   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1500   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1501   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1502   extra_isl_gmp_configure_flags='--with-gmp-builddir=$$r/$(HOST_SUBDIR)/gmp'
1503   # Do not test the gmp version.  Assume that it is sufficient, since
1504   # it is in the source tree, and the library has not been built yet
1505   # but it would be included on the link line in the version check below
1506   # hence making the test fail.
1507   have_gmp=yes
1508 fi
1509
1510 if test -d ${srcdir}/gcc && test "x$have_gmp" = xno; then
1511   have_gmp=yes
1512   saved_CFLAGS="$CFLAGS"
1513   CFLAGS="$CFLAGS $gmpinc"
1514   # Check for the recommended and required versions of GMP.
1515   AC_MSG_CHECKING([for the correct version of gmp.h])
1516   AC_TRY_COMPILE([#include "gmp.h"],[
1517   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1518   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1519   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,3)
1520   choke me
1521   #endif
1522   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1523   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1524   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1525   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1526   choke me
1527   #endif
1528   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1529    [AC_MSG_RESULT([no]); have_gmp=no])
1530
1531   # If we have GMP, check the MPFR version.
1532   if test x"$have_gmp" = xyes; then
1533     # Check for the recommended and required versions of MPFR.
1534     AC_MSG_CHECKING([for the correct version of mpfr.h])
1535     AC_TRY_COMPILE([#include <gmp.h>
1536     #include <mpfr.h>],[
1537     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,0)
1538     choke me
1539     #endif
1540     ], [AC_TRY_COMPILE([#include <gmp.h>
1541     #include <mpfr.h>],[
1542     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,2)
1543     choke me
1544     #endif
1545     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1546      [AC_MSG_RESULT([no]); have_gmp=no])
1547   fi
1548
1549   # Check for the MPC header version.
1550   if test x"$have_gmp" = xyes ; then
1551     # Check for the recommended and required versions of MPC.
1552     AC_MSG_CHECKING([for the correct version of mpc.h])
1553     AC_TRY_COMPILE([#include <mpc.h>],[
1554     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1555     choke me
1556     #endif
1557     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1558     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1559     choke me
1560     #endif
1561     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1562      [AC_MSG_RESULT([no]); have_gmp=no])
1563   fi
1564
1565   # Now check the MPFR library.
1566   if test x"$have_gmp" = xyes; then
1567     saved_LIBS="$LIBS"
1568     LIBS="$LIBS $gmplibs"
1569     AC_MSG_CHECKING([for the correct version of the gmp/mpfr/mpc libraries])
1570     AC_TRY_LINK([#include <mpc.h>],[
1571     mpfr_t n;
1572     mpfr_t x;
1573     mpc_t c;
1574     int t;
1575     mpfr_init (n);
1576     mpfr_init (x);
1577     mpfr_atan2 (n, n, x, GMP_RNDN);
1578     mpfr_erfc (n, x, GMP_RNDN);
1579     mpfr_subnormalize (x, t, GMP_RNDN);
1580     mpfr_clear(n);
1581     mpfr_clear(x);
1582     mpc_init2 (c, 53);
1583     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1584     mpc_cosh (c, c, MPC_RNDNN);
1585     mpc_pow (c, c, c, MPC_RNDNN);
1586     mpc_acosh (c, c, MPC_RNDNN);
1587     mpc_clear (c);
1588     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1589     LIBS="$saved_LIBS"
1590   fi
1591
1592   CFLAGS="$saved_CFLAGS"
1593
1594 # The library versions listed in the error message below should match
1595 # the HARD-minimums enforced above.
1596   if test x$have_gmp != xyes; then
1597     AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 2.4.0+ and MPC 0.8.0+.
1598 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1599 their locations.  Source code for these libraries can be found at
1600 their respective hosting sites as well as at
1601 ftp://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1602 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1603 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1604 make sure that you have installed both the libraries and the header
1605 files.  They may be located in separate packages.])
1606   fi
1607 fi
1608
1609 # Flags needed for both GMP, MPFR and/or MPC.
1610 AC_SUBST(gmplibs)
1611 AC_SUBST(gmpinc)
1612 AC_SUBST(extra_mpfr_configure_flags)
1613 AC_SUBST(extra_mpc_gmp_configure_flags)
1614 AC_SUBST(extra_mpc_mpfr_configure_flags)
1615 AC_SUBST(extra_isl_gmp_configure_flags)
1616
1617 # Libraries to use for stage1 or when not bootstrapping.
1618 AC_ARG_WITH(stage1-libs,
1619 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1620 [if test "$withval" = "no" -o "$withval" = "yes"; then
1621    stage1_libs=
1622  else
1623    stage1_libs=$withval
1624  fi],
1625 [stage1_libs=])
1626 AC_SUBST(stage1_libs)
1627
1628 # Whether or not to use -static-libstdc++ and -static-libgcc.  The
1629 # default is yes if gcc is being built; no otherwise.  The reason for
1630 # this default is that gdb is sometimes linked against GNU Source
1631 # Highlight, which is a shared library that uses C++ exceptions.  In
1632 # this case, -static-libstdc++ will cause crashes.
1633 AC_ARG_WITH(static-standard-libraries,
1634 [AS_HELP_STRING([--with-static-standard-libraries],
1635                 [use -static-libstdc++ and -static-libgcc (default=auto)])],
1636 [], [with_static_standard_libraries=auto])
1637 if test "$with_static_standard_libraries" = auto; then
1638   with_static_standard_libraries=$have_compiler
1639 fi
1640
1641 # Linker flags to use for stage1 or when not bootstrapping.
1642 AC_ARG_WITH(stage1-ldflags,
1643 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1644 [if test "$withval" = "no" -o "$withval" = "yes"; then
1645    stage1_ldflags=
1646  else
1647    stage1_ldflags=$withval
1648  fi],
1649 [stage1_ldflags=
1650  # In stage 1, default to linking libstdc++ and libgcc statically with GCC
1651  # if supported.  But if the user explicitly specified the libraries to use,
1652  # trust that they are doing what they want.
1653  if test "$with_static_standard_libraries" = yes -a "$stage1_libs" = "" \
1654      -a "$have_static_libs" = yes; then
1655    stage1_ldflags="-static-libstdc++ -static-libgcc"
1656  fi])
1657 AC_SUBST(stage1_ldflags)
1658
1659 # Libraries to use for stage2 and later builds.
1660 AC_ARG_WITH(boot-libs,
1661 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1662 [if test "$withval" = "no" -o "$withval" = "yes"; then
1663    poststage1_libs=
1664  else
1665    poststage1_libs=$withval
1666  fi],
1667 [poststage1_libs=])
1668 AC_SUBST(poststage1_libs)
1669
1670 # Linker flags to use for stage2 and later builds.
1671 AC_ARG_WITH(boot-ldflags,
1672 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1673                 [linker flags for stage2 and later])],
1674 [if test "$withval" = "no" -o "$withval" = "yes"; then
1675    poststage1_ldflags=
1676  else
1677    poststage1_ldflags=$withval
1678  fi],
1679 [poststage1_ldflags=
1680  # In stages 2 and 3, default to linking libstdc++ and libgcc
1681  # statically.  But if the user explicitly specified the libraries to
1682  # use, trust that they are doing what they want.
1683  if test "$poststage1_libs" = ""; then
1684    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1685  fi])
1686 AC_SUBST(poststage1_ldflags)
1687
1688 # GCC GRAPHITE dependency isl.
1689 # Basic setup is inlined here, actual checks are in config/isl.m4
1690
1691 AC_ARG_WITH(isl,
1692   [AS_HELP_STRING(
1693    [--with-isl=PATH],
1694    [Specify prefix directory for the installed isl package.
1695     Equivalent to --with-isl-include=PATH/include
1696     plus --with-isl-lib=PATH/lib])])
1697
1698 # Treat --without-isl as a request to disable
1699 # GRAPHITE support and skip all following checks.
1700 if test "x$with_isl" != "xno"; then
1701   # Check for isl
1702   dnl Provide configure switches and initialize islinc & isllibs
1703   dnl with user input.
1704   ISL_INIT_FLAGS
1705   dnl The versions of isl that work for Graphite
1706   ISL_CHECK_VERSION()
1707   dnl Only execute fail-action, if isl has been requested.
1708   ISL_IF_FAILED([
1709     AC_MSG_ERROR([Unable to find a usable isl.  See config.log for details.])])
1710 fi
1711
1712 # If the isl check failed, disable builds of in-tree variant of isl
1713 if test "x$with_isl" = xno ||
1714    test "x$gcc_cv_isl" = xno; then
1715   noconfigdirs="$noconfigdirs isl"
1716   islinc=
1717 fi
1718
1719 AC_SUBST(isllibs)
1720 AC_SUBST(islinc)
1721
1722 # Check for LTO support.
1723 AC_ARG_ENABLE(lto,
1724 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1725 enable_lto=$enableval,
1726 enable_lto=yes; default_enable_lto=yes)
1727
1728 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1729   build_lto_plugin=yes
1730 ],[if test x"$default_enable_lto" = x"yes" ; then
1731     case $target in
1732       *-apple-darwin[[912]]* | *-cygwin* | *-mingw* | *djgpp*) ;;
1733       # On other non-ELF platforms, LTO has yet to be validated.
1734       *) enable_lto=no ;;
1735     esac
1736   else
1737   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1738   # It would also be nice to check the binutils support, but we don't
1739   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1740   # warn during gcc/ subconfigure; unless you're bootstrapping with
1741   # -flto it won't be needed until after installation anyway.
1742     case $target in
1743       *-cygwin* | *-mingw* | *-apple-darwin* | *djgpp*) ;;
1744       *) if test x"$enable_lto" = x"yes"; then
1745         AC_MSG_ERROR([LTO support is not enabled for this target.])
1746         fi
1747       ;;
1748     esac
1749   fi
1750   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1751   # Build it unless LTO was explicitly disabled.
1752   case $target in
1753     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1754     *) ;;
1755   esac
1756 ])
1757
1758 AC_ARG_ENABLE(linker-plugin-configure-flags,
1759   [AS_HELP_STRING([[--enable-linker-plugin-configure-flags=FLAGS]],
1760     [additional flags for configuring linker plugins @<:@none@:>@])],
1761   extra_linker_plugin_configure_flags=$enableval,
1762   extra_linker_plugin_configure_flags=)
1763 AC_SUBST(extra_linker_plugin_configure_flags)
1764 AC_ARG_ENABLE(linker-plugin-flags,
1765   [AS_HELP_STRING([[--enable-linker-plugin-flags=FLAGS]],
1766     [additional flags for configuring and building linker plugins @<:@none@:>@])],
1767   extra_linker_plugin_flags=$enableval,
1768   extra_linker_plugin_flags=)
1769 AC_SUBST(extra_linker_plugin_flags)
1770
1771 # Enable --enable-host-shared.
1772 # Checked early to determine whether jit is an 'all' language
1773 AC_ARG_ENABLE(host-shared,
1774 [AS_HELP_STRING([--enable-host-shared],
1775                 [build host code as shared libraries])],
1776 [host_shared=$enableval], [host_shared=no])
1777 AC_SUBST(host_shared)
1778
1779 # By default, C and C++ are the only stage 1 languages.
1780 stage1_languages=,c,
1781
1782 # Target libraries that we bootstrap.
1783 bootstrap_target_libs=,target-libgcc,
1784
1785 # Figure out what language subdirectories are present.
1786 # Look if the user specified --enable-languages="..."; if not, use
1787 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1788 # go away some day.
1789 # NB:  embedded tabs in this IF block -- do not untabify
1790 if test -d ${srcdir}/gcc; then
1791   if test x"${enable_languages+set}" != xset; then
1792     if test x"${LANGUAGES+set}" = xset; then
1793       enable_languages="${LANGUAGES}"
1794         echo configure.ac: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
1795     else
1796       enable_languages=default
1797     fi
1798   else
1799     if test x"${enable_languages}" = x ||
1800        test x"${enable_languages}" = xyes;
1801        then
1802       echo configure.ac: --enable-languages needs at least one language argument 1>&2
1803       exit 1
1804     fi
1805   fi
1806   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
1807
1808   # 'f95' is the old name for the 'fortran' language. We issue a warning
1809   # and make the substitution.
1810   case ,${enable_languages}, in
1811     *,f95,*)
1812       echo configure.ac: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
1813       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
1814       ;;
1815   esac
1816
1817   # If bootstrapping, C++ must be enabled.
1818   case ",$enable_languages,:$enable_bootstrap" in
1819     *,c++,*:*) ;;
1820     *:yes)
1821       if test -f ${srcdir}/gcc/cp/config-lang.in; then
1822         enable_languages="${enable_languages},c++"
1823       else
1824         AC_MSG_ERROR([bootstrapping requires c++ sources])
1825       fi
1826       ;;
1827   esac
1828
1829   # First scan to see if an enabled language requires some other language.
1830   # We assume that a given config-lang.in will list all the language
1831   # front ends it requires, even if some are required indirectly.
1832   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1833     case ${lang_frag} in
1834       ..) ;;
1835       # The odd quoting in the next line works around
1836       # an apparent bug in bash 1.12 on linux.
1837       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1838       *)
1839         # From the config-lang.in, get $language, $lang_requires, and
1840         # $lang_requires_boot_languages.
1841         language=
1842         lang_requires=
1843         lang_requires_boot_languages=
1844         # set srcdir during sourcing lang_frag to the gcc dir.
1845         # Sadly overriding srcdir on the . line doesn't work in plain sh as it
1846         # polutes this shell
1847         saved_srcdir=${srcdir}
1848         srcdir=${srcdir}/gcc . ${lang_frag}
1849         srcdir=${saved_srcdir}
1850         for other in ${lang_requires} ${lang_requires_boot_languages}; do
1851           case ,${enable_languages}, in
1852             *,$other,*) ;;
1853             *,default,*) ;;
1854             *,all,*) ;;
1855             *,$language,*)
1856               echo " \`$other' language required by \`$language'; enabling" 1>&2
1857               enable_languages="${enable_languages},${other}"
1858               ;;
1859           esac
1860         done
1861         for other in ${lang_requires_boot_languages} ; do
1862           if test "$other" != "c"; then
1863             case ,${enable_stage1_languages}, in
1864               *,$other,*) ;;
1865               *,default,*) ;;
1866               *,all,*) ;;
1867               *)
1868                 case ,${enable_languages}, in
1869                   *,$language,*)
1870                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
1871                     enable_stage1_languages="$enable_stage1_languages,${other}"
1872                     ;;
1873                 esac
1874                 ;;
1875             esac
1876           fi
1877         done
1878         ;;
1879     esac
1880   done
1881
1882   new_enable_languages=,c,
1883
1884   # If LTO is enabled, add the LTO front end.
1885   if test "$enable_lto" = "yes" ; then
1886     case ,${enable_languages}, in
1887       *,lto,*) ;;
1888       *) enable_languages="${enable_languages},lto" ;;
1889     esac
1890     if test "${build_lto_plugin}" = "yes" ; then
1891       configdirs="$configdirs lto-plugin"
1892     fi
1893   fi
1894
1895   # If we're building an offloading compiler, add the LTO front end.
1896   if test x"$enable_as_accelerator_for" != x ; then
1897     case ,${enable_languages}, in
1898       *,lto,*) ;;
1899       *) enable_languages="${enable_languages},lto" ;;
1900     esac
1901   fi
1902
1903   missing_languages=`echo ",$enable_languages," | sed -e s/,default,/,/ -e s/,all,/,/ -e s/,c,/,/ `
1904   potential_languages=,c,
1905
1906   enabled_target_libs=
1907   disabled_target_libs=
1908
1909   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1910     case ${lang_frag} in
1911       ..) ;;
1912       # The odd quoting in the next line works around
1913       # an apparent bug in bash 1.12 on linux.
1914       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1915       *)
1916         # From the config-lang.in, get $language, $target_libs,
1917         # $lang_dirs, $boot_language, and $build_by_default
1918         language=
1919         target_libs=
1920         lang_dirs=
1921         subdir_requires=
1922         boot_language=no
1923         build_by_default=yes
1924         # set srcdir during sourcing.  See above about save & restore
1925         saved_srcdir=${srcdir}
1926         srcdir=${srcdir}/gcc . ${lang_frag}
1927         srcdir=${saved_srcdir}
1928         if test x${language} = x; then
1929           echo "${lang_frag} doesn't set \$language." 1>&2
1930           exit 1
1931         fi
1932
1933         if test "$language" = "c++"; then
1934           boot_language=yes
1935         fi
1936
1937         add_this_lang=no
1938         # C is always enabled, so no need to add it again
1939         if test "$language" != "c"; then
1940           case ,${enable_languages}, in
1941             *,${language},*)
1942               # Language was explicitly selected; include it
1943               add_this_lang=yes
1944               ;;
1945             *,all,*)
1946               # All languages are enabled
1947               add_this_lang=all
1948               ;;
1949             *,default,*)
1950               # 'default' was selected, select it if it is a default language
1951               add_this_lang=${build_by_default}
1952               ;;
1953           esac
1954         fi
1955
1956         # Disable languages that need other directories if these aren't available.
1957         for i in $subdir_requires; do
1958           test -f "$srcdir/gcc/$i/config-lang.in" && continue
1959           case ${add_this_lang} in
1960             yes)
1961               # Specifically requested language; tell them.
1962               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
1963               ;;
1964             all)
1965               AC_MSG_WARN([The gcc/$i directory contains parts of $language but is missing])
1966               add_this_lang=unsupported
1967               ;;
1968             *)
1969               # Silently disable.
1970               add_this_lang=unsupported
1971               ;;
1972           esac
1973         done
1974
1975         # Disable Ada if no preexisting GNAT is available.
1976         case ${add_this_lang}:${language}:${have_gnat} in
1977           yes:ada:no)
1978             # Specifically requested language; tell them.
1979             AC_MSG_ERROR([GNAT is required to build $language])
1980             ;;
1981           all:ada:no)
1982             AC_MSG_WARN([GNAT is required to build $language])
1983             add_this_lang=unsupported
1984             ;;
1985           *:ada:no)
1986             # Silently disable.
1987             add_this_lang=unsupported
1988             ;;
1989         esac
1990
1991         # Disable jit if -enable-host-shared not specified
1992         case ${add_this_lang}:${language}:${host_shared} in
1993           yes:jit:no)
1994             # PR jit/64780: explicitly specify --enable-host-shared
1995             AC_MSG_ERROR([
1996 Enabling language "jit" requires --enable-host-shared.
1997
1998 --enable-host-shared typically slows the rest of the compiler down by
1999 a few %, so you must explicitly enable it.
2000
2001 If you want to build both the jit and the regular compiler, it is often
2002 best to do this via two separate configure/builds, in separate
2003 directories, to avoid imposing the performance cost of
2004 --enable-host-shared on the regular compiler.])
2005             ;;
2006           all:jit:no)
2007             AC_MSG_WARN([--enable-host-shared required to build $language])
2008             add_this_lang=unsupported
2009             ;;
2010           *:jit:no)
2011             # Silently disable.
2012             add_this_lang=unsupported
2013             ;;
2014         esac
2015
2016         # Disable a language that is unsupported by the target.
2017         case "${add_this_lang}: $unsupported_languages " in
2018           no:*) ;;
2019           unsupported:*) ;;
2020           *:*" $language "*)
2021             AC_MSG_WARN([${language} not supported for this target])
2022             add_this_lang=unsupported
2023             ;;
2024         esac
2025
2026         case $add_this_lang in
2027           unsupported)
2028             # Remove language-dependent dirs.
2029             disabled_target_libs="$disabled_target_libs $target_libs"
2030             noconfigdirs="$noconfigdirs $lang_dirs"
2031             ;;
2032           no)
2033             # Remove language-dependent dirs; still show language as supported.
2034             disabled_target_libs="$disabled_target_libs $target_libs"
2035             noconfigdirs="$noconfigdirs $lang_dirs"
2036             potential_languages="${potential_languages}${language},"
2037             ;;
2038           all|yes)
2039             new_enable_languages="${new_enable_languages}${language},"
2040             potential_languages="${potential_languages}${language},"
2041             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
2042             enabled_target_libs="$enabled_target_libs $target_libs"
2043             case "${boot_language}:,$enable_stage1_languages," in
2044               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
2045                 # Add to (comma-separated) list of stage 1 languages.
2046                 case ",$stage1_languages," in
2047                   *,$language,* | ,yes, | ,all,) ;;
2048                   *) stage1_languages="${stage1_languages}${language}," ;;
2049                 esac
2050                 # We need to bootstrap any supporting libraries.
2051                 bootstrap_target_libs="${bootstrap_target_libs}${target_libs},"
2052                 ;;
2053             esac
2054             ;;
2055         esac
2056         ;;
2057     esac
2058   done
2059
2060   # Add target libraries which are only needed for disabled languages
2061   # to noconfigdirs.
2062   if test -n "$disabled_target_libs"; then
2063     for dir in $disabled_target_libs; do
2064       case " $enabled_target_libs " in
2065       *" ${dir} "*) ;;
2066       *) noconfigdirs="$noconfigdirs $dir" ;;
2067       esac
2068     done
2069   fi
2070
2071   AC_ARG_ENABLE(stage1-languages,
2072   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
2073                   [choose additional languages to build during
2074                   stage1.  Mostly useful for compiler development])],
2075   [case ,${enable_stage1_languages}, in
2076     ,no,|,,)
2077       # Set it to something that will have no effect in the loop below
2078       enable_stage1_languages=c ;;
2079     ,yes,)
2080       enable_stage1_languages=`echo $new_enable_languages | \
2081         sed -e "s/^,//" -e "s/,$//" ` ;;
2082     *,all,*)
2083       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
2084         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
2085   esac
2086
2087   # Add "good" languages from enable_stage1_languages to stage1_languages,
2088   # while "bad" languages go in missing_languages.  Leave no duplicates.
2089   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
2090     case $potential_languages in
2091       *,$i,*)
2092         case $stage1_languages in
2093           *,$i,*) ;;
2094           *) stage1_languages="$stage1_languages$i," ;;
2095         esac ;;
2096       *)
2097         case $missing_languages in
2098           *,$i,*) ;;
2099           *) missing_languages="$missing_languages$i," ;;
2100         esac ;;
2101      esac
2102   done])
2103
2104   # Remove leading/trailing commas that were added for simplicity
2105   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
2106   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
2107   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
2108   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
2109
2110   if test "x$missing_languages" != x; then
2111     AC_MSG_ERROR([
2112 The following requested languages could not be built: ${missing_languages}
2113 Supported languages are: ${potential_languages}])
2114   fi
2115   if test "x$new_enable_languages" != "x$enable_languages"; then
2116     echo The following languages will be built: ${new_enable_languages}
2117     enable_languages="$new_enable_languages"
2118   fi
2119
2120   AC_SUBST(stage1_languages)
2121   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
2122 fi
2123
2124 # Handle --disable-<component> generically.
2125 for dir in $configdirs $build_configdirs $target_configdirs ; do
2126   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
2127   varname=`echo $dirname | sed -e s/+/_/g`
2128   if eval test x\${enable_${varname}} "=" xno ; then
2129     noconfigdirs="$noconfigdirs $dir"
2130   fi
2131 done
2132
2133 # Check for Boehm's garbage collector
2134 AC_ARG_ENABLE(objc-gc,
2135 [AS_HELP_STRING([--enable-objc-gc],
2136                 [enable use of Boehm's garbage collector with the
2137                  GNU Objective-C runtime])])
2138 AC_ARG_WITH([target-bdw-gc],
2139 [AS_HELP_STRING([--with-target-bdw-gc=PATHLIST],
2140                 [specify prefix directory for installed bdw-gc package.
2141                  Equivalent to --with-target-bdw-gc-include=PATH/include
2142                  plus --with-target-bdw-gc-lib=PATH/lib])])
2143 AC_ARG_WITH([target-bdw-gc-include],
2144 [AS_HELP_STRING([--with-target-bdw-gc-include=PATHLIST],
2145                 [specify directories for installed bdw-gc include files])])
2146 AC_ARG_WITH([target-bdw-gc-lib],
2147 [AS_HELP_STRING([--with-target-bdw-gc-lib=PATHLIST],
2148                 [specify directories for installed bdw-gc library])])
2149
2150 case ,${enable_languages},:${enable_objc_gc} in *,objc,*:yes|*,objc,*:auto)
2151   AC_MSG_CHECKING([for bdw garbage collector])
2152   if test "x$with_target_bdw_gc$with_target_bdw_gc_include$with_target_bdw_gc_lib" = x; then
2153     dnl no bdw-gw options, assume default locations
2154     AC_MSG_RESULT([using bdw-gc in default locations])
2155   else
2156     dnl bdw-gw options, first error checking, complete checking in libobjc
2157     if test "x$with_target_bdw_gc_include" = x && test "x$with_target_bdw_gc_lib" != x; then
2158       AC_MSG_ERROR([found --with-target-bdw-gc-lib but --with-target-bdw-gc-include missing])
2159     elif test "x$with_target_bdw_gc_include" != x && test "x$with_target_bdw_gc_lib" = x; then
2160       AC_MSG_ERROR([found --with-target-bdw-gc-include but --with-target-bdw-gc-lib missing])
2161     else
2162       AC_MSG_RESULT([using paths configured with --with-target-bdw-gc options])
2163     fi
2164   fi
2165 esac
2166
2167 # Disable libitm, libsanitizer, libvtv, liboffloadmic if we're not building C++
2168 case ,${enable_languages}, in
2169   *,c++,*)
2170     # Disable libitm, libsanitizer if we're not building libstdc++
2171     case "${noconfigdirs}" in
2172       *target-libstdc++-v3*)
2173         noconfigdirs="$noconfigdirs target-libitm target-libsanitizer"
2174         ;;
2175       *) ;;
2176     esac
2177     ;;
2178   *)
2179     noconfigdirs="$noconfigdirs target-liboffloadmic target-libitm target-libsanitizer target-libvtv"
2180     ;;
2181 esac
2182
2183 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
2184 # $build_configdirs and $target_configdirs.
2185 # If we have the source for $noconfigdirs entries, add them to $notsupp.
2186
2187 notsupp=""
2188 for dir in . $skipdirs $noconfigdirs ; do
2189   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
2190   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2191     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
2192     if test -r $srcdir/$dirname/configure ; then
2193       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2194         true
2195       else
2196         notsupp="$notsupp $dir"
2197       fi
2198     fi
2199   fi
2200   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2201     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
2202     if test -r $srcdir/$dirname/configure ; then
2203       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2204         true
2205       else
2206         notsupp="$notsupp $dir"
2207       fi
2208     fi
2209   fi
2210   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2211     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
2212     if test -r $srcdir/$dirname/configure ; then
2213       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2214         true
2215       else
2216         notsupp="$notsupp $dir"
2217       fi
2218     fi
2219   fi
2220 done
2221
2222 # Quietly strip out all directories which aren't configurable in this tree.
2223 # This relies on all configurable subdirectories being autoconfiscated, which
2224 # is now the case.
2225 build_configdirs_all="$build_configdirs"
2226 build_configdirs=
2227 for i in ${build_configdirs_all} ; do
2228   j=`echo $i | sed -e s/build-//g`
2229   if test -f ${srcdir}/$j/configure ; then
2230     build_configdirs="${build_configdirs} $i"
2231   fi
2232 done
2233
2234 configdirs_all="$configdirs"
2235 configdirs=
2236 for i in ${configdirs_all} ; do
2237   if test -f ${srcdir}/$i/configure ; then
2238     configdirs="${configdirs} $i"
2239   fi
2240 done
2241
2242 target_configdirs_all="$target_configdirs"
2243 target_configdirs=
2244 for i in ${target_configdirs_all} ; do
2245   j=`echo $i | sed -e s/target-//g`
2246   if test -f ${srcdir}/$j/configure ; then
2247     target_configdirs="${target_configdirs} $i"
2248   fi
2249 done
2250
2251 # libiberty-linker-plugin is special: it doesn't have its own source directory,
2252 # so we have to add it after the preceding checks.
2253 if test x"$extra_linker_plugin_flags$extra_linker_plugin_configure_flags" != x
2254 then
2255   case " $configdirs " in
2256     *" libiberty "*)
2257       # If we can build libiberty, we can also build libiberty-linker-plugin.
2258       configdirs="$configdirs libiberty-linker-plugin"
2259       extra_linker_plugin_configure_flags="$extra_linker_plugin_configure_flags \
2260         --with-libiberty=../libiberty-linker-plugin";;
2261     *)
2262       AC_MSG_ERROR([libiberty missing]);;
2263   esac
2264 fi
2265
2266 # Sometimes we have special requirements for the host libiberty.
2267 extra_host_libiberty_configure_flags=
2268 extra_host_zlib_configure_flags=
2269 case " $configdirs " in
2270   *" lto-plugin "* | *" libcc1 "*)
2271     # When these are to be built as shared libraries, the same applies to
2272     # libiberty.
2273     extra_host_libiberty_configure_flags=--enable-shared
2274     ;;
2275   *" bfd "*)
2276     # When bfd is to be built as a shared library, the same applies to
2277     # zlib.
2278     if test "$enable_shared" = "yes"; then
2279       extra_host_zlib_configure_flags=--enable-host-shared
2280     fi
2281     ;;
2282 esac
2283 AC_SUBST(extra_host_libiberty_configure_flags)
2284 AC_SUBST(extra_host_zlib_configure_flags)
2285
2286 # Produce a warning message for the subdirs we can't configure.
2287 # This isn't especially interesting in the Cygnus tree, but in the individual
2288 # FSF releases, it's important to let people know when their machine isn't
2289 # supported by the one or two programs in a package.
2290
2291 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2292   # If $appdirs is non-empty, at least one of those directories must still
2293   # be configured, or we error out.  (E.g., if the gas release supports a
2294   # specified target in some subdirs but not the gas subdir, we shouldn't
2295   # pretend that all is well.)
2296   if test -n "$appdirs" ; then
2297     for dir in $appdirs ; do
2298       if test -r $dir/Makefile.in ; then
2299         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2300           appdirs=""
2301           break
2302         fi
2303         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2304           appdirs=""
2305           break
2306         fi
2307       fi
2308     done
2309     if test -n "$appdirs" ; then
2310       echo "*** This configuration is not supported by this package." 1>&2
2311       exit 1
2312     fi
2313   fi
2314   # Okay, some application will build, or we don't care to check.  Still
2315   # notify of subdirs not getting built.
2316   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2317   echo "    ${notsupp}" 1>&2
2318   echo "    (Any other directories should still work fine.)" 1>&2
2319 fi
2320
2321 case "$host" in
2322   *msdosdjgpp*)
2323     enable_gdbtk=no ;;
2324 esac
2325
2326 # To find our prefix, in gcc_cv_tool_prefix.
2327 ACX_TOOL_DIRS
2328
2329 copy_dirs=
2330
2331 AC_ARG_WITH([build-sysroot],
2332   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2333                   [use sysroot as the system root during the build])],
2334   [if test x"$withval" != x ; then
2335      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2336    fi],
2337   [SYSROOT_CFLAGS_FOR_TARGET=])
2338 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2339
2340 AC_ARG_WITH([debug-prefix-map],
2341   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2342                   [map A to B, C to D ... in debug information])],
2343   [if test x"$withval" != x; then
2344      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2345      for debug_map in $withval; do
2346        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2347      done
2348    fi],
2349   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2350 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2351
2352 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2353 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2354 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2355 # We want to ensure that TARGET libraries (which we know are built with
2356 # gcc) are built with "-O2 -g", so include those options when setting
2357 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2358 if test "x$CFLAGS_FOR_TARGET" = x; then
2359   if test "x${is_cross_compiler}" = xyes; then
2360     CFLAGS_FOR_TARGET="-g -O2"
2361   else
2362     CFLAGS_FOR_TARGET=$CFLAGS
2363     case " $CFLAGS " in
2364       *" -O2 "*) ;;
2365       *) CFLAGS_FOR_TARGET="-O2 $CFLAGS_FOR_TARGET" ;;
2366     esac
2367     case " $CFLAGS " in
2368       *" -g "* | *" -g3 "*) ;;
2369       *) CFLAGS_FOR_TARGET="-g $CFLAGS_FOR_TARGET" ;;
2370     esac
2371   fi
2372 fi
2373 AC_SUBST(CFLAGS_FOR_TARGET)
2374
2375 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2376   if test "x${is_cross_compiler}" = xyes; then
2377     CXXFLAGS_FOR_TARGET="-g -O2"
2378   else
2379     CXXFLAGS_FOR_TARGET=$CXXFLAGS
2380     case " $CXXFLAGS " in
2381       *" -O2 "*) ;;
2382       *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS_FOR_TARGET" ;;
2383     esac
2384     case " $CXXFLAGS " in
2385       *" -g "* | *" -g3 "*) ;;
2386       *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS_FOR_TARGET" ;;
2387     esac
2388   fi
2389 fi
2390 AC_SUBST(CXXFLAGS_FOR_TARGET)
2391
2392 AC_SUBST(LDFLAGS_FOR_TARGET)
2393
2394 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2395 # the named directory are copied to $(tooldir)/sys-include.
2396 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2397   if test x${is_cross_compiler} = xno ; then
2398     echo 1>&2 '***' --with-headers is only supported when cross compiling
2399     exit 1
2400   fi
2401   if test x"${with_headers}" != xyes ; then
2402     x=${gcc_cv_tool_prefix}
2403     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2404   fi
2405 fi
2406
2407 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2408 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2409 # are permitted.
2410 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2411   if test x${is_cross_compiler} = xno ; then
2412     echo 1>&2 '***' --with-libs is only supported when cross compiling
2413     exit 1
2414   fi
2415   if test x"${with_libs}" != xyes ; then
2416     # Copy the libraries in reverse order, so that files in the first named
2417     # library override files in subsequent libraries.
2418     x=${gcc_cv_tool_prefix}
2419     for l in ${with_libs}; do
2420       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2421     done
2422   fi
2423 fi
2424
2425 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2426 #
2427 # This is done by determining whether or not the appropriate directory
2428 # is available, and by checking whether or not specific configurations
2429 # have requested that this magic not happen.
2430 #
2431 # The command line options always override the explicit settings in
2432 # configure.ac, and the settings in configure.ac override this magic.
2433 #
2434 # If the default for a toolchain is to use GNU as and ld, and you don't
2435 # want to do that, then you should use the --without-gnu-as and
2436 # --without-gnu-ld options for the configure script.  Similarly, if
2437 # the default is to use the included zlib and you don't want to do that,
2438 # you should use the --with-system-zlib option for the configure script.
2439
2440 if test x${use_gnu_as} = x &&
2441    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2442   with_gnu_as=yes
2443   extra_host_args="$extra_host_args --with-gnu-as"
2444 fi
2445
2446 if test x${use_gnu_ld} = x &&
2447    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2448   with_gnu_ld=yes
2449   extra_host_args="$extra_host_args --with-gnu-ld"
2450 fi
2451
2452 if test x${use_included_zlib} = x &&
2453    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2454   :
2455 else
2456   with_system_zlib=yes
2457   extra_host_args="$extra_host_args --with-system-zlib"
2458 fi
2459
2460 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2461 # can detect this case.
2462
2463 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2464   with_newlib=yes
2465   extra_host_args="$extra_host_args --with-newlib"
2466 fi
2467
2468 # Handle ${copy_dirs}
2469 set fnord ${copy_dirs}
2470 shift
2471 while test $# != 0 ; do
2472   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2473     :
2474   else
2475     echo Copying $1 to $2
2476
2477     # Use the install script to create the directory and all required
2478     # parent directories.
2479     if test -d $2 ; then
2480       :
2481     else
2482       echo >config.temp
2483       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2484     fi
2485
2486     # Copy the directory, assuming we have tar.
2487     # FIXME: Should we use B in the second tar?  Not all systems support it.
2488     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2489
2490     # It is the responsibility of the user to correctly adjust all
2491     # symlinks.  If somebody can figure out how to handle them correctly
2492     # here, feel free to add the code.
2493
2494     echo $1 > $2/COPIED
2495   fi
2496   shift; shift
2497 done
2498
2499 # Determine a target-dependent exec_prefix that the installed
2500 # gcc will search in.  Keep this list sorted by triplet, with
2501 # the *-*-osname triplets last.
2502 md_exec_prefix=
2503 case "${target}" in
2504   i[[34567]]86-pc-msdosdjgpp*)
2505     md_exec_prefix=/dev/env/DJDIR/bin
2506     ;;
2507   *-*-hpux* | \
2508   *-*-nto-qnx* | \
2509   *-*-solaris2*)
2510     md_exec_prefix=/usr/ccs/bin
2511     ;;
2512 esac
2513
2514 extra_arflags_for_target=
2515 extra_nmflags_for_target=
2516 extra_ranlibflags_for_target=
2517 target_makefile_frag=/dev/null
2518 case "${target}" in
2519   spu-*-*)
2520     target_makefile_frag="config/mt-spu"
2521     ;;
2522   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
2523     target_makefile_frag="config/mt-sde"
2524     ;;
2525   mipsisa*-*-elfoabi*)
2526     target_makefile_frag="config/mt-mips-elfoabi"
2527     ;;
2528   mips*-*-*linux* | mips*-*-gnu*)
2529     target_makefile_frag="config/mt-mips-gnu"
2530     ;;
2531   nios2-*-elf*)
2532     target_makefile_frag="config/mt-nios2-elf"
2533     ;;
2534   *-*-linux-android*)
2535     target_makefile_frag="config/mt-android"
2536     ;;
2537   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2538     target_makefile_frag="config/mt-gnu"
2539     ;;
2540   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2541     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2542     # commands to handle both 32-bit and 64-bit objects.  These flags are
2543     # harmless if we're using GNU nm or ar.
2544     extra_arflags_for_target=" -X32_64"
2545     extra_nmflags_for_target=" -B -X32_64"
2546     ;;
2547 esac
2548
2549 alphaieee_frag=/dev/null
2550 case $target in
2551   alpha*-*-*)
2552     # This just makes sure to use the -mieee option to build target libs.
2553     # This should probably be set individually by each library.
2554     alphaieee_frag="config/mt-alphaieee"
2555     ;;
2556 esac
2557
2558 # If --enable-target-optspace always use -Os instead of -O2 to build
2559 # the target libraries, similarly if it is not specified, use -Os
2560 # on selected platforms.
2561 ospace_frag=/dev/null
2562 case "${enable_target_optspace}:${target}" in
2563   yes:*)
2564     ospace_frag="config/mt-ospace"
2565     ;;
2566   :d30v-*)
2567     ospace_frag="config/mt-d30v"
2568     ;;
2569   :m32r-* | :d10v-* | :fr30-* | :i?86*-*-elfiamcu)
2570     ospace_frag="config/mt-ospace"
2571     ;;
2572   no:* | :*)
2573     ;;
2574   *)
2575     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2576     ;;
2577 esac
2578
2579 # Some systems (e.g., one of the i386-aix systems the gas testers are
2580 # using) don't handle "\$" correctly, so don't use it here.
2581 tooldir='${exec_prefix}'/${target_noncanonical}
2582 build_tooldir=${tooldir}
2583
2584 # Create a .gdbinit file which runs the one in srcdir
2585 # and tells GDB to look there for source files.
2586
2587 if test -r ${srcdir}/.gdbinit ; then
2588   case ${srcdir} in
2589     .) ;;
2590     *) cat > ./.gdbinit <<EOF
2591 # ${NO_EDIT}
2592 dir ${srcdir}
2593 dir .
2594 source ${srcdir}/.gdbinit
2595 EOF
2596     ;;
2597   esac
2598 fi
2599
2600 # Make sure that the compiler is able to generate an executable.  If it
2601 # can't, we are probably in trouble.  We don't care whether we can run the
2602 # executable--we might be using a cross compiler--we only care whether it
2603 # can be created.  At this point the main configure script has set CC.
2604 we_are_ok=no
2605 echo "int main () { return 0; }" > conftest.c
2606 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2607 if test $? = 0 ; then
2608   if test -s conftest || test -s conftest.exe ; then
2609     we_are_ok=yes
2610   fi
2611 fi
2612 case $we_are_ok in
2613   no)
2614     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2615     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2616     rm -f conftest*
2617     exit 1
2618     ;;
2619 esac
2620 rm -f conftest*
2621
2622 # Decide which environment variable is used to find dynamic libraries.
2623 case "${host}" in
2624   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2625   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2626   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2627   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2628 esac
2629
2630 # On systems where the dynamic library environment variable is PATH,
2631 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2632 # built executables to PATH.
2633 if test "$RPATH_ENVVAR" = PATH; then
2634   GCC_SHLIB_SUBDIR=/shlib
2635 else
2636   GCC_SHLIB_SUBDIR=
2637 fi
2638
2639 # Adjust the toplevel makefile according to whether bootstrap was selected.
2640 case $enable_bootstrap in
2641   yes)
2642     bootstrap_suffix=bootstrap
2643     BUILD_CONFIG=bootstrap-debug
2644     ;;
2645   no)
2646     bootstrap_suffix=no-bootstrap
2647     BUILD_CONFIG=
2648     ;;
2649 esac
2650
2651 AC_MSG_CHECKING(for default BUILD_CONFIG)
2652
2653 AC_ARG_WITH([build-config],
2654   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2655                   [use config/NAME.mk build configuration])],
2656   [case $with_build_config in
2657    yes) with_build_config= ;;
2658    no) with_build_config= BUILD_CONFIG= ;;
2659    esac])
2660
2661 if test "x${with_build_config}" != x; then
2662   BUILD_CONFIG=$with_build_config
2663 else
2664   case $BUILD_CONFIG in
2665   bootstrap-debug)
2666     if echo "int f (void) { return 0; }" > conftest.c &&
2667        ${CC} -c conftest.c &&
2668        mv conftest.o conftest.o.g0 &&
2669        ${CC} -c -g conftest.c &&
2670        mv conftest.o conftest.o.g &&
2671        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
2672       :
2673     else
2674       BUILD_CONFIG=
2675     fi
2676     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2677     ;;
2678   esac
2679 fi
2680 AC_MSG_RESULT($BUILD_CONFIG)
2681 AC_SUBST(BUILD_CONFIG)
2682
2683 # Use same top-level configure hooks in libgcc/libstdc++/libvtv.
2684 AC_MSG_CHECKING([for --enable-vtable-verify])
2685 AC_ARG_ENABLE(vtable-verify,
2686 [AS_HELP_STRING([--enable-vtable-verify],
2687                 [Enable vtable verification feature])],
2688 [case "$enableval" in
2689  yes) enable_vtable_verify=yes ;;
2690  no)  enable_vtable_verify=no ;;
2691  *)   enable_vtable_verify=no;;
2692  esac],
2693 [enable_vtable_verify=no])
2694 AC_MSG_RESULT($enable_vtable_verify)
2695
2696 # Record target_configdirs and the configure arguments for target and
2697 # build configuration in Makefile.
2698 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
2699 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
2700 bootstrap_fixincludes=no
2701
2702 # If we are building libgomp, bootstrap it.
2703 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
2704   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
2705 fi
2706
2707 # If we are building libsanitizer and $BUILD_CONFIG contains bootstrap-asan
2708 # or bootstrap-ubsan, bootstrap it.
2709 if echo " ${target_configdirs} " | grep " libsanitizer " > /dev/null 2>&1; then
2710   case "$BUILD_CONFIG" in
2711     *bootstrap-asan* | *bootstrap-ubsan* )
2712       bootstrap_target_libs=${bootstrap_target_libs}target-libsanitizer,
2713       bootstrap_fixincludes=yes
2714       ;;
2715   esac
2716 fi
2717
2718 # If we are building libvtv and --enable-vtable-verify, bootstrap it.
2719 if echo " ${target_configdirs} " | grep " libvtv " > /dev/null 2>&1 &&
2720    test "$enable_vtable_verify" != no; then
2721   bootstrap_target_libs=${bootstrap_target_libs}target-libvtv,
2722 fi
2723
2724 # Determine whether gdb needs tk/tcl or not.
2725 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
2726 # and in that case we want gdb to be built without tk.  Ugh!
2727 # In fact I believe gdb is the *only* package directly dependent on tk,
2728 # so we should be able to put the 'maybe's in unconditionally and
2729 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
2730 # 100% sure that that's safe though.
2731
2732 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
2733 case "$enable_gdbtk" in
2734   no)
2735     GDB_TK="" ;;
2736   yes)
2737     GDB_TK="${gdb_tk}" ;;
2738   *)
2739     # Only add the dependency on gdbtk when GDBtk is part of the gdb
2740     # distro.  Eventually someone will fix this and move Insight, nee
2741     # gdbtk to a separate directory.
2742     if test -d ${srcdir}/gdb/gdbtk ; then
2743       GDB_TK="${gdb_tk}"
2744     else
2745       GDB_TK=""
2746     fi
2747     ;;
2748 esac
2749 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
2750 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
2751
2752 # gdb and gdbserver depend on gnulib and gdbsupport, but as nothing
2753 # else does, only include them if one of these is built.  The Makefile
2754 # provides the ordering, so it's enough here to add to the list.
2755 case " ${configdirs} " in
2756   *\ gdb\ *)
2757     configdirs="${configdirs} gnulib gdbsupport"
2758     ;;
2759   *\ gdbserver\ *)
2760     configdirs="${configdirs} gnulib gdbsupport"
2761     ;;
2762 esac
2763
2764 # Strip out unwanted targets.
2765
2766 # While at that, we remove Makefiles if we were started for recursive
2767 # configuration, so that the top-level Makefile reconfigures them,
2768 # like we used to do when configure itself was recursive.
2769
2770 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
2771 # but now we're fixing up the Makefile ourselves with the additional
2772 # commands passed to AC_CONFIG_FILES.  Use separate variables
2773 # extrasub-{build,host,target} not because there is any reason to split
2774 # the substitutions up that way, but only to remain below the limit of
2775 # 99 commands in a script, for HP-UX sed.
2776
2777 # Do not nest @if/@endif or @unless/@endunless pairs, because
2778 # configure will not warn you at all.
2779
2780 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
2781   yes:yes:*\ gold\ *:*,c++,*) ;;
2782   yes:yes:*\ gold\ *:*)
2783     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
2784     ;;
2785 esac
2786
2787 extrasub_build=
2788 for module in ${build_configdirs} ; do
2789   if test -z "${no_recursion}" \
2790      && test -f ${build_subdir}/${module}/Makefile; then
2791     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
2792     rm -f ${build_subdir}/${module}/Makefile
2793   fi
2794   extrasub_build="$extrasub_build
2795 /^@if build-$module\$/d
2796 /^@endif build-$module\$/d
2797 /^@unless build-$module\$/,/^@endunless build-$module\$/d
2798 /^@if build-$module-$bootstrap_suffix\$/d
2799 /^@endif build-$module-$bootstrap_suffix\$/d
2800 /^@unless build-$module-$bootstrap_suffix\$/,/^@endunless build-$module-$bootstrap_suffix\$/d"
2801 done
2802 extrasub_host=
2803 for module in ${configdirs} ; do
2804   if test -z "${no_recursion}"; then
2805     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
2806       if test -f ${file}; then
2807         echo 1>&2 "*** removing ${file} to force reconfigure"
2808         rm -f ${file}
2809       fi
2810     done
2811   fi
2812   case ${module},${bootstrap_fixincludes} in
2813     fixincludes,no) host_bootstrap_suffix=no-bootstrap ;;
2814     *) host_bootstrap_suffix=$bootstrap_suffix ;;
2815   esac
2816   extrasub_host="$extrasub_host
2817 /^@if $module\$/d
2818 /^@endif $module\$/d
2819 /^@unless $module\$/,/^@endunless $module\$/d
2820 /^@if $module-$host_bootstrap_suffix\$/d
2821 /^@endif $module-$host_bootstrap_suffix\$/d
2822 /^@unless $module-$host_bootstrap_suffix\$/,/^@endunless $module-$host_bootstrap_suffix\$/d"
2823 done
2824 extrasub_target=
2825 for module in ${target_configdirs} ; do
2826   if test -z "${no_recursion}" \
2827      && test -f ${target_subdir}/${module}/Makefile; then
2828     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
2829     rm -f ${target_subdir}/${module}/Makefile
2830   fi
2831
2832   # We only bootstrap target libraries listed in bootstrap_target_libs.
2833   case $bootstrap_target_libs in
2834     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
2835     *) target_bootstrap_suffix=no-bootstrap ;;
2836   esac
2837
2838   extrasub_target="$extrasub_target
2839 /^@if target-$module\$/d
2840 /^@endif target-$module\$/d
2841 /^@unless target-$module\$/,/^@endunless target-$module\$/d
2842 /^@if target-$module-$target_bootstrap_suffix\$/d
2843 /^@endif target-$module-$target_bootstrap_suffix\$/d
2844 /^@unless target-$module-$target_bootstrap_suffix\$/,/^@endunless target-$module-$target_bootstrap_suffix\$/d"
2845 done
2846
2847 # Do the final fixup along with target modules.
2848 extrasub_target="$extrasub_target
2849 /^@if /,/^@endif /d
2850 /^@unless /d
2851 /^@endunless /d"
2852
2853 # Create the serialization dependencies.  This uses a temporary file.
2854
2855 AC_ARG_ENABLE([serial-configure],
2856 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
2857                 [force sequential configuration of
2858                  sub-packages for the host, target or build
2859                  machine, or all sub-packages])])
2860
2861 case ${enable_serial_configure} in
2862   yes)
2863     enable_serial_build_configure=yes
2864     enable_serial_host_configure=yes
2865     enable_serial_target_configure=yes
2866     ;;
2867 esac
2868
2869 # These force 'configure's to be done one at a time, to avoid problems
2870 # with contention over a shared config.cache.
2871 rm -f serdep.tmp
2872 echo '# serdep.tmp' > serdep.tmp
2873 olditem=
2874 test "x${enable_serial_build_configure}" = xyes &&
2875 for item in ${build_configdirs} ; do
2876   case ${olditem} in
2877     "") ;;
2878     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
2879   esac
2880   olditem=${item}
2881 done
2882 olditem=
2883 test "x${enable_serial_host_configure}" = xyes &&
2884 for item in ${configdirs} ; do
2885   case ${olditem} in
2886     "") ;;
2887     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
2888   esac
2889   olditem=${item}
2890 done
2891 olditem=
2892 test "x${enable_serial_target_configure}" = xyes &&
2893 for item in ${target_configdirs} ; do
2894   case ${olditem} in
2895     "") ;;
2896     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
2897   esac
2898   olditem=${item}
2899 done
2900 serialization_dependencies=serdep.tmp
2901 AC_SUBST_FILE(serialization_dependencies)
2902
2903 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
2904 # target, nonopt, and variable assignments.  These are the ones we
2905 # might not want to pass down to subconfigures.  The exception being
2906 # --cache-file=/dev/null, which is used to turn off the use of cache
2907 # files altogether, and which should be passed on to subconfigures.
2908 # Also strip program-prefix, program-suffix, and program-transform-name,
2909 # so that we can pass down a consistent program-transform-name.
2910 baseargs=
2911 tbaseargs=
2912 keep_next=no
2913 skip_next=no
2914 eval "set -- $ac_configure_args"
2915 for ac_arg
2916 do
2917   if test X"$skip_next" = X"yes"; then
2918     skip_next=no
2919     continue
2920   fi
2921   if test X"$keep_next" = X"yes"; then
2922     case $ac_arg in
2923       *\'*)
2924         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2925     esac
2926     baseargs="$baseargs '$ac_arg'"
2927     tbaseargs="$tbaseargs '$ac_arg'"
2928     keep_next=no
2929     continue
2930   fi
2931
2932   # Handle separated arguments.  Based on the logic generated by
2933   # autoconf 2.59.
2934   case $ac_arg in
2935     *=* | --config-cache | -C | -disable-* | --disable-* \
2936       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
2937       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
2938       | -with-* | --with-* | -without-* | --without-* | --x)
2939       separate_arg=no
2940       ;;
2941     -*)
2942       separate_arg=yes
2943       ;;
2944     *)
2945       separate_arg=no
2946       ;;
2947   esac
2948
2949   skip_targ=no
2950   case $ac_arg in
2951 changequote(,)
2952   --with-* | --without-*)
2953     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
2954
2955     case $libopt in
2956     *[-_]include)
2957       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
2958       ;;
2959     *[-_]lib)
2960       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
2961       ;;
2962     *)
2963       lib=$libopt
2964       ;;
2965     esac
2966 changequote([,])
2967
2968     case $lib in
2969     mpc | mpfr | gmp | isl)
2970       # If we're processing --with-$lib, --with-$lib-include or
2971       # --with-$lib-lib, for one of the libs above, and target is
2972       # different from host, don't pass the current argument to any
2973       # target library's configure.
2974       if test x$is_cross_compiler = xyes; then
2975         skip_targ=yes
2976       fi
2977       ;;
2978     esac
2979     ;;
2980   esac
2981
2982   case "$ac_arg" in
2983     --cache-file=/dev/null | \
2984     -cache-file=/dev/null )
2985       # Handled here to avoid the test to skip args below.
2986       baseargs="$baseargs '$ac_arg'"
2987       tbaseargs="$tbaseargs '$ac_arg'"
2988       # Assert: $separate_arg should always be no.
2989       keep_next=$separate_arg
2990       ;;
2991     --no*)
2992       continue
2993       ;;
2994     --c* | \
2995     --sr* | \
2996     --ho* | \
2997     --bu* | \
2998     --t* | \
2999     --program-* | \
3000     -cache_file* | \
3001     -srcdir* | \
3002     -host* | \
3003     -build* | \
3004     -target* | \
3005     -program-prefix* | \
3006     -program-suffix* | \
3007     -program-transform-name* )
3008       skip_next=$separate_arg
3009       continue
3010       ;;
3011     -*)
3012       # An option.  Add it.
3013       case $ac_arg in
3014         *\'*)
3015           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
3016       esac
3017       baseargs="$baseargs '$ac_arg'"
3018       if test X"$skip_targ" = Xno; then
3019         tbaseargs="$tbaseargs '$ac_arg'"
3020       fi
3021       keep_next=$separate_arg
3022       ;;
3023     *)
3024       # Either a variable assignment, or a nonopt (triplet).  Don't
3025       # pass it down; let the Makefile handle this.
3026       continue
3027       ;;
3028   esac
3029 done
3030 # Remove the initial space we just introduced and, as these will be
3031 # expanded by make, quote '$'.
3032 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
3033
3034 # Add in --program-transform-name, after --program-prefix and
3035 # --program-suffix have been applied to it.  Autoconf has already
3036 # doubled dollar signs and backslashes in program_transform_name; we want
3037 # the backslashes un-doubled, and then the entire thing wrapped in single
3038 # quotes, because this will be expanded first by make and then by the shell.
3039 # Also, because we want to override the logic in subdir configure scripts to
3040 # choose program_transform_name, replace any s,x,x, with s,y,y,.
3041 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
3042 ${program_transform_name}
3043 EOF_SED
3044 gcc_transform_name=`cat conftestsed.out`
3045 rm -f conftestsed.out
3046 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
3047 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
3048 if test "$silent" = yes; then
3049   baseargs="$baseargs --silent"
3050   tbaseargs="$tbaseargs --silent"
3051 fi
3052 baseargs="$baseargs --disable-option-checking"
3053 tbaseargs="$tbaseargs --disable-option-checking"
3054
3055 # Record and document user additions to sub configure arguments.
3056 AC_ARG_VAR([build_configargs],
3057            [additional configure arguments for build directories])
3058 AC_ARG_VAR([host_configargs],
3059            [additional configure arguments for host directories])
3060 AC_ARG_VAR([target_configargs],
3061            [additional configure arguments for target directories])
3062
3063 # For the build-side libraries, we just need to pretend we're native,
3064 # and not use the same cache file.  Multilibs are neither needed nor
3065 # desired.  We can't even use the same cache file for all build-side
3066 # libraries, as they're compiled differently; some with C, some with
3067 # C++ or with different feature-enabling options.
3068 build_configargs="$build_configargs --cache-file=./config.cache ${baseargs}"
3069
3070 # For host modules, accept cache file option, or specification as blank.
3071 case "${cache_file}" in
3072 "") # empty
3073   cache_file_option="" ;;
3074 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
3075   cache_file_option="--cache-file=${cache_file}" ;;
3076 *) # relative path
3077   cache_file_option="--cache-file=../${cache_file}" ;;
3078 esac
3079
3080 # Host dirs don't like to share a cache file either, horribly enough.
3081 # This seems to be due to autoconf 2.5x stupidity.
3082 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}"
3083
3084 target_configargs="$target_configargs ${tbaseargs}"
3085
3086 # Passing a --with-cross-host argument lets the target libraries know
3087 # whether they are being built with a cross-compiler or being built
3088 # native.  However, it would be better to use other mechanisms to make the
3089 # sorts of decisions they want to make on this basis.  Please consider
3090 # this option to be deprecated.  FIXME.
3091 if test x${is_cross_compiler} = xyes ; then
3092   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
3093 fi
3094
3095 # Special user-friendly check for native x86_64-linux build, if
3096 # multilib is not explicitly enabled.
3097 case "$target:$have_compiler:$host:$target:$enable_multilib" in
3098   x86_64-*linux*:yes:$build:$build:)
3099     # Make sure we have a development environment that handles 32-bit
3100     dev64=no
3101     echo "int main () { return 0; }" > conftest.c
3102     ${CC} -m32 -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
3103     if test $? = 0 ; then
3104       if test -s conftest || test -s conftest.exe ; then
3105         dev64=yes
3106       fi
3107     fi
3108     rm -f conftest*
3109     if test x${dev64} != xyes ; then
3110       AC_MSG_ERROR([I suspect your system does not have 32-bit development libraries (libc and headers). If you have them, rerun configure with --enable-multilib. If you do not have them, and want to build a 64-bit-only compiler, rerun configure with --disable-multilib.])
3111     fi
3112     ;;
3113 esac
3114
3115 # Default to --enable-multilib.
3116 if test x${enable_multilib} = x ; then
3117   target_configargs="--enable-multilib ${target_configargs}"
3118 fi
3119
3120 # Pass --with-newlib if appropriate.  Note that target_configdirs has
3121 # changed from the earlier setting of with_newlib.
3122 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
3123   target_configargs="--with-newlib ${target_configargs}"
3124 fi
3125
3126 # Different target subdirs use different values of certain variables
3127 # (notably CXX).  Worse, multilibs use *lots* of different values.
3128 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
3129 # it doesn't automatically accept command-line overrides of them.
3130 # This means it's not safe for target subdirs to share a cache file,
3131 # which is disgusting, but there you have it.  Hopefully this can be
3132 # fixed in future.  It's still worthwhile to use a cache file for each
3133 # directory.  I think.
3134
3135 # Pass the appropriate --build, --host, --target and --cache-file arguments.
3136 # We need to pass --target, as newer autoconf's requires consistency
3137 # for target_alias and gcc doesn't manage it consistently.
3138 target_configargs="--cache-file=./config.cache ${target_configargs}"
3139
3140 FLAGS_FOR_TARGET=
3141 case " $target_configdirs " in
3142  *" newlib "*)
3143   case " $target_configargs " in
3144   *" --with-newlib "*)
3145    case "$target" in
3146     *-cygwin*)
3147       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -isystem $$s/winsup/cygwin/include'
3148       ;;
3149    esac
3150
3151    # If we're not building GCC, don't discard standard headers.
3152    if test -d ${srcdir}/gcc; then
3153      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
3154
3155      if test "${build}" != "${host}"; then
3156        # On Canadian crosses, CC_FOR_TARGET will have already been set
3157        # by `configure', so we won't have an opportunity to add -Bgcc/
3158        # to it.  This is right: we don't want to search that directory
3159        # for binaries, but we want the header files in there, so add
3160        # them explicitly.
3161        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
3162
3163        # Someone might think of using the pre-installed headers on
3164        # Canadian crosses, in case the installed compiler is not fully
3165        # compatible with the compiler being built.  In this case, it
3166        # would be better to flag an error than risking having
3167        # incompatible object files being constructed.  We can't
3168        # guarantee that an error will be flagged, but let's hope the
3169        # compiler will do it, when presented with incompatible header
3170        # files.
3171      fi
3172    fi
3173
3174    case "${target}-${is_cross_compiler}" in
3175    i[[3456789]]86-*-linux*-no)
3176       # Here host == target, so we don't need to build gcc,
3177       # so we don't want to discard standard headers.
3178       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
3179       ;;
3180    *)
3181       # If we're building newlib, use its generic headers last, but search
3182       # for any libc-related directories first (so make it the last -B
3183       # switch).
3184       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
3185
3186       # If we're building libgloss, find the startup file, simulator library
3187       # and linker script.
3188       case " $target_configdirs " in
3189         *" libgloss "*)
3190         # Look for startup file, simulator library and maybe linker script.
3191         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
3192         # Look for libnosys.a in case the target needs it.
3193         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
3194         # Most targets have the linker script in the source directory.
3195         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
3196         ;;
3197       esac
3198       ;;
3199    esac
3200    ;;
3201   esac
3202   ;;
3203 esac
3204
3205 case "$target" in
3206   x86_64-*mingw* | *-w64-mingw*)
3207   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
3208   # however, use a symlink named 'mingw' in ${prefix} .
3209     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
3210     ;;
3211   *-mingw*)
3212   # MinGW can't be handled as Cygwin above since it does not use newlib.
3213     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
3214     ;;
3215 esac
3216
3217 # Allow the user to override the flags for
3218 # our build compiler if desired.
3219 if test x"${build}" = x"${host}" ; then
3220   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
3221   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
3222   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
3223 fi
3224
3225 # On Canadian crosses, we'll be searching the right directories for
3226 # the previously-installed cross compiler, so don't bother to add
3227 # flags for directories within the install tree of the compiler
3228 # being built; programs in there won't even run.
3229 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
3230   # Search for pre-installed headers if nothing else fits.
3231   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
3232 fi
3233
3234 if test "x${use_gnu_ld}" = x &&
3235    echo " ${configdirs} " | grep " ld " > /dev/null ; then
3236   # Arrange for us to find uninstalled linker scripts.
3237   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
3238 fi
3239
3240 # Search for other target-specific linker scripts and such.
3241 case "${target}" in
3242   mep*)
3243     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
3244     ;;
3245 esac
3246
3247 # Makefile fragments.
3248 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
3249 do
3250   eval fragval=\$$frag
3251   if test $fragval != /dev/null; then
3252     eval $frag=${srcdir}/$fragval
3253   fi
3254 done
3255 AC_SUBST_FILE(host_makefile_frag)
3256 AC_SUBST_FILE(target_makefile_frag)
3257 AC_SUBST_FILE(alphaieee_frag)
3258 AC_SUBST_FILE(ospace_frag)
3259
3260 # Miscellanea: directories, flags, etc.
3261 AC_SUBST(RPATH_ENVVAR)
3262 AC_SUBST(GCC_SHLIB_SUBDIR)
3263 AC_SUBST(tooldir)
3264 AC_SUBST(build_tooldir)
3265 AC_SUBST(CONFIGURE_GDB_TK)
3266 AC_SUBST(GDB_TK)
3267 AC_SUBST(INSTALL_GDB_TK)
3268
3269 # Build module lists & subconfigure args.
3270 AC_SUBST(build_configargs)
3271 AC_SUBST(build_configdirs)
3272
3273 # Host module lists & subconfigure args.
3274 AC_SUBST(host_configargs)
3275 AC_SUBST(configdirs)
3276 AC_SUBST(target_configdirs)
3277
3278 # Target module lists & subconfigure args.
3279 AC_SUBST(target_configargs)
3280
3281
3282 # Build tools.
3283 AC_SUBST(AR_FOR_BUILD)
3284 AC_SUBST(AS_FOR_BUILD)
3285 AC_SUBST(CC_FOR_BUILD)
3286 AC_SUBST(CFLAGS_FOR_BUILD)
3287 AC_SUBST(CXXFLAGS_FOR_BUILD)
3288 AC_SUBST(CXX_FOR_BUILD)
3289 AC_SUBST(DLLTOOL_FOR_BUILD)
3290 AC_SUBST(GFORTRAN_FOR_BUILD)
3291 AC_SUBST(GOC_FOR_BUILD)
3292 AC_SUBST(LDFLAGS_FOR_BUILD)
3293 AC_SUBST(LD_FOR_BUILD)
3294 AC_SUBST(NM_FOR_BUILD)
3295 AC_SUBST(RANLIB_FOR_BUILD)
3296 AC_SUBST(WINDMC_FOR_BUILD)
3297 AC_SUBST(WINDRES_FOR_BUILD)
3298
3299 # Generate default definitions for YACC, M4, LEX and other programs that run
3300 # on the build machine.  These are used if the Makefile can't locate these
3301 # programs in objdir.
3302 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
3303
3304 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
3305 case " $build_configdirs " in
3306   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
3307 esac
3308
3309 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
3310 case " $build_configdirs " in
3311   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
3312 esac
3313
3314 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
3315 case " $build_configdirs " in
3316   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
3317 esac
3318
3319 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3320 case " $build_configdirs " in
3321   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3322   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
3323 esac
3324
3325 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3326 case " $build_configdirs " in
3327   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3328 esac
3329
3330 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3331 case " $build_configdirs " in
3332   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3333   *)
3334 changequote(,)
3335     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3336     # higher, else we use the "missing" dummy.
3337     if ${MAKEINFO} --version \
3338        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3339       :
3340     else
3341       MAKEINFO="$MISSING makeinfo"
3342     fi
3343     ;;
3344 changequote([,])
3345 esac
3346
3347 # FIXME: expect and dejagnu may become build tools?
3348
3349 AC_CHECK_PROGS(EXPECT, expect, expect)
3350 case " $configdirs " in
3351   *" expect "*)
3352     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3353     ;;
3354 esac
3355
3356 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3357 case " $configdirs " in
3358   *" dejagnu "*)
3359     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3360     ;;
3361 esac
3362
3363
3364 # Host tools.
3365 NCN_STRICT_CHECK_TOOLS(AR, ar)
3366 NCN_STRICT_CHECK_TOOLS(AS, as)
3367 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3368 NCN_STRICT_CHECK_TOOLS(LD, ld)
3369 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3370 NCN_STRICT_CHECK_TOOLS(NM, nm)
3371 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3372 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3373 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3374 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3375 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3376 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3377 NCN_STRICT_CHECK_TOOLS(READELF, readelf)
3378 AC_SUBST(CC)
3379 AC_SUBST(CXX)
3380 AC_SUBST(CFLAGS)
3381 AC_SUBST(CXXFLAGS)
3382
3383 # Target tools.
3384 AC_ARG_WITH([build-time-tools],
3385   [AS_HELP_STRING([--with-build-time-tools=PATH],
3386                   [use given path to find target tools during the build])],
3387   [case x"$withval" in
3388      x/*) ;;
3389      *)
3390        with_build_time_tools=
3391        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3392        ;;
3393    esac],
3394   [with_build_time_tools=])
3395
3396 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3397 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3398 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3399 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3400 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3401
3402 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3403 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3404 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3405 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3406 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3407 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3408 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJCOPY_FOR_TARGET, objcopy)
3409 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3410 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3411 ACX_CHECK_INSTALLED_TARGET_TOOL(READELF_FOR_TARGET, readelf)
3412 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3413 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3414 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3415
3416 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3417
3418 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3419 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3420 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3421 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3422 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3423                 [gcc/xg++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3424                 c++)
3425 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3426                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3427                 c++)
3428 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3429 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3430 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3431                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3432 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3433                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3434 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3435 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3436 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3437 GCC_TARGET_TOOL(objcopy, OBJCOPY_FOR_TARGET, OBJCOPY, [binutils/objcopy])
3438 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3439 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3440 GCC_TARGET_TOOL(readelf, READELF_FOR_TARGET, READELF, [binutils/readelf])
3441 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3442 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3443 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3444
3445 AC_SUBST(FLAGS_FOR_TARGET)
3446 AC_SUBST(RAW_CXX_FOR_TARGET)
3447
3448 # Certain tools may need extra flags.
3449 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3450 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3451 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3452
3453 # When building target libraries, except in a Canadian cross, we use
3454 # the same toolchain as the compiler we just built.
3455 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3456 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3457 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3458 if test $host = $build; then
3459   case " $configdirs " in
3460     *" gcc "*)
3461       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3462       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3463       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3464       ;;
3465   esac
3466 fi
3467
3468 AC_SUBST(COMPILER_AS_FOR_TARGET)
3469 AC_SUBST(COMPILER_LD_FOR_TARGET)
3470 AC_SUBST(COMPILER_NM_FOR_TARGET)
3471
3472 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3473 AC_ARG_ENABLE(maintainer-mode,
3474 [AS_HELP_STRING([--enable-maintainer-mode],
3475                 [enable make rules and dependencies not useful
3476                  (and sometimes confusing) to the casual installer])],
3477       USE_MAINTAINER_MODE=$enableval,
3478       USE_MAINTAINER_MODE=no)
3479 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3480 AC_SUBST(MAINTAINER_MODE_TRUE)
3481 AC_SUBST(MAINTAINER_MODE_FALSE)
3482 if test "$USE_MAINTAINER_MODE" = yes; then
3483   MAINTAINER_MODE_TRUE=
3484   MAINTAINER_MODE_FALSE='#'
3485 else
3486   MAINTAINER_MODE_TRUE='#'
3487   MAINTAINER_MODE_FALSE=
3488 fi
3489 MAINT=$MAINTAINER_MODE_TRUE
3490 AC_SUBST(MAINT)dnl
3491
3492 # ---------------------
3493 # GCC bootstrap support
3494 # ---------------------
3495
3496 # Stage specific cflags for build.
3497 stage1_cflags="-g"
3498 case $build in
3499   vax-*-*)
3500     case ${GCC} in
3501       yes) stage1_cflags="-g -Wa,-J" ;;
3502       *) stage1_cflags="-g -J" ;;
3503     esac ;;
3504 esac
3505
3506 AC_SUBST(stage1_cflags)
3507
3508 # Enable --enable-checking in stage1 of the compiler.
3509 AC_ARG_ENABLE(stage1-checking,
3510 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3511                 [choose additional checking for stage1 of the compiler])],
3512 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3513 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3514   # For --disable-checking or implicit --enable-checking=release, avoid
3515   # setting --enable-checking=gc in the default stage1 checking for LTO
3516   # bootstraps.  See PR62077.
3517   case $BUILD_CONFIG in
3518     *lto*)
3519       stage1_checking=--enable-checking=release,misc,gimple,rtlflag,tree,types;;
3520     *)
3521       stage1_checking=--enable-checking=yes,types;;
3522   esac
3523   if test "x$enable_checking" = x && \
3524      test -d ${srcdir}/gcc && \
3525      test x"`cat ${srcdir}/gcc/DEV-PHASE`" = xexperimental; then
3526     stage1_checking=--enable-checking=yes,types,extra
3527   fi
3528 else
3529   stage1_checking=--enable-checking=$enable_checking,types
3530 fi])
3531 AC_SUBST(stage1_checking)
3532
3533 # Enable -Werror in bootstrap stage2 and later.
3534 AC_ARG_ENABLE(werror,
3535 [AS_HELP_STRING([--enable-werror],
3536                 [enable -Werror in bootstrap stage2 and later])],
3537 [
3538 case ${enable_werror} in
3539   yes) stage2_werror_flag="--enable-werror-always" ;;
3540   *) stage2_werror_flag="" ;;
3541 esac
3542 ],
3543 [
3544 if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3545   case $BUILD_CONFIG in
3546   bootstrap-debug)
3547       stage2_werror_flag="--enable-werror-always" ;;
3548   "")
3549       stage2_werror_flag="--enable-werror-always" ;;
3550   esac
3551 fi
3552 ])
3553
3554 AC_SUBST(stage2_werror_flag)
3555
3556 # Specify what files to not compare during bootstrap.
3557
3558 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3559 case "$target" in
3560   hppa*64*-*-hpux*) ;;
3561   hppa*-*-hpux*) compare_exclusions="gcc/cc*-checksum\$(objext) | */libgcc/lib2funcs* | gcc/ada/*tools/* | gcc/function-tests.o" ;;
3562   powerpc*-ibm-aix*) compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/* | *libgomp*\$(objext)" ;;
3563 esac
3564 AC_SUBST(compare_exclusions)
3565
3566 AC_CONFIG_FILES([Makefile],
3567   [sed "$extrasub_build" Makefile |
3568    sed "$extrasub_host" |
3569    sed "$extrasub_target" > mf$$
3570    mv -f mf$$ Makefile],
3571   [extrasub_build="$extrasub_build"
3572    extrasub_host="$extrasub_host"
3573    extrasub_target="$extrasub_target"])
3574 AC_OUTPUT