ld/ldlex.l

   1 %{
   2
   3 /* Copyright (C) 1991 Free Software Foundation, Inc.
   4
   5 This file is part of GLD, the Gnu Linker.
   6
   7 GLD is free software; you can redistribute it and/or modify
   8 it under the terms of the GNU General Public License as published by
   9 the Free Software Foundation; either version 2, or (at your option)
  10 any later version.
  11
  12 GLD is distributed in the hope that it will be useful,
  13 but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 GNU General Public License for more details.
  16
  17 You should have received a copy of the GNU General Public License
  18 along with GLD; see the file COPYING.  If not, write to
  19 the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.  */
  20
  21 /*
  22 This was written by steve chamberlain
  23                     [email protected]
  24 */
  25
  26
  27 typedef int bfd_vma;
  28 #include <ansidecl.h>
  29 #include "ldgram.h"
  30
  31 int ldgram_in_defsym;
  32 int ldgram_had_equals;
  33 int ldgram_in_script;
  34
  35 int hex_mode;
  36 extern int fgetc();
  37 extern int yyparse();
  38
  39
  40
  41 char *buystring();
  42
  43 unsigned int lineno = 1;
  44 int old;
  45
  46 static comment();
  47
  48 #undef YY_INPUT
  49 #define YY_INPUT(buf,result,max_size) yy_input(buf, &result, max_size)
  50 #undef YY_FATAL_ERROR
  51 #define YY_FATAL_ERROR ;
  52 #define MAX_INCLUDE_DEPTH 10
  53 YY_BUFFER_STATE include_stack[MAX_INCLUDE_DEPTH];
  54 char *file_name_stack[MAX_INCLUDE_DEPTH];
  55 unsigned int include_stack_ptr = 0;
  56
  57
  58 /* STATES
  59         COMMAND         on command line
  60         COMMENT         in a C comment
  61         EXPRESSION      definiatelyt in an expression
  62         SCRIPT          definately in a script
  63         SOMEWHERE       either EXPRESSION or SCRIPT
  64         MRI             in an MRI script
  65 */
  66 #define RTOKEN(x)  {  yylval.token = x; return x; }
  67 %}
  68
  69 %a 4000
  70 %o 5000
  71
  72 CMDFILENAMECHAR   [_a-zA-Z0-9\/\.\\_\+\$\:\[\]\\\,\=\&\!\<\>\-\~]
  73 CMDFILENAMECHAR1  [_a-zA-Z0-9\/\.\\_\+\$\:\[\]\\\,\=\&\!\<\>\~]
  74 FILENAMECHAR1   [_a-zA-Z\/\.\\\$\_\~]
  75 SYMBOLCHARN     [_a-zA-Z\/\.\\0-9]
  76 FILENAMECHAR    [_a-zA-Z0-9\/\.\-\_\+\=\$\:\[\]\\\,\~]
  77 FILENAME        {FILENAMECHAR}+
  78 WHITE           [ \t\n]+
  79
  80 NOCFILENAMECHAR [_a-zA-Z0-9\/\.\-\_\+\$\:\[\]\\\~]
  81
  82
  83 %s COMMAND
  84 %s SCRIPT
  85 %s EXPRESSION
  86 %s COMMENT
  87 %s BOTH
  88 %s DEFSYMEXP
  89 %s MRI
  90 %%
  91
  92
  93 <BOTH,SCRIPT,EXPRESSION,COMMAND>"/*"    { comment(); }
  94
  95
  96 <DEFSYMEXP>"-"                  { RTOKEN('-');}
  97 <DEFSYMEXP>"+"                  { RTOKEN('+');}
  98 <DEFSYMEXP>{FILENAMECHAR1}{SYMBOLCHARN}*   { yylval.name = buystring(yytext); return NAME; }
  99 <DEFSYMEXP>[ \t]                { RTOKEN(DEFSYMEND); }
 100 <DEFSYMEXP>"="                  { RTOKEN('='); }
 101 <COMMAND>"-defsym"{WHITE}*      { return OPTION_defsym; }
 102 <COMMAND>"-noinhibit_exec"      { return OPTION_noinhibit_exec; }
 103 <COMMAND>"-noinhibit-exec"      { return OPTION_noinhibit_exec; }
 104 <COMMAND>"-sort_common"         { return OPTION_sort_common;}
 105 <COMMAND>"-sort-common"         { return OPTION_sort_common;}
 106 <COMMAND>"-format"              { return OPTION_format; }
 107 <COMMAND>"-n"                   { return OPTION_n; }
 108 <COMMAND>"-N"                   { return OPTION_N; }
 109 <COMMAND>"-r"                   { return OPTION_r; }
 110 <COMMAND>"-relax"               { return OPTION_relax; }
 111 <COMMAND>"-i"                   { return OPTION_r; }
 112 <COMMAND>"-Ur"                  { return OPTION_Ur; }
 113 <COMMAND>"-o"                   { return OPTION_o; }
 114 <COMMAND>"-g"                   { return OPTION_g; }
 115 <COMMAND>"-e"                   { return OPTION_e; }
 116 <COMMAND>"-b"                   { return OPTION_b; }
 117 <COMMAND>"-dc"                  { return OPTION_dc; }
 118 <COMMAND>"-dp"                  { return OPTION_dp; }
 119 <COMMAND>"-d"                   { return OPTION_d; }
 120 <COMMAND>"-v"                   { return OPTION_v; }
 121 <COMMAND>"-V"                   { return OPTION_V; }
 122 <COMMAND>"-m"                   { return OPTION_m; }
 123 <COMMAND>"-m"{FILENAME}         { return OPTION_memul; }
 124 <COMMAND>"-M"                   { return OPTION_M; }
 125 <COMMAND>"-Map"                 { return OPTION_Map;}
 126 <COMMAND>"-t"                   { return OPTION_t; }
 127 <COMMAND>"-X"                   { return OPTION_X; }
 128 <COMMAND>"-x"                   { return OPTION_x; }
 129 <COMMAND>"-c"                   { return OPTION_c; }
 130 <COMMAND>"-R"                   { return OPTION_R; }
 131 <COMMAND>"-u"                   { return OPTION_u; }
 132 <COMMAND>"-s"                   { return OPTION_s; }
 133 <COMMAND>"-S"                   { return OPTION_S; }
 134 <COMMAND>"-Bstat"               { return OPTION_Bstatic; }
 135 <COMMAND>"-B"{FILENAME}         { /* Ignored */ }
 136 <COMMAND>"-l"{FILENAME}         {
 137                                         yylval.name = buystring(yytext+2);
 138                                         return OPTION_l;
 139                                 }
 140
 141 <COMMAND>"-L"{FILENAME}         {
 142                                         yylval.name = buystring(yytext+2);
 143                                         return OPTION_L;
 144                                 }
 145 <COMMAND>"-Ttext"               {
 146                                  yylval.name = ".text";
 147                                  return OPTION_Texp;
 148                                 }
 149 <COMMAND>"-Tdata"               {
 150                                  yylval.name = ".data";
 151                                  return OPTION_Texp;
 152                                }
 153 <COMMAND>"-Tbss"                {
 154                                  yylval.name = ".bss";
 155                                  return OPTION_Texp;
 156                                }
 157 <COMMAND>"-O"{FILENAME}         {
 158                                 yylval.name = buystring(yytext+2);
 159                                 return OPTION_Texp;
 160                                 }
 161
 162 <COMMAND>"-T"{FILENAME}         {
 163                                  yylval.name = buystring(yytext+2);
 164                                  return OPTION_Tfile;
 165                                }
 166 <COMMAND>"-T"                   {
 167                                  return OPTION_T;
 168                                }
 169
 170 <COMMAND>"-F"{FILENAME}         {
 171                                  return OPTION_F;
 172                                }
 173 <COMMAND>"-F"                   {
 174                                  return OPTION_F;
 175                                }
 176
 177 <COMMAND>"-y"{FILENAME}         {
 178                                         yylval.name = buystring(yytext+2);
 179                                         return OPTION_y;
 180                                 }
 181
 182 <COMMAND>"-A"{FILENAME}         {
 183                                         yylval.name = buystring(yytext+2);
 184                                         return OPTION_Aarch;
 185                                 }
 186
 187 <COMMAND>"-retain-symbols-file" { return OPTION_RETAIN_SYMBOLS_FILE; }
 188
 189 <COMMAND>"-EB"                  {
 190                                         return OPTION_EB;
 191                                 }
 192 <COMMAND>"-EL"                  {
 193                                         return OPTION_EL;
 194                                 }
 195 <COMMAND>"-G"                   {
 196                                         return OPTION_G;
 197                                 }
 198 <COMMAND>"-G"([0-9])+           {
 199                                         yylval.integer = atoi (yytext + 2);
 200                                         return OPTION_Gval;
 201                                 }
 202 <MRI,EXPRESSION>"$"([0-9A-Fa-f])+ {
 203                                 yylval.integer = strtoul(yytext+1, 0,16);
 204                                 return INT;
 205                         }
 206
 207 <MRI,EXPRESSION>([0-9A-Fa-f])+(H|X|B|O|D) {
 208                                    int base ;
 209                                    switch (yytext[yyleng-1]) {
 210                                     case 'X':
 211                                     case 'H':
 212                                      base = 16;
 213                                      break;
 214                                     case 'O':
 215                                      base = 8;
 216                                      break;
 217                                     case 'B':
 218                                      base = 2;
 219                                      break;
 220                                     default:
 221                                      base = 10;
 222                                    }
 223                                    yylval.integer = strtoul(yytext+1, 0, base);
 224                                    return INT;
 225                                  }
 226 <SCRIPT,DEFSYMEXP,MRI,BOTH,EXPRESSION>"$"?"0x"?([0-9A-Fa-f])+(M|K|m|k)? {
 227                                   yylval.integer = strtoul(yytext,0,hex_mode);
 228                                   if (yytext[yyleng-1]=='M'
 229                                         || yytext[yyleng-1] == 'm') {
 230                                       yylval.integer *= 1024*1024;
 231                                     }
 232                                   if (yytext[yyleng-1]=='K'
 233                                 || yytext[yyleng-1]=='k') {
 234                                       yylval.integer *= 1024;
 235                                     }
 236                                   return INT;
 237                                 }
 238 <BOTH,SCRIPT,EXPRESSION>"]"             { RTOKEN(']');}
 239 <BOTH,SCRIPT,EXPRESSION>"["             { RTOKEN('[');}
 240 <BOTH,SCRIPT,EXPRESSION>"<<="   { RTOKEN(LSHIFTEQ);}
 241 <BOTH,SCRIPT,EXPRESSION>">>="   { RTOKEN(RSHIFTEQ);}
 242 <BOTH,SCRIPT,EXPRESSION>"||"    { RTOKEN(OROR);}
 243 <BOTH,SCRIPT,EXPRESSION>"=="    { RTOKEN(EQ);}
 244 <BOTH,SCRIPT,EXPRESSION>"!="    { RTOKEN(NE);}
 245 <BOTH,SCRIPT,EXPRESSION>">="    { RTOKEN(GE);}
 246 <BOTH,SCRIPT,EXPRESSION>"<="    { RTOKEN(LE);}
 247 <BOTH,SCRIPT,EXPRESSION>"<<"    { RTOKEN(LSHIFT);}
 248 <BOTH,SCRIPT,EXPRESSION>">>"    { RTOKEN(RSHIFT);}
 249 <BOTH,SCRIPT,EXPRESSION>"+="    { RTOKEN(PLUSEQ);}
 250 <BOTH,SCRIPT,EXPRESSION>"-="    { RTOKEN(MINUSEQ);}
 251 <BOTH,SCRIPT,EXPRESSION>"*="    { RTOKEN(MULTEQ);}
 252 <BOTH,SCRIPT,EXPRESSION>"/="    { RTOKEN(DIVEQ);}
 253 <BOTH,SCRIPT,EXPRESSION>"&="    { RTOKEN(ANDEQ);}
 254 <BOTH,SCRIPT,EXPRESSION>"|="    { RTOKEN(OREQ);}
 255 <BOTH,SCRIPT,EXPRESSION>"&&"    { RTOKEN(ANDAND);}
 256 <BOTH,SCRIPT,EXPRESSION>">"             { RTOKEN('>');}
 257 <MRI,BOTH,SCRIPT,EXPRESSION>","         { RTOKEN(',');}
 258 <BOTH,SCRIPT,EXPRESSION>"&"             { RTOKEN('&');}
 259 <BOTH,SCRIPT,EXPRESSION>"|"             { RTOKEN('|');}
 260 <BOTH,SCRIPT,EXPRESSION>"~"             { RTOKEN('~');}
 261 <BOTH,SCRIPT,EXPRESSION>"!"             { RTOKEN('!');}
 262 <BOTH,SCRIPT,EXPRESSION>"?"             { RTOKEN('?');}
 263 <BOTH,SCRIPT,EXPRESSION>"*"             { RTOKEN('*');}
 264 <BOTH,SCRIPT,EXPRESSION>"+"             { RTOKEN('+');}
 265 <BOTH,SCRIPT,EXPRESSION>"-"             { RTOKEN('-');}
 266 <BOTH,SCRIPT,EXPRESSION>"/"             { RTOKEN('/');}
 267 <BOTH,SCRIPT,EXPRESSION>"%"             { RTOKEN('%');}
 268 <BOTH,SCRIPT,EXPRESSION>"<"             { RTOKEN('<');}
 269 <BOTH,SCRIPT,EXPRESSION>">"             { RTOKEN('>');}
 270 <MRI,BOTH,SCRIPT,EXPRESSION>"="          { RTOKEN('=');}
 271 <BOTH,SCRIPT,EXPRESSION>"}"                     { RTOKEN('}') ; }
 272 <BOTH,SCRIPT,EXPRESSION>"{"                     { RTOKEN('{'); }
 273 <BOTH,SCRIPT,EXPRESSION>")"                     { RTOKEN(')');}
 274 <BOTH,SCRIPT,EXPRESSION>"("                     { RTOKEN('(');}
 275 <BOTH,SCRIPT,EXPRESSION>"]"             { RTOKEN(']');}
 276 <BOTH,SCRIPT,EXPRESSION>"["             { RTOKEN('[');}
 277 <BOTH,SCRIPT,EXPRESSION>":"             { RTOKEN(':'); }
 278 <BOTH,SCRIPT,EXPRESSION>";"             { RTOKEN(';');}
 279 <BOTH,SCRIPT,EXPRESSION>"-"             { RTOKEN('-');}
 280 <BOTH,SCRIPT,EXPRESSION>"/"             { RTOKEN('/');}
 281 <BOTH,SCRIPT>"MEMORY"           { RTOKEN(MEMORY);}
 282 <BOTH,SCRIPT>"ORIGIN"           { RTOKEN(ORIGIN);}
 283 <BOTH,SCRIPT>"BLOCK"                    { RTOKEN(BLOCK);}
 284 <BOTH,SCRIPT>"LENGTH"           { RTOKEN(LENGTH);}
 285 <EXPRESSION,BOTH,SCRIPT>"ALIGN"                 { RTOKEN(ALIGN_K);}
 286 <EXPRESSION,BOTH,SCRIPT>"ADDR"                  { RTOKEN(ADDR);}
 287 <BOTH,SCRIPT>"ENTRY"                    { RTOKEN(ENTRY);}
 288 <EXPRESSION,BOTH,SCRIPT>"NEXT"                  { RTOKEN(NEXT);}
 289 <EXPRESSION,BOTH,SCRIPT>"sizeof_headers"        { RTOKEN(SIZEOF_HEADERS);}
 290 <EXPRESSION,BOTH,SCRIPT>"SIZEOF_HEADERS"        { RTOKEN(SIZEOF_HEADERS);}
 291 <BOTH,SCRIPT>"MAP"                      { RTOKEN(MAP);}
 292 <EXPRESSION,BOTH,SCRIPT>"SIZEOF"                { RTOKEN(SIZEOF);}
 293 <BOTH,SCRIPT>"TARGET"           { RTOKEN(TARGET_K);}
 294 <BOTH,SCRIPT>"SEARCH_DIR"               { RTOKEN(SEARCH_DIR);}
 295 <BOTH,SCRIPT>"OUTPUT"           { RTOKEN(OUTPUT);}
 296 <BOTH,SCRIPT>"INPUT"                    { RTOKEN(INPUT);}
 297 <EXPRESSION,BOTH,SCRIPT>"DEFINED"               { RTOKEN(DEFINED);}
 298 <BOTH,SCRIPT>"CREATE_OBJECT_SYMBOLS"    { RTOKEN(CREATE_OBJECT_SYMBOLS);}
 299 <BOTH,SCRIPT>"CONSTRUCTORS"             { RTOKEN( CONSTRUCTORS);}
 300 <BOTH,SCRIPT>"FORCE_COMMON_ALLOCATION" { RTOKEN(FORCE_COMMON_ALLOCATION);}
 301 <BOTH,SCRIPT>"SECTIONS"         { RTOKEN(SECTIONS);}
 302 <BOTH,SCRIPT>"FILL"                     { RTOKEN(FILL);}
 303 <BOTH,SCRIPT>"STARTUP"          { RTOKEN(STARTUP);}
 304 <BOTH,SCRIPT>"OUTPUT_FORMAT"            { RTOKEN(OUTPUT_FORMAT);}
 305 <BOTH,SCRIPT>"OUTPUT_ARCH"              { RTOKEN( OUTPUT_ARCH);}
 306 <BOTH,SCRIPT>"HLL"                      { RTOKEN(HLL);}
 307 <BOTH,SCRIPT>"SYSLIB"           { RTOKEN(SYSLIB);}
 308 <BOTH,SCRIPT>"FLOAT"                    { RTOKEN(FLOAT);}
 309 <BOTH,SCRIPT>"LONG"                     { RTOKEN( LONG);}
 310 <BOTH,SCRIPT>"SHORT"                    { RTOKEN( SHORT);}
 311 <BOTH,SCRIPT>"BYTE"                     { RTOKEN( BYTE);}
 312 <BOTH,SCRIPT>"NOFLOAT"          { RTOKEN(NOFLOAT);}
 313 <EXPRESSION,BOTH,SCRIPT>"NOLOAD"                { RTOKEN(NOLOAD);}
 314 <BOTH,SCRIPT>"DSECT"                    { RTOKEN(DSECT);}
 315 <BOTH,SCRIPT>"COPY"                     { RTOKEN(COPY);}
 316 <BOTH,SCRIPT>"INFO"                     { RTOKEN(INFO);}
 317 <BOTH,SCRIPT>"OVERLAY"          { RTOKEN(OVERLAY);}
 318 <BOTH,SCRIPT>"o"                        { RTOKEN(ORIGIN);}
 319 <BOTH,SCRIPT>"org"                      { RTOKEN(ORIGIN);}
 320 <BOTH,SCRIPT>"l"                        { RTOKEN( LENGTH);}
 321 <BOTH,SCRIPT>"len"                      { RTOKEN( LENGTH);}
 322 <BOTH,SCRIPT>"INCLUDE"                  { RTOKEN(INCLUDE);}
 323 <EXPRESSION,BOTH,SCRIPT>"AT"                    { RTOKEN(AT);}
 324 <MRI>"\n"                       { ++ lineno;  RTOKEN(NEWLINE); }
 325 <MRI>"*".*                      { /* Mri comment line */ }
 326 <MRI>"END"                      { RTOKEN(ENDWORD); }
 327 <MRI>"ALIGNMOD"         { RTOKEN(ALIGNMOD);}
 328 <MRI>"ALIGN"            { RTOKEN(ALIGN_K);}
 329
 330 <MRI>"CHIP"                     { RTOKEN(CHIP); }
 331 <MRI>"BASE"                     { RTOKEN(BASE); }
 332 <MRI>"ALIAS"                     { RTOKEN(ALIAS); }
 333 <MRI>"TRUNCATE"                     { RTOKEN(TRUNCATE); }
 334 <MRI>"LOAD"                     { RTOKEN(LOAD); }
 335 <MRI>"PUBLIC"                   { RTOKEN(PUBLIC); }
 336 <MRI>"ORDER"                    { RTOKEN(ORDER); }
 337 <MRI>"NAME"                     { RTOKEN(NAMEWORD); }
 338 <MRI>"FORMAT"                   { RTOKEN(FORMAT); }
 339 <MRI>"LIST".*                   { RTOKEN(LIST); /* LIST and ignore to end of line */ }
 340 <MRI>"SECT"                     { RTOKEN(SECT); }
 341 <EXPRESSION,BOTH,SCRIPT,MRI>"ABSOLUTE"                  { RTOKEN(ABSOLUTE); }
 342 <MRI>"end"                      { RTOKEN(ENDWORD); }
 343 <MRI>"chip"                     { RTOKEN(CHIP); }
 344 <MRI>"load"                     { RTOKEN(LOAD); }
 345 <MRI>"order"                    { RTOKEN(ORDER); }
 346 <MRI>"name"                     { RTOKEN(NAMEWORD); }
 347 <MRI>"format"                   { RTOKEN(FORMAT); }
 348 <MRI>"list".*                   { RTOKEN(LIST); /* LIST and ignore to end of line */ }
 349 <MRI>"sect"                     { RTOKEN(SECT); }
 350 <EXPRESSION,BOTH,SCRIPT,MRI>"absolute"                  { RTOKEN(ABSOLUTE); }
 351
 352 <COMMAND>{CMDFILENAMECHAR1}{CMDFILENAMECHAR}*   {
 353                                  yylval.name = buystring(yytext);
 354                                   return NAME;
 355                                 }
 356
 357
 358 <MRI>{FILENAMECHAR1}{NOCFILENAMECHAR}*  {
 359 /* Filename without commas, needed to parse mri stuff */
 360                                  yylval.name = buystring(yytext);
 361                                   return NAME;
 362                                 }
 363
 364
 365 <BOTH,EXPRESSION>{FILENAMECHAR1}{FILENAMECHAR}* {
 366                                  yylval.name = buystring(yytext);
 367                                   return NAME;
 368                                 }
 369 <SCRIPT,COMMAND>{FILENAMECHAR}* { yylval.name = buystring(yytext);
 370                                   return NAME;
 371                                 }
 372
 373 <EXPRESSION,BOTH,COMMAND,SCRIPT>"\""[^\"]*"\"" {
 374                                         /* No matter the state, quotes
 375                                            give what's inside */
 376                                         yylval.name = buystring(yytext+1);
 377                                         yylval.name[yyleng-2] = 0;
 378                                         return NAME;
 379                                 }
 380 <BOTH,SCRIPT,EXPRESSION>"\n"            { lineno++;}
 381 <MRI,COMMAND,BOTH,SCRIPT,EXPRESSION>[ \t]
 382
 383 <<EOF>> {
 384   extern char *ldfile_input_filename;
 385   include_stack_ptr--;
 386
 387   if (include_stack_ptr == 0)
 388   {
 389     yyterminate();
 390   }
 391   else
 392   {
 393     yy_switch_to_buffer(include_stack[include_stack_ptr]);
 394
 395   }
 396   if (include_stack_ptr==1)
 397   {
 398     BEGIN(COMMAND);
 399   }
 400   else
 401   {
 402     BEGIN(SCRIPT);
 403     ldfile_input_filename = file_name_stack[include_stack_ptr-1];
 404   }
 405
 406   return END;
 407 }
 408
 409 %%
 410
 411 void
 412 lex_push_file (file, name)
 413      FILE *file;
 414      char *name;
 415 {
 416   if (include_stack_ptr >= MAX_INCLUDE_DEPTH)
 417   {
 418     einfo("%F:includes nested too deeply");
 419   }
 420   file_name_stack[include_stack_ptr] = name;
 421   include_stack[include_stack_ptr] = YY_CURRENT_BUFFER;
 422
 423   include_stack_ptr++;
 424   yyin = file;
 425   yy_switch_to_buffer(yy_create_buffer(yyin, YY_BUF_SIZE));
 426
 427   BEGIN(SCRIPT);
 428 }
 429
 430 YY_BUFFER_STATE
 431 yy_create_string_buffer (string,  size)
 432      CONST char *string;
 433      int size;
 434 {
 435   YY_BUFFER_STATE b;
 436
 437   b = (YY_BUFFER_STATE) malloc( sizeof( struct yy_buffer_state ) );
 438   b->yy_input_file = 0;
 439
 440   if ( ! b )
 441    YY_FATAL_ERROR( "out of dynamic memory in yy_create_buffer()" );
 442
 443   b->yy_buf_size = size;
 444
 445   /* yy_ch_buf has to be 2 characters longer than the size given because
 446    * we need to put in 2 end-of-buffer characters.
 447    */
 448   b->yy_ch_buf = (YY_CHAR *) malloc( (unsigned) (b->yy_buf_size + 3) );
 449
 450   if ( ! b->yy_ch_buf )
 451    YY_FATAL_ERROR( "out of dynamic memory in yy_create_buffer()" );
 452
 453
 454   b->yy_ch_buf[0] = '\n';
 455   strcpy(b->yy_ch_buf+1,  string);
 456   b->yy_ch_buf[size+1] = YY_END_OF_BUFFER_CHAR;
 457   b->yy_ch_buf[size+2] = YY_END_OF_BUFFER_CHAR;
 458     b->yy_n_chars = size+1;
 459   b->yy_buf_pos = &b->yy_ch_buf[1];
 460
 461   b->yy_eof_status = EOF_NOT_SEEN;
 462
 463   return ( b );
 464 }
 465
 466
 467
 468 void
 469 lex_redirect (string)
 470      CONST  char *string;
 471 {
 472   YY_BUFFER_STATE tmp;
 473
 474   int len = strlen(string);
 475   yy_init = 0  ;
 476   if (include_stack_ptr >= MAX_INCLUDE_DEPTH)
 477   {
 478     einfo("%F: macros nested too deeply");
 479   }
 480   file_name_stack[include_stack_ptr] = "redirect";
 481   include_stack[include_stack_ptr] = YY_CURRENT_BUFFER;
 482   include_stack_ptr++;
 483   tmp =   yy_create_string_buffer(string, len);
 484
 485   yy_switch_to_buffer(tmp);
 486   BEGIN(COMMAND);
 487   yyout = stdout;
 488 }
 489
 490 int state_stack[20];
 491 int *state_stack_p = state_stack;
 492
 493 void
 494 ldlex_script ()
 495 {
 496   *(state_stack_p)++ = yy_start;
 497
 498   BEGIN(SCRIPT);
 499 }
 500
 501
 502 void
 503 ldlex_mri_script ()
 504 {
 505   *(state_stack_p)++ = yy_start;
 506   BEGIN(MRI);
 507 }
 508
 509 void
 510 ldlex_defsym ()
 511 {
 512   *(state_stack_p)++ = yy_start;
 513   BEGIN(DEFSYMEXP);
 514 }
 515
 516 void
 517 ldlex_expression ()
 518 {
 519   *(state_stack_p)++ = yy_start;
 520   BEGIN(EXPRESSION);
 521
 522 }
 523 void
 524 ldlex_both ()
 525 {
 526   *(state_stack_p)++ = yy_start;
 527   BEGIN(BOTH);
 528 }
 529 void
 530 ldlex_command ()
 531 {
 532   *(state_stack_p)++ = yy_start;
 533   BEGIN(COMMAND);
 534 }
 535
 536 void
 537 ldlex_popstate ()
 538 {
 539   yy_start = *(--state_stack_p);
 540 }
 541
 542 yy_input(buf, result, max_size)
 543 char *buf;
 544 int *result;
 545 int max_size;
 546 {
 547   *result = 0;
 548   if (yy_current_buffer->yy_input_file)
 549   {
 550     if (yyin)
 551      if ( (*result = read( fileno(yyin), (char *) buf, max_size )) < 0 )
 552       YY_FATAL_ERROR( "read() in flex scanner failed" );
 553   }
 554 }
 555
 556 static
 557 comment()
 558 {
 559   int c;
 560   while (1)
 561   {
 562     c = input();
 563     while (c !='*' && c != EOF)
 564     {
 565       if (c == '\n') lineno++;
 566       c = input();
 567     }
 568
 569
 570     if (c == '*')
 571     {
 572       c = input();
 573       while ( c == '*')
 574        c = input();
 575       if ( c == '/' )
 576        break;                   /* found the end */
 577     }
 578
 579     if ( c == EOF )
 580     {
 581       einfo( "%F%P :EOF in comment");
 582       break;
 583     }
 584   }
 585 }