gas/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl
   7 AC_PREREQ(2.5)dnl v2.5 needed for --bindir et al
   8 AC_INIT(as.h)dnl
   9 dnl
  10 user_bfd_gas=
  11 AC_ARG_ENABLE(bfd-assembler,
  12 [  --enable-bfd-assembler  use BFD back end for writing object files],
  13 [case "${enableval}" in
  14   yes) need_bfd=yes user_bfd_gas=yes ;;
  15   no)  user_bfd_gas=no ;;
  16   *)   AC_MSG_ERROR(bad value ${enableval} given for bfd-assembler option) ;;
  17 esac])dnl
  18 AC_ARG_ENABLE(targets,
  19 [    targets            alternative target configurations besides the primary],
  20 [case "${enableval}" in
  21   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  22             ;;
  23   no)       enable_targets= ;;
  24   *)        enable_targets=$enableval ;;
  25 esac])dnl
  26 AC_ARG_ENABLE(shared,
  27 [  --enable-shared         build shared BFD library],
  28 [case "${enableval}" in
  29   yes) shared=true shared_bfd=true shared_opcodes=true ;;
  30   no)  shared=false ;;
  31   *bfd*opcodes*) shared=true shared_bfd=true shared_opcodes=true ;;
  32   *opcodes*bfd*) shared=true shared_bfd=true shared_opcodes=true ;;
  33   *bfd*) shared=true shared_bfd=true ;;
  34   *opcodes*) shared=true shared_opcodes=true ;;
  35   *) shared=false ;;
  36 esac])dnl
  37
  38 # Generate a header file -- gets more post-processing by Makefile later.
  39 AC_CONFIG_HEADER(conf)
  40
  41 dnl For recursion to work right, this must be an absolute pathname.
  42 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  43 AC_CANONICAL_SYSTEM
  44 AC_ARG_PROGRAM
  45
  46 te_file=generic
  47
  48 canon_targets=""
  49 if test -n "$enable_targets" ; then
  50   for t in `echo $enable_targets | sed 's/,/ /g'`; do
  51     result=`$ac_config_sub $t 2>/dev/null`
  52     if test -n "$result" ; then
  53       canon_targets="$canon_targets $result"
  54 #    else
  55 #      # Permit "all", etc.  We don't support it yet though.
  56 #      canon_targets="$canon_targets $t"
  57     fi
  58   done
  59   GAS_UNIQ(canon_targets)
  60 fi
  61
  62 emulations=""
  63
  64 for this_target in $target $canon_targets ; do
  65
  66 changequote(,)dnl
  67     eval `echo $this_target | sed 's/^\([^-]*\)-\([^-]*\)-\(.*\)$/cpu=\1 vendor=\2 os=\3/'`
  68 changequote([,])dnl
  69
  70     # check for architecture variants
  71     case ${cpu} in
  72       armeb)            cpu_type=arm endian=big ;;
  73       arm*)             cpu_type=arm endian=little ;;
  74       hppa*)            cpu_type=hppa ;;
  75 changequote(,)dnl
  76       i[456]86)         cpu_type=i386 ;;
  77       m680[012346]0)    cpu_type=m68k ;;
  78       m68008)           cpu_type=m68k ;;
  79       m683??)           cpu_type=m68k ;;
  80 changequote([,])dnl
  81       m8*)              cpu_type=m88k ;;
  82       mips*el)          cpu_type=mips endian=little ;;
  83       mips*)            cpu_type=mips endian=big ;;
  84       powerpcle*)       cpu_type=ppc endian=little ;;
  85       powerpc*)         cpu_type=ppc endian=big ;;
  86       rs6000*)          cpu_type=ppc ;;
  87       sparc64)          cpu_type=sparc want_sparc_v9=true ;;
  88       sparc*)           cpu_type=sparc ;;
  89       *)                cpu_type=${cpu} ;;
  90     esac
  91
  92     if test ${this_target} = $target ; then
  93       target_cpu_type=${cpu_type}
  94     elif test ${target_cpu_type} != ${cpu_type} ; then
  95       continue
  96     fi
  97
  98     targ=${cpu_type}
  99     generic_target=${cpu_type}-$vendor-$os
 100     dev=no
 101     bfd_gas=no
 102     em=generic
 103
 104     # assign object format
 105     case ${generic_target} in
 106       a29k-*-coff)          fmt=coff targ=ebmon29k ;;
 107       a29k-amd-udi)         fmt=coff targ=ebmon29k ;;
 108       a29k-amd-ebmon)       fmt=coff targ=ebmon29k ;;
 109       a29k-nyu-sym1)        fmt=coff targ=ebmon29k ;;
 110       a29k-*-vxworks*)      fmt=coff ;;
 111
 112       alpha-*-*vms*)        fmt=evax ;;
 113       alpha-*-netware*)     fmt=ecoff ;;
 114       alpha-*-osf*)         fmt=ecoff ;;
 115       alpha-*-linuxecoff*)  fmt=ecoff ;;
 116       alpha-*-linux*)       fmt=elf em=linux ;;
 117
 118 # start-sanitize-arc
 119       arc-*-elf*)           fmt=elf bfd_gas=yes ;;
 120 # end-sanitize-arc
 121
 122       arm-*-riscix*)        fmt=aout targ=arm-lit em=riscix ;;
 123       arm-*-aout)           fmt=aout
 124                             case "$endian" in
 125                               big)      targ=arm-big ;;
 126                               *)        targ=arm-lit ;;
 127                             esac
 128                             ;;
 129       arm-*-coff)           fmt=coff ;;
 130       arm-*-riscix*)        fmt=aout ;;
 131       arm-*-pe)             fmt=coff targ=armcoff em=pe ;;
 132
 133       d10v-*-*)             fmt=elf bfd_gas=yes ;;
 134 # start-sanitize-d30v
 135       d30v-*-*)             fmt=elf bfd_gas=yes ;;
 136 # end-sanitize-d30v
 137
 138       hppa-*-*elf*)         fmt=elf em=hppa ;;
 139       hppa-*-lites*)        fmt=elf em=hppa ;;
 140       hppa-*-osf*)          fmt=som em=hppa ;;
 141       hppa-*-hpux*)         fmt=som em=hppa ;;
 142       hppa-*-bsd*)          fmt=som em=hppa ;;
 143       hppa-*-hiux*)         fmt=som em=hppa ;;
 144
 145       h8300-*-coff)         fmt=coff ;;
 146
 147       i386-ibm-aix*)        fmt=coff targ=i386coff
 148                              em=i386aix ;;
 149       i386-sequent-bsd*)    fmt=aout em=dynix bfd_gas=yes ;;
 150       i386-*-bsd*)          fmt=aout em=386bsd ;;
 151       i386-*-netbsd0.8)     fmt=aout em=386bsd ;;
 152       i386-*-netbsd*)       fmt=aout em=nbsd bfd_gas=yes;;
 153       i386-*-linux*aout* | i386-*-linuxoldld)   fmt=aout em=linux ;;
 154       i386-*-linux*coff*)   fmt=coff em=linux
 155                              targ=i386coff ;;
 156       i386-*-linux*)        fmt=elf em=linux ;;
 157       i386-*-lynxos*)       fmt=coff targ=i386coff
 158                              em=lynx ;;
 159       i386-*-sysv4* | i386-*-solaris* | i386-*-elf | i386-*-freebsdelf*)
 160                             fmt=elf ;;
 161       i386-*-sco*elf*)      fmt=elf targ=sco5 ;;
 162       i386-*-coff | i386-*-sysv* | i386-*-sco* | i386-*-isc*)
 163                             fmt=coff targ=i386coff ;;
 164       i386-*-vsta)          fmt=aout ;;
 165       i386-*-go32)          fmt=coff targ=i386coff ;;
 166       i386-*-rtems*)        fmt=coff targ=i386coff ;;
 167       i386-*-gnu*)          fmt=elf ;;
 168       i386-*-mach*)
 169                             fmt=aout em=mach bfd_gas=yes ;;
 170       i386-*-msdos*)        fmt=aout ;;
 171       i386-*-moss*)         fmt=elf ;;
 172       i386-*-pe)            fmt=coff targ=i386coff em=pe ;;
 173       i386-*-cygwin32)      fmt=coff targ=i386coff em=pe ;;
 174       i386-*-*nt)           fmt=coff targ=i386coff em=pe ;;
 175       i960-*-bout)          fmt=bout ;;
 176       i960-*-coff)          fmt=coff em=ic960 targ=ic960coff ;;
 177       i960-*-rtems*)        fmt=coff em=ic960 targ=ic960coff ;;
 178       i960-*-nindy*)        fmt=bout ;;
 179       i960-*-vxworks4*)     fmt=bout ;;
 180       i960-*-vxworks5.0)    fmt=bout ;;
 181       i960-*-vxworks5.*)    fmt=coff em=ic960 targ=ic960coff ;;
 182       i960-*-vxworks*)      fmt=bout ;;
 183
 184       m68k-*-vxworks* | m68k-ericsson-ose | m68k-*-sunos*)
 185                             fmt=aout em=sun3 ;;
 186       m68k-motorola-sysv*)  fmt=coff targ=m68kcoff em=delta ;;
 187       m68k-bull-sysv3*)     fmt=coff targ=m68kcoff em=dpx2 ;;
 188       m68k-apollo-*)        fmt=coff targ=apollo em=apollo ;;
 189       m68k-*-sysv4*) # must be before -sysv*
 190                             fmt=elf em=svr4 ;;
 191       m68k-*-elf*)          fmt=elf ;;
 192       m68k-*-coff | m68k-*-sysv* | m68k-*-rtems*)
 193                             fmt=coff targ=m68kcoff ;;
 194       m68k-*-hpux*)         fmt=hp300 em=hp300 ;;
 195       m68k-*-linux*aout*)   fmt=aout em=linux ;;
 196       m68k-*-linux*)        fmt=elf em=linux ;;
 197       m68k-*-lynxos*)       fmt=coff targ=m68kcoff
 198                              em=lynx ;;
 199       m68k-*-netbsd*)       fmt=aout em=nbsd bfd_gas=yes ;;
 200       m68k-apple-aux*)      fmt=coff targ=m68kcoff em=aux ;;
 201       m68k-*-psos*)         fmt=elf em=psos;;
 202
 203       m88k-motorola-sysv3*) fmt=coff targ=m88kcoff em=delt88 ;;
 204       m88k-*-coff*)         fmt=coff targ=m88kcoff ;;
 205
 206       # don't change em like *-*-bsd does
 207       mips-dec-netbsd*)     fmt=elf targ=mips-lit endian=little ;;
 208       mips-dec-bsd*)        fmt=aout targ=mips-lit ;;
 209       mips-sony-bsd*)       fmt=ecoff targ=mips-big ;;
 210       mips-*-bsd*)          AC_MSG_ERROR(Unknown vendor for mips-bsd configuration.) ;;
 211       mips-*-ultrix*)       fmt=ecoff targ=mips-lit endian=little ;;
 212       mips-*-osf*)          fmt=ecoff targ=mips-lit endian=little ;;
 213       mips-*-ecoff*)        fmt=ecoff
 214                             case "$endian" in
 215                             big) targ=mips-big ;;
 216                             *)   targ=mips-lit ;;
 217                             esac
 218                             ;;
 219       mips-*-ecoff*)        fmt=ecoff targ=mips-big ;;
 220       mips-*-gnu*)          fmt=aout
 221                             case "$endian" in
 222                             big) targ=mips-big ;;
 223                             *)   targ=mips-lit ;;
 224                             esac
 225                             ;;
 226       mips-*-irix6*)        fmt=elf targ=mips-big ;;
 227       mips-*-irix5*)        fmt=elf targ=mips-big ;;
 228       mips-*-irix*)         fmt=ecoff targ=mips-big ;;
 229       mips-*-riscos*)       fmt=ecoff targ=mips-big ;;
 230       mips-*-sysv*)         fmt=ecoff targ=mips-big ;;
 231       mips-*-elf* | mips-*-rtems* | mips-*-linux*)
 232                             fmt=elf
 233                             case "$endian" in
 234                             big) targ=mips-big ;;
 235                             *)   targ=mips-lit ;;
 236                             esac
 237                             ;;
 238       mn10200-*-*)          fmt=elf bfd_gas=yes ;;
 239       mn10300-*-*)          fmt=elf bfd_gas=yes ;;
 240       ppc-*-pe | ppc-*-cygwin32 | ppc-*-winnt*)
 241                             fmt=coff em=pe
 242                             case "$endian" in
 243                             big) targ=ppc-big ;;
 244                             *)   targ=ppc-lit ;;
 245                             esac
 246                             ;;
 247       ppc-*-aix*)           fmt=coff ;;
 248       ppc-*-elf* | ppc-*-eabi* | ppc-*-sysv4*)
 249                             fmt=elf
 250                             case "$endian" in
 251                             big)  targ=ppc-big ;;
 252                             *)    targ=ppc-lit ;;
 253                             esac
 254                             ;;
 255       ppc-*-linux*)         fmt=elf
 256                             case "$endian" in
 257                             big)  targ=ppc-big ;;
 258                             *)    AC_MSG_ERROR(Linux must be configured big endian) ;;
 259                             esac
 260                             ;;
 261       ppc-*-solaris*)       fmt=elf
 262                             case "$endian" in
 263                             big)  AC_MSG_ERROR(Solaris must be configured little endian) ;;
 264                             *)    targ=ppc-sol ;;
 265                             esac
 266                             ;;
 267       ppc-*-rtems*)
 268                             fmt=elf
 269                             case "$endian" in
 270                             big)  targ=ppc-big ;;
 271                             *)    targ=ppc-lit ;;
 272                             esac
 273                             ;;
 274       ppc-*-macos* | ppc-*-mpw*)
 275                             fmt=coff em=macos ;;
 276       ppc-*-netware*)       fmt=elf em=ppcnw ;;
 277
 278       sh-*-elf*)            fmt=elf ;;
 279       sh-*-coff*)           fmt=coff ;;
 280
 281       ns32k-pc532-mach* | ns32k-pc532-ux*)    fmt=aout em=pc532mach ;;
 282       ns32k-pc532-netbsd* | ns32k-pc532-lites*)  fmt=aout em=nbsd532 ;;
 283
 284       sparc-*-rtems*)       fmt=aout ;;
 285       sparc-*-sunos4*)      fmt=aout em=sun3 ;;
 286       sparc-*-aout | sparc*-*-vxworks*)
 287                             fmt=aout em=sparcaout ;;
 288       sparc-*-coff)         fmt=coff ;;
 289       sparc-*-lynxos*)      fmt=coff em=lynx ;;
 290       sparc-fujitsu-none)   fmt=aout ;;
 291       sparc-*-elf | sparc-*-sysv4* | sparc-*-solaris*)
 292                             fmt=elf ;;
 293       sparc-*-netbsd*)      fmt=aout em=nbsd bfd_gas=yes ;;
 294
 295 # start-sanitize-tic80
 296       tic80-*-*)            fmt=coff targ=tic80coff;;
 297 # end-sanitize-tic80
 298       v850-*-*)             fmt=elf bfd_gas=yes ;;
 299
 300       vax-*-bsd* | vax-*-ultrix*)
 301                             fmt=aout ;;
 302       vax-*-vms)            fmt=vms ;;
 303
 304       z8k-*-coff | z8k-*-sim)
 305                             fmt=coff ;;
 306
 307       w65-*-*)              fmt=coff ;;
 308
 309       *-*-aout | *-*-scout)
 310                             fmt=aout ;;
 311       *-*-nindy*)
 312                             fmt=bout ;;
 313       *-*-bsd*)
 314                             fmt=aout em=sun3 ;;
 315       *-*-generic)          fmt=generic ;;
 316       *-*-xray | *-*-hms)   fmt=coff ;;
 317       *-*-sim)              fmt=coff ;;
 318       *-*-elf | *-*-sysv4* | *-*-solaris*)
 319                             AC_MSG_WARN(GAS support for ${generic_target} is incomplete.)
 320                             fmt=elf dev=yes ;;
 321       *-*-vxworks)          fmt=aout ;;
 322       *-*-netware)          fmt=elf ;;
 323     esac
 324
 325     case ${cpu_type}-${fmt} in
 326       alpha-*)  bfd_gas=yes ;;
 327       arm-*)    bfd_gas=yes ;;
 328     # not yet
 329     # i386-aout)        bfd_gas=preferred ;;
 330       mips-*)   bfd_gas=yes ;;
 331       ns32k-*)  bfd_gas=yes ;;
 332       ppc-*)    bfd_gas=yes ;;
 333       sparc-*)  bfd_gas=yes ;;
 334       *-elf)    bfd_gas=yes ;;
 335       *-ecoff)  bfd_gas=yes ;;
 336       *-som)    bfd_gas=yes ;;
 337       *)                ;;
 338     esac
 339
 340 # Other random stuff.
 341
 342     # do we need the opcodes library?
 343     case ${cpu_type} in
 344       vax | i386)
 345         ;;
 346       *)
 347         need_opcodes=yes
 348         if test "${shared_opcodes}" = "true"; then
 349           # A shared libopcodes must be linked against libbfd.
 350           need_bfd=yes
 351         fi
 352         ;;
 353     esac
 354
 355     test -n "$want_sparc_v9" && AC_DEFINE(SPARC_V9)
 356
 357     case ${cpu}-${vendor}-${os} in
 358       sparc64-*-elf*) AC_DEFINE(SPARC_ARCH64) ;;
 359     esac
 360
 361     case ${cpu_type} in
 362       m68k)
 363         case ${extra_objects} in
 364         *m68k-parse.o*) ;;
 365         *) extra_objects="$extra_objects m68k-parse.o" ;;
 366         esac
 367         ;;
 368
 369       mips)
 370         `echo ${extra_objects}` | grep -s "itbl-parse.o"
 371         if test $? -ne 0 ; then
 372         extra_objects="$extra_objects itbl-parse.o"
 373         fi
 374
 375         `echo ${extra_objects}` | grep -s "itbl-lex.o"
 376         if test $? -ne 0 ; then
 377         extra_objects="$extra_objects itbl-lex.o"
 378         fi
 379
 380         `echo ${extra_objects}` | grep -s "itbl-ops.o"
 381         if test $? -ne 0 ; then
 382         extra_objects="$extra_objects itbl-ops.o"
 383         fi
 384         ;;
 385
 386       *)
 387         ;;
 388     esac
 389
 390 # See if we really can support this configuration with the emulation code.
 391
 392     if test $this_target = $target ; then
 393       primary_bfd_gas=$bfd_gas
 394       obj_format=$fmt
 395       gas_target=$targ
 396       te_file=$em
 397
 398       if test $bfd_gas = no ; then
 399         # Can't support other configurations this way.
 400         break
 401       fi
 402     elif test $bfd_gas = no ; then
 403       # Can't support this configuration.
 404       break
 405     fi
 406
 407 # From target name and format, produce a list of supported emulations.
 408
 409     case ${generic_target}-${fmt} in
 410       mips-*-irix5*-*)  emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 411       mips-*-*-ecoff)   case "$endian" in
 412                         big)    emulation="mipsbecoff mipslecoff mipsecoff" ;;
 413                         *)      emulation="mipslecoff mipsbecoff mipsecoff" ;;
 414                         esac ;;
 415       mips-*-*-elf)     case "$endian" in
 416                         big)    emulation="mipsbelf mipslelf mipself" ;;
 417                         *)      emulation="mipslelf mipsbelf mipself" ;;
 418                         esac ;;
 419     esac
 420
 421     emulations="$emulations $emulation"
 422
 423 done
 424
 425 # Assign floating point type.  Most processors with FP support
 426 # IEEE FP.  On those that don't support FP at all, usually IEEE
 427 # is emulated.
 428 case ${target_cpu} in
 429   vax | tahoe ) atof=${target_cpu} ;;
 430   *)            atof=ieee ;;
 431 esac
 432
 433 case "${obj_format}" in
 434   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 435 esac
 436
 437 dnl
 438 dnl Make sure the desired support files exist.
 439 dnl
 440
 441 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 442   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 443 fi
 444
 445 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 446   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 447 fi
 448
 449 # and target makefile frag
 450
 451 target_frag=${srcdir}/config/${gas_target}.mt
 452 if test ! -r ${target_frag}; then
 453   target_frag=/dev/null # ick! but subst_file can't be conditionalized
 454 fi
 455 AC_SUBST_FILE(target_frag)
 456
 457 case ${user_bfd_gas}-${primary_bfd_gas} in
 458   yes-yes | no-no)
 459     # We didn't override user's choice.
 460     ;;
 461   no-yes)
 462     AC_MSG_WARN(Use of BFD is required for ${target}; overriding config options.)
 463     ;;
 464   no-preferred)
 465     primary_bfd_gas=no
 466     ;;
 467   *-preferred)
 468     primary_bfd_gas=yes
 469     ;;
 470   yes-*)
 471     primary_bfd_gas=yes
 472     ;;
 473   -*)
 474     # User specified nothing.
 475     ;;
 476 esac
 477
 478 # Some COFF configurations want these random other flags set.
 479 case ${obj_format} in
 480   coff)
 481     case ${target_cpu_type} in
 482       i386) AC_DEFINE(I386COFF) ;;
 483       m68k) AC_DEFINE(M68KCOFF) ;;
 484       m88k) AC_DEFINE(M88KCOFF) ;;
 485     esac
 486     ;;
 487 esac
 488
 489 # Getting this done right is going to be a bitch.  Each configuration specified
 490 # with --enable-targets=... should be checked for environment, format, cpu, and
 491 # bfd_gas setting.
 492 #
 493 # For each configuration, the necessary object file support code must be linked
 494 # in.  This might be only one, it might be up to four.  The necessary emulation
 495 # code needs to be provided, too.
 496 #
 497 # And then there's "--enable-targets=all"....
 498 #
 499 # For now, just always do it for MIPS ELF or ECOFF configurations.  Sigh.
 500
 501 formats="${obj_format}"
 502 emfiles=""
 503 EMULATIONS=""
 504 GAS_UNIQ(emulations)
 505 for em in . $emulations ; do
 506   case $em in
 507     .)  continue ;;
 508     mipsbelf | mipslelf)
 509         fmt=elf   file=mipself ;;
 510     mipsbecoff | mipslecoff)
 511         fmt=ecoff file=mipsecoff ;;
 512   esac
 513   formats="$formats $fmt"
 514   emfiles="$emfiles e-$file.o"
 515   EMULATIONS="$EMULATIONS &$em,"
 516 done
 517 GAS_UNIQ(formats)
 518 GAS_UNIQ(emfiles)
 519 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 520   for fmt in $formats ; do
 521     case $fmt in
 522       aout)     AC_DEFINE(OBJ_MAYBE_AOUT)    ;;
 523       bout)     AC_DEFINE(OBJ_MAYBE_BOUT)    ;;
 524       coff)     AC_DEFINE(OBJ_MAYBE_COFF)    ;;
 525       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF)   ;;
 526       elf)      AC_DEFINE(OBJ_MAYBE_ELF)     ;;
 527       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC) ;;
 528       hp300)    AC_DEFINE(OBJ_MAYBE_HP300)   ;;
 529       ieee)     AC_DEFINE(OBJ_MAYBE_IEEE)    ;;
 530       som)      AC_DEFINE(OBJ_MAYBE_SOM)     ;;
 531       vms)      AC_DEFINE(OBJ_MAYBE_VMS)     ;;
 532     esac
 533     extra_objects="$extra_objects obj-$fmt.o"
 534   done
 535   obj_format=multi
 536 fi
 537 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 538   te_file=multi
 539   extra_objects="$extra_objects $emfiles"
 540   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 541   AC_DEFINE(USE_EMULATIONS)
 542 fi
 543 AC_SUBST(extra_objects)
 544 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS)
 545 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION")
 546
 547 files="config/tc-${target_cpu_type}.c config/tc-${target_cpu_type}.h \
 548         config/obj-${obj_format}.h config/obj-${obj_format}.c \
 549         config/te-${te_file}.h config/atof-${atof}.c \
 550         config/itbl-${target_cpu_type}.h \
 551         $extra_files"
 552 links="targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c \
 553         itbl-cpu.h \
 554         $extra_links"
 555
 556 case ${primary_bfd_gas}-${target_cpu_type}-${obj_format} in
 557   yes-*-coff)   need_bfd=yes ;;
 558   no-*-coff)    need_bfd=yes
 559                 AC_DEFINE(MANY_SEGMENTS) ;;
 560 esac
 561
 562 reject_dev_configs=yes
 563
 564 case ${reject_dev_configs}-${dev} in
 565   yes-yes) # Oops.
 566     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 567     ;;
 568 esac
 569
 570 AC_SUBST(target_cpu_type)
 571 AC_SUBST(obj_format)
 572 AC_SUBST(atof)
 573 dnl AC_SUBST(emulation)
 574
 575 AC_LINK_FILES($files, $links)
 576
 577 case "${primary_bfd_gas}" in
 578   yes)  AC_DEFINE(BFD_ASSEMBLER)
 579         need_bfd=yes ;;
 580 esac
 581
 582 # do we need the opcodes library?
 583 case "${need_opcodes}" in
 584 yes)
 585   OPCODES_DEP=../opcodes/libopcodes.a
 586   OPCODES_LIB='-L../opcodes -lopcodes'
 587
 588   # We need to handle some special cases for shared libraries.
 589   case "${host}" in
 590   *-*-sunos*)
 591     # On SunOS, we must link against the name we are going to install,
 592     # not -lbfd, since SunOS does not support SONAME.
 593     if test "${shared_opcodes}" = "true"; then
 594       OPCODES_LIB='-L../opcodes -l`echo opcodes | sed '"'"'$(program_transform_name)'"'"'`'
 595     fi
 596     ;;
 597   alpha*-*-osf*)
 598     # On Alpha OSF/1, the native linker searches all the -L
 599     # directories for any LIB.so files, and only then searches for any
 600     # LIB.a files.  That means that if there is an installed
 601     # libbfd.so, but this build is not done with --enable-shared, the
 602     # link will wind up being against the install libbfd.so rather
 603     # than the newly built libbfd.  To avoid this, we must explicitly
 604     # link against libbfd.a when --enable-shared is not used.
 605     if test "${shared_opcodes}" != "true"; then
 606       OPCODES_LIB='../opcodes/libopcodes.a'
 607     fi
 608     ;;
 609   esac
 610   ;;
 611 esac
 612 AC_SUBST(OPCODES_DEP)
 613 AC_SUBST(OPCODES_LIB)
 614
 615 case "${need_bfd}" in
 616 yes)
 617   BFDDEP=../bfd/libbfd.a
 618   BFDLIB='-L../bfd -lbfd'
 619   ALL_OBJ_DEPS="$ALL_OBJ_DEPS ../bfd/bfd.h"
 620
 621   # We need to handle some special cases for shared libraries
 622   case "${host}" in
 623   *-*-sunos*)
 624     # On SunOS, we must link against the name we are going to install,
 625     # not -lbfd, since SunOS does not support SONAME.
 626     if test "${shared_bfd}" = "true"; then
 627       BFDLIB='-L../bfd -l`echo bfd | sed '"'"'$(program_transform_name)'"'"'`'
 628     fi
 629     ;;
 630   alpha*-*-osf*)
 631     # On Alpha OSF/1, the native linker searches all the -L
 632     # directories for any LIB.so files, and only then searches for any
 633     # LIB.a files.  That means that if there is an installed
 634     # libbfd.so, but this build is not done with --enable-shared, the
 635     # link will wind up being against the install libbfd.so rather
 636     # than the newly built libbfd.  To avoid this, we must explicitly
 637     # link against libbfd.a when --enable-shared is not used.
 638     if test "${shared_bfd}" != "true"; then
 639       BFDLIB='../bfd/libbfd.a'
 640     fi
 641     ;;
 642   esac
 643   ;;
 644 esac
 645 AC_SUBST(BFDDEP)
 646 AC_SUBST(BFDLIB)
 647 AC_SUBST(ALL_OBJ_DEPS)
 648
 649 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}")
 650 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}")
 651 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}")
 652 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}")
 653 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}")
 654
 655 AC_PROG_CC
 656 AC_PROG_INSTALL
 657
 658 AC_CHECK_HEADERS(string.h stdlib.h memory.h strings.h unistd.h stdarg.h varargs.h errno.h sys/types.h)
 659
 660 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 661 # people who are not cross-compiling but are compiling cross-assemblers.
 662 AC_MSG_CHECKING(whether compiling a cross-assembler)
 663 if test "${host}" = "${target}"; then
 664   cross_gas=no
 665 else
 666   cross_gas=yes
 667   AC_DEFINE(CROSS_COMPILE)
 668 fi
 669 AC_MSG_RESULT($cross_gas)
 670
 671 dnl ansidecl.h will deal with const
 672 dnl AC_CONST
 673 AC_FUNC_ALLOCA
 674 AC_C_INLINE
 675
 676 # VMS doesn't have unlink.
 677 AC_CHECK_FUNCS(unlink remove, break)
 678
 679 # Some systems don't have sbrk().
 680 AC_CHECK_FUNCS(sbrk)
 681
 682 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
 683 # enough, but on some of those systems, the assert macro relies on requoting
 684 # working properly!
 685 GAS_WORKING_ASSERT
 686
 687 # On some systems, the system header files may not declare malloc, realloc,
 688 # and free.  There are places where gas needs these functions to have been
 689 # declared -- such as when taking their addresses.
 690 gas_test_headers="
 691 #ifdef HAVE_MEMORY_H
 692 #include <memory.h>
 693 #endif
 694 #ifdef HAVE_STRING_H
 695 #include <string.h>
 696 #else
 697 #ifdef HAVE_STRINGS_H
 698 #include <strings.h>
 699 #endif
 700 #endif
 701 #ifdef HAVE_STDLIB_H
 702 #include <stdlib.h>
 703 #endif
 704 #ifdef HAVE_UNISTD_H
 705 #include <unistd.h>
 706 #endif
 707 "
 708 GAS_CHECK_DECL_NEEDED(strstr, f, char *(*f)(), $gas_test_headers)
 709 GAS_CHECK_DECL_NEEDED(malloc, f, char *(*f)(), $gas_test_headers)
 710 GAS_CHECK_DECL_NEEDED(free, f, void (*f)(), $gas_test_headers)
 711 GAS_CHECK_DECL_NEEDED(sbrk, f, char *(*f)(), $gas_test_headers)
 712
 713 # Does errno.h declare errno, or do we have to add a separate declaration
 714 # for it?
 715 GAS_CHECK_DECL_NEEDED(errno, f, int f, [
 716 #ifdef HAVE_ERRNO_H
 717 #include <errno.h>
 718 #endif
 719 ])
 720
 721 HLDFLAGS=
 722 HLDENV=
 723 RPATH_ENVVAR=LD_LIBRARY_PATH
 724 # If we have shared libraries, try to set rpath reasonably.
 725 if test "${shared}" = "true"; then
 726   case "${host}" in
 727   *-*-hpux*)
 728     HLDFLAGS='-Wl,+s,+b,$(libdir)'
 729     RPATH_ENVVAR=SHLIB_PATH
 730     ;;
 731   *-*-irix5* | *-*-irix6*)
 732     HLDFLAGS='-Wl,-rpath,$(libdir)'
 733     ;;
 734   *-*-linux*aout*)
 735     ;;
 736   *-*-linux*)
 737     HLDFLAGS='-Wl,-rpath,$(libdir)'
 738     ;;
 739   *-*-solaris*)
 740     HLDFLAGS='-R $(libdir)'
 741     ;;
 742   *-*-sysv4*)
 743     HLDENV='if test -z "$${LD_RUN_PATH}"; then LD_RUN_PATH=$(libdir); else LD_RUN_PATH=$${LD_RUN_PATH}:$(libdir); fi; export LD_RUN_PATH;'
 744     ;;
 745   esac
 746 fi
 747
 748 # On SunOS, if the linker supports the -rpath option, use it to
 749 # prevent ../bfd and ../opcodes from being included in the run time
 750 # search path.
 751 case "${host}" in
 752   *-*-sunos*)
 753     echo 'main () { }' > conftest.c
 754     ${CC} -o conftest -Wl,-rpath= conftest.c >/dev/null 2>conftest.t
 755     if grep 'unrecognized' conftest.t >/dev/null 2>&1; then
 756       :
 757     elif grep 'No such file' conftest.t >/dev/null 2>&1; then
 758       :
 759     elif grep 'do not mix' conftest.t >/dev/null 2>&1; then
 760       :
 761     elif test "${shared}" = "true"; then
 762       HLDFLAGS='-Wl,-rpath=$(libdir)'
 763     else
 764       HLDFLAGS='-Wl,-rpath='
 765     fi
 766     rm -f conftest.t conftest.c conftest
 767     ;;
 768 esac
 769 AC_SUBST(HLDFLAGS)
 770 AC_SUBST(HLDENV)
 771 AC_SUBST(RPATH_ENVVAR)
 772
 773 dnl This must come last.
 774 AC_OUTPUT(Makefile doc/Makefile .gdbinit:gdbinit.in)