gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004
   3 dnl Free Software Foundation, Inc.
   4 dnl
   5 dnl This file is part of GDB.
   6 dnl
   7 dnl This program is free software; you can redistribute it and/or modify
   8 dnl it under the terms of the GNU General Public License as published by
   9 dnl the Free Software Foundation; either version 2 of the License, or
  10 dnl (at your option) any later version.
  11 dnl
  12 dnl This program is distributed in the hope that it will be useful,
  13 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 dnl GNU General Public License for more details.
  16 dnl
  17 dnl You should have received a copy of the GNU General Public License
  18 dnl along with this program; if not, write to the Free Software
  19 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  20
  21 dnl Process this file with autoconf to produce a configure script.
  22
  23 AC_PREREQ(2.59)dnl
  24 AC_INIT(main.c)
  25 AC_CONFIG_HEADER(config.h:config.in)
  26 AM_MAINTAINER_MODE
  27
  28 AC_PROG_CC
  29 AC_GNU_SOURCE
  30 AC_AIX
  31 AC_ISC_POSIX
  32 AM_PROG_CC_STDC
  33
  34 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  35 AC_CANONICAL_SYSTEM
  36
  37 # FIXME: kettenis/20030102: The AC_PROG_RANLIB from Autoconf 2.13
  38 # doesn't support cross-compilation, but the one from Autoconf 2.5x
  39 # does.  Override RANLIB here (i.e. before running AC_PROG_RANLIB) to
  40 # deal with the lossage.  Note that CY_GNU_GETTEXT currently calls
  41 # AC_PROG_RANLIB.  This can be removed when we switch to Autoconf
  42 # 2.5x.
  43 AC_CHECK_TOOL(RANLIB, ranlib, :)
  44
  45 dnl List of object files and targets accumulated by configure.
  46
  47 CONFIG_OBS=
  48 CONFIG_DEPS=
  49 CONFIG_SRCS=
  50 ENABLE_CFLAGS=
  51
  52 CONFIG_ALL=
  53 CONFIG_CLEAN=
  54 CONFIG_INSTALL=
  55 CONFIG_UNINSTALL=
  56
  57 dnl Set up for gettext.  PACKAGE is used when we call bindtextdomain.
  58
  59 CY_GNU_GETTEXT
  60
  61 localedir='${datadir}/locale'
  62 AC_SUBST(localedir)
  63
  64 if test "x$POSUB" != x; then
  65
  66   dnl Lifted from GCC's config/gettext.m4.
  67   AC_MSG_CHECKING(for catalogs to be installed)
  68   # Look for .po and .gmo files in the source directory.
  69   CATALOGS=  AC_SUBST(CATALOGS)
  70   XLINGUAS=
  71   for cat in $srcdir/po/*.gmo $srcdir/po/*.po; do
  72     # If there aren't any .gmo files the shell will give us the
  73     # literal string "../path/to/srcdir/po/*.gmo" which has to be
  74     # weeded out.
  75     case "$cat" in *\**)
  76       continue;;
  77     esac
  78     # The quadruple backslash is collapsed to a double backslash
  79     # by the backticks, then collapsed again by the double quotes,
  80     # leaving us with one backslash in the sed expression (right
  81     # before the dot that mustn't act as a wildcard).
  82     cat=`echo $cat | sed -e "s!$srcdir/!!" -e "s!\\\\.po!.gmo!"`
  83     lang=`echo $cat | sed -e 's!po/!!' -e "s!\\\\.gmo!!"`
  84     # The user is allowed to set LINGUAS to a list of languages to
  85     # install catalogs for.  If it's empty that means "all of them."
  86     if test "x$LINGUAS" = x; then
  87       CATALOGS="$CATALOGS $cat"
  88       XLINGUAS="$XLINGUAS $lang"
  89     else
  90       case "$LINGUAS" in *$lang*)
  91         CATALOGS="$CATALOGS $cat"
  92         XLINGUAS="$XLINGUAS $lang"
  93         ;;
  94       esac
  95     fi
  96   done
  97   LINGUAS="$XLINGUAS"
  98   AC_MSG_RESULT($LINGUAS)
  99
 100    CONFIG_ALL="$CONFIG_ALL all-po"
 101    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
 102    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
 103    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
 104 fi
 105
 106 PACKAGE=gdb
 107 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
 108 AC_SUBST(PACKAGE)
 109
 110 debugdir=${libdir}/debug
 111
 112 AC_ARG_WITH(separate-debug-dir,
 113 [  --with-separate-debug-dir=path   Look for global separate debug info in this path [LIBDIR/debug]],
 114 [debugdir="${withval}"])
 115
 116 AC_DEFINE_DIR(DEBUGDIR, debugdir,
 117               [Global directory for separate debug files. ])
 118 #AC_DEFINE_UNQUOTED(DEBUGDIR, "$debugdir"),
 119
 120 AC_CONFIG_SUBDIRS(doc testsuite)
 121
 122 . $srcdir/configure.host
 123
 124 . $srcdir/configure.tgt
 125
 126 # Fetch the default architecture and default target vector from BFD.
 127 targ=$target; . $srcdir/../bfd/config.bfd
 128
 129 # We only want the first architecture, so strip off the others if
 130 # there is more than one.
 131 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 132
 133 if test "x$targ_archs" != x; then
 134   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 135     [Define to BFD's default architecture. ])
 136 fi
 137 if test "x$targ_defvec" != x; then
 138   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 139     [Define to BFD's default target vector. ])
 140 fi
 141
 142 AC_ARG_PROGRAM
 143
 144 # The CLI cannot be disabled yet, but may be in the future.
 145
 146 # Enable CLI.
 147 AC_ARG_ENABLE(gdbcli,
 148 [  --disable-gdbcli        disable command-line interface (CLI)],
 149   [case $enableval in
 150     yes)
 151       ;;
 152     no)
 153       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 154     *)
 155       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 156   esac],
 157   [enable_gdbcli=yes])
 158 if test x"$enable_gdbcli" = xyes; then
 159   if test -d $srcdir/cli; then
 160     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 161     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 162     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 163     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 164   fi
 165 fi
 166
 167 # Enable MI.
 168 AC_ARG_ENABLE(gdbmi,
 169 [  --disable-gdbmi         disable machine-interface (MI)],
 170   [case $enableval in
 171     yes | no)
 172       ;;
 173     *)
 174       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 175   esac],
 176   [enable_gdbmi=yes])
 177 if test x"$enable_gdbmi" = xyes; then
 178   if test -d $srcdir/mi; then
 179     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 180     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 181     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 182     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 183   fi
 184 fi
 185
 186 # Enable TUI.
 187 AC_ARG_ENABLE(tui,
 188 [  --enable-tui            enable full-screen terminal user interface (TUI)],
 189   [case $enableval in
 190     yes | no)
 191       ;;
 192     *)
 193       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 194   esac],enable_tui=yes)
 195
 196 # Enable gdbtk.
 197 AC_ARG_ENABLE(gdbtk,
 198 [  --enable-gdbtk          enable gdbtk graphical user interface (GUI)],
 199   [case $enableval in
 200     yes | no)
 201       ;;
 202     *)
 203       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 204   esac],
 205   [if test -d $srcdir/gdbtk; then
 206     enable_gdbtk=yes
 207   else
 208     enable_gdbtk=no
 209   fi])
 210 # We unconditionally disable gdbtk tests on selected platforms.
 211 case $host_os in
 212   go32* | windows*)
 213     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 214     enable_gdbtk=no ;;
 215 esac
 216
 217 # Libunwind support.
 218 AC_ARG_WITH(libunwind,
 219 [  --with-libunwind            Use libunwind frame unwinding support],
 220 [case "${withval}" in
 221   yes)  enable_libunwind=yes ;;
 222   no)   enable_libunwind=no ;;
 223   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-libunwind option) ;;
 224 esac],[
 225   AC_CHECK_HEADERS(libunwind.h)
 226   AC_CHECK_HEADERS(libunwind-ia64.h)
 227   if test x"$ac_cv_header_libunwind_h" = xyes -a x"$ac_cv_header_libunwind_ia64_h" = xyes; then
 228     enable_libunwind=yes;
 229   fi
 230 ])
 231
 232 if test x"$enable_libunwind" = xyes; then
 233   AC_CHECK_HEADERS(libunwind.h)
 234   AC_CHECK_HEADERS(libunwind-ia64.h)
 235   AC_DEFINE(HAVE_LIBUNWIND, 1)
 236   CONFIG_OBS="$CONFIG_OBS libunwind-frame.o"
 237   CONFIG_DEPS="$CONFIG_DEPS libunwind-frame.o"
 238   CONFIG_SRCS="$CONFIG_SRCS libunwind-frame.c"
 239 fi
 240
 241 # Profiling support.
 242 AC_ARG_ENABLE(profiling,
 243 [  --enable-profiling      enable profiling of GDB],
 244   [case $enableval in
 245     yes | no)
 246       ;;
 247     *)
 248       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 249   esac],
 250  [enable_profiling=no])
 251
 252 AC_CHECK_FUNCS(monstartup _mcleanup)
 253 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 254 [AC_TRY_LINK(
 255 [#include <stdlib.h>
 256 extern char _etext;
 257 ],
 258 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 259 if test $ac_cv_var__etext = yes; then
 260   AC_DEFINE(HAVE__ETEXT, 1,
 261             [Define to 1 if your system has the _etext variable. ])
 262 fi
 263 if test "$enable_profiling" = yes ; then
 264   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 265     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 266   fi
 267   PROFILE_CFLAGS=-pg
 268   OLD_CFLAGS="$CFLAGS"
 269   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 270
 271   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 272     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 273      ac_cv_cc_supports_pg=no)])
 274
 275   if test $ac_cv_cc_supports_pg = no; then
 276     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 277   fi
 278
 279   CFLAGS="$OLD_CFLAGS"
 280 fi
 281
 282 # --------------------- #
 283 # Checks for programs.  #
 284 # --------------------- #
 285
 286 AC_PROG_AWK
 287 AC_PROG_INSTALL
 288 AC_PROG_LN_S
 289 AC_PROG_RANLIB
 290 AC_PROG_YACC
 291
 292 AC_CHECK_TOOL(AR, ar)
 293 AC_CHECK_TOOL(DLLTOOL, dlltool)
 294 AC_CHECK_TOOL(WINDRES, windres)
 295
 296 # Needed for GNU/Hurd.
 297 AC_CHECK_TOOL(MIG, mig)
 298
 299 # ---------------------- #
 300 # Checks for libraries.  #
 301 # ---------------------- #
 302
 303 # We might need to link with -lm; most simulators need it.
 304 AC_CHECK_LIB(m, main)
 305
 306 # We need to link with -lw to get `wctype' on Solaris before Solaris
 307 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 308 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 309 # is known to have this problem).  Therefore we avoid libw if we can.
 310 AC_CHECK_FUNC(wctype, [],
 311   [AC_CHECK_LIB(w, wctype)])
 312
 313 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 314 AC_SEARCH_LIBS(gethostbyname, nsl)
 315
 316 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 317 AC_SEARCH_LIBS(socketpair, socket)
 318
 319 # For the TUI, we need enhanced curses functionality.
 320 #
 321 # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 322 # curses library because the latter might not provide all the
 323 # functionality we need.  However, this leads to problems on systems
 324 # where the linker searches /usr/local/lib, but the compiler doesn't
 325 # search /usr/local/include, if ncurses is installed in /usr/local.  A
 326 # default installation of ncurses on alpha*-dec-osf* will lead to such
 327 # a situation.
 328 AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
 329
 330 # Since GDB uses Readline, we need termcap functionality.  In many
 331 # cases this will be provided by the curses library, but some systems
 332 # have a seperate termcap library, or no curses library at all.
 333
 334 case $host_os in
 335   cygwin*)
 336     if test -d $srcdir/libtermcap; then
 337       LIBS="../libtermcap/libtermcap.a $LIBS"
 338       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 339     fi ;;
 340   go32* | *djgpp*)
 341     ac_cv_search_tgetent="none required"
 342     ;;
 343 esac
 344
 345 # These are the libraries checked by Readline.
 346 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
 347
 348 if test "$ac_cv_search_tgetent" = no; then
 349   AC_MSG_ERROR([no termcap library found])
 350 fi
 351
 352 # ------------------------- #
 353 # Checks for header files.  #
 354 # ------------------------- #
 355
 356 AC_HEADER_DIRENT
 357 AC_HEADER_STAT
 358 AC_HEADER_STDC
 359 AC_CHECK_HEADERS(nlist.h)
 360 AC_CHECK_HEADERS(link.h, [], [],
 361 [#if HAVE_SYS_TYPES_H
 362 # include <sys/types.h>
 363 #endif
 364 #if HAVE_NLIST_H
 365 # include <nlist.h>
 366 #endif
 367 ])
 368 AC_CHECK_HEADERS(machine/reg.h)
 369 AC_CHECK_HEADERS(poll.h sys/poll.h)
 370 AC_CHECK_HEADERS(proc_service.h thread_db.h gnu/libc-version.h)
 371 AC_CHECK_HEADERS(stddef.h)
 372 AC_CHECK_HEADERS(stdlib.h)
 373 AC_CHECK_HEADERS(stdint.h)
 374 AC_CHECK_HEADERS(string.h memory.h strings.h)
 375 AC_CHECK_HEADERS(sys/fault.h)
 376 AC_CHECK_HEADERS(sys/file.h)
 377 AC_CHECK_HEADERS(sys/filio.h)
 378 AC_CHECK_HEADERS(sys/ioctl.h)
 379 AC_CHECK_HEADERS(sys/param.h)
 380 AC_CHECK_HEADERS(sys/proc.h, [], [],
 381 [#if HAVE_SYS_PARAM_H
 382 # include <sys/param.h>
 383 #endif
 384 ])
 385 AC_CHECK_HEADERS(sys/procfs.h)
 386 AC_CHECK_HEADERS(sys/ptrace.h ptrace.h)
 387 AC_CHECK_HEADERS(sys/reg.h sys/debugreg.h)
 388 AC_CHECK_HEADERS(sys/select.h)
 389 AC_CHECK_HEADERS(sys/syscall.h)
 390 AC_CHECK_HEADERS(sys/types.h)
 391 AC_CHECK_HEADERS(sys/user.h, [], [],
 392 [#if HAVE_SYS_PARAM_H
 393 # include <sys/param.h>
 394 #endif
 395 ])
 396 AC_CHECK_HEADERS(sys/wait.h wait.h)
 397 AC_CHECK_HEADERS(termios.h termio.h sgtty.h)
 398 AC_CHECK_HEADERS(unistd.h)
 399
 400 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
 401 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
 402 # think that we don't have <curses.h> if we're using GCC.
 403 case $host_os in
 404   solaris2.[[789]])
 405     if test "$GCC" = yes; then
 406       AC_DEFINE(_MSE_INT_H, 1,
 407         [[Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
 408    Solaris 2.[789] when using GCC. ]])
 409     fi ;;
 410 esac
 411 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h)
 412 AC_CHECK_HEADERS(ncurses/term.h)
 413 AC_CHECK_HEADERS(term.h, [], [],
 414 [#if HAVE_CURSES_H
 415 # include <curses.h>
 416 #endif
 417 ])
 418
 419 # FIXME: kettenis/20030102: In most cases we include these
 420 # unconditionally, so what's the point in checking these?
 421 AC_CHECK_HEADERS(ctype.h time.h)
 422
 423 # ------------------------- #
 424 # Checks for declarations.  #
 425 # ------------------------- #
 426
 427 AC_CHECK_DECLS([free, malloc, realloc])
 428 AC_CHECK_DECLS([strerror, strstr])
 429 AC_CHECK_DECLS(getopt)
 430
 431 # ----------------------- #
 432 # Checks for structures.  #
 433 # ----------------------- #
 434
 435 AC_CHECK_MEMBERS([struct stat.st_blocks])
 436
 437 # ------------------ #
 438 # Checks for types.  #
 439 # ------------------ #
 440
 441 AC_TYPE_SIGNAL
 442
 443 # ------------------------------------- #
 444 # Checks for compiler characteristics.  #
 445 # ------------------------------------- #
 446
 447 AC_C_CONST
 448 AC_C_INLINE
 449
 450 # ------------------------------ #
 451 # Checks for library functions.  #
 452 # ------------------------------ #
 453
 454 AC_FUNC_ALLOCA
 455 AC_FUNC_MMAP
 456 AC_FUNC_VFORK
 457 AC_CHECK_FUNCS(canonicalize_file_name realpath)
 458 AC_CHECK_FUNCS(poll)
 459 AC_CHECK_FUNCS(pread64)
 460 AC_CHECK_FUNCS(sbrk)
 461 AC_CHECK_FUNCS(setpgid setpgrp)
 462 AC_CHECK_FUNCS(sigaction sigprocmask sigsetmask)
 463 AC_CHECK_FUNCS(socketpair)
 464 AC_CHECK_FUNCS(syscall)
 465 AC_CHECK_FUNCS(ttrace)
 466 AC_CHECK_FUNCS(wborder)
 467
 468 # Check the return and argument types of ptrace.  No canned test for
 469 # this, so roll our own.
 470 gdb_ptrace_headers='
 471 #if HAVE_SYS_TYPES_H
 472 # include <sys/types.h>
 473 #endif
 474 #if HAVE_SYS_PTRACE_H
 475 # include <sys/ptrace.h>
 476 #endif
 477 #if HAVE_UNISTD_H
 478 # include <unistd.h>
 479 #endif
 480 '
 481 # There is no point in checking if we don't have a prototype.
 482 AC_CHECK_DECLS(ptrace, [], [
 483   : ${gdb_cv_func_ptrace_ret='int'}
 484   : ${gdb_cv_func_ptrace_args='int,int,long,long'}
 485 ], $gdb_ptrace_headers)
 486 # Check return type.
 487 AC_CACHE_CHECK([return type of ptrace], gdb_cv_func_ptrace_ret,
 488   AC_TRY_COMPILE($gdb_ptrace_headers,
 489     [extern int ptrace ();],
 490     gdb_cv_func_ptrace_ret='int',
 491     gdb_cv_func_ptrace_ret='long'))
 492 AC_DEFINE_UNQUOTED(PTRACE_TYPE_RET, $gdb_cv_func_ptrace_ret,
 493   [Define as the return type of ptrace.])
 494 # Check argument types.
 495 AC_CACHE_CHECK([types of arguments for ptrace], gdb_cv_func_ptrace_args, [
 496 for gdb_arg1 in 'int' 'long'; do
 497  for gdb_arg2 in 'pid_t' 'int' 'long'; do
 498   for gdb_arg3 in 'int *' 'caddr_t' 'int' 'long'; do
 499    for gdb_arg4 in 'int' 'long'; do
 500      AC_TRY_COMPILE($gdb_ptrace_headers, [
 501 extern $gdb_cv_func_ptrace_ret
 502   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4);
 503 ], [gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4";
 504     break 4;])
 505     for gdb_arg5 in 'int *' 'int' 'long'; do
 506      AC_TRY_COMPILE($gdb_ptrace_headers, [
 507 extern $gdb_cv_func_ptrace_ret
 508   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4, $gdb_arg5);
 509 ], [
 510 gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4,$gdb_arg5";
 511     break 5;])
 512     done
 513    done
 514   done
 515  done
 516 done
 517 # Provide a safe default value.
 518 : ${gdb_cv_func_ptrace_args='int,int,long,long'}
 519 ])
 520 ac_save_IFS=$IFS; IFS=','
 521 set dummy `echo "$gdb_cv_func_ptrace_args" | sed 's/\*/\*/g'`
 522 IFS=$ac_save_IFS
 523 shift
 524 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG3, $[3],
 525   [Define to the type of arg 3 for ptrace.])
 526 if test -n "$[5]"; then
 527   AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG5, $[5],
 528     [Define to the type of arg 5 for ptrace.])
 529 fi
 530
 531 dnl AC_FUNC_SETPGRP does not work when cross compiling
 532 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
 533 if test "$cross_compiling" = no; then
 534   AC_FUNC_SETPGRP
 535 else
 536   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
 537     [AC_TRY_COMPILE([
 538 #include <unistd.h>
 539 ], [
 540   if (setpgrp(1,1) == -1)
 541     exit (0);
 542   else
 543     exit (1);
 544 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
 545 if test $ac_cv_func_setpgrp_void = yes; then
 546   AC_DEFINE(SETPGRP_VOID, 1)
 547 fi
 548 fi
 549
 550 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
 551 # since sigsetjmp might only be defined as a macro.
 552 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
 553 [AC_TRY_COMPILE([
 554 #include <setjmp.h>
 555 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
 556 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
 557 if test $gdb_cv_func_sigsetjmp = yes; then
 558   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
 559 fi
 560
 561 # Assume we'll default to using the included libiberty regex.
 562 gdb_use_included_regex=yes
 563
 564 # However, if the system regex is GNU regex, then default to *not*
 565 # using the included regex.
 566 AC_CACHE_CHECK(
 567   [for GNU regex],
 568   [gdb_cv_have_gnu_regex],
 569   [AC_TRY_COMPILE(
 570     [#include <gnu-versions.h>],
 571     [#define REGEX_INTERFACE_VERSION 1
 572 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
 573 # error "Version mismatch"
 574 #endif],
 575     gdb_cv_have_gnu_regex=yes,
 576     gdb_cv_have_gnu_regex=no)])
 577 if test $gdb_cv_have_gnu_regex = yes; then
 578   gdb_use_included_regex=no
 579 fi
 580
 581 AC_ARG_WITH(included-regex,
 582   [  --without-included-regex don't use included regex; this is the default
 583                           on systems with version 2 of the GNU C library
 584                           (use with caution on other system)],
 585   gdb_with_regex=$withval,
 586   gdb_with_regex=$gdb_use_included_regex)
 587 if test "$gdb_with_regex" = yes; then
 588   AC_DEFINE(USE_INCLUDED_REGEX, 1,
 589     [Define to 1 if the regex included in libiberty should be used.])
 590 fi
 591
 592 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
 593 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
 594 [#include <sys/param.h>
 595 #include <sys/proc.h>
 596 ])
 597
 598 # See if <sys/lwp.h> defines `struct lwp`.
 599 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
 600 [AC_TRY_COMPILE([#include <sys/param.h>
 601 #include <sys/lwp.h>], [struct lwp l;],
 602 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
 603 if test $gdb_cv_struct_lwp = yes; then
 604   AC_DEFINE(HAVE_STRUCT_LWP, 1,
 605             [Define to 1 if your system has struct lwp.])
 606 fi
 607
 608 # See if <machine/reg.h> degines `struct reg'.
 609 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
 610 [AC_TRY_COMPILE([#include <sys/types.h>
 611 #include <machine/reg.h>], [struct reg r;],
 612 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
 613 if test $gdb_cv_struct_reg = yes; then
 614   AC_DEFINE(HAVE_STRUCT_REG, 1,
 615             [Define to 1 if your system has struct reg in <machine/reg.h>.])
 616 fi
 617
 618 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
 619 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
 620 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
 621                  [#include <machine/reg.h>])
 622
 623 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
 624 AC_MSG_CHECKING(for PTRACE_GETREGS)
 625 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
 626 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 627                 [PTRACE_GETREGS;],
 628                 [gdb_cv_have_ptrace_getregs=yes],
 629                 [gdb_cv_have_ptrace_getregs=no])])
 630 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
 631 if test $gdb_cv_have_ptrace_getregs = yes; then
 632   AC_DEFINE(HAVE_PTRACE_GETREGS)
 633 fi
 634
 635 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
 636 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
 637 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
 638 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 639                 [PTRACE_GETFPXREGS;],
 640                 [gdb_cv_have_ptrace_getfpxregs=yes],
 641                 [gdb_cv_have_ptrace_getfpxregs=no])])
 642 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
 643 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
 644   AC_DEFINE(HAVE_PTRACE_GETFPXREGS)
 645 fi
 646
 647 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
 648 AC_MSG_CHECKING(for PT_GETDBREGS)
 649 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
 650 [AC_TRY_COMPILE([#include <sys/types.h>
 651 #include <sys/ptrace.h>],
 652                 [PT_GETDBREGS;],
 653                 [gdb_cv_have_pt_getdbregs=yes],
 654                 [gdb_cv_have_pt_getdbregs=no])])
 655 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
 656 if test $gdb_cv_have_pt_getdbregs = yes; then
 657   AC_DEFINE(HAVE_PT_GETDBREGS)
 658 fi
 659
 660 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
 661 AC_MSG_CHECKING(for PT_GETXMMREGS)
 662 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
 663 [AC_TRY_COMPILE([#include <sys/types.h>
 664 #include <sys/ptrace.h>],
 665                 [PT_GETXMMREGS;],
 666                 [gdb_cv_have_pt_getxmmregs=yes],
 667                 [gdb_cv_have_pt_getxmmregs=no])])
 668 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
 669 if test $gdb_cv_have_pt_getxmmregs = yes; then
 670   AC_DEFINE(HAVE_PT_GETXMMREGS)
 671 fi
 672
 673 # See if stdint.h provides the uintptr_t type.
 674 # Autoconf 2.5X has an improved AC_CHECK_TYPE which will simplify this.
 675 AC_CACHE_CHECK([for uintptr_t in stdint.h], gdb_cv_have_uintptr_t,
 676   [AC_TRY_COMPILE(
 677     [#include <stdint.h>],
 678     [uintptr_t foo = 0;],
 679     gdb_cv_have_uintptr_t=yes,
 680     gdb_cv_have_uintptr_t=no)])
 681 if test $gdb_cv_have_uintptr_t = yes; then
 682   AC_DEFINE(HAVE_UINTPTR_T, 1, [Define if <stdint.h> provides the uintptr_t type.])
 683 fi
 684
 685 # If we are configured native on GNU/Linux, work around problems with
 686 # sys/procfs.h
 687 # Also detect which type of /proc is in use, such as for Unixware or Solaris.
 688
 689 if test "${target}" = "${host}"; then
 690   case "${host}" in
 691   i[[3456]]86-*-linux*)
 692         AC_DEFINE(START_INFERIOR_TRAPS_EXPECTED,2)
 693         AC_DEFINE(sys_quotactl)
 694         ;;
 695   *-*-unixware* | *-*-sysv4.2* | *-*-sysv5* | *-*-interix* )
 696       AC_DEFINE(NEW_PROC_API)
 697       ;;
 698   *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]])
 699       AC_DEFINE(NEW_PROC_API)
 700       ;;
 701   mips-sgi-irix5*)
 702       # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5.
 703       AC_DEFINE([_KMEMUSER], 1)
 704       ;;
 705   esac
 706 fi
 707
 708 if test "$ac_cv_header_sys_procfs_h" = yes; then
 709   BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
 710   BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
 711   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
 712   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
 713   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
 714   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
 715   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
 716   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t)
 717   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
 718   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
 719   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
 720   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
 721   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
 722   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
 723
 724
 725   dnl Check for broken prfpregset_t type
 726
 727   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
 728   dnl prfpregset_t type (it's a typedef for the pointer to a struct
 729   dnl instead of the struct itself).  We detect this here, and work
 730   dnl around it in gdb_proc_service.h.
 731
 732   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
 733     AC_MSG_CHECKING(whether prfpregset_t type is broken)
 734     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
 735       [AC_TRY_RUN([#include <sys/procfs.h>
 736        int main ()
 737        {
 738          if (sizeof (prfpregset_t) == sizeof (void *))
 739            return 1;
 740          return 0;
 741        }],
 742        gdb_cv_prfpregset_t_broken=no,
 743        gdb_cv_prfpregset_t_broken=yes,
 744        gdb_cv_prfpregset_t_broken=yes)])
 745     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
 746     if test $gdb_cv_prfpregset_t_broken = yes; then
 747       AC_DEFINE(PRFPREGSET_T_BROKEN)
 748     fi
 749   fi
 750
 751   dnl Check for PIOCSET ioctl entry
 752
 753   AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
 754   AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
 755   [AC_TRY_COMPILE([#include <unistd.h>
 756 #include <sys/types.h>
 757 #include <sys/procfs.h>
 758 ], [
 759     int dummy;;
 760     dummy = ioctl(0, PIOCSET, &dummy);
 761   ],
 762   gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
 763   AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
 764   if test $gdb_cv_have_procfs_piocset = yes; then
 765     AC_DEFINE(HAVE_PROCFS_PIOCSET)
 766   fi
 767 fi
 768
 769 dnl For native ports (host == target), check to see what kind of
 770 dnl legacy link.h support is needed.  (See solib-legacy.c.)
 771 if test ${host} = ${target} ; then
 772   dnl Check for struct link_map with l_ members which are indicative
 773   dnl of SVR4-like shared libraries
 774
 775   AC_MSG_CHECKING(for member l_addr in struct link_map)
 776   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_l_members,
 777     [AC_TRY_COMPILE([#include <link.h>],
 778                     [struct link_map lm; (void) lm.l_addr;],
 779                     gdb_cv_have_struct_link_map_with_l_members=yes,
 780                     gdb_cv_have_struct_link_map_with_l_members=no)])
 781   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_l_members)
 782   if test $gdb_cv_have_struct_link_map_with_l_members = yes; then
 783     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_L_MEMBERS)
 784   fi
 785
 786   dnl Check for struct link_map with lm_ members which are indicative
 787   dnl of SunOS-like shared libraries
 788
 789   AC_MSG_CHECKING(for member lm_addr in struct link_map)
 790   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_lm_members,
 791     [AC_TRY_COMPILE([#include <sys/types.h>
 792 #include <link.h>],
 793                     [struct link_map lm; (void) lm.lm_addr;],
 794                     gdb_cv_have_struct_link_map_with_lm_members=yes,
 795                     gdb_cv_have_struct_link_map_with_lm_members=no)])
 796   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_lm_members)
 797   if test $gdb_cv_have_struct_link_map_with_lm_members = yes; then
 798     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_LM_MEMBERS)
 799   fi
 800
 801   dnl Check for struct so_map with som_ members which are found on
 802   dnl some *BSD systems.
 803
 804   AC_MSG_CHECKING(for member som_addr in struct so_map)
 805   AC_CACHE_VAL(gdb_cv_have_struct_so_map_with_som_members,
 806     [AC_TRY_COMPILE([#include <sys/types.h>
 807 #ifdef HAVE_NLIST_H
 808 #include <nlist.h>
 809 #endif
 810 #include <link.h>],
 811                     [struct so_map lm; (void) lm.som_addr;],
 812                     gdb_cv_have_struct_so_map_with_som_members=yes,
 813                     gdb_cv_have_struct_so_map_with_som_members=no)])
 814   AC_MSG_RESULT($gdb_cv_have_struct_so_map_with_som_members)
 815   if test $gdb_cv_have_struct_so_map_with_som_members = yes; then
 816     AC_DEFINE(HAVE_STRUCT_SO_MAP_WITH_SOM_MEMBERS)
 817   fi
 818
 819   dnl Check for struct link_map32 type, which allows a 64-bit Solaris
 820   dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries.
 821
 822   AC_MSG_CHECKING(for struct link_map32 in sys/link.h)
 823   AC_CACHE_VAL(gdb_cv_have_struct_link_map32,
 824     [AC_TRY_COMPILE([#define _SYSCALL32
 825 #include <sys/link.h>], [struct link_map32 l;],
 826      gdb_cv_have_struct_link_map32=yes,
 827      gdb_cv_have_struct_link_map32=no)])
 828   AC_MSG_RESULT($gdb_cv_have_struct_link_map32)
 829   if test $gdb_cv_have_struct_link_map32 = yes; then
 830     AC_DEFINE(HAVE_STRUCT_LINK_MAP32)
 831     AC_DEFINE(_SYSCALL32)
 832   fi
 833 fi
 834
 835 # Check if the compiler supports the `long long' type.
 836
 837 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
 838                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 839 [[extern long long foo;]],
 840 [[switch (foo & 2) { case 0: return 1; }]])],
 841                                   gdb_cv_c_long_long=yes,
 842                                   gdb_cv_c_long_long=no)])
 843 if test $gdb_cv_c_long_long = yes; then
 844   AC_DEFINE(CC_HAS_LONG_LONG, 1,
 845             [Define to 1 if the compiler supports long long.])
 846 fi
 847
 848 # Check if the compiler and runtime support printing long longs.
 849
 850 AC_CACHE_CHECK([for long long support in printf],
 851                gdb_cv_printf_has_long_long,
 852                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 853 [[char buf[32];
 854   long long l = 0;
 855   l = (l << 16) + 0x0123;
 856   l = (l << 16) + 0x4567;
 857   l = (l << 16) + 0x89ab;
 858   l = (l << 16) + 0xcdef;
 859   sprintf (buf, "0x%016llx", l);
 860   return (strcmp ("0x0123456789abcdef", buf));]])],
 861                               gdb_cv_printf_has_long_long=yes,
 862                               gdb_cv_printf_has_long_long=no,
 863                               gdb_cv_printf_has_long_long=no)])
 864 if test $gdb_cv_printf_has_long_long = yes; then
 865   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
 866             [Define to 1 if the "%ll" format works to print long longs.])
 867 fi
 868
 869 # Check if the compiler supports the `long double' type.  We can't use
 870 # AC_C_LONG_DOUBLE because that one does additional checks on the
 871 # constants defined in <float.h> that fail on some systems,
 872 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
 873
 874 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
 875                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
 876                                   gdb_cv_c_long_double=yes,
 877                                   gdb_cv_c_long_double=no)])
 878 if test $gdb_cv_c_long_double = yes; then
 879   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
 880            [Define to 1 if the compiler supports long double.])
 881 fi
 882
 883 # Check if the compiler and runtime support printing long doubles.
 884
 885 AC_CACHE_CHECK([for long double support in printf],
 886                gdb_cv_printf_has_long_double,
 887                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 888 [[char buf[16];
 889   long double f = 3.141592653;
 890   sprintf (buf, "%Lg", f);
 891   return (strncmp ("3.14159", buf, 7));]])],
 892                               gdb_cv_printf_has_long_double=yes,
 893                               gdb_cv_printf_has_long_double=no,
 894                               gdb_cv_printf_has_long_double=no)])
 895 if test $gdb_cv_printf_has_long_double = yes; then
 896   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
 897             [Define to 1 if the "%Lg" format works to print long doubles.])
 898 fi
 899
 900 # Check if the compiler and runtime support scanning long doubles.
 901
 902 AC_CACHE_CHECK([for long double support in scanf],
 903                gdb_cv_scanf_has_long_double,
 904                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 905 [[#include <stdio.h>]],
 906 [[char *buf = "3.141592653";
 907   long double f = 0;
 908   sscanf (buf, "%Lg", &f);
 909   return !(f > 3.14159 && f < 3.14160);]])],
 910                               gdb_cv_scanf_has_long_double=yes,
 911                               gdb_cv_scanf_has_long_double=no,
 912                               gdb_cv_scanf_has_long_double=no)])
 913 if test $gdb_cv_scanf_has_long_double = yes; then
 914   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
 915             [Define to 1 if the "%Lg" format works to scan long doubles.])
 916 fi
 917
 918 case ${host_os} in
 919 aix*)
 920   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
 921     SAVE_LDFLAGS=$LDFLAGS
 922
 923     case $GCC in
 924     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
 925     *) gdb_cv_bigtoc=-bbigtoc ;;
 926     esac
 927
 928     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
 929     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
 930     LDFLAGS="${SAVE_LDFLAGS}"
 931   ])
 932   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
 933   ;;
 934 esac
 935
 936
 937 dnl For certain native configurations, we need to check whether thread
 938 dnl support can be built in or not.
 939 dnl
 940 dnl Note that we only want this if we are both native (host == target),
 941 dnl and not doing a canadian cross build (build == host).
 942
 943 if test ${build} = ${host} -a ${host} = ${target} ; then
 944    case ${host_os} in
 945    hpux*)
 946       AC_MSG_CHECKING(for HPUX/OSF thread support)
 947       if test -f /usr/include/dce/cma_config.h ; then
 948          if test "$GCC" = "yes" ; then
 949             AC_MSG_RESULT(yes)
 950             AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT)
 951             CONFIG_OBS="${CONFIG_OBS} hpux-thread.o"
 952             CONFIG_SRCS="${CONFIG_SRCS} hpux-thread.c"
 953          else
 954             AC_MSG_RESULT(no (suppressed because you are not using GCC))
 955          fi
 956       else
 957          AC_MSG_RESULT(no)
 958       fi
 959       ;;
 960    solaris*)
 961       # See if thread_db library is around for Solaris thread debugging.
 962       # Note that we must explicitly test for version 1 of the library
 963       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
 964       # the same API.
 965       AC_MSG_CHECKING(for Solaris thread debugging library)
 966       if test -f /usr/lib/libthread_db.so.1 ; then
 967          AC_MSG_RESULT(yes)
 968          AC_DEFINE(HAVE_THREAD_DB_LIB)
 969          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
 970          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
 971          AC_CHECK_LIB(dl, dlopen)
 972          if test "$GCC" = "yes" ; then
 973             # The GNU linker requires the -export-dynamic option to make
 974             # all symbols visible in the dynamic symbol table.
 975             hold_ldflags=$LDFLAGS
 976             AC_MSG_CHECKING(for the ld -export-dynamic flag)
 977             LDFLAGS="${LDFLAGS} -Wl,-export-dynamic"
 978             AC_TRY_LINK(, [int i;], found=yes, found=no)
 979             LDFLAGS=$hold_ldflags
 980             AC_MSG_RESULT($found)
 981             if test $found = yes; then
 982                CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Wl,-export-dynamic"
 983             fi
 984          fi
 985          # Sun randomly tweaked the prototypes in <proc_service.h>
 986          # at one point.
 987          AC_MSG_CHECKING(if <proc_service.h> is old)
 988          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
 989             AC_TRY_COMPILE([
 990                 #include <proc_service.h>
 991                 ps_err_e ps_pdwrite
 992                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
 993             ],, gdb_cv_proc_service_is_old=no,
 994                 gdb_cv_proc_service_is_old=yes)
 995          ])
 996          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
 997          if test $gdb_cv_proc_service_is_old = yes; then
 998             AC_DEFINE(PROC_SERVICE_IS_OLD)
 999          fi
1000       else
1001          AC_MSG_RESULT(no)
1002       fi
1003       ;;
1004    aix*)
1005       AC_MSG_CHECKING(for AiX thread debugging library)
1006       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1007                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1008                                    [#ifndef PTHDB_VERSION_3
1009                                     #error
1010                                     #endif],
1011                                    gdb_cv_have_aix_thread_debug=yes,
1012                                    gdb_cv_have_aix_thread_debug=no)])
1013       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1014       if test $gdb_cv_have_aix_thread_debug = yes; then
1015          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1016          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1017          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -lpthdebug"
1018       fi
1019       ;;
1020    esac
1021    AC_SUBST(CONFIG_LDFLAGS)
1022 fi
1023
1024 dnl See if we have a thread_db header file that has TD_NOTALLOC.
1025 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1026    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1027                   gdb_cv_thread_db_h_has_td_notalloc,
1028      AC_TRY_COMPILE(
1029        [#include <thread_db.h>],
1030        [int i = TD_NOTALLOC;],
1031        gdb_cv_thread_db_h_has_td_notalloc=yes,
1032        gdb_cv_thread_db_h_has_td_notalloc=no
1033      )
1034    )
1035 fi
1036 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1037   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1038             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1039 fi
1040
1041 dnl See if we have a sys/syscall header file that has __NR_tkill.
1042 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
1043    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
1044                   gdb_cv_sys_syscall_h_has_tkill,
1045      AC_TRY_COMPILE(
1046        [#include <sys/syscall.h>],
1047        [int i = __NR_tkill;],
1048        gdb_cv_sys_syscall_h_has_tkill=yes,
1049        gdb_cv_sys_syscall_h_has_tkill=no
1050      )
1051    )
1052 fi
1053 dnl See if we can issue tkill syscall.
1054 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes" && test "x$ac_cv_func_syscall" = "xyes"; then
1055   AC_DEFINE(HAVE_TKILL_SYSCALL, 1,
1056             [Define if we can use the tkill syscall.])
1057 fi
1058
1059 dnl Handle optional features that can be enabled.
1060
1061 AC_ARG_WITH(sysroot,
1062 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
1063 [
1064  case ${with_sysroot} in
1065  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
1066  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
1067  esac
1068
1069  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
1070
1071  if test "x$exec_prefix" = xNONE; then
1072   if test "x$prefix" = xNONE; then
1073    test_prefix=/usr/local
1074   else
1075    test_prefix=$prefix
1076   fi
1077  else
1078   test_prefix=$exec_prefix
1079  fi
1080  case ${TARGET_SYSTEM_ROOT} in
1081  "${test_prefix}"|"${test_prefix}/"*|\
1082  '${exec_prefix}'|'${exec_prefix}/'*)
1083    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
1084    TARGET_SYSTEM_ROOT_DEFINE="$t"
1085    ;;
1086  esac
1087 ], [
1088  TARGET_SYSTEM_ROOT=
1089  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
1090 ])
1091 AC_SUBST(TARGET_SYSTEM_ROOT)
1092 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
1093
1094 # NOTE: Don't add -Wall or -Wunused, they both include
1095 # -Wunused-parameter which reports bogus warnings.
1096 # NOTE: If you add to this list, remember to update
1097 # gdb/doc/gdbint.texinfo.
1098 build_warnings="-Wimplicit -Wreturn-type -Wcomment -Wtrigraphs \
1099 -Wformat -Wparentheses -Wpointer-arith -Wuninitialized -Wformat-nonliteral \
1100 -Wunused-label -Wunused-function"
1101 # Up for debate: -Wswitch -Wcomment -trigraphs -Wtrigraphs
1102 # -Wunused-function -Wunused-variable -Wunused-value
1103 # -Wchar-subscripts -Wtraditional -Wshadow -Wcast-qual
1104 # -Wcast-align -Wwrite-strings -Wconversion -Wstrict-prototypes
1105 # -Wmissing-prototypes -Wmissing-declarations -Wredundant-decls
1106 # -Woverloaded-virtual -Winline -Werror"
1107 AC_ARG_ENABLE(build-warnings,
1108 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
1109 [case "${enableval}" in
1110   yes)  ;;
1111   no)   build_warnings="-w";;
1112   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1113         build_warnings="${build_warnings} ${t}";;
1114   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1115         build_warnings="${t} ${build_warnings}";;
1116   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1117 esac
1118 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1119   echo "Setting compiler warning flags = $build_warnings" 6>&1
1120 fi])dnl
1121 AC_ARG_ENABLE(gdb-build-warnings,
1122 [  --enable-gdb-build-warnings Enable GDB specific build-time compiler warnings if gcc is used],
1123 [case "${enableval}" in
1124   yes)  ;;
1125   no)   build_warnings="-w";;
1126   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1127         build_warnings="${build_warnings} ${t}";;
1128   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1129         build_warnings="${t} ${build_warnings}";;
1130   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1131 esac
1132 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1133   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
1134 fi])dnl
1135 WARN_CFLAGS=""
1136 WERROR_CFLAGS=""
1137 if test "x${build_warnings}" != x -a "x$GCC" = xyes
1138 then
1139     AC_MSG_CHECKING(compiler warning flags)
1140     # Separate out the -Werror flag as some files just cannot be
1141     # compiled with it enabled.
1142     for w in ${build_warnings}; do
1143         case $w in
1144         -Werr*) WERROR_CFLAGS=-Werror ;;
1145         *) # Check that GCC accepts it
1146             saved_CFLAGS="$CFLAGS"
1147             CFLAGS="$CFLAGS $w"
1148             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
1149             CFLAGS="$saved_CFLAGS"
1150         esac
1151     done
1152     AC_MSG_RESULT(${WARN_CFLAGS}${WERROR_CFLAGS})
1153 fi
1154 AC_SUBST(WARN_CFLAGS)
1155 AC_SUBST(WERROR_CFLAGS)
1156
1157 # In the Cygwin environment, we need some additional flags.
1158 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1159 [AC_EGREP_CPP(lose, [
1160 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1161 lose
1162 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1163
1164
1165 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1166 SER_HARDWIRE="ser-unix.o ser-pipe.o ser-tcp.o"
1167 case ${host} in
1168   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1169   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1170 esac
1171 AC_SUBST(SER_HARDWIRE)
1172
1173 # libreadline needs libuser32.a in a cygwin environment
1174 WIN32LIBS=
1175 if test x$gdb_cv_os_cygwin = xyes; then
1176     WIN32LIBS="-luser32"
1177     case "${target}" in
1178         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1179         ;;
1180     esac
1181 fi
1182 AC_SUBST(WIN32LIBS)
1183
1184 LIBGUI="../libgui/src/libgui.a"
1185 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1186 AC_SUBST(LIBGUI)
1187 AC_SUBST(GUI_CFLAGS_X)
1188
1189 WIN32LDAPP=
1190 AC_SUBST(WIN32LIBS)
1191 AC_SUBST(WIN32LDAPP)
1192
1193 case "${host}" in
1194 *-*-cygwin*)
1195     configdir="win"
1196     ;;
1197 *)
1198     configdir="unix"
1199     ;;
1200 esac
1201
1202 GDBTKLIBS=
1203 if test "${enable_gdbtk}" = "yes"; then
1204
1205     # Gdbtk must have an absolute path to srcdir in order to run
1206     # properly when not installed.
1207     here=`pwd`
1208     cd ${srcdir}
1209     GDBTK_SRC_DIR=`pwd`
1210     cd $here
1211
1212     CY_AC_PATH_TCLCONFIG
1213     if test -z "${no_tcl}"; then
1214         CY_AC_LOAD_TCLCONFIG
1215         CY_AC_PATH_TKCONFIG
1216
1217         # now look for Tcl library stuff
1218
1219         tcldir="../tcl/${configdir}/"
1220
1221         TCL_DEPS="${tcldir}${TCL_LIB_FILE}"
1222
1223         # If $no_tk is nonempty, then we can't do Tk, and there is no
1224         # point to doing Tcl.
1225         if test -z "${no_tk}"; then
1226            CY_AC_LOAD_TKCONFIG
1227            CY_AC_PATH_TCLH
1228            CY_AC_PATH_TKH
1229            CY_AC_PATH_ITCLH
1230            CY_AC_PATH_ITKH
1231
1232
1233            # now look for Tk library stuff
1234
1235            tkdir="../tk/${configdir}/"
1236
1237            TK_DEPS="${tkdir}${TK_LIB_FILE}"
1238
1239            # now look for Itcl library stuff
1240
1241            CY_AC_PATH_ITCLCONFIG
1242            if test -z "${no_itcl}"; then
1243              CY_AC_LOAD_ITCLCONFIG
1244
1245              ITCLLIB="${ITCL_BUILD_LIB_SPEC}"
1246              ITCL_DEPS="${ITCL_LIB_FULL_PATH}"
1247            fi
1248
1249
1250            # now look for Itk library stuff
1251            CY_AC_PATH_ITKCONFIG
1252            if test -z "${no_itcl}"; then
1253              CY_AC_LOAD_ITKCONFIG
1254
1255              ITKLIB="${ITK_BUILD_LIB_SPEC}"
1256              ITK_DEPS="${ITK_LIB_FULL_PATH}"
1257            fi
1258
1259            ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
1260            # Tcl/Tk 8.1 require -fwritable strings.  I don't
1261            # know whether 8.2 will or not, but I bet it will.
1262            # I don't have to worry about 7.x since we don't support it.
1263            GDBTK_CFLAGS=""
1264            if test "$GCC" = "yes"; then
1265                if test "$TCL_VERSION" != "8.0" ; then
1266                    GDBTK_CFLAGS="-fwritable-strings"
1267                fi
1268            fi
1269
1270            # Include some libraries that Tcl and Tk want.
1271            TCL_LIBS='$(LIBGUI) $(ITCL) $(ITK) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
1272            # Yes, the ordering seems wrong here.  But it isn't.
1273            # TK_LIBS is the list of libraries that need to be linked
1274            # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
1275            # were in LIBS then any link tests after this point would
1276            # try to include things like `$(LIBGUI)', which wouldn't work.
1277            GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
1278
1279            CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
1280            CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
1281            CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
1282            CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
1283            CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
1284            CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
1285            CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
1286
1287            if test x$gdb_cv_os_cygwin = xyes; then
1288               WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
1289               WIN32LDAPP="-Wl,--subsystem,console"
1290               CONFIG_OBS="${CONFIG_OBS} gdbres.o"
1291            fi
1292         fi
1293     fi
1294
1295     AC_CONFIG_SUBDIRS(gdbtk)
1296 fi
1297
1298 AC_SUBST(X_CFLAGS)
1299 AC_SUBST(X_LDFLAGS)
1300 AC_SUBST(X_LIBS)
1301 AC_SUBST(TCL_DEPS)
1302 AC_SUBST(TK_DEPS)
1303 AC_SUBST(ITCLLIB)
1304 AC_SUBST(ITCL_DEPS)
1305 AC_SUBST(ITKLIB)
1306 AC_SUBST(ITK_DEPS)
1307 AC_SUBST(GDBTKLIBS)
1308 AC_SUBST(GDBTK_CFLAGS)
1309 AC_SUBST(GDBTK_SRC_DIR)
1310
1311 AC_PATH_X
1312
1313 # Check whether we should enable the TUI, but only do so if we really
1314 # can.
1315 if test x"$enable_tui" = xyes; then
1316   if test -d $srcdir/tui; then
1317     if test "$ac_cv_search_waddstr" != no; then
1318       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
1319       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
1320       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
1321       CONFIG_INITS="$CONFIG_INITS \$(SUBDIR_TUI_INITS)"
1322       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
1323       CONFIG_ALL="${CONFIG_ALL} all-tui"
1324       CONFIG_CLEAN="${CONFIG_CLEAN} clean-tui"
1325       CONFIG_INSTALL="${CONFIG_INSTALL} install-tui"
1326       CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-tui"
1327     else
1328       AC_MSG_WARN([no enhanced curses library found; disabling TUI])
1329     fi
1330   fi
1331 fi
1332
1333 # Unlike the sim directory, whether a simulator is linked is controlled by
1334 # presence of a SIM= and a SIM_OBS= definition in the target '.mt' file.
1335 # This code just checks for a few cases where we'd like to ignore those
1336 # definitions, even when they're present in the '.mt' file.  These cases
1337 # are when --disable-sim is specified, or if the simulator directory is
1338 # not part of the source tree.
1339 #
1340 AC_ARG_ENABLE(sim,
1341 [  --enable-sim            Link gdb with simulator],
1342 [echo "enable_sim = $enable_sim";
1343  echo "enableval = ${enableval}";
1344  case "${enableval}" in
1345   yes) ignore_sim=false ;;
1346   no)  ignore_sim=true ;;
1347   *)   ignore_sim=false ;;
1348  esac],
1349 [ignore_sim=false])
1350
1351 if test ! -d "${srcdir}/../sim"; then
1352   ignore_sim=true
1353 fi
1354
1355 if test "${ignore_sim}" = "true"; then
1356     IGNORE_SIM="SIM="
1357     IGNORE_SIM_OBS="SIM_OBS="
1358 else
1359     IGNORE_SIM=""
1360     IGNORE_SIM_OBS=""
1361     AC_DEFINE(WITH_SIM)
1362 fi
1363 AC_SUBST(IGNORE_SIM)
1364 AC_SUBST(IGNORE_SIM_OBS)
1365
1366 AC_SUBST(ENABLE_CFLAGS)
1367 AC_SUBST(PROFILE_CFLAGS)
1368
1369 AC_SUBST(CONFIG_OBS)
1370 AC_SUBST(CONFIG_DEPS)
1371 AC_SUBST(CONFIG_SRCS)
1372 AC_SUBST(CONFIG_ALL)
1373 AC_SUBST(CONFIG_CLEAN)
1374 AC_SUBST(CONFIG_INSTALL)
1375 AC_SUBST(CONFIG_UNINSTALL)
1376
1377 # List of host floatformats.
1378 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
1379 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
1380 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
1381
1382 # target_subdir is used by the testsuite to find the target libraries.
1383 target_subdir=
1384 if test "${host}" != "${target}"; then
1385     target_subdir="${target_alias}/"
1386 fi
1387 AC_SUBST(target_subdir)
1388
1389 frags=
1390 if test "${target}" = "${host}"; then
1391   host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
1392   if test ! -f ${host_makefile_frag}; then
1393     AC_MSG_ERROR("*** Gdb does not support native target ${host}")
1394   fi
1395   frags="$frags $host_makefile_frag"
1396 else
1397   host_makefile_frag=/dev/null
1398 fi
1399
1400 target_makefile_frag=${srcdir}/config/${gdb_target_cpu}/${gdb_target}.mt
1401 if test ! -f ${target_makefile_frag}; then
1402   AC_MSG_ERROR("*** Gdb does not support target ${target}")
1403 fi
1404 frags="$frags $target_makefile_frag"
1405
1406 AC_SUBST_FILE(host_makefile_frag)
1407 AC_SUBST_FILE(target_makefile_frag)
1408 AC_SUBST(frags)
1409
1410 changequote(,)dnl
1411 hostfile=`sed -n '
1412 s/XM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
1413 ' ${host_makefile_frag}`
1414
1415 targetfile=`sed -n '
1416 s/DEPRECATED_TM_FILE[   ]*=[    ]*\([^  ]*\)/\1/p
1417 ' ${target_makefile_frag}`
1418
1419 if test "${target}" = "${host}"; then
1420 # We pick this up from the host configuration file (.mh) because we
1421 # do not have a native configuration Makefile fragment.
1422 nativefile=`sed -n '
1423 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
1424 ' ${host_makefile_frag}`
1425 fi
1426 changequote([,])
1427
1428 if test x"${gdb_osabi}" != x ; then
1429     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
1430                        [Define to the default OS ABI for this configuration.])
1431 fi
1432
1433 # Enable multi-ice-gdb-server.
1434 AC_ARG_ENABLE(multi-ice,
1435 [  --enable-multi-ice      build the multi-ice-gdb-server],
1436   [case $enableval in
1437     yes | no)
1438       ;;
1439     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
1440   esac])
1441 if test "x$enable_multi_ice" = xyes; then
1442    AC_CONFIG_SUBDIRS(multi-ice)
1443 fi
1444
1445 # We only build gdbserver automatically if host and target are the same.
1446 if test "x$target" = "x$host"; then
1447   AC_MSG_CHECKING(whether gdbserver is supported on this host)
1448   if test "x$build_gdbserver" = xyes; then
1449     AC_MSG_RESULT(yes)
1450     AC_CONFIG_SUBDIRS(gdbserver)
1451   else
1452     AC_MSG_RESULT(no)
1453   fi
1454 fi
1455
1456 # We build rdi-share on ARM-based targets, as instructed by configure.tgt.
1457 if test "x$build_rdi_share" = xyes; then
1458    AC_CONFIG_SUBDIRS(rdi-share)
1459 fi
1460
1461 # We configure the nlm subdirectory on netware targets, as instructed
1462 # by configure.tgt.
1463 if test "x$build_nlm" = xyes; then
1464    AC_CONFIG_SUBDIRS(nlm)
1465 fi
1466
1467 # If hostfile (XM_FILE) and/or targetfile (DEPRECATED_TM_FILE) and/or
1468 # nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link
1469 # to an empty version.
1470
1471 files=
1472 links=
1473
1474 rm -f xm.h
1475 xm_h=""
1476 if test "${hostfile}" != ""; then
1477     xm_h=xm.h
1478     case "${hostfile}" in
1479       xm-*.h ) GDB_XM_FILE="config/${gdb_host_cpu}/${hostfile}" ;;
1480       * ) GDB_XM_FILE="${hostfile}"
1481     esac
1482     files="${files} ${GDB_XM_FILE}"
1483     links="${links} xm.h"
1484     AC_DEFINE_UNQUOTED(GDB_XM_FILE, "${GDB_XM_FILE}")
1485 fi
1486 AC_SUBST(xm_h)
1487
1488 rm -f tm.h
1489 tm_h=""
1490 if test "${targetfile}" != ""; then
1491     tm_h=tm.h
1492     case "${targetfile}" in
1493       tm-*.h ) GDB_TM_FILE="config/${gdb_target_cpu}/${targetfile}" ;;
1494       * ) GDB_TM_FILE="${targetfile}"
1495     esac
1496     files="${files} ${GDB_TM_FILE}"
1497     links="${links} tm.h"
1498     AC_DEFINE_UNQUOTED(GDB_TM_FILE, "${GDB_TM_FILE}")
1499 fi
1500 AC_SUBST(tm_h)
1501
1502 rm -f nm.h
1503 nm_h=""
1504 if test "${nativefile}" != ""; then
1505     nm_h=nm.h
1506     case "${nativefile}" in
1507       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
1508       * ) GDB_NM_FILE="${nativefile}"
1509     esac
1510     files="${files} ${GDB_NM_FILE}"
1511     links="${links} nm.h"
1512     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}")
1513 fi
1514 AC_SUBST(nm_h)
1515
1516 AC_LINK_FILES($files, $links)
1517
1518 dnl Check for exe extension set on certain hosts (e.g. Win32)
1519 AC_EXEEXT
1520
1521 dnl  Detect the character set used by this host.
1522
1523 dnl  At the moment, we just assume it's ISO-8859-1 (which is a
1524 dnl  superset of ASCII containing the characters needed for French,
1525 dnl  German, Spanish, Italian, and possibly others), but if were
1526 dnl  *were* to support any host character sets other than ISO-8859-1,
1527 dnl  here's where we'd detect it.
1528 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "ISO-8859-1",
1529           [Define to be a string naming the default host character set.])
1530
1531 AM_ICONV
1532
1533 AC_OUTPUT(Makefile .gdbinit:gdbinit.in,
1534 [
1535 dnl Autoconf doesn't provide a mechanism for modifying definitions
1536 dnl provided by makefile fragments.
1537 dnl
1538
1539 changequote(,)dnl
1540 sed -e '/^DEPRECATED_TM_FILE[   ]*=/s,^DEPRECATED_TM_FILE[      ]*=[    ]*,&config/'"${gdb_target_cpu}"'/,
1541 /^XM_FILE[      ]*=/s,^XM_FILE[         ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,
1542 /^NAT_FILE[     ]*=/s,^NAT_FILE[        ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp
1543 mv -f Makefile.tmp Makefile
1544 changequote([,])dnl
1545
1546
1547 case x$CONFIG_HEADERS in
1548 xconfig.h:config.in)
1549 echo > stamp-h ;;
1550 esac
1551 ],
1552 [
1553 gdb_host_cpu=$gdb_host_cpu
1554 gdb_target_cpu=$gdb_target_cpu
1555 nativefile=$nativefile
1556 ])
1557
1558 exit 0