libiberty/configure.in

   1 dnl Process this file with autoconf to produce a configure script
   2
   3 AC_PREREQ(2.13)
   4 AC_INIT(xmalloc.c)
   5
   6 # This works around the fact that libtool configuration may change LD
   7 # for this particular configuration, but some shells, instead of
   8 # keeping the changes in LD private, export them just because LD is
   9 # exported.  We don't use libtool yet, but some day we might, so...
  10 ORIGINAL_LD_FOR_MULTILIBS=$LD
  11
  12 dnl We use these options to decide which functions to include.
  13 AC_ARG_WITH(target-subdir,
  14 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory for target])
  15 AC_ARG_WITH(build-subdir,
  16 [  --with-build-subdir=SUBDIR       Configuring in a subdirectory for build])
  17 AC_ARG_WITH(cross-host,
  18 [  --with-cross-host=HOST           Configuring with a cross compiler])
  19 AC_ARG_WITH(newlib,
  20 [  --with-newlib                    Configuring with newlib])
  21
  22 if test "${srcdir}" = "."; then
  23   if test -n "${with_build_subdir}"; then
  24     libiberty_topdir="${srcdir}/../.."
  25     with_target_subdir=
  26   elif test -z "${with_target_subdir}"; then
  27     libiberty_topdir="${srcdir}/.."
  28   else
  29     if test "${with_target_subdir}" != "."; then
  30       libiberty_topdir="${srcdir}/${with_multisrctop}../.."
  31     else
  32       libiberty_topdir="${srcdir}/${with_multisrctop}.."
  33     fi
  34   fi
  35 else
  36   libiberty_topdir="${srcdir}/.."
  37 fi
  38 AC_SUBST(libiberty_topdir)
  39 AC_CONFIG_AUX_DIR($libiberty_topdir)
  40
  41 dnl Very limited version of automake's enable-maintainer-mode
  42
  43 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
  44   dnl maintainer-mode is disabled by default
  45   AC_ARG_ENABLE(maintainer-mode,
  46 [  --enable-maintainer-mode
  47                           enable make rules and dependencies not useful
  48                           (and sometimes confusing) to the casual installer],
  49       maintainer_mode=$enableval,
  50       maintainer_mode=no)
  51
  52 AC_MSG_RESULT($maintainer_mode)
  53
  54 if test "$maintainer_mode" = "yes"; then
  55   MAINT=''
  56   NOTMAINT='#'
  57 else
  58   MAINT='#'
  59   NOTMAINT=''
  60 fi
  61 AC_SUBST(MAINT)dnl
  62 AC_SUBST(NOTMAINT)dnl
  63
  64 # Do we have a single-tree copy of texinfo?  Even if we do, we can't
  65 # rely on it - libiberty is built before texinfo.
  66 AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo, )
  67 if test "x$MAKEINFO" = "x"; then
  68     MAKEINFO="@echo makeinfo missing; true"
  69     BUILD_INFO=
  70 else
  71     BUILD_INFO=info
  72     case x"`$MAKEINFO --version | grep 'GNU texinfo'`" in
  73       x*\ [[1-3]].* )
  74         MAKEINFO="@echo $MAKEINFO is too old, 4.0 or newer required; true"
  75         BUILD_INFO=
  76         AC_MSG_WARN([
  77 *** Makeinfo is too old. Info documentation will not be built.])
  78         ;;
  79     esac
  80 fi
  81 AC_SUBST(MAKEINFO)
  82 AC_SUBST(BUILD_INFO)
  83
  84 AC_CHECK_PROG(PERL, perl, perl, )
  85 if test x"$PERL" = x""; then
  86   HAVE_PERL='#'
  87 else
  88   HAVE_PERL=''
  89 fi
  90 AC_SUBST(HAVE_PERL)
  91
  92 AC_CANONICAL_HOST
  93
  94 dnl When we start using automake:
  95 dnl AM_INIT_AUTOMAKE(libiberty, 1.0)
  96
  97 dnl These must be called before AM_PROG_LIBTOOL, because it may want
  98 dnl to call AC_CHECK_PROG.
  99 AC_CHECK_TOOL(AR, ar)
 100 AC_CHECK_TOOL(RANLIB, ranlib, :)
 101
 102 LIB_AC_PROG_CC
 103
 104 AC_PROG_CC_C_O
 105 # autoconf is lame and doesn't give us any substitution variable for this.
 106 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 107   NO_MINUS_C_MINUS_O=yes
 108 else
 109   OUTPUT_OPTION='-o $@'
 110 fi
 111 AC_SUBST(NO_MINUS_C_MINUS_O)
 112 AC_SUBST(OUTPUT_OPTION)
 113
 114 AC_ISC_POSIX
 115 AC_C_CONST
 116 AC_C_INLINE
 117
 118 dnl When we start using libtool:
 119 dnl Default to a non shared library.  This may be overridden by the
 120 dnl configure option --enable-shared.
 121 dnl AM_DISABLE_SHARED
 122
 123 dnl When we start using libtool:
 124 dnl AM_PROG_LIBTOOL
 125
 126 dnl When we start using automake:
 127 dnl AM_CONFIG_HEADER(config.h:config.in)
 128 AC_CONFIG_HEADER(config.h:config.in)
 129
 130 dnl When we start using automake:
 131 dnl AM_MAINTAINER_MODE
 132 dnl AC_EXEEXT
 133
 134 dnl When we start using automake:
 135 dnl AM_PROG_INSTALL
 136 AC_PROG_INSTALL
 137
 138 . ${srcdir}/config.table
 139 host_makefile_frag=${frag}
 140 AC_SUBST_FILE(host_makefile_frag)
 141
 142 # It's OK to check for header files.  Although the compiler may not be
 143 # able to link anything, it had better be able to at least compile
 144 # something.
 145 AC_CHECK_HEADERS(sys/file.h sys/param.h limits.h stdlib.h string.h unistd.h strings.h sys/time.h time.h sys/resource.h sys/stat.h sys/mman.h fcntl.h alloca.h sys/pstat.h sys/sysmp.h sys/sysinfo.h machine/hal_sysinfo.h sys/table.h sys/sysctl.h sys/systemcfg.h)
 146 AC_HEADER_SYS_WAIT
 147 AC_HEADER_TIME
 148
 149 libiberty_AC_DECLARE_ERRNO
 150
 151 AC_CHECK_TYPE(uintptr_t, unsigned long)
 152 # Given the above check, we always have uintptr_t or a fallback
 153 # definition.  So define HAVE_UINTPTR_T in case any imported code
 154 # relies on it.
 155 AC_DEFINE(HAVE_UINTPTR_T, 1, [Define if you have the \`uintptr_t' type.])
 156
 157 AC_TYPE_PID_T
 158
 159 # This is the list of functions which libiberty will provide if they
 160 # are not available on the host.
 161
 162 funcs="asprintf"
 163 funcs="$funcs atexit"
 164 funcs="$funcs basename"
 165 funcs="$funcs bcmp"
 166 funcs="$funcs bcopy"
 167 funcs="$funcs bsearch"
 168 funcs="$funcs bzero"
 169 funcs="$funcs calloc"
 170 funcs="$funcs clock"
 171 funcs="$funcs ffs"
 172 funcs="$funcs getcwd"
 173 funcs="$funcs getpagesize"
 174 funcs="$funcs index"
 175 funcs="$funcs insque"
 176 funcs="$funcs memchr"
 177 funcs="$funcs memcmp"
 178 funcs="$funcs memcpy"
 179 funcs="$funcs memmove"
 180 funcs="$funcs mempcpy"
 181 funcs="$funcs memset"
 182 funcs="$funcs mkstemps"
 183 funcs="$funcs putenv"
 184 funcs="$funcs random"
 185 funcs="$funcs rename"
 186 funcs="$funcs rindex"
 187 funcs="$funcs setenv"
 188 funcs="$funcs snprintf"
 189 funcs="$funcs sigsetmask"
 190 funcs="$funcs stpcpy"
 191 funcs="$funcs stpncpy"
 192 funcs="$funcs strcasecmp"
 193 funcs="$funcs strchr"
 194 funcs="$funcs strdup"
 195 funcs="$funcs strncasecmp"
 196 funcs="$funcs strrchr"
 197 funcs="$funcs strstr"
 198 funcs="$funcs strtod"
 199 funcs="$funcs strtol"
 200 funcs="$funcs strtoul"
 201 funcs="$funcs tmpnam"
 202 funcs="$funcs vasprintf"
 203 funcs="$funcs vfprintf"
 204 funcs="$funcs vprintf"
 205 funcs="$funcs vsnprintf"
 206 funcs="$funcs vsprintf"
 207 funcs="$funcs waitpid"
 208
 209 # Also in the old function.def file: alloca, vfork, getopt.
 210
 211 vars="sys_errlist sys_nerr sys_siglist _system_configuration"
 212
 213 checkfuncs="getrusage on_exit psignal strerror strsignal sysconf times sbrk gettimeofday"
 214 checkfuncs="$checkfuncs realpath canonicalize_file_name pstat_getstatic pstat_getdynamic sysmp"
 215 checkfuncs="$checkfuncs getsysinfo table sysctl"
 216
 217 # These are neither executed nor required, but they help keep
 218 # autoheader happy without adding a bunch of text to acconfig.h.
 219 if test "x" = "y"; then
 220   AC_CHECK_FUNCS(asprintf atexit basename bcmp bcopy bsearch bzero calloc clock)
 221   AC_CHECK_FUNCS(getcwd getpagesize index insque mkstemps memchr memcmp memcpy)
 222   AC_CHECK_FUNCS(memmove mempcpy memset putenv random rename rindex sigsetmask)
 223   AC_CHECK_FUNCS(strcasecmp setenv stpcpy stpncpy strchr strdup strncasecmp strrchr strstr)
 224   AC_CHECK_FUNCS(strtod strtol strtoul tmpnam vasprintf vfprintf vprintf)
 225   AC_CHECK_FUNCS(vsprintf waitpid getrusage on_exit psignal strerror strsignal)
 226   AC_CHECK_FUNCS(sysconf times sbrk gettimeofday ffs snprintf vsnprintf)
 227   AC_CHECK_FUNCS(pstat_getstatic pstat_getdynamic sysmp getsysinfo table sysctl)
 228   AC_CHECK_FUNCS(realpath canonicalize_file_name)
 229   AC_DEFINE(HAVE_SYS_ERRLIST, 1, [Define if you have the sys_errlist variable.])
 230   AC_DEFINE(HAVE_SYS_NERR,    1, [Define if you have the sys_nerr variable.])
 231   AC_DEFINE(HAVE_SYS_SIGLIST, 1, [Define if you have the sys_siglist variable.])
 232   AC_DEFINE(HAVE__SYSTEM_CONFIGURATION, 1, [Define if you have the _system_configuration variable.])
 233 fi
 234
 235 # For each of these functions, if the host does not provide the
 236 # function we want to put FN.o in LIBOBJS, and if the host does
 237 # provide the function, we want to define HAVE_FN in config.h.
 238
 239 setobjs=
 240 CHECK=
 241 target_header_dir=
 242 if test -n "${with_target_subdir}"; then
 243
 244   # We are being configured as a target library.  AC_REPLACE_FUNCS
 245   # may not work correctly, because the compiler may not be able to
 246   # link executables.  Note that we may still be being configured
 247   # native.
 248
 249   # If we are being configured for newlib, we know which functions
 250   # newlib provide and which ones we will be expected to provide.
 251
 252   if test "x${with_newlib}" = "xyes"; then
 253     LIBOBJS="asprintf.o basename.o insque.o random.o strdup.o vasprintf.o"
 254
 255     for f in $funcs; do
 256       case "$f" in
 257         asprintf | basename | insque | random | strdup | vasprintf)
 258           ;;
 259         *)
 260           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 261           AC_DEFINE_UNQUOTED($n)
 262           ;;
 263       esac
 264     done
 265
 266     # newlib doesnt provide any of the variables in $vars, so we
 267     # dont have to check them here.
 268
 269     # Of the functions in $checkfuncs, newlib only has strerror.
 270     AC_DEFINE_NOAUTOHEADER(HAVE_STRERROR)
 271
 272     setobjs=yes
 273
 274   fi
 275
 276   # We may wish to install the target headers somewhere.
 277   AC_ARG_ENABLE(install-libiberty,
 278   [  --enable-install-libiberty       Install headers for end users],
 279   enable_install_libiberty=$enableval,
 280   enable_install_libiberty=no)dnl
 281
 282   # Option parsed, now set things appropriately.
 283   case x"$enable_install_libiberty" in
 284     xyes|x)
 285       target_header_dir=libiberty
 286       ;;
 287     xno)
 288       target_header_dir=
 289       ;;
 290     *)
 291       # This could be sanity-checked in various ways...
 292       target_header_dir="${enable_install_libiberty}"
 293       ;;
 294   esac
 295
 296
 297 else
 298
 299    # Not a target library, so we set things up to run the test suite.
 300    CHECK=check-cplus-dem
 301
 302 fi
 303
 304 AC_SUBST(CHECK)
 305 AC_SUBST(target_header_dir)
 306
 307 case "${host}" in
 308   *-*-cygwin* | *-*-mingw*)
 309     AC_DEFINE_NOAUTOHEADER(HAVE_SYS_ERRLIST)
 310     AC_DEFINE_NOAUTOHEADER(HAVE_SYS_NERR)
 311     ;;
 312 esac
 313
 314 if test -z "${setobjs}"; then
 315   case "${host}" in
 316
 317   *-*-vxworks*)
 318     # Handle VxWorks configuration specially, since on VxWorks the
 319     # libraries are actually on the target board, not in the file
 320     # system.
 321     LIBOBJS="basename.o getpagesize.o insque.o random.o strcasecmp.o"
 322     LIBOBJS="$LIBOBJS strncasecmp.o strdup.o vfork.o waitpid.o vasprintf.o"
 323     for f in $funcs; do
 324       case "$f" in
 325         basename | getpagesize | insque | random | strcasecmp)
 326           ;;
 327         strncasecmp | strdup | vfork | waitpid | vasprintf)
 328           ;;
 329         *)
 330           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 331           AC_DEFINE_UNQUOTED($n)
 332           ;;
 333       esac
 334     done
 335
 336     # VxWorks doesn't provide any of the variables in $vars, so we
 337     # don't have to check them here.
 338
 339     # Of the functions in $checkfuncs, VxWorks only has strerror.
 340     AC_DEFINE_NOAUTOHEADER(HAVE_STRERROR)
 341
 342     setobjs=yes
 343     ;;
 344
 345   esac
 346 fi
 347
 348 if test -z "${setobjs}"; then
 349
 350   case "${host}" in
 351
 352   *-*-cygwin*)
 353     # The Cygwin library actually uses a couple of files from
 354     # libiberty when it is built.  If we are building a native
 355     # Cygwin, and we run the tests, we will appear to have these
 356     # files.  However, when we go on to build winsup, we will wind up
 357     # with a library which does not have the files, since they should
 358     # have come from libiberty.
 359
 360     # We handle this by removing the functions the winsup library
 361     # provides from our shell variables, so that they appear to be
 362     # missing.
 363
 364     # DJ - only if we're *building* cygwin, not just building *with* cygwin
 365
 366     if test -n "${with_target_subdir}"
 367     then
 368       funcs="`echo $funcs | sed -e 's/random//'`"
 369       LIBOBJS="$LIBOBJS random.o"
 370       vars="`echo $vars | sed -e 's/sys_siglist//'`"
 371       checkfuncs="`echo $checkfuncs | sed -e 's/strsignal//' -e 's/psignal//'`"
 372     fi
 373     ;;
 374
 375   *-*-mingw32*)
 376     # Under mingw32, sys_nerr and sys_errlist exist, but they are
 377     # macros, so the test below won't find them.
 378     libiberty_cv_var_sys_nerr=yes
 379     libiberty_cv_var_sys_errlist=yes
 380     ;;
 381
 382   *-*-uwin*)
 383     # Under some versions of uwin, vfork is notoriously buggy and the test
 384     # can hang configure; on other versions, vfork exists just as a stub.
 385     # FIXME: This should be removed once vfork in uwin's runtime is fixed.
 386     ac_cv_func_vfork_works=no
 387     # Under uwin 2.0+, sys_nerr and sys_errlist exist, but they are
 388     # macros (actually, these are imported from a DLL, but the end effect
 389     # is the same), so the test below won't find them.
 390     libiberty_cv_var_sys_nerr=yes
 391     libiberty_cv_var_sys_errlist=yes
 392     ;;
 393
 394   *-*-*vms*)
 395     # Under VMS, vfork works very different than on Unix. The standard test
 396     # won't work, and it isn't easily adaptable. It makes more sense to
 397     # just force it.
 398     ac_cv_func_vfork_works=yes
 399     ;;
 400
 401   esac
 402
 403   # We haven't set the list of objects yet.  Use the standard autoconf
 404   # tests.  This will only work if the compiler works.
 405   AC_PROG_CC_WORKS
 406   AC_REPLACE_FUNCS($funcs)
 407   libiberty_AC_FUNC_C_ALLOCA
 408   AC_FUNC_VFORK
 409   if test $ac_cv_func_vfork_works = no; then
 410     LIBOBJS="$LIBOBJS vfork.o"
 411   fi
 412   # We only need _doprnt if we might use it to implement v*printf.
 413   if test $ac_cv_func_vprintf != yes \
 414      || test $ac_cv_func_vfprintf != yes \
 415      || test $ac_cv_func_vsprintf != yes; then
 416     AC_REPLACE_FUNCS(_doprnt)
 417   else
 418     AC_CHECK_FUNCS(_doprnt)
 419   fi
 420
 421   for v in $vars; do
 422     AC_MSG_CHECKING([for $v])
 423     AC_CACHE_VAL(libiberty_cv_var_$v,
 424       [AC_TRY_LINK([int *p;], [extern int $v []; p = $v;],
 425                    [eval "libiberty_cv_var_$v=yes"],
 426                    [eval "libiberty_cv_var_$v=no"])])
 427     if eval "test \"`echo '$libiberty_cv_var_'$v`\" = yes"; then
 428       AC_MSG_RESULT(yes)
 429       n=HAVE_`echo $v | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 430       AC_DEFINE_UNQUOTED($n)
 431     else
 432       AC_MSG_RESULT(no)
 433     fi
 434   done
 435   AC_CHECK_FUNCS($checkfuncs)
 436   libiberty_NEED_DECLARATION(canonicalize_file_name)
 437 fi
 438
 439 # Figure out which version of pexecute to use.
 440 case "${host}" in
 441      *-*-mingw* | *-*-winnt*)   pexecute=pex-win32.o  ;;
 442      *-*-msdosdjgpp*)           pexecute=pex-djgpp.o  ;;
 443      *-*-msdos*)                pexecute=pex-msdos.o  ;;
 444      *-*-os2-emx*)              pexecute=pex-os2.o    ;;
 445      *)                         pexecute=pex-unix.o   ;;
 446 esac
 447 AC_SUBST(pexecute)
 448
 449 libiberty_AC_FUNC_STRNCMP
 450
 451 # Install a library built with a cross compiler in $(tooldir) rather
 452 # than $(libdir).
 453 if test -z "${with_cross_host}"; then
 454   INSTALL_DEST=libdir
 455 else
 456   INSTALL_DEST=tooldir
 457 fi
 458 AC_SUBST(INSTALL_DEST)
 459
 460 # We need multilib support, but only if configuring for the target.
 461 AC_OUTPUT(Makefile testsuite/Makefile,
 462 [test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
 463 if test -n "$CONFIG_FILES"; then
 464   if test -n "${with_build_subdir}" || test -n "${with_target_subdir}"; then
 465     # FIXME: We shouldn't need to set ac_file
 466     ac_file=Makefile
 467     LD="${ORIGINAL_LD_FOR_MULTILIBS}"
 468     . ${libiberty_topdir}/config-ml.in
 469   fi
 470 fi],
 471 srcdir=${srcdir}
 472 host=${host}
 473 target=${target}
 474 with_target_subdir=${with_target_subdir}
 475 with_build_subdir=${with_build_subdir}
 476 with_multisubdir=${with_multisubdir}
 477 ac_configure_args="--enable-multilib ${ac_configure_args}"
 478 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 479 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
 480 libiberty_topdir=${libiberty_topdir}
 481 )