gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004,
   3 dnl 2005, 2006, 2007, 2008
   4 dnl Free Software Foundation, Inc.
   5 dnl
   6 dnl This file is part of GDB.
   7 dnl
   8 dnl This program is free software; you can redistribute it and/or modify
   9 dnl it under the terms of the GNU General Public License as published by
  10 dnl the Free Software Foundation; either version 3 of the License, or
  11 dnl (at your option) any later version.
  12 dnl
  13 dnl This program is distributed in the hope that it will be useful,
  14 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 dnl GNU General Public License for more details.
  17 dnl
  18 dnl You should have received a copy of the GNU General Public License
  19 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 dnl Process this file with autoconf to produce a configure script.
  22
  23 AC_PREREQ(2.59)dnl
  24 AC_INIT(main.c)
  25 AC_CONFIG_HEADER(config.h:config.in)
  26 AM_MAINTAINER_MODE
  27
  28 AC_PROG_CC
  29 AC_GNU_SOURCE
  30 AC_AIX
  31 AC_ISC_POSIX
  32 gl_EARLY
  33 AM_PROG_CC_STDC
  34
  35 AC_CONFIG_AUX_DIR(..)
  36 AC_CANONICAL_SYSTEM
  37
  38 dnl List of object files and targets accumulated by configure.
  39
  40 CONFIG_OBS=
  41 CONFIG_DEPS=
  42 CONFIG_SRCS=
  43 ENABLE_CFLAGS=
  44
  45 CONFIG_ALL=
  46 CONFIG_CLEAN=
  47 CONFIG_INSTALL=
  48 CONFIG_UNINSTALL=
  49
  50 dnl Set up for gettext.
  51 ZW_GNU_GETTEXT_SISTER_DIR
  52
  53 localedir='${datadir}/locale'
  54 AC_SUBST(localedir)
  55
  56 if test x"$USE_NLS" = xyes; then
  57    CONFIG_ALL="$CONFIG_ALL all-po"
  58    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  59    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  60    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  61 fi
  62
  63 gl_INIT
  64
  65 PACKAGE=gdb
  66 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  67 AC_SUBST(PACKAGE)
  68
  69 # GDB does not use automake, but gnulib does.  This line lets us
  70 # generate its Makefile.in.
  71 AM_INIT_AUTOMAKE(gdb, UNUSED-VERSION, [no-define])
  72
  73 debugdir=${libdir}/debug
  74
  75 AC_ARG_WITH(separate-debug-dir,
  76 [  --with-separate-debug-dir=path   Look for global separate debug info in this path [LIBDIR/debug]],
  77 [debugdir="${withval}"])
  78
  79 AC_DEFINE_DIR(DEBUGDIR, debugdir,
  80               [Global directory for separate debug files. ])
  81 #AC_DEFINE_UNQUOTED(DEBUGDIR, "$debugdir"),
  82
  83 if test "x$exec_prefix" = xNONE || test "x$exec_prefix" = 'x${prefix}'; then
  84   if test "x$prefix" = xNONE; then
  85     test_prefix=/usr/local
  86   else
  87     test_prefix=$prefix
  88   fi
  89 else
  90   test_prefix=$exec_prefix
  91 fi
  92 case ${debugdir} in
  93 "${test_prefix}"|"${test_prefix}/"*|\
  94 '${exec_prefix}'|'${exec_prefix}/'*)
  95   AC_DEFINE(DEBUGDIR_RELOCATABLE, 1, [Define if the debug directory should be relocated when GDB is moved.])
  96   ;;
  97 esac
  98
  99 AC_CONFIG_SUBDIRS(doc testsuite)
 100
 101 # Check whether to support alternative target configurations
 102 AC_ARG_ENABLE(targets,
 103 [  --enable-targets        alternative target configurations],
 104 [case "${enableval}" in
 105   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 106             ;;
 107   no)       enable_targets= ;;
 108   *)        enable_targets=$enableval ;;
 109 esac])
 110
 111 # Check whether to enable 64-bit support on 32-bit hosts
 112 AC_ARG_ENABLE(64-bit-bfd,
 113 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
 114 [case "${enableval}" in
 115   yes)  want64=true  ;;
 116   no)   want64=false ;;
 117   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 118 esac],[want64=false])dnl
 119
 120 # Provide defaults for some variables set by the per-host and per-target
 121 # configuration.
 122 gdb_host_obs=posix-hdep.o
 123
 124 if test "${target}" = "${host}"; then
 125   gdb_native=yes
 126 else
 127   gdb_native=no
 128 fi
 129
 130 . $srcdir/configure.host
 131
 132 # Accumulate some settings from configure.tgt over all enabled targets
 133
 134 TARGET_OBS=
 135 all_targets=
 136
 137 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 138 do
 139   if test "$targ_alias" = "all"; then
 140     all_targets=true
 141   else
 142     # Canonicalize the secondary target names.
 143     result=`$ac_config_sub $targ_alias 2>/dev/null`
 144     if test -n "$result"; then
 145         targ=$result
 146     else
 147         targ=$targ_alias
 148     fi
 149
 150     . ${srcdir}/configure.tgt
 151
 152     # Target-specific object files
 153     for i in ${gdb_target_obs}; do
 154         case " $TARGET_OBS " in
 155         *" ${i} "*) ;;
 156         *)
 157           TARGET_OBS="$TARGET_OBS ${i}"
 158           ;;
 159         esac
 160     done
 161
 162     # Check whether this target needs 64-bit CORE_ADDR
 163     if test x${want64} = xfalse; then
 164       . ${srcdir}/../bfd/config.bfd
 165     fi
 166   fi
 167 done
 168
 169 if test x${all_targets} = xtrue; then
 170
 171   # We want all 64-bit targets if we either:
 172   #  - run on a 64-bit host  or
 173   #  - already require 64-bit support for some other target  or
 174   #  - the --enable-64-bit-bfd option was supplied
 175   # Otherwise we only support all 32-bit targets.
 176   #
 177   # NOTE: This test must be in sync with the corresponding
 178   #       tests in BFD!
 179
 180   if test x${want64} = xfalse; then
 181     AC_CHECK_SIZEOF(long)
 182     if test "x${ac_cv_sizeof_long}" = "x8"; then
 183       want64=true
 184     fi
 185   fi
 186   if test x${want64} = xtrue; then
 187     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 188   else
 189     TARGET_OBS='$(ALL_TARGET_OBS)'
 190   fi
 191 fi
 192
 193 AC_SUBST(TARGET_OBS)
 194
 195 # For other settings, only the main target counts.
 196 gdb_sim=
 197 gdb_osabi=
 198 build_gdbserver=
 199 targ=$target; . ${srcdir}/configure.tgt
 200
 201 # Fetch the default architecture and default target vector from BFD.
 202 targ=$target; . $srcdir/../bfd/config.bfd
 203
 204 # We only want the first architecture, so strip off the others if
 205 # there is more than one.
 206 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 207
 208 if test "x$targ_archs" != x; then
 209   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 210     [Define to BFD's default architecture. ])
 211 fi
 212 if test "x$targ_defvec" != x; then
 213   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 214     [Define to BFD's default target vector. ])
 215 fi
 216
 217 # The CLI cannot be disabled yet, but may be in the future.
 218
 219 # Enable CLI.
 220 AC_ARG_ENABLE(gdbcli,
 221 [  --disable-gdbcli        disable command-line interface (CLI)],
 222   [case $enableval in
 223     yes)
 224       ;;
 225     no)
 226       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 227     *)
 228       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 229   esac],
 230   [enable_gdbcli=yes])
 231 if test x"$enable_gdbcli" = xyes; then
 232   if test -d $srcdir/cli; then
 233     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 234     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 235     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 236     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 237   fi
 238 fi
 239
 240 # Enable MI.
 241 AC_ARG_ENABLE(gdbmi,
 242 [  --disable-gdbmi         disable machine-interface (MI)],
 243   [case $enableval in
 244     yes | no)
 245       ;;
 246     *)
 247       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 248   esac],
 249   [enable_gdbmi=yes])
 250 if test x"$enable_gdbmi" = xyes; then
 251   if test -d $srcdir/mi; then
 252     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 253     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 254     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 255     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 256   fi
 257 fi
 258
 259 # Enable TUI.
 260 AC_ARG_ENABLE(tui,
 261 [  --enable-tui            enable full-screen terminal user interface (TUI)],
 262   [case $enableval in
 263     yes | no)
 264       ;;
 265     *)
 266       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 267   esac],enable_tui=yes)
 268
 269 # Enable gdbtk.
 270 AC_ARG_ENABLE(gdbtk,
 271 [  --enable-gdbtk          enable gdbtk graphical user interface (GUI)],
 272   [case $enableval in
 273     yes | no)
 274       ;;
 275     *)
 276       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 277   esac],
 278   [if test -d $srcdir/gdbtk -a -d $srcdir/../itcl; then
 279     enable_gdbtk=yes
 280   else
 281     enable_gdbtk=no
 282   fi])
 283 # We unconditionally disable gdbtk tests on selected platforms.
 284 case $host_os in
 285   go32* | windows*)
 286     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 287     enable_gdbtk=no ;;
 288 esac
 289
 290 # Libunwind support.
 291 AC_ARG_WITH(libunwind,
 292 [  --with-libunwind            Use libunwind frame unwinding support],
 293 [case "${withval}" in
 294   yes)  enable_libunwind=yes ;;
 295   no)   enable_libunwind=no ;;
 296   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-libunwind option) ;;
 297 esac],[
 298   AC_CHECK_HEADERS(libunwind.h)
 299   AC_CHECK_HEADERS(libunwind-ia64.h)
 300   if test x"$ac_cv_header_libunwind_h" = xyes -a x"$ac_cv_header_libunwind_ia64_h" = xyes; then
 301     enable_libunwind=yes;
 302   fi
 303 ])
 304
 305 if test x"$enable_libunwind" = xyes; then
 306   AC_CHECK_HEADERS(libunwind.h)
 307   AC_CHECK_HEADERS(libunwind-ia64.h)
 308   AC_DEFINE(HAVE_LIBUNWIND, 1, [Define if libunwind library is being used.])
 309   CONFIG_OBS="$CONFIG_OBS libunwind-frame.o"
 310   CONFIG_DEPS="$CONFIG_DEPS libunwind-frame.o"
 311   CONFIG_SRCS="$CONFIG_SRCS libunwind-frame.c"
 312 fi
 313
 314 # Profiling support.
 315 AC_ARG_ENABLE(profiling,
 316 [  --enable-profiling      enable profiling of GDB],
 317   [case $enableval in
 318     yes | no)
 319       ;;
 320     *)
 321       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 322   esac],
 323  [enable_profiling=no])
 324
 325 AC_CHECK_FUNCS(monstartup _mcleanup)
 326 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 327 [AC_TRY_LINK(
 328 [#include <stdlib.h>
 329 extern char _etext;
 330 ],
 331 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 332 if test $ac_cv_var__etext = yes; then
 333   AC_DEFINE(HAVE__ETEXT, 1,
 334             [Define to 1 if your system has the _etext variable. ])
 335 fi
 336 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 337 [AC_TRY_LINK(
 338 [#include <stdlib.h>
 339 extern char etext;
 340 ],
 341 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 342 if test $ac_cv_var_etext = yes; then
 343   AC_DEFINE(HAVE_ETEXT, 1,
 344             [Define to 1 if your system has the etext variable. ])
 345 fi
 346 if test "$enable_profiling" = yes ; then
 347   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 348     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 349   fi
 350   PROFILE_CFLAGS=-pg
 351   OLD_CFLAGS="$CFLAGS"
 352   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 353
 354   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 355     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 356      ac_cv_cc_supports_pg=no)])
 357
 358   if test $ac_cv_cc_supports_pg = no; then
 359     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 360   fi
 361
 362   CFLAGS="$OLD_CFLAGS"
 363 fi
 364
 365 # --------------------- #
 366 # Checks for programs.  #
 367 # --------------------- #
 368
 369 AC_PROG_AWK
 370 AC_PROG_INSTALL
 371 AC_PROG_LN_S
 372 AC_PROG_RANLIB
 373 AC_PROG_YACC
 374
 375 AC_CHECK_TOOL(AR, ar)
 376 AC_CHECK_TOOL(DLLTOOL, dlltool)
 377 AC_CHECK_TOOL(WINDRES, windres)
 378
 379 # Needed for GNU/Hurd.
 380 AC_CHECK_TOOL(MIG, mig)
 381
 382 # ---------------------- #
 383 # Checks for libraries.  #
 384 # ---------------------- #
 385
 386 # We might need to link with -lm; most simulators need it.
 387 AC_CHECK_LIB(m, main)
 388
 389 # We need to link with -lw to get `wctype' on Solaris before Solaris
 390 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 391 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 392 # is known to have this problem).  Therefore we avoid libw if we can.
 393 AC_CHECK_FUNC(wctype, [],
 394   [AC_CHECK_LIB(w, wctype)])
 395
 396 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 397 AC_SEARCH_LIBS(gethostbyname, nsl)
 398
 399 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 400 AC_SEARCH_LIBS(socketpair, socket)
 401
 402 # Link in zlib if we can.  This allows us to read compressed debug sections.
 403 AC_SEARCH_LIBS(zlibVersion, z, [AC_CHECK_HEADERS(zlib.h)])
 404
 405 # For the TUI, we need enhanced curses functionality.
 406 #
 407 # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 408 # curses library because the latter might not provide all the
 409 # functionality we need.  However, this leads to problems on systems
 410 # where the linker searches /usr/local/lib, but the compiler doesn't
 411 # search /usr/local/include, if ncurses is installed in /usr/local.  A
 412 # default installation of ncurses on alpha*-dec-osf* will lead to such
 413 # a situation.
 414 AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
 415
 416 # On HP/UX we may need libxpdl for dlgetmodinfo (used by solib-pa64.c).
 417 AC_SEARCH_LIBS(dlgetmodinfo, [dl xpdl])
 418
 419 # Since GDB uses Readline, we need termcap functionality.  In many
 420 # cases this will be provided by the curses library, but some systems
 421 # have a seperate termcap library, or no curses library at all.
 422
 423 case $host_os in
 424   cygwin*)
 425     if test -d $srcdir/libtermcap; then
 426       LIBS="../libtermcap/libtermcap.a $LIBS"
 427       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 428     fi ;;
 429   go32* | *djgpp*)
 430     ac_cv_search_tgetent="none required"
 431     ;;
 432   *mingw32*)
 433     ac_cv_search_tgetent="none required"
 434     CONFIG_OBS="$CONFIG_OBS win32-termcap.o"
 435     ;;
 436 esac
 437
 438 # These are the libraries checked by Readline.
 439 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
 440
 441 if test "$ac_cv_search_tgetent" = no; then
 442   AC_MSG_ERROR([no termcap library found])
 443 fi
 444
 445 AC_ARG_WITH([system-readline],
 446   [AS_HELP_STRING([--with-system-readline],
 447                   [use installed readline library])])
 448
 449 if test "$with_system_readline" = yes; then
 450   READLINE=-lreadline
 451   READLINE_DEPS=
 452   READLINE_CFLAGS=
 453 else
 454   READLINE='$(READLINE_DIR)/libreadline.a'
 455   READLINE_DEPS='$(READLINE)'
 456   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 457 fi
 458 AC_SUBST(READLINE)
 459 AC_SUBST(READLINE_DEPS)
 460 AC_SUBST(READLINE_CFLAGS)
 461
 462 AC_ARG_WITH(expat,
 463   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 464   [], [with_expat=auto])
 465 AC_MSG_CHECKING([whether to use expat])
 466 AC_MSG_RESULT([$with_expat])
 467
 468 if test "${with_expat}" = no; then
 469   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 470   HAVE_LIBEXPAT=no
 471 else
 472   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 473                         [XML_Parser p = XML_ParserCreate (0);])
 474   if test "$HAVE_LIBEXPAT" != yes; then
 475     if test "$with_expat" = yes; then
 476       AC_MSG_ERROR([expat is missing or unusable])
 477     else
 478       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 479     fi
 480   else
 481     save_LIBS=$LIBS
 482     LIBS="$LIBS $LIBEXPAT"
 483     AC_CHECK_FUNCS(XML_StopParser)
 484     LIBS=$save_LIBS
 485   fi
 486 fi
 487
 488 # ------------------------- #
 489 # Checks for header files.  #
 490 # ------------------------- #
 491
 492 AC_HEADER_DIRENT
 493 AC_HEADER_STAT
 494 AC_HEADER_STDC
 495 AC_CHECK_HEADERS(nlist.h)
 496 AC_CHECK_HEADERS(link.h, [], [],
 497 [#if HAVE_SYS_TYPES_H
 498 # include <sys/types.h>
 499 #endif
 500 #if HAVE_NLIST_H
 501 # include <nlist.h>
 502 #endif
 503 ])
 504 AC_CHECK_HEADERS(machine/reg.h)
 505 AC_CHECK_HEADERS(poll.h sys/poll.h)
 506 AC_CHECK_HEADERS(proc_service.h thread_db.h gnu/libc-version.h)
 507 AC_CHECK_HEADERS(signal.h)
 508 AC_CHECK_HEADERS(stddef.h)
 509 AC_CHECK_HEADERS(stdlib.h)
 510 AC_CHECK_HEADERS(stdint.h)
 511 AC_CHECK_HEADERS(string.h memory.h strings.h)
 512 AC_CHECK_HEADERS(sys/fault.h)
 513 AC_CHECK_HEADERS(sys/file.h)
 514 AC_CHECK_HEADERS(sys/filio.h)
 515 AC_CHECK_HEADERS(sys/ioctl.h)
 516 AC_CHECK_HEADERS(sys/param.h)
 517 AC_CHECK_HEADERS(sys/resource.h)
 518 AC_CHECK_HEADERS(sys/proc.h, [], [],
 519 [#if HAVE_SYS_PARAM_H
 520 # include <sys/param.h>
 521 #endif
 522 ])
 523 AC_CHECK_HEADERS(sys/procfs.h)
 524 AC_CHECK_HEADERS(sys/ptrace.h ptrace.h)
 525 AC_CHECK_HEADERS(sys/reg.h sys/debugreg.h)
 526 AC_CHECK_HEADERS(sys/select.h)
 527 AC_CHECK_HEADERS(sys/syscall.h)
 528 AC_CHECK_HEADERS(sys/types.h)
 529 AC_CHECK_HEADERS(sys/user.h, [], [],
 530 [#if HAVE_SYS_PARAM_H
 531 # include <sys/param.h>
 532 #endif
 533 ])
 534 AC_CHECK_HEADERS(sys/wait.h wait.h)
 535 AC_CHECK_HEADERS(termios.h termio.h sgtty.h)
 536 AC_CHECK_HEADERS(unistd.h)
 537
 538 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
 539 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
 540 # think that we don't have <curses.h> if we're using GCC.
 541 case $host_os in
 542   solaris2.[[789]])
 543     if test "$GCC" = yes; then
 544       AC_DEFINE(_MSE_INT_H, 1,
 545         [Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
 546    Solaris 2.[789] when using GCC. ])
 547     fi ;;
 548 esac
 549 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h)
 550 AC_CHECK_HEADERS(ncurses/term.h)
 551 AC_CHECK_HEADERS(term.h, [], [],
 552 [#if HAVE_CURSES_H
 553 # include <curses.h>
 554 #endif
 555 ])
 556
 557 # Check for HP/UX 64-bit shared library support
 558 AC_CHECK_HEADERS(elf_hp.h)
 559
 560 # FIXME: kettenis/20030102: In most cases we include these
 561 # unconditionally, so what's the point in checking these?
 562 AC_CHECK_HEADERS(ctype.h time.h)
 563
 564 # Create a header we can use portably to get the standard integer types.
 565 GCC_HEADER_STDINT(gdb_stdint.h)
 566
 567 # ------------------------- #
 568 # Checks for declarations.  #
 569 # ------------------------- #
 570
 571 AC_CHECK_DECLS([free, malloc, realloc])
 572 AC_CHECK_DECLS([strerror, strstr])
 573 AC_CHECK_DECLS([getopt, snprintf, vsnprintf])
 574
 575 # ----------------------- #
 576 # Checks for structures.  #
 577 # ----------------------- #
 578
 579 AC_CHECK_MEMBERS([struct stat.st_blocks])
 580 AC_CHECK_MEMBERS([struct stat.st_blksize])
 581
 582 # ------------------ #
 583 # Checks for types.  #
 584 # ------------------ #
 585
 586 AC_TYPE_SIGNAL
 587 AC_CHECK_TYPES(socklen_t, [], [],
 588 [#include <sys/types.h>
 589 #include <sys/socket.h>
 590 ])
 591 AC_CHECK_TYPES(uintptr_t, [], [], [#include <stdint.h>])
 592
 593 # ------------------------------------- #
 594 # Checks for compiler characteristics.  #
 595 # ------------------------------------- #
 596
 597 AC_C_CONST
 598 AC_C_INLINE
 599 AC_C_BIGENDIAN
 600
 601 # ------------------------------ #
 602 # Checks for library functions.  #
 603 # ------------------------------ #
 604
 605 AC_FUNC_ALLOCA
 606 AC_FUNC_MMAP
 607 AC_FUNC_VFORK
 608 AC_CHECK_FUNCS(canonicalize_file_name realpath)
 609 AC_CHECK_FUNCS(getrusage)
 610 AC_CHECK_FUNCS(getuid getgid)
 611 AC_CHECK_FUNCS(poll)
 612 AC_CHECK_FUNCS(pread64)
 613 AC_CHECK_FUNCS(sbrk)
 614 AC_CHECK_FUNCS(setpgid setpgrp setsid)
 615 AC_CHECK_FUNCS(sigaction sigprocmask sigsetmask)
 616 AC_CHECK_FUNCS(socketpair)
 617 AC_CHECK_FUNCS(syscall)
 618 AC_CHECK_FUNCS(ttrace)
 619 AC_CHECK_FUNCS(wborder)
 620
 621 # Check the return and argument types of ptrace.  No canned test for
 622 # this, so roll our own.
 623 gdb_ptrace_headers='
 624 #if HAVE_SYS_TYPES_H
 625 # include <sys/types.h>
 626 #endif
 627 #if HAVE_SYS_PTRACE_H
 628 # include <sys/ptrace.h>
 629 #endif
 630 #if HAVE_UNISTD_H
 631 # include <unistd.h>
 632 #endif
 633 '
 634 # There is no point in checking if we don't have a prototype.
 635 AC_CHECK_DECLS(ptrace, [], [
 636   : ${gdb_cv_func_ptrace_ret='int'}
 637   : ${gdb_cv_func_ptrace_args='int,int,long,long'}
 638 ], $gdb_ptrace_headers)
 639 # Check return type.
 640 AC_CACHE_CHECK([return type of ptrace], gdb_cv_func_ptrace_ret,
 641   AC_TRY_COMPILE($gdb_ptrace_headers,
 642     [extern int ptrace ();],
 643     gdb_cv_func_ptrace_ret='int',
 644     gdb_cv_func_ptrace_ret='long'))
 645 AC_DEFINE_UNQUOTED(PTRACE_TYPE_RET, $gdb_cv_func_ptrace_ret,
 646   [Define as the return type of ptrace.])
 647 # Check argument types.
 648 AC_CACHE_CHECK([types of arguments for ptrace], gdb_cv_func_ptrace_args, [
 649 for gdb_arg1 in 'int' 'long'; do
 650  for gdb_arg2 in 'pid_t' 'int' 'long'; do
 651   for gdb_arg3 in 'int *' 'caddr_t' 'int' 'long' 'void *'; do
 652    for gdb_arg4 in 'int' 'long'; do
 653      AC_TRY_COMPILE($gdb_ptrace_headers, [
 654 extern $gdb_cv_func_ptrace_ret
 655   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4);
 656 ], [gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4";
 657     break 4;])
 658     for gdb_arg5 in 'int *' 'int' 'long'; do
 659      AC_TRY_COMPILE($gdb_ptrace_headers, [
 660 extern $gdb_cv_func_ptrace_ret
 661   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4, $gdb_arg5);
 662 ], [
 663 gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4,$gdb_arg5";
 664     break 5;])
 665     done
 666    done
 667   done
 668  done
 669 done
 670 # Provide a safe default value.
 671 : ${gdb_cv_func_ptrace_args='int,int,long,long'}
 672 ])
 673 ac_save_IFS=$IFS; IFS=','
 674 set dummy `echo "$gdb_cv_func_ptrace_args" | sed 's/\*/\*/g'`
 675 IFS=$ac_save_IFS
 676 shift
 677 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG3, $[3],
 678   [Define to the type of arg 3 for ptrace.])
 679 if test -n "$[5]"; then
 680   AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG5, $[5],
 681     [Define to the type of arg 5 for ptrace.])
 682 fi
 683
 684 dnl AC_FUNC_SETPGRP does not work when cross compiling
 685 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
 686 if test "$cross_compiling" = no; then
 687   AC_FUNC_SETPGRP
 688 else
 689   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
 690     [AC_TRY_COMPILE([
 691 #include <unistd.h>
 692 ], [
 693   if (setpgrp(1,1) == -1)
 694     exit (0);
 695   else
 696     exit (1);
 697 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
 698 if test $ac_cv_func_setpgrp_void = yes; then
 699   AC_DEFINE(SETPGRP_VOID, 1)
 700 fi
 701 fi
 702
 703 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
 704 # since sigsetjmp might only be defined as a macro.
 705 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
 706 [AC_TRY_COMPILE([
 707 #include <setjmp.h>
 708 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
 709 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
 710 if test $gdb_cv_func_sigsetjmp = yes; then
 711   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
 712 fi
 713
 714 # Assume we'll default to using the included libiberty regex.
 715 gdb_use_included_regex=yes
 716
 717 # However, if the system regex is GNU regex, then default to *not*
 718 # using the included regex.
 719 AC_CACHE_CHECK(
 720   [for GNU regex],
 721   [gdb_cv_have_gnu_regex],
 722   [AC_TRY_COMPILE(
 723     [#include <gnu-versions.h>],
 724     [#define REGEX_INTERFACE_VERSION 1
 725 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
 726 # error "Version mismatch"
 727 #endif],
 728     gdb_cv_have_gnu_regex=yes,
 729     gdb_cv_have_gnu_regex=no)])
 730 if test $gdb_cv_have_gnu_regex = yes; then
 731   gdb_use_included_regex=no
 732 fi
 733
 734 AC_ARG_WITH(included-regex,
 735   [  --without-included-regex don't use included regex; this is the default
 736                           on systems with version 2 of the GNU C library
 737                           (use with caution on other system)],
 738   gdb_with_regex=$withval,
 739   gdb_with_regex=$gdb_use_included_regex)
 740 if test "$gdb_with_regex" = yes; then
 741   AC_DEFINE(USE_INCLUDED_REGEX, 1,
 742     [Define to 1 if the regex included in libiberty should be used.])
 743 fi
 744
 745 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
 746 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
 747 [#include <sys/param.h>
 748 #include <sys/proc.h>
 749 ])
 750
 751 # See if <sys/lwp.h> defines `struct lwp`.
 752 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
 753 [AC_TRY_COMPILE([#include <sys/param.h>
 754 #include <sys/lwp.h>], [struct lwp l;],
 755 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
 756 if test $gdb_cv_struct_lwp = yes; then
 757   AC_DEFINE(HAVE_STRUCT_LWP, 1,
 758             [Define to 1 if your system has struct lwp.])
 759 fi
 760
 761 # See if <machine/reg.h> degines `struct reg'.
 762 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
 763 [AC_TRY_COMPILE([#include <sys/types.h>
 764 #include <machine/reg.h>], [struct reg r;],
 765 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
 766 if test $gdb_cv_struct_reg = yes; then
 767   AC_DEFINE(HAVE_STRUCT_REG, 1,
 768             [Define to 1 if your system has struct reg in <machine/reg.h>.])
 769 fi
 770
 771 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
 772 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
 773 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
 774                  [#include <machine/reg.h>])
 775
 776 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
 777 AC_MSG_CHECKING(for PTRACE_GETREGS)
 778 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
 779 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 780                 [PTRACE_GETREGS;],
 781                 [gdb_cv_have_ptrace_getregs=yes],
 782                 [gdb_cv_have_ptrace_getregs=no])])
 783 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
 784 if test $gdb_cv_have_ptrace_getregs = yes; then
 785   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
 786   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
 787 fi
 788
 789 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
 790 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
 791 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
 792 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 793                 [PTRACE_GETFPXREGS;],
 794                 [gdb_cv_have_ptrace_getfpxregs=yes],
 795                 [gdb_cv_have_ptrace_getfpxregs=no])])
 796 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
 797 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
 798   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
 799   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
 800 fi
 801
 802 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
 803 AC_MSG_CHECKING(for PT_GETDBREGS)
 804 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
 805 [AC_TRY_COMPILE([#include <sys/types.h>
 806 #include <sys/ptrace.h>],
 807                 [PT_GETDBREGS;],
 808                 [gdb_cv_have_pt_getdbregs=yes],
 809                 [gdb_cv_have_pt_getdbregs=no])])
 810 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
 811 if test $gdb_cv_have_pt_getdbregs = yes; then
 812   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
 813   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
 814 fi
 815
 816 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
 817 AC_MSG_CHECKING(for PT_GETXMMREGS)
 818 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
 819 [AC_TRY_COMPILE([#include <sys/types.h>
 820 #include <sys/ptrace.h>],
 821                 [PT_GETXMMREGS;],
 822                 [gdb_cv_have_pt_getxmmregs=yes],
 823                 [gdb_cv_have_pt_getxmmregs=no])])
 824 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
 825 if test $gdb_cv_have_pt_getxmmregs = yes; then
 826   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
 827   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
 828 fi
 829
 830 # Detect which type of /proc is in use, such as for Unixware or Solaris.
 831
 832 if test "${target}" = "${host}"; then
 833   case "${host}" in
 834   *-*-unixware* | *-*-sysv4.2* | *-*-sysv5* | *-*-interix* )
 835       AC_DEFINE(NEW_PROC_API, 1,
 836       [Define if you want to use new multi-fd /proc interface
 837        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
 838       ;;
 839   *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]]*)
 840       AC_DEFINE(NEW_PROC_API, 1,
 841       [Define if you want to use new multi-fd /proc interface
 842        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
 843       ;;
 844   mips-sgi-irix5*)
 845       # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5.
 846       AC_DEFINE([_KMEMUSER], 1,
 847       [Define to 1 so <sys/proc.h> gets a definition of anon_hdl.  Works
 848        around a <sys/proc.h> problem on IRIX 5.])
 849       ;;
 850   esac
 851 fi
 852
 853 if test "$ac_cv_header_sys_procfs_h" = yes; then
 854   BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
 855   BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
 856   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
 857   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
 858   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
 859   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
 860   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
 861   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t)
 862   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
 863   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
 864   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
 865   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
 866   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
 867   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
 868
 869
 870   dnl Check for broken prfpregset_t type
 871
 872   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
 873   dnl prfpregset_t type (it's a typedef for the pointer to a struct
 874   dnl instead of the struct itself).  We detect this here, and work
 875   dnl around it in gdb_proc_service.h.
 876
 877   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
 878     AC_MSG_CHECKING(whether prfpregset_t type is broken)
 879     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
 880       [AC_TRY_RUN([#include <sys/procfs.h>
 881        int main ()
 882        {
 883          if (sizeof (prfpregset_t) == sizeof (void *))
 884            return 1;
 885          return 0;
 886        }],
 887        gdb_cv_prfpregset_t_broken=no,
 888        gdb_cv_prfpregset_t_broken=yes,
 889        gdb_cv_prfpregset_t_broken=yes)])
 890     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
 891     if test $gdb_cv_prfpregset_t_broken = yes; then
 892       AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
 893       [Define if the prfpregset_t type is broken.])
 894     fi
 895   fi
 896
 897   dnl Check for PIOCSET ioctl entry
 898
 899   AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
 900   AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
 901   [AC_TRY_COMPILE([#include <unistd.h>
 902 #include <sys/types.h>
 903 #include <sys/procfs.h>
 904 ], [
 905     int dummy;;
 906     dummy = ioctl(0, PIOCSET, &dummy);
 907   ],
 908   gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
 909   AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
 910   if test $gdb_cv_have_procfs_piocset = yes; then
 911     AC_DEFINE(HAVE_PROCFS_PIOCSET, 1,
 912     [Define if ioctl argument PIOCSET is available.])
 913   fi
 914 fi
 915
 916 dnl For native ports (host == target), check to see what kind of
 917 dnl legacy link.h support is needed.  (See solib-legacy.c.)
 918 if test ${host} = ${target} ; then
 919   dnl Check for struct link_map with l_ members which are indicative
 920   dnl of SVR4-like shared libraries
 921
 922   AC_MSG_CHECKING(for member l_addr in struct link_map)
 923   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_l_members,
 924     [AC_TRY_COMPILE([#include <link.h>],
 925                     [struct link_map lm; (void) lm.l_addr;],
 926                     gdb_cv_have_struct_link_map_with_l_members=yes,
 927                     gdb_cv_have_struct_link_map_with_l_members=no)])
 928   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_l_members)
 929   if test $gdb_cv_have_struct_link_map_with_l_members = yes; then
 930     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_L_MEMBERS,1,
 931     [Define if <link.h> exists and defines struct link_map which has
 932      members with an ``l_'' prefix.  (For Solaris, SVR4, and
 933      SVR4-like systems.)])
 934   fi
 935
 936   dnl Check for struct link_map with lm_ members which are indicative
 937   dnl of SunOS-like shared libraries
 938
 939   AC_MSG_CHECKING(for member lm_addr in struct link_map)
 940   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_lm_members,
 941     [AC_TRY_COMPILE([#include <sys/types.h>
 942 #include <link.h>],
 943                     [struct link_map lm; (void) lm.lm_addr;],
 944                     gdb_cv_have_struct_link_map_with_lm_members=yes,
 945                     gdb_cv_have_struct_link_map_with_lm_members=no)])
 946   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_lm_members)
 947   if test $gdb_cv_have_struct_link_map_with_lm_members = yes; then
 948     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_LM_MEMBERS, 1,
 949     [Define if <link.h> exists and defines struct link_map which has
 950      members with an ``lm_'' prefix.  (For SunOS.)])
 951   fi
 952
 953   dnl Check for struct so_map with som_ members which are found on
 954   dnl some *BSD systems.
 955
 956   AC_MSG_CHECKING(for member som_addr in struct so_map)
 957   AC_CACHE_VAL(gdb_cv_have_struct_so_map_with_som_members,
 958     [AC_TRY_COMPILE([#include <sys/types.h>
 959 #ifdef HAVE_NLIST_H
 960 #include <nlist.h>
 961 #endif
 962 #include <link.h>],
 963                     [struct so_map lm; (void) lm.som_addr;],
 964                     gdb_cv_have_struct_so_map_with_som_members=yes,
 965                     gdb_cv_have_struct_so_map_with_som_members=no)])
 966   AC_MSG_RESULT($gdb_cv_have_struct_so_map_with_som_members)
 967   if test $gdb_cv_have_struct_so_map_with_som_members = yes; then
 968     AC_DEFINE(HAVE_STRUCT_SO_MAP_WITH_SOM_MEMBERS, 1,
 969     [Define if <link.h> exists and defines a struct so_map which has
 970      members with an ``som_'' prefix.  (Found on older *BSD systems.)])
 971   fi
 972
 973   dnl Check for struct link_map32 type, which allows a 64-bit Solaris
 974   dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries.
 975
 976   AC_MSG_CHECKING(for struct link_map32 in sys/link.h)
 977   AC_CACHE_VAL(gdb_cv_have_struct_link_map32,
 978     [AC_TRY_COMPILE([#define _SYSCALL32
 979 #include <sys/link.h>], [struct link_map32 l;],
 980      gdb_cv_have_struct_link_map32=yes,
 981      gdb_cv_have_struct_link_map32=no)])
 982   AC_MSG_RESULT($gdb_cv_have_struct_link_map32)
 983   if test $gdb_cv_have_struct_link_map32 = yes; then
 984     AC_DEFINE(HAVE_STRUCT_LINK_MAP32, 1,
 985     [Define if <sys/link.h> has struct link_map32])
 986     AC_DEFINE(_SYSCALL32, 1,
 987     [Define if <sys/link.h> has link_map32 (solaris sparc-64 target)])
 988   fi
 989 fi
 990
 991 # Check if the compiler supports the `long long' type.
 992
 993 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
 994                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 995 [[extern long long foo;]],
 996 [[switch (foo & 2) { case 0: return 1; }]])],
 997                                   gdb_cv_c_long_long=yes,
 998                                   gdb_cv_c_long_long=no)])
 999 if test $gdb_cv_c_long_long = yes; then
1000   AC_DEFINE(CC_HAS_LONG_LONG, 1,
1001             [Define to 1 if the compiler supports long long.])
1002 fi
1003
1004 # Check if the compiler and runtime support printing long longs.
1005
1006 AC_CACHE_CHECK([for long long support in printf],
1007                gdb_cv_printf_has_long_long,
1008                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1009 [[char buf[32];
1010   long long l = 0;
1011   l = (l << 16) + 0x0123;
1012   l = (l << 16) + 0x4567;
1013   l = (l << 16) + 0x89ab;
1014   l = (l << 16) + 0xcdef;
1015   sprintf (buf, "0x%016llx", l);
1016   return (strcmp ("0x0123456789abcdef", buf));]])],
1017                               gdb_cv_printf_has_long_long=yes,
1018                               gdb_cv_printf_has_long_long=no,
1019                               gdb_cv_printf_has_long_long=no)])
1020 if test $gdb_cv_printf_has_long_long = yes; then
1021   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1022             [Define to 1 if the "%ll" format works to print long longs.])
1023 fi
1024
1025 # Check if the compiler and runtime support printing decfloats.
1026
1027 AC_CACHE_CHECK([for decfloat support in printf],
1028                gdb_cv_printf_has_decfloat,
1029                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1030 [[char buf[64];
1031   _Decimal32 d32 = 1.2345df;
1032   _Decimal64 d64 = 1.2345dd;
1033   _Decimal128 d128 = 1.2345dl;
1034   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1035   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1036                               gdb_cv_printf_has_decfloat=yes,
1037                               gdb_cv_printf_has_decfloat=no,
1038                               gdb_cv_printf_has_decfloat=no)])
1039 if test $gdb_cv_printf_has_decfloat = yes; then
1040   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1041             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1042 fi
1043
1044 # Check if the compiler supports the `long double' type.  We can't use
1045 # AC_C_LONG_DOUBLE because that one does additional checks on the
1046 # constants defined in <float.h> that fail on some systems,
1047 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1048
1049 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1050                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1051                                   gdb_cv_c_long_double=yes,
1052                                   gdb_cv_c_long_double=no)])
1053 if test $gdb_cv_c_long_double = yes; then
1054   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1055            [Define to 1 if the compiler supports long double.])
1056 fi
1057
1058 # Check if the compiler and runtime support printing long doubles.
1059
1060 AC_CACHE_CHECK([for long double support in printf],
1061                gdb_cv_printf_has_long_double,
1062                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1063 [[char buf[16];
1064   long double f = 3.141592653;
1065   sprintf (buf, "%Lg", f);
1066   return (strncmp ("3.14159", buf, 7));]])],
1067                               gdb_cv_printf_has_long_double=yes,
1068                               gdb_cv_printf_has_long_double=no,
1069                               gdb_cv_printf_has_long_double=no)])
1070 if test $gdb_cv_printf_has_long_double = yes; then
1071   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1072             [Define to 1 if the "%Lg" format works to print long doubles.])
1073 fi
1074
1075 # Check if the compiler and runtime support scanning long doubles.
1076
1077 AC_CACHE_CHECK([for long double support in scanf],
1078                gdb_cv_scanf_has_long_double,
1079                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1080 [[#include <stdio.h>]],
1081 [[char *buf = "3.141592653";
1082   long double f = 0;
1083   sscanf (buf, "%Lg", &f);
1084   return !(f > 3.14159 && f < 3.14160);]])],
1085                               gdb_cv_scanf_has_long_double=yes,
1086                               gdb_cv_scanf_has_long_double=no,
1087                               gdb_cv_scanf_has_long_double=no)])
1088 if test $gdb_cv_scanf_has_long_double = yes; then
1089   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1090             [Define to 1 if the "%Lg" format works to scan long doubles.])
1091 fi
1092
1093 case ${host_os} in
1094 aix*)
1095   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1096     SAVE_LDFLAGS=$LDFLAGS
1097
1098     case $GCC in
1099     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1100     *) gdb_cv_bigtoc=-bbigtoc ;;
1101     esac
1102
1103     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1104     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1105     LDFLAGS="${SAVE_LDFLAGS}"
1106   ])
1107   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1108   ;;
1109 esac
1110
1111
1112 dnl For certain native configurations, we need to check whether thread
1113 dnl support can be built in or not.
1114 dnl
1115 dnl Note that we only want this if we are both native (host == target),
1116 dnl and not doing a canadian cross build (build == host).
1117
1118 if test ${build} = ${host} -a ${host} = ${target} ; then
1119    case ${host_os} in
1120    hpux*)
1121       AC_MSG_CHECKING(for HPUX/OSF thread support)
1122       if test -f /usr/include/dce/cma_config.h ; then
1123          if test "$GCC" = "yes" ; then
1124             AC_MSG_RESULT(yes)
1125             AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT, 1,
1126             [Define if you have HPUX threads])
1127             CONFIG_OBS="${CONFIG_OBS} hpux-thread.o"
1128             CONFIG_SRCS="${CONFIG_SRCS} hpux-thread.c"
1129          else
1130             AC_MSG_RESULT(no (suppressed because you are not using GCC))
1131          fi
1132       else
1133          AC_MSG_RESULT(no)
1134       fi
1135       ;;
1136    solaris*)
1137       # See if thread_db library is around for Solaris thread debugging.
1138       # Note that we must explicitly test for version 1 of the library
1139       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
1140       # the same API.
1141       AC_MSG_CHECKING(for Solaris thread debugging library)
1142       if test -f /usr/lib/libthread_db.so.1 ; then
1143          AC_MSG_RESULT(yes)
1144          AC_DEFINE(HAVE_THREAD_DB_LIB, 1,
1145          [Define if using Solaris thread debugging.])
1146          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
1147          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
1148          AC_CHECK_LIB(dl, dlopen)
1149          if test "$GCC" = "yes" ; then
1150             # The GNU linker requires the -export-dynamic option to make
1151             # all symbols visible in the dynamic symbol table.
1152             hold_ldflags=$LDFLAGS
1153             AC_MSG_CHECKING(for the ld -export-dynamic flag)
1154             LDFLAGS="${LDFLAGS} -Wl,-export-dynamic"
1155             AC_TRY_LINK(, [int i;], found=yes, found=no)
1156             LDFLAGS=$hold_ldflags
1157             AC_MSG_RESULT($found)
1158             if test $found = yes; then
1159                CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Wl,-export-dynamic"
1160             fi
1161          fi
1162          # Sun randomly tweaked the prototypes in <proc_service.h>
1163          # at one point.
1164          AC_MSG_CHECKING(if <proc_service.h> is old)
1165          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
1166             AC_TRY_COMPILE([
1167                 #include <proc_service.h>
1168                 ps_err_e ps_pdwrite
1169                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
1170             ],, gdb_cv_proc_service_is_old=no,
1171                 gdb_cv_proc_service_is_old=yes)
1172          ])
1173          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
1174          if test $gdb_cv_proc_service_is_old = yes; then
1175             AC_DEFINE(PROC_SERVICE_IS_OLD, 1,
1176             [Define if <proc_service.h> on solaris uses int instead of
1177              size_t, and assorted other type changes.])
1178          fi
1179       else
1180          AC_MSG_RESULT(no)
1181       fi
1182       ;;
1183    aix*)
1184       AC_MSG_CHECKING(for AiX thread debugging library)
1185       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1186                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1187                                    [#ifndef PTHDB_VERSION_3
1188                                     #error
1189                                     #endif],
1190                                    gdb_cv_have_aix_thread_debug=yes,
1191                                    gdb_cv_have_aix_thread_debug=no)])
1192       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1193       if test $gdb_cv_have_aix_thread_debug = yes; then
1194          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1195          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1196          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -lpthdebug"
1197       fi
1198       ;;
1199    esac
1200    AC_SUBST(CONFIG_LDFLAGS)
1201 fi
1202
1203 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1204 dnl other error codes.
1205 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1206    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1207                   gdb_cv_thread_db_h_has_td_notalloc,
1208      AC_TRY_COMPILE(
1209        [#include <thread_db.h>],
1210        [int i = TD_NOTALLOC;],
1211        gdb_cv_thread_db_h_has_td_notalloc=yes,
1212        gdb_cv_thread_db_h_has_td_notalloc=no
1213      )
1214    )
1215    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1216                   gdb_cv_thread_db_h_has_td_version,
1217      AC_TRY_COMPILE(
1218        [#include <thread_db.h>],
1219        [int i = TD_VERSION;],
1220        gdb_cv_thread_db_h_has_td_version=yes,
1221        gdb_cv_thread_db_h_has_td_version=no
1222      )
1223    )
1224    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1225                   gdb_cv_thread_db_h_has_td_notls,
1226      AC_TRY_COMPILE(
1227        [#include <thread_db.h>],
1228        [int i = TD_NOTLS;],
1229        gdb_cv_thread_db_h_has_td_notls=yes,
1230        gdb_cv_thread_db_h_has_td_notls=no
1231      )
1232    )
1233 fi
1234 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1235   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1236             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1237 fi
1238 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1239   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1240             [Define if <thread_db.h> has the TD_VERSION error code.])
1241 fi
1242 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1243   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1244             [Define if <thread_db.h> has the TD_NOTLS error code.])
1245 fi
1246
1247 dnl See if we have a sys/syscall header file that has __NR_tkill.
1248 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
1249    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
1250                   gdb_cv_sys_syscall_h_has_tkill,
1251      AC_TRY_COMPILE(
1252        [#include <sys/syscall.h>],
1253        [int i = __NR_tkill;],
1254        gdb_cv_sys_syscall_h_has_tkill=yes,
1255        gdb_cv_sys_syscall_h_has_tkill=no
1256      )
1257    )
1258 fi
1259 dnl See if we can issue tkill syscall.
1260 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes" && test "x$ac_cv_func_syscall" = "xyes"; then
1261   AC_DEFINE(HAVE_TKILL_SYSCALL, 1, [Define if you support the tkill syscall.])
1262 fi
1263
1264 dnl Handle optional features that can be enabled.
1265
1266 AC_ARG_WITH(sysroot,
1267 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
1268 [
1269  case ${with_sysroot} in
1270  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
1271  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
1272  esac
1273
1274  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
1275
1276  if test "x$prefix" = xNONE; then
1277   test_prefix=/usr/local
1278  else
1279   test_prefix=$prefix
1280  fi
1281  if test "x$exec_prefix" = xNONE || test "x$exec_prefix" = 'x${prefix}'; then
1282   test_exec_prefix=$test_prefix
1283  else
1284   test_exec_prefix=$exec_prefix
1285  fi
1286  case ${TARGET_SYSTEM_ROOT} in
1287  "${test_prefix}"|"${test_prefix}/"*|\
1288  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
1289  '${prefix}'|'${prefix}/'*|\
1290  '${exec_prefix}'|'${exec_prefix}/'*)
1291    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
1292    TARGET_SYSTEM_ROOT_DEFINE="$t"
1293    ;;
1294  esac
1295 ], [
1296  TARGET_SYSTEM_ROOT=
1297  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
1298 ])
1299 AC_SUBST(TARGET_SYSTEM_ROOT)
1300 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
1301
1302 AC_ARG_ENABLE(werror,
1303   [  --enable-werror    treat compile warnings as errors],
1304   [case "${enableval}" in
1305      yes | y) ERROR_ON_WARNING="yes" ;;
1306      no | n)  ERROR_ON_WARNING="no" ;;
1307      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
1308    esac])
1309
1310 # Enable -Werror by default when using gcc
1311 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" ; then
1312     ERROR_ON_WARNING=yes
1313 fi
1314
1315 WERROR_CFLAGS=""
1316 if test "${ERROR_ON_WARNING}" = yes ; then
1317     WERROR_CFLAGS="-Werror"
1318 fi
1319
1320 # The entries after -Wno-pointer-sign are disabled warnings which may
1321 # be enabled in the future, which can not currently be used to build
1322 # GDB.
1323 # NOTE: If you change this list, remember to update
1324 # gdb/doc/gdbint.texinfo.
1325 build_warnings="-Wall -Wdeclaration-after-statement -Wpointer-arith \
1326 -Wformat-nonliteral -Wno-pointer-sign \
1327 -Wno-unused -Wno-switch -Wno-char-subscripts"
1328
1329 AC_ARG_ENABLE(build-warnings,
1330 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
1331 [case "${enableval}" in
1332   yes)  ;;
1333   no)   build_warnings="-w";;
1334   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1335         build_warnings="${build_warnings} ${t}";;
1336   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1337         build_warnings="${t} ${build_warnings}";;
1338   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1339 esac
1340 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1341   echo "Setting compiler warning flags = $build_warnings" 6>&1
1342 fi])dnl
1343 AC_ARG_ENABLE(gdb-build-warnings,
1344 [  --enable-gdb-build-warnings Enable GDB specific build-time compiler warnings if gcc is used],
1345 [case "${enableval}" in
1346   yes)  ;;
1347   no)   build_warnings="-w";;
1348   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1349         build_warnings="${build_warnings} ${t}";;
1350   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1351         build_warnings="${t} ${build_warnings}";;
1352   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1353 esac
1354 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1355   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
1356 fi])dnl
1357 WARN_CFLAGS=""
1358 if test "x${build_warnings}" != x -a "x$GCC" = xyes
1359 then
1360     AC_MSG_CHECKING(compiler warning flags)
1361     # Separate out the -Werror flag as some files just cannot be
1362     # compiled with it enabled.
1363     for w in ${build_warnings}; do
1364         case $w in
1365         -Werr*) WERROR_CFLAGS=-Werror ;;
1366         *) # Check that GCC accepts it
1367             saved_CFLAGS="$CFLAGS"
1368             CFLAGS="$CFLAGS $w"
1369             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
1370             CFLAGS="$saved_CFLAGS"
1371         esac
1372     done
1373     AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
1374 fi
1375 AC_SUBST(WARN_CFLAGS)
1376 AC_SUBST(WERROR_CFLAGS)
1377
1378 # In the Cygwin environment, we need some additional flags.
1379 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1380 [AC_EGREP_CPP(lose, [
1381 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1382 lose
1383 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1384
1385
1386 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1387 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1388 case ${host} in
1389   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1390   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1391   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1392 esac
1393 AC_SUBST(SER_HARDWIRE)
1394
1395 # libreadline needs libuser32.a in a cygwin environment
1396 WIN32LIBS=
1397 if test x$gdb_cv_os_cygwin = xyes; then
1398     WIN32LIBS="-luser32"
1399     case "${target}" in
1400         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1401         ;;
1402     esac
1403 fi
1404
1405 # The ser-tcp.c module requires sockets.
1406 case ${host} in
1407   *mingw32*)
1408     AC_DEFINE(USE_WIN32API, 1,
1409               [Define if we should use the Windows API, instead of the
1410                POSIX API.  On Windows, we use the Windows API when
1411                building for MinGW, but the POSIX API when building
1412                for Cygwin.])
1413     WIN32LIBS="$WIN32LIBS -lws2_32"
1414     ;;
1415 esac
1416 AC_SUBST(WIN32LIBS)
1417
1418 # Add ELF support to GDB, but only if BFD includes ELF support.
1419 OLD_CFLAGS=$CFLAGS
1420 OLD_LDFLAGS=$LDFLAGS
1421 OLD_LIBS=$LIBS
1422 CFLAGS="$CFLAGS -I${srcdir}/../include -I../bfd -I${srcdir}/../bfd"
1423 LDFLAGS="$LDFLAGS -L../bfd -L../libiberty"
1424 intl=`echo $LIBINTL | sed 's,${top_builddir}/,,g'`
1425 LIBS="$LIBS -lbfd -liberty $intl"
1426 AC_CACHE_CHECK([for ELF support in BFD], gdb_cv_var_elf,
1427 [AC_TRY_LINK(
1428 [#include <stdlib.h>
1429 #include "bfd.h"
1430 #include "elf-bfd.h"
1431 ],
1432 [bfd *abfd = NULL; bfd_get_elf_phdr_upper_bound (abfd); ],
1433 gdb_cv_var_elf=yes, gdb_cv_var_elf=no)])
1434 if test $gdb_cv_var_elf = yes; then
1435   CONFIG_OBS="$CONFIG_OBS elfread.o"
1436   AC_DEFINE(HAVE_ELF, 1,
1437             [Define if ELF support should be included.])
1438 fi
1439 CFLAGS=$OLD_CFLAGS
1440 LDFLAGS=$OLD_LDFLAGS
1441 LIBS=$OLD_LIBS
1442
1443 # Add any host-specific objects to GDB.
1444 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
1445
1446 LIBGUI="../libgui/src/libgui.a"
1447 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1448 AC_SUBST(LIBGUI)
1449 AC_SUBST(GUI_CFLAGS_X)
1450
1451 WIN32LDAPP=
1452 AC_SUBST(WIN32LIBS)
1453 AC_SUBST(WIN32LDAPP)
1454
1455 case "${host}" in
1456 *-*-cygwin* | *-*-mingw* )
1457     configdir="win"
1458     ;;
1459 *)
1460     configdir="unix"
1461     ;;
1462 esac
1463
1464 GDBTKLIBS=
1465 if test "${enable_gdbtk}" = "yes"; then
1466
1467     # Gdbtk must have an absolute path to srcdir in order to run
1468     # properly when not installed.
1469     here=`pwd`
1470     cd ${srcdir}
1471     GDBTK_SRC_DIR=`pwd`
1472     cd $here
1473
1474     CY_AC_PATH_TCLCONFIG
1475     if test -z "${no_tcl}"; then
1476         CY_AC_LOAD_TCLCONFIG
1477         CY_AC_PATH_TKCONFIG
1478
1479         # now look for Tcl library stuff
1480
1481         tcldir="../tcl/${configdir}/"
1482
1483         TCL_DEPS="${tcldir}${TCL_LIB_FILE}"
1484
1485         # If $no_tk is nonempty, then we can't do Tk, and there is no
1486         # point to doing Tcl.
1487         if test -z "${no_tk}"; then
1488            CY_AC_LOAD_TKCONFIG
1489            CY_AC_PATH_TCLH
1490            CY_AC_PATH_TKH
1491            CY_AC_PATH_ITCLH
1492            CY_AC_PATH_ITKH
1493
1494
1495            # now look for Tk library stuff
1496
1497            tkdir="../tk/${configdir}/"
1498
1499            TK_DEPS="${tkdir}${TK_LIB_FILE}"
1500
1501            # now look for Itcl library stuff
1502
1503            CY_AC_PATH_ITCLCONFIG
1504            if test -z "${no_itcl}"; then
1505              CY_AC_LOAD_ITCLCONFIG
1506
1507              ITCLLIB="${ITCL_BUILD_LIB_SPEC}"
1508              ITCL_DEPS="${ITCL_LIB_FULL_PATH}"
1509            fi
1510
1511
1512            # now look for Itk library stuff
1513            CY_AC_PATH_ITKCONFIG
1514            if test -z "${no_itcl}"; then
1515              CY_AC_LOAD_ITKCONFIG
1516
1517              ITKLIB="${ITK_BUILD_LIB_SPEC}"
1518              ITK_DEPS="${ITK_LIB_FULL_PATH}"
1519            fi
1520
1521            ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
1522
1523            # Include some libraries that Tcl and Tk want.
1524            TCL_LIBS='$(LIBGUI) $(ITCL) $(ITK) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
1525            # Yes, the ordering seems wrong here.  But it isn't.
1526            # TK_LIBS is the list of libraries that need to be linked
1527            # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
1528            # were in LIBS then any link tests after this point would
1529            # try to include things like `$(LIBGUI)', which wouldn't work.
1530            GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
1531
1532            CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
1533            CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
1534            CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
1535            CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
1536            CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
1537            CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
1538            CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
1539
1540            if test x$gdb_cv_os_cygwin = xyes; then
1541               WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
1542               WIN32LDAPP="-Wl,--subsystem,console"
1543               CONFIG_OBS="${CONFIG_OBS} gdbres.o"
1544            fi
1545         fi
1546     fi
1547
1548     AC_CONFIG_SUBDIRS(gdbtk)
1549 fi
1550
1551 AC_SUBST(X_CFLAGS)
1552 AC_SUBST(X_LDFLAGS)
1553 AC_SUBST(X_LIBS)
1554 AC_SUBST(TCL_DEPS)
1555 AC_SUBST(TK_DEPS)
1556 AC_SUBST(ITCLLIB)
1557 AC_SUBST(ITCL_DEPS)
1558 AC_SUBST(ITKLIB)
1559 AC_SUBST(ITK_DEPS)
1560 AC_SUBST(GDBTKLIBS)
1561 AC_SUBST(GDBTK_CFLAGS)
1562 AC_SUBST(GDBTK_SRC_DIR)
1563
1564 AC_PATH_X
1565
1566 # Check whether we should enable the TUI, but only do so if we really
1567 # can.
1568 if test x"$enable_tui" = xyes; then
1569   if test -d $srcdir/tui; then
1570     if test "$ac_cv_search_waddstr" != no; then
1571       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
1572       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
1573       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
1574       CONFIG_INITS="$CONFIG_INITS \$(SUBDIR_TUI_INITS)"
1575       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
1576       CONFIG_ALL="${CONFIG_ALL} all-tui"
1577       CONFIG_CLEAN="${CONFIG_CLEAN} clean-tui"
1578       CONFIG_INSTALL="${CONFIG_INSTALL} install-tui"
1579       CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-tui"
1580     else
1581       AC_MSG_WARN([no enhanced curses library found; disabling TUI])
1582     fi
1583   fi
1584 fi
1585
1586 # Unlike the sim directory, whether a simulator is linked is controlled by
1587 # presence of a gdb_sim definition in the target configure.tgt entry.
1588 # This code just checks for a few cases where we'd like to ignore those
1589 # definitions, even when they're present in the '.mt' file.  These cases
1590 # are when --disable-sim is specified, or if the simulator directory is
1591 # not part of the source tree.
1592 #
1593 AC_ARG_ENABLE(sim,
1594 [  --enable-sim            Link gdb with simulator],
1595 [echo "enable_sim = $enable_sim";
1596  echo "enableval = ${enableval}";
1597  case "${enableval}" in
1598   yes) ignore_sim=false ;;
1599   no)  ignore_sim=true ;;
1600   *)   ignore_sim=false ;;
1601  esac],
1602 [ignore_sim=false])
1603
1604 if test ! -d "${srcdir}/../sim"; then
1605   ignore_sim=true
1606 fi
1607
1608 SIM=
1609 SIM_OBS=
1610 if test "${ignore_sim}" = "false"; then
1611   if test x"${gdb_sim}" != x ; then
1612     SIM="${gdb_sim}"
1613     SIM_OBS="remote-sim.o"
1614     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
1615   fi
1616 fi
1617 AC_SUBST(SIM)
1618 AC_SUBST(SIM_OBS)
1619
1620 AC_SUBST(ENABLE_CFLAGS)
1621 AC_SUBST(PROFILE_CFLAGS)
1622
1623 AC_SUBST(CONFIG_OBS)
1624 AC_SUBST(CONFIG_DEPS)
1625 AC_SUBST(CONFIG_SRCS)
1626 AC_SUBST(CONFIG_ALL)
1627 AC_SUBST(CONFIG_CLEAN)
1628 AC_SUBST(CONFIG_INSTALL)
1629 AC_SUBST(CONFIG_UNINSTALL)
1630
1631 # List of host floatformats.
1632 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
1633 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
1634 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
1635
1636 # target_subdir is used by the testsuite to find the target libraries.
1637 target_subdir=
1638 if test "${host}" != "${target}"; then
1639     target_subdir="${target_alias}/"
1640 fi
1641 AC_SUBST(target_subdir)
1642
1643 frags=
1644 if test "${gdb_native}" = "yes"; then
1645   host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
1646   if test ! -f ${host_makefile_frag}; then
1647     AC_MSG_ERROR("*** Gdb does not support native target ${host}")
1648   fi
1649   frags="$frags $host_makefile_frag"
1650 else
1651   host_makefile_frag=/dev/null
1652 fi
1653
1654 AC_SUBST_FILE(host_makefile_frag)
1655 AC_SUBST(frags)
1656
1657 changequote(,)dnl
1658 if test "${gdb_native}" = "yes"; then
1659 # We pick this up from the host configuration file (.mh) because we
1660 # do not have a native configuration Makefile fragment.
1661 nativefile=`sed -n '
1662 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
1663 ' ${host_makefile_frag}`
1664 fi
1665 changequote([,])
1666
1667 if test x"${gdb_osabi}" != x ; then
1668     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
1669                        [Define to the default OS ABI for this configuration.])
1670 fi
1671
1672 # Enable multi-ice-gdb-server.
1673 AC_ARG_ENABLE(multi-ice,
1674 [  --enable-multi-ice      build the multi-ice-gdb-server],
1675   [case $enableval in
1676     yes | no)
1677       ;;
1678     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
1679   esac])
1680 if test "x$enable_multi_ice" = xyes; then
1681    AC_CONFIG_SUBDIRS(multi-ice)
1682 fi
1683
1684 # We only build gdbserver automatically in a native configuration.
1685 if test "$gdb_native" = "yes"; then
1686   AC_MSG_CHECKING(whether gdbserver is supported on this host)
1687   if test "x$build_gdbserver" = xyes; then
1688     AC_MSG_RESULT(yes)
1689     AC_CONFIG_SUBDIRS(gdbserver)
1690   else
1691     AC_MSG_RESULT(no)
1692   fi
1693 fi
1694
1695 # If nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link
1696 # to an empty version.
1697
1698 files=
1699 links=
1700
1701 rm -f nm.h
1702 nm_h=""
1703 if test "${nativefile}" != ""; then
1704     nm_h=nm.h
1705     case "${nativefile}" in
1706       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
1707       * ) GDB_NM_FILE="${nativefile}"
1708     esac
1709     files="${files} ${GDB_NM_FILE}"
1710     links="${links} nm.h"
1711     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
1712 fi
1713 AC_SUBST(nm_h)
1714
1715 AC_LINK_FILES($files, $links)
1716
1717 dnl Check for exe extension set on certain hosts (e.g. Win32)
1718 AC_EXEEXT
1719
1720 dnl  Detect the character set used by this host.
1721
1722 dnl  At the moment, we just assume it's ISO-8859-1 (which is a
1723 dnl  superset of ASCII containing the characters needed for French,
1724 dnl  German, Spanish, Italian, and possibly others), but if were
1725 dnl  *were* to support any host character sets other than ISO-8859-1,
1726 dnl  here's where we'd detect it.
1727 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "ISO-8859-1",
1728           [Define to be a string naming the default host character set.])
1729
1730 AM_ICONV
1731
1732 AC_OUTPUT(Makefile .gdbinit:gdbinit.in gnulib/Makefile,
1733 [
1734 dnl Autoconf doesn't provide a mechanism for modifying definitions
1735 dnl provided by makefile fragments.
1736 dnl
1737
1738 changequote(,)dnl
1739 sed -e '/^NAT_FILE[     ]*=/s,^NAT_FILE[        ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp
1740 mv -f Makefile.tmp Makefile
1741 changequote([,])dnl
1742
1743
1744 case x$CONFIG_HEADERS in
1745 xconfig.h:config.in)
1746 echo > stamp-h ;;
1747 esac
1748 ],
1749 [
1750 gdb_host_cpu=$gdb_host_cpu
1751 nativefile=$nativefile
1752 ])
1753
1754 exit 0