bfd/mpw-make.sed

   1 # Sed commands to finish translating the Unix BFD Makefile into MPW syntax.
   2
   3 # Whack out unused host and target define bits.
   4 /HDEFINES/s/@HDEFINES@//
   5 /TDEFINES/s/@TDEFINES@//
   6
   7 /INCDIR=/s/"{srcdir}":/"{topsrcdir}"/
   8 /^CSEARCH = .*$/s/$/ -i "{INCDIR}":mpw: -i ::extra-include:/
   9
  10 /WORDSIZE/s/^WORDSIZE = /#WORDSIZE = /
  11 /BFD_MACHINES/s/^BFD_MACHINES = /#BFD_MACHINES = /
  12 /BFD_BACKENDS/s/^BFD_BACKENDS = /#BFD_BACKENDS = /
  13 /TDEFAULTS/s/^TDEFAULTS = /#TDEFAULTS = /
  14
  15 # Remove extra, useless, "all".
  16 /^all \\Option-f _oldest/,/^$/d
  17
  18 # Remove the Makefile rebuild rule.
  19 /^Makefile /,/--recheck/d
  20
  21 # Don't do any recursive subdir stuff.
  22 / subdir_do/s/{MAKE}/null-command/
  23
  24 /BFD_H/s/^{BFD_H}/#{BFD_H}/
  25
  26 # Point at include files that are always in the objdir.
  27 /bfd/s/"{s}"bfd\.h/"{o}"bfd.h/g
  28 /config/s/"{s}"config\.h/"{o}"config.h/g
  29 /elf32-target/s/"{s}"elf32-target\.h/"{o}"elf32-target.h/g
  30 /elf64-target/s/"{s}"elf64-target\.h/"{o}"elf64-target.h/g
  31
  32 /"{s}"{INCDIR}/s/"{s}"{INCDIR}/"{INCDIR}"/g
  33
  34 /dep/s/\.dep/__dep/g
  35
  36 # Removing duplicates is cool but presently unnecessary,
  37 # so whack this out.
  38 /^ofiles \\Option-f/,/^$/d
  39 /ofiles/s/{OFILES} ofiles/{OFILES}/
  40 /echo ofiles = /d
  41 /cat ofiles/s/`cat ofiles`/{OFILES}/
  42
  43 # No corefile support.
  44 /COREFILE/s/@COREFILE@//
  45 /COREFLAG/s/@COREFLAG@//
  46
  47 # MPW Make doesn't know about $<.
  48 /"{o}"targets.c.o \\Option-f "{s}"targets.c Makefile/,/^$/c\
  49 "{o}"targets.c.o \\Option-f "{s}"targets.c Makefile\
  50         {CC} {ALL_CFLAGS} {TDEFAULTS} "{s}"targets.c -o "{o}"targets.c.o
  51
  52 /"{o}"archures.c.o \\Option-f "{s}"archures.c Makefile/,/^$/c\
  53 "{o}"archures.c.o \\Option-f "{s}"archures.c Makefile\
  54         {CC} {ALL_CFLAGS} {TDEFAULTS} "{s}"archures.c -o "{o}"archures.c.o
  55