configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011
   3 #   Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include([libtool.m4])
  27 m4_include([ltoptions.m4])
  28 m4_include([ltsugar.m4])
  29 m4_include([ltversion.m4])
  30 m4_include([lt~obsolete.m4])
  31 m4_include([config/cloog.m4])
  32
  33 AC_INIT(move-if-change)
  34 AC_PREREQ(2.64)
  35 AC_DISABLE_OPTION_CHECKING
  36
  37 progname=$0
  38 # if PWD already has a value, it is probably wrong.
  39 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  40
  41 # Export original configure arguments for use by sub-configures.
  42 # Quote arguments with shell meta charatcers.
  43 TOPLEVEL_CONFIGURE_ARGUMENTS=
  44 set -- "$progname" "$@"
  45 for ac_arg
  46 do
  47   case "$ac_arg" in
  48   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  49     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  50     # if the argument is of the form -foo=baz, quote the baz part only
  51     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  52   *) ;;
  53   esac
  54   # Add the quoted argument to the list.
  55   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  56 done
  57 if test "$silent" = yes; then
  58   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  59 fi
  60 # Remove the initial space we just introduced and, as these will be
  61 # expanded by make, quote '$'.
  62 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  63 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  64
  65 # Find the build, host, and target systems.
  66 ACX_NONCANONICAL_BUILD
  67 ACX_NONCANONICAL_HOST
  68 ACX_NONCANONICAL_TARGET
  69
  70 dnl Autoconf 2.5x and later will set a default program prefix if
  71 dnl --target was used, even if it was the same as --host.  Disable
  72 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  73 dnl to take effect.
  74 test "$host_noncanonical" = "$target_noncanonical" &&
  75   test "$program_prefix$program_suffix$program_transform_name" = \
  76     NONENONEs,x,x, &&
  77   program_transform_name=s,y,y,
  78
  79 AC_CANONICAL_SYSTEM
  80 AC_ARG_PROGRAM
  81
  82 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  83 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  84
  85 # Get 'install' or 'install-sh' and its variants.
  86 AC_PROG_INSTALL
  87 ACX_PROG_LN
  88 AC_PROG_LN_S
  89 AC_PROG_SED
  90 AC_PROG_AWK
  91
  92 ### we might need to use some other shell than /bin/sh for running subshells
  93 ### If we are on Windows, search for the shell.  This will permit people
  94 ### to not have /bin/sh, but to be able to see /SOME/PATH/sh configure
  95 ### without also having to set CONFIG_SHELL.  This code will work when
  96 ### using bash, which sets OSTYPE.
  97 case "${OSTYPE}" in
  98 *win32*)
  99   if test x${CONFIG_SHELL} = x ; then
 100     if test ! -f /bin/sh ; then
 101       if test x${SHELL} != x && test -f ${SHELL} ; then
 102         CONFIG_SHELL=${SHELL}
 103         export CONFIG_SHELL
 104       else
 105         for prog in sh sh.exe bash bash.exe; do
 106           IFS="${IFS=   }"; save_ifs="$IFS"; IFS="${IFS}:"
 107           for dir in $PATH; do
 108             test -z "$dir" && dir=.
 109             if test -f $dir/$prog; then
 110               CONFIG_SHELL=$dir/$prog
 111               export CONFIG_SHELL
 112               break
 113             fi
 114           done
 115           IFS="$save_ifs"
 116           test -n "${CONFIG_SHELL}" && break
 117         done
 118       fi
 119     fi
 120   fi
 121   ;;
 122 esac
 123
 124 config_shell=${CONFIG_SHELL-/bin/sh}
 125
 126 moveifchange=${srcdir}/move-if-change
 127
 128 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
 129
 130 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
 131 # a relative path.
 132 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
 133   INSTALL="${srcpwd}/install-sh -c"
 134 fi
 135
 136 # Set srcdir to "." if that's what it is.
 137 # This is important for multilib support.
 138 pwd=`${PWDCMD-pwd}`
 139 if test "${pwd}" = "${srcpwd}" ; then
 140   srcdir=.
 141 fi
 142
 143 topsrcdir=$srcpwd
 144
 145 extra_host_args=
 146
 147 ### To add a new directory to the tree, first choose whether it is a target
 148 ### or a host dependent tool.  Then put it into the appropriate list
 149 ### (library or tools, host or target), doing a dependency sort.
 150
 151 # Subdirs will be configured in the order listed in build_configdirs,
 152 # configdirs, or target_configdirs; see the serialization section below.
 153
 154 # Dependency sorting is only needed when *configuration* must be done in
 155 # a particular order.  In all cases a dependency should be specified in
 156 # the Makefile, whether or not it's implicitly specified here.
 157
 158 # Double entries in build_configdirs, configdirs, or target_configdirs may
 159 # cause circular dependencies and break everything horribly.
 160
 161 # these library is used by various programs built for the build
 162 # environment
 163 #
 164 build_libs="build-libiberty"
 165
 166 # these tools are built for the build environment
 167 build_tools="build-texinfo build-byacc build-flex build-bison build-m4 build-fixincludes"
 168
 169 # these libraries are used by various programs built for the host environment
 170 #
 171 host_libs="intl mmalloc libiberty opcodes bfd readline tcl tk itcl libgui zlib libcpp libdecnumber gmp mpfr mpc ppl cloog libelf libiconv"
 172
 173 # these tools are built for the host environment
 174 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 175 # know that we are building the simulator.
 176 # binutils, gas and ld appear in that order because it makes sense to run
 177 # "make check" in that particular order.
 178 # If --enable-gold is used, "gold" may replace "ld".
 179 host_tools="texinfo byacc flex bison binutils gas ld fixincludes gcc cgen sid sim gdb make patch prms send-pr gprof etc expect dejagnu ash bash bzip2 m4 autoconf automake libtool diff rcs fileutils shellutils time textutils wdiff find uudecode hello tar gzip indent recode release sed utils guile perl gawk findutils gettext zip fastjar gnattools"
 180
 181 # libgcj represents the runtime libraries only used by gcj.
 182 libgcj="target-libffi \
 183         target-zlib \
 184         target-qthreads \
 185         target-libjava"
 186
 187 # these libraries are built for the target environment, and are built after
 188 # the host libraries and the host tools (which may be a cross compiler)
 189 #
 190 target_libraries="target-libgcc \
 191                 target-libiberty \
 192                 target-libgloss \
 193                 target-newlib \
 194                 target-libgomp \
 195                 target-libstdc++-v3 \
 196                 target-libmudflap \
 197                 target-libssp \
 198                 target-libquadmath \
 199                 target-libgfortran \
 200                 target-boehm-gc \
 201                 ${libgcj} \
 202                 target-libobjc \
 203                 target-libada \
 204                 target-libgo"
 205
 206 # these tools are built using the target libraries, and are intended to
 207 # run only in the target environment
 208 #
 209 # note: any program that *uses* libraries that are in the "target_libraries"
 210 # list belongs in this list.
 211 #
 212 target_tools="target-examples target-gperf target-rda"
 213
 214 ################################################################################
 215
 216 ## All tools belong in one of the four categories, and are assigned above
 217 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 218 ## is important because configure will choke if they ever get through.
 219 ## ${configdirs} is directories we build using the host tools.
 220 ## ${target_configdirs} is directories we build using the target tools.
 221 configdirs=`echo ${host_libs} ${host_tools}`
 222 target_configdirs=`echo ${target_libraries} ${target_tools}`
 223 build_configdirs=`echo ${build_libs} ${build_tools}`
 224
 225 m4_divert_text([PARSE_ARGS],
 226 [case $srcdir in
 227   *" "*)
 228 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 229     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 230 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 231     ;;
 232 esac
 233 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 234 ])
 235
 236 ################################################################################
 237
 238 srcname="gnu development package"
 239
 240 # This gets set non-empty for some net releases of packages.
 241 appdirs=""
 242
 243 # Define is_cross_compiler to save on calls to 'test'.
 244 is_cross_compiler=
 245 if test x"${host}" = x"${target}" ; then
 246   is_cross_compiler=no
 247 else
 248   is_cross_compiler=yes
 249 fi
 250
 251 # Find the build and target subdir names.
 252 GCC_TOPLEV_SUBDIRS
 253 # Be sure to cover against remnants of an in-tree build.
 254 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 255   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 256 Use a pristine source tree when building in a separate tree])
 257 fi
 258
 259 # Skipdirs are removed silently.
 260 skipdirs=
 261 # Noconfigdirs are removed loudly.
 262 noconfigdirs=""
 263
 264 use_gnu_ld=
 265 # Make sure we don't let GNU ld be added if we didn't want it.
 266 if test x$with_gnu_ld = xno ; then
 267   use_gnu_ld=no
 268   noconfigdirs="$noconfigdirs ld gold"
 269 fi
 270
 271 use_gnu_as=
 272 # Make sure we don't let GNU as be added if we didn't want it.
 273 if test x$with_gnu_as = xno ; then
 274   use_gnu_as=no
 275   noconfigdirs="$noconfigdirs gas"
 276 fi
 277
 278 use_included_zlib=
 279 # Make sure we don't let ZLIB be added if we didn't want it.
 280 if test x$with_system_zlib = xyes ; then
 281   use_included_zlib=no
 282   noconfigdirs="$noconfigdirs zlib"
 283 fi
 284
 285 # some tools are so dependent upon X11 that if we're not building with X,
 286 # it's not even worth trying to configure, much less build, that tool.
 287
 288 case ${with_x} in
 289   yes | "") ;; # the default value for this tree is that X11 is available
 290   no)
 291     skipdirs="${skipdirs} tk itcl libgui"
 292     # We won't be able to build gdbtk without X.
 293     enable_gdbtk=no
 294     ;;
 295   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 296 esac
 297
 298 # Some are only suitable for cross toolchains.
 299 # Remove these if host=target.
 300 cross_only="target-libgloss target-newlib target-opcodes"
 301
 302 case $is_cross_compiler in
 303   no) skipdirs="${skipdirs} ${cross_only}" ;;
 304 esac
 305
 306 # If both --with-headers and --with-libs are specified, default to
 307 # --without-newlib.
 308 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 309    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 310   if test x"${with_newlib}" = x ; then
 311     with_newlib=no
 312   fi
 313 fi
 314
 315 # Recognize --with-newlib/--without-newlib.
 316 case ${with_newlib} in
 317   no) skipdirs="${skipdirs} target-newlib" ;;
 318   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 319 esac
 320
 321 # Handle --enable-gold, --enable-ld.
 322 # --disable-gold [--enable-ld]
 323 #     Build only ld.  Default option.
 324 # --enable-gold [--enable-ld]
 325 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 326 #     as "ld.bfd" and "ld".
 327 # --enable-gold=default [--enable-ld]
 328 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 329 #     install ld as "ld.bfd".
 330 # --enable-gold[=default] --disable-ld
 331 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 332 # --enable-gold --enable-ld=default
 333 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 334 #     and ld.bfd).
 335 #     In other words, ld is default
 336 # --enable-gold=default --enable-ld=default
 337 #     Error.
 338
 339 default_ld=
 340 AC_ARG_ENABLE(gold,
 341 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 342                 [build gold @<:@ARG={default,yes,no}@:>@])],
 343 ENABLE_GOLD=$enableval,
 344 ENABLE_GOLD=no)
 345 case "${ENABLE_GOLD}" in
 346   yes|default)
 347     # Check for ELF target.
 348     is_elf=no
 349     case "${target}" in
 350       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 351       | *-*-linux* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 352       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 353       | *-*-solaris2* | *-*-nto*)
 354         case "${target}" in
 355           *-*-linux*aout* | *-*-linux*oldld*)
 356             ;;
 357           *)
 358             is_elf=yes
 359             ;;
 360         esac
 361     esac
 362
 363     if test "$is_elf" = "yes"; then
 364       # Check for target supported by gold.
 365       case "${target}" in
 366         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-*)
 367           configdirs="$configdirs gold"
 368           if test x${ENABLE_GOLD} = xdefault; then
 369             default_ld=gold
 370           fi
 371           ENABLE_GOLD=yes
 372           ;;
 373       esac
 374     fi
 375     ;;
 376   no)
 377     ;;
 378   *)
 379     AC_MSG_ERROR([invalid --enable-gold argument])
 380     ;;
 381 esac
 382
 383 AC_ARG_ENABLE(ld,
 384 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 385                 [build ld @<:@ARG={default,yes,no}@:>@])],
 386 ENABLE_LD=$enableval,
 387 ENABLE_LD=yes)
 388
 389 case "${ENABLE_LD}" in
 390   default)
 391     if test x${default_ld} != x; then
 392       AC_MSG_ERROR([either gold or ld can be the default ld])
 393     fi
 394     ;;
 395   yes)
 396     ;;
 397   no)
 398     if test x${ENABLE_GOLD} != xyes; then
 399       AC_MSG_WARN([neither ld nor gold are enabled])
 400     fi
 401     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 402     ;;
 403   *)
 404     AC_MSG_ERROR([invalid --enable-ld argument])
 405     ;;
 406 esac
 407
 408 # Configure extra directories which are host specific
 409
 410 case "${host}" in
 411   *-cygwin*)
 412     configdirs="$configdirs libtermcap" ;;
 413 esac
 414
 415 # A target can indicate whether a language isn't supported for some reason.
 416 # Only spaces may be used in this macro; not newlines or tabs.
 417 unsupported_languages=
 418
 419 # Remove more programs from consideration, based on the host or
 420 # target this usually means that a port of the program doesn't
 421 # exist yet.
 422
 423 case "${host}" in
 424   i[[3456789]]86-*-msdosdjgpp*)
 425     noconfigdirs="$noconfigdirs tcl tk itcl"
 426     ;;
 427 esac
 428
 429
 430 AC_ARG_ENABLE(libquadmath,
 431 AS_HELP_STRING([--disable-libquadmath],
 432   [do not build libquadmath directory]),
 433 ENABLE_LIBQUADMATH=$enableval,
 434 ENABLE_LIBQUADMATH=yes)
 435 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 436   noconfigdirs="$noconfigdirs target-libquadmath"
 437 fi
 438
 439
 440 AC_ARG_ENABLE(libquadmath-support,
 441 AS_HELP_STRING([--disable-libquadmath-support],
 442   [disable libquadmath support for Fortran]),
 443 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 444 ENABLE_LIBQUADMATH_SUPPORT=yes)
 445 enable_libquadmath_support=
 446 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 447   enable_libquadmath_support=no
 448 fi
 449
 450
 451 AC_ARG_ENABLE(libada,
 452 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 453 ENABLE_LIBADA=$enableval,
 454 ENABLE_LIBADA=yes)
 455 if test "${ENABLE_LIBADA}" != "yes" ; then
 456   noconfigdirs="$noconfigdirs gnattools"
 457 fi
 458
 459 AC_ARG_ENABLE(libssp,
 460 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 461 ENABLE_LIBSSP=$enableval,
 462 ENABLE_LIBSSP=yes)
 463
 464 # Save it here so that, even in case of --enable-libgcj, if the Java
 465 # front-end isn't enabled, we still get libgcj disabled.
 466 libgcj_saved=$libgcj
 467 case $enable_libgcj in
 468 yes)
 469   # If we reset it here, it won't get added to noconfigdirs in the
 470   # target-specific build rules, so it will be forcibly enabled
 471   # (unless the Java language itself isn't enabled).
 472   libgcj=
 473   ;;
 474 no)
 475   # Make sure we get it printed in the list of not supported target libs.
 476   # Don't disable libffi, though, other languages use it.
 477   noconfigdirs="$noconfigdirs `echo ${libgcj} | sed -e 's/target-libffi//'`"
 478   # Clear libgcj_saved so that even if java is enabled libffi won't be
 479   # built.
 480   libgcj_saved=
 481   ;;
 482 esac
 483
 484
 485 # Disable libmudflap on some systems.
 486 if test x$enable_libmudflap = x ; then
 487     case "${target}" in
 488     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | bfin*-*-uclinux* | *-*-kopensolaris*-gnu)
 489         # Enable libmudflap by default in GNU and friends.
 490         ;;
 491     *-*-freebsd*)
 492         # Enable libmudflap by default in FreeBSD.
 493         ;;
 494     *)
 495         # Disable it by default everywhere else.
 496         noconfigdirs="$noconfigdirs target-libmudflap"
 497         ;;
 498     esac
 499 fi
 500
 501 # Disable libgomp on non POSIX hosted systems.
 502 if test x$enable_libgomp = x ; then
 503     # Enable libgomp by default on hosted POSIX systems.
 504     case "${target}" in
 505     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 506         ;;
 507     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 508         ;;
 509     *-*-solaris2* | *-*-sysv4* | *-*-irix6* | *-*-osf* | *-*-hpux11*)
 510         ;;
 511     *-*-darwin* | *-*-aix*)
 512         ;;
 513     *)
 514         noconfigdirs="$noconfigdirs target-libgomp"
 515         ;;
 516     esac
 517 fi
 518
 519 # Disable libssp for some systems.
 520 case "${target}" in
 521   avr-*-*)
 522     noconfigdirs="$noconfigdirs target-libssp"
 523     ;;
 524   powerpc-*-aix* | rs6000-*-aix*)
 525     noconfigdirs="$noconfigdirs target-libssp"
 526     ;;
 527   microblaze*)
 528     noconfigdirs="$noconfigdirs target-libssp"
 529     ;;
 530 esac
 531
 532 # Disable target libiberty for some systems.
 533 case "${target}" in
 534   *-*-kaos*)
 535     # Remove unsupported stuff on all kaOS configurations.
 536     skipdirs="target-libiberty"
 537     ;;
 538   *-*-netbsd*)
 539     # Skip some stuff on all NetBSD configurations.
 540     noconfigdirs="$noconfigdirs target-libiberty"
 541     ;;
 542   *-*-netware*)
 543     noconfigdirs="$noconfigdirs target-libiberty"
 544     ;;
 545   *-*-rtems*)
 546     skipdirs="${skipdirs} target-libiberty"
 547     ;;
 548   *-*-tpf*)
 549     noconfigdirs="$noconfigdirs target-libiberty"
 550     ;;
 551   *-*-vxworks*)
 552     noconfigdirs="$noconfigdirs target-libiberty"
 553     ;;
 554   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 555     noconfigdirs="$noconfigdirs target-libiberty"
 556     ;;
 557   arm*-*-symbianelf*)
 558     noconfigdirs="$noconfigdirs target-libiberty"
 559     ;;
 560   avr-*-*)
 561     noconfigdirs="$noconfigdirs target-libiberty"
 562     ;;
 563   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 564     noconfigdirs="$noconfigdirs target-libiberty"
 565     ;;
 566   picochip-*-*)
 567     noconfigdirs="$noconfigdirs target-libiberty"
 568     ;;
 569   mips*-sde-elf*)
 570     skipdirs="$skipdirs target-libiberty"
 571     ;;
 572   ip2k-*-*)
 573     noconfigdirs="$noconfigdirs target-libiberty"
 574     ;;
 575 esac
 576
 577 # Disable libstdc++-v3 for some systems.
 578 case "${target}" in
 579   *-*-vxworks*)
 580     # VxWorks uses the Dinkumware C++ library.
 581     noconfigdirs="$noconfigdirs target-libstdc++-v3"
 582     ;;
 583   arm*-wince-pe*)
 584     # the C++ libraries don't build on top of CE's C libraries
 585     noconfigdirs="$noconfigdirs target-libstdc++-v3"
 586     ;;
 587   avr-*-*)
 588     noconfigdirs="$noconfigdirs target-libstdc++-v3"
 589     ;;
 590 esac
 591
 592 # Disable Fortran for some systems.
 593 case "${target}" in
 594   mmix-*-*)
 595     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 596     unsupported_languages="$unsupported_languages fortran"
 597     ;;
 598 esac
 599
 600 # Default libgloss CPU subdirectory.
 601 libgloss_dir="$target_cpu"
 602
 603 case "${target}" in
 604   *-*-chorusos)
 605     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 606     ;;
 607   powerpc-*-darwin*)
 608     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 609     noconfigdirs="$noconfigdirs sim target-rda"
 610     ;;
 611   i[[3456789]]86-*-darwin*)
 612     noconfigdirs="$noconfigdirs ld gprof"
 613     noconfigdirs="$noconfigdirs sim target-rda"
 614     ;;
 615   x86_64-*-darwin[[912]]*)
 616     noconfigdirs="$noconfigdirs ld gas gprof"
 617     noconfigdirs="$noconfigdirs sim target-rda"
 618     ;;
 619   *-*-darwin*)
 620     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 621     noconfigdirs="$noconfigdirs sim target-rda"
 622     noconfigdirs="$noconfigdirs ${libgcj}"
 623     ;;
 624   *-*-dragonfly*)
 625     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 626     ;;
 627   *-*-freebsd*)
 628     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 629     if test "x$with_gmp" = x && test "x$with_gmp_dir" = x \
 630         && test -f /usr/local/include/gmp.h; then
 631       with_gmp=/usr/local
 632     fi
 633
 634     # Skip some stuff that's unsupported on some FreeBSD configurations.
 635     case "${target}" in
 636       i*86-*-*) ;;
 637       alpha*-*-*) ;;
 638       x86_64-*-*) ;;
 639       *)
 640         noconfigdirs="$noconfigdirs ${libgcj}"
 641         ;;
 642     esac
 643     ;;
 644   *-*-kaos*)
 645     # Remove unsupported stuff on all kaOS configurations.
 646     noconfigdirs="$noconfigdirs target-libgloss"
 647     ;;
 648   *-*-netbsd*)
 649     # Skip some stuff on all NetBSD configurations.
 650     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 651
 652     # Skip some stuff that's unsupported on some NetBSD configurations.
 653     case "${target}" in
 654       i*86-*-netbsdelf*) ;;
 655       arm*-*-netbsdelf*) ;;
 656       *)
 657         noconfigdirs="$noconfigdirs ${libgcj}"
 658         ;;
 659     esac
 660     ;;
 661   *-*-netware*)
 662     noconfigdirs="$noconfigdirs target-newlib target-libgloss ${libgcj}"
 663     ;;
 664   *-*-rtems*)
 665     noconfigdirs="$noconfigdirs target-libgloss ${libgcj}"
 666     ;;
 667     # The tpf target doesn't support gdb yet.
 668   *-*-tpf*)
 669     noconfigdirs="$noconfigdirs target-newlib target-libgloss ${libgcj} gdb tcl tk libgui itcl"
 670     ;;
 671   *-*-uclinux*)
 672     noconfigdirs="$noconfigdirs target-newlib target-libgloss target-rda ${libgcj}"
 673     ;;
 674   *-*-vxworks*)
 675     noconfigdirs="$noconfigdirs target-newlib target-libgloss ${libgcj}"
 676     ;;
 677   alpha*-dec-osf*)
 678     # ld works, but does not support shared libraries.
 679     # newlib is not 64 bit ready.
 680     # gas doesn't generate exception information.
 681     noconfigdirs="$noconfigdirs gas ld target-newlib target-libgloss"
 682     ;;
 683   alpha*-*-*vms*)
 684     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss ${libgcj}"
 685     ;;
 686   alpha*-*-linux*)
 687     # newlib is not 64 bit ready
 688     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 689     ;;
 690   alpha*-*-*)
 691     # newlib is not 64 bit ready
 692     noconfigdirs="$noconfigdirs target-newlib target-libgloss ${libgcj}"
 693     ;;
 694   am33_2.0-*-linux*)
 695     noconfigdirs="$noconfigdirs ${libgcj} target-newlib target-libgloss"
 696     ;;
 697   sh-*-linux*)
 698     noconfigdirs="$noconfigdirs ${libgcj} target-newlib target-libgloss"
 699     ;;
 700   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 701     noconfigdirs="$noconfigdirs ${libgcj}"
 702     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
 703     noconfigdirs="$noconfigdirs target-newlib"
 704     libgloss_dir=wince
 705     ;;
 706   arc-*-*)
 707     noconfigdirs="$noconfigdirs target-libgloss"
 708     ;;
 709   arm-*-coff)
 710     libgloss_dir=arm
 711     ;;
 712   arm-*-elf* | arm*-*-eabi* )
 713     noconfigdirs="$noconfigdirs target-libffi"
 714     libgloss_dir=arm
 715     ;;
 716   arm*-*-linux-gnueabi)
 717     case ${with_newlib} in
 718       no) noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 719     esac
 720     libgloss_dir=arm
 721     ;;
 722   arm*-*-symbianelf*)
 723     noconfigdirs="$noconfigdirs ${libgcj}"
 724     libgloss_dir=arm
 725     ;;
 726   arm-*-pe*)
 727     noconfigdirs="$noconfigdirs target-libgloss ${libgcj}"
 728     ;;
 729   arm-*-riscix*)
 730     noconfigdirs="$noconfigdirs ld target-libgloss"
 731     ;;
 732   avr-*-*)
 733     noconfigdirs="$noconfigdirs ${libgcj}"
 734     ;;
 735   bfin-*-*)
 736     unsupported_languages="$unsupported_languages java"
 737     noconfigdirs="$noconfigdirs target-boehm-gc"
 738     ;;
 739   c4x-*-* | tic4x-*-*)
 740     noconfigdirs="$noconfigdirs target-libgloss"
 741     ;;
 742   tic54x-*-*)
 743     noconfigdirs="$noconfigdirs target-libgloss gdb"
 744     ;;
 745   cr16-*-*)
 746     noconfigdirs="$noconfigdirs ${libgcj} gdb"
 747     ;;
 748   cris-*-* | crisv32-*-*)
 749     unsupported_languages="$unsupported_languages java"
 750     case "${target}" in
 751       *-*-linux*)
 752         noconfigdirs="$noconfigdirs target-newlib target-libgloss";;
 753       *) # See PR46792 regarding target-libffi.
 754         noconfigdirs="$noconfigdirs target-libffi target-boehm-gc";;
 755     esac
 756     libgloss_dir=cris
 757     ;;
 758   d10v-*-*)
 759     noconfigdirs="$noconfigdirs target-libgloss"
 760     ;;
 761   d30v-*-*)
 762     noconfigdirs="$noconfigdirs gdb"
 763     ;;
 764   fr30-*-elf*)
 765     noconfigdirs="$noconfigdirs ${libgcj} gdb"
 766     ;;
 767   frv-*-*)
 768     noconfigdirs="$noconfigdirs ${libgcj}"
 769     ;;
 770   moxie-*-*)
 771     noconfigdirs="$noconfigdirs ${libgcj}"
 772     noconfigdirs="$noconfigdirs gprof"
 773     ;;
 774   h8300*-*-*)
 775     noconfigdirs="$noconfigdirs target-libgloss ${libgcj}"
 776     ;;
 777   h8500-*-*)
 778     noconfigdirs="$noconfigdirs target-libgloss"
 779     ;;
 780   hppa1.1-*-osf* | hppa1.1-*-bsd* )
 781     ;;
 782   hppa*64*-*-linux*)
 783     # In this case, it's because the hppa64-linux target is for
 784     # the kernel only at this point and has no libc, and thus no
 785     # headers, crt*.o, etc., all of which are needed by these.
 786     noconfigdirs="$noconfigdirs target-zlib"
 787     ;;
 788   hppa*-*-linux*)
 789     ;;
 790   hppa*-*-*elf* | \
 791   hppa*-*-lites* | \
 792   hppa*-*-openbsd* | \
 793   hppa*64*-*-*)
 794     noconfigdirs="$noconfigdirs ${libgcj}"
 795     ;;
 796   hppa*-hp-hpux11*)
 797     noconfigdirs="$noconfigdirs ld"
 798     ;;
 799   hppa*-*-pro*)
 800     libgloss_dir=pa
 801     ;;
 802   hppa*-*-*)
 803     # According to Alexandre Oliva <[email protected]>, libjava won't
 804     # build on HP-UX 10.20.
 805     noconfigdirs="$noconfigdirs ld ${libgcj}"
 806     ;;
 807   i960-*-*)
 808     noconfigdirs="$noconfigdirs gdb"
 809     ;;
 810   ia64*-*-elf*)
 811     # No gdb support yet.
 812     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
 813     ;;
 814   ia64*-**-hpux*)
 815     # No ld support yet.
 816     noconfigdirs="$noconfigdirs ${libgcj} libgui itcl ld"
 817     ;;
 818   ia64*-*-*vms*)
 819     # No gdb or ld support yet.
 820     noconfigdirs="$noconfigdirs ${libgcj} readline libgui itcl gdb ld"
 821     ;;
 822   i[[3456789]]86-*-coff | i[[3456789]]86-*-elf)
 823     noconfigdirs="$noconfigdirs ${libgcj}"
 824     libgloss_dir=i386
 825     ;;
 826   i[[3456789]]86-*-linux*)
 827     # This section makes it possible to build newlib natively on linux.
 828     # If we are using a cross compiler then don't configure newlib.
 829     if test x${is_cross_compiler} != xno ; then
 830       noconfigdirs="$noconfigdirs target-newlib"
 831     fi
 832     noconfigdirs="$noconfigdirs target-libgloss"
 833     # If we are not using a cross compiler, do configure newlib.
 834     # Note however, that newlib will only be configured in this situation
 835     # if the --with-newlib option has been given, because otherwise
 836     # 'target-newlib' will appear in skipdirs.
 837     ;;
 838   i[[3456789]]86-w64-mingw*)
 839     noconfigdirs="$noconfigdirs target-libgloss target-newlib ${libgcj}"
 840     ;;
 841   i[[3456789]]86-*-mingw*)
 842     target_configdirs="$target_configdirs target-winsup"
 843     noconfigdirs="$noconfigdirs target-libgloss target-newlib ${libgcj}"
 844     ;;
 845   x86_64-*-mingw*)
 846     noconfigdirs="$noconfigdirs target-libgloss target-newlib ${libgcj}"
 847     ;;
 848   *-*-cygwin*)
 849     target_configdirs="$target_configdirs target-libtermcap target-winsup"
 850     noconfigdirs="$noconfigdirs target-libgloss"
 851     # always build newlib if winsup directory is present.
 852     if test -d "$srcdir/winsup/cygwin"; then
 853       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
 854     elif test -d "$srcdir/newlib"; then
 855       echo "Warning: winsup/cygwin is missing so newlib can't be built."
 856     fi
 857     ;;
 858   i[[3456789]]86-*-interix* )
 859     ;;
 860   i[[3456789]]86-*-pe)
 861     noconfigdirs="$noconfigdirs target-libgloss"
 862     ;;
 863   i[[3456789]]86-*-sco3.2v5*)
 864     # The linker does not yet know about weak symbols in COFF,
 865     # and is not configured to handle mixed ELF and COFF.
 866     noconfigdirs="$noconfigdirs ld target-libgloss"
 867     ;;
 868   i[[3456789]]86-*-sco*)
 869     noconfigdirs="$noconfigdirs gprof target-libgloss"
 870     ;;
 871   i[[3456789]]86-*-solaris2*)
 872     noconfigdirs="$noconfigdirs target-libgloss"
 873     ;;
 874   i[[3456789]]86-*-sysv4*)
 875     noconfigdirs="$noconfigdirs target-libgloss"
 876     ;;
 877   i[[3456789]]86-*-beos*)
 878     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
 879     ;;
 880   i[[3456789]]86-*-rdos*)
 881     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
 882     ;;
 883   m32r-*-*)
 884     noconfigdirs="$noconfigdirs ${libgcj}"
 885     ;;
 886   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 887     libgloss_dir=m68hc11
 888     ;;
 889   m68k-*-elf*)
 890     noconfigdirs="$noconfigdirs ${libgcj}"
 891     ;;
 892   m68*-*-* | fido-*-*)
 893     libgloss_dir=m68k
 894     ;;
 895   mmix-*-*)
 896     noconfigdirs="$noconfigdirs target-libffi target-boehm-gc gdb"
 897     unsupported_languages="$unsupported_languages java"
 898     ;;
 899   mt-*-*)
 900     noconfigdirs="$noconfigdirs sim"
 901     ;;
 902   powerpc-*-aix*)
 903     # copied from rs6000-*-* entry
 904     noconfigdirs="$noconfigdirs gprof target-libgloss target-newlib ${libgcj}"
 905     ;;
 906   powerpc*-*-winnt* | powerpc*-*-pe*)
 907     target_configdirs="$target_configdirs target-winsup"
 908     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
 909     # always build newlib.
 910     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
 911     ;;
 912     # This is temporary until we can link against shared libraries
 913   powerpcle-*-solaris*)
 914     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
 915     libgloss_dir=rs6000
 916     ;;
 917   powerpc-*-beos*)
 918     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
 919     ;;
 920   powerpc-*-eabi)
 921     noconfigdirs="$noconfigdirs ${libgcj}"
 922     libgloss_dir=rs6000
 923     ;;
 924   powerpc-*-eabi* | powerpcle-*-eabi* | powerpc-*-rtems* )
 925     libgloss_dir=rs6000
 926     ;;
 927   rs6000-*-lynxos*)
 928     noconfigdirs="$noconfigdirs target-newlib gprof ${libgcj}"
 929     ;;
 930   rs6000-*-aix*)
 931     noconfigdirs="$noconfigdirs gprof target-libgloss target-newlib ${libgcj}"
 932     ;;
 933   rs6000-*-*)
 934     noconfigdirs="$noconfigdirs gprof ${libgcj}"
 935     ;;
 936   m68k-apollo-*)
 937     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
 938     ;;
 939   microblaze*)
 940     noconfigdirs="$noconfigdirs gprof ${libgcj}"
 941     ;;
 942   mips*-sde-elf*)
 943     noconfigdirs="$noconfigdirs ${libgcj}"
 944     if test x$with_newlib = xyes; then
 945       noconfigdirs="$noconfigdirs gprof"
 946     fi
 947     libgloss_dir=mips
 948     ;;
 949   mips*-*-irix5*)
 950     noconfigdirs="$noconfigdirs gprof target-libgloss"
 951     ;;
 952   mips*-*-irix6*)
 953     # Linking libjava exceeds command-line length limits on at least
 954     # IRIX 6.2, but not on IRIX 6.5.
 955     # Also, boehm-gc won't build on IRIX 6.5, according to Jeffrey Oldham
 956     # <[email protected]>
 957     noconfigdirs="$noconfigdirs gprof target-libgloss ${libgcj}"
 958     ;;
 959   mips*-*-bsd*)
 960     noconfigdirs="$noconfigdirs gprof target-libgloss"
 961     ;;
 962   mips*-*-linux*)
 963     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 964     ;;
 965   mips*-*-*)
 966     noconfigdirs="$noconfigdirs gprof ${libgcj}"
 967     libgloss_dir=mips
 968     ;;
 969   sh-*-* | sh64-*-*)
 970     case "${target}" in
 971       sh*-*-elf)
 972          noconfigdirs="$noconfigdirs ${libgcj}" ;;
 973       *)
 974          noconfigdirs="$noconfigdirs target-libgloss ${libgcj}" ;;
 975     esac
 976     ;;
 977   sparclet-*-aout* | sparc86x-*-*)
 978     libgloss_dir=sparc
 979     ;;
 980   sparc-*-elf*)
 981     noconfigdirs="$noconfigdirs ${libgcj}"
 982     ;;
 983   sparc64-*-elf*)
 984     noconfigdirs="$noconfigdirs ${libgcj}"
 985     libgloss_dir=sparc
 986     ;;
 987   sparclite-*-*)
 988     libgloss_dir=sparc
 989     ;;
 990   sparc-*-sunos4*)
 991     if test x${is_cross_compiler} != xno ; then
 992            noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
 993     else
 994            use_gnu_ld=no
 995     fi
 996     ;;
 997   sparc-*-solaris* | sparc64-*-solaris* | sparcv9-*-solaris*)
 998     ;;
 999   tic6x-*-*)
1000     noconfigdirs="$noconfigdirs gdb sim ${libgcj}"
1001     ;;
1002   v810-*-*)
1003     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1004     ;;
1005   vax-*-*)
1006     noconfigdirs="$noconfigdirs target-newlib target-libgloss ${libgcj}"
1007     ;;
1008   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
1009     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1010     ;;
1011   *-*-lynxos*)
1012     noconfigdirs="$noconfigdirs target-newlib target-libgloss ${libgcj}"
1013     ;;
1014   *-*-*)
1015     noconfigdirs="$noconfigdirs ${libgcj}"
1016     ;;
1017 esac
1018
1019 # If we aren't building newlib, then don't build libgloss, since libgloss
1020 # depends upon some newlib header files.
1021 case "${noconfigdirs}" in
1022   *target-libgloss*) ;;
1023   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1024 esac
1025
1026 # Work in distributions that contain no compiler tools, like Autoconf.
1027 host_makefile_frag=/dev/null
1028 if test -d ${srcdir}/config ; then
1029 case "${host}" in
1030   i[[3456789]]86-*-msdosdjgpp*)
1031     host_makefile_frag="config/mh-djgpp"
1032     ;;
1033   *-cygwin*)
1034     ACX_CHECK_CYGWIN_CAT_WORKS
1035     host_makefile_frag="config/mh-cygwin"
1036     ;;
1037   *-mingw*)
1038     host_makefile_frag="config/mh-mingw"
1039     ;;
1040   *-interix*)
1041     host_makefile_frag="config/mh-interix"
1042     ;;
1043   hppa*-hp-hpux10*)
1044     host_makefile_frag="config/mh-pa-hpux10"
1045     ;;
1046   hppa*-hp-hpux*)
1047     host_makefile_frag="config/mh-pa"
1048     ;;
1049   hppa*-*)
1050     host_makefile_frag="config/mh-pa"
1051     ;;
1052   *-*-darwin*)
1053     host_makefile_frag="config/mh-darwin"
1054     ;;
1055   powerpc-*-aix*)
1056     host_makefile_frag="config/mh-ppc-aix"
1057     ;;
1058   rs6000-*-aix*)
1059     host_makefile_frag="config/mh-ppc-aix"
1060     ;;
1061 esac
1062 fi
1063
1064 if test "${build}" != "${host}" ; then
1065   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1066   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1067   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1068   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1069   GCJ_FOR_BUILD=${GCJ_FOR_BUILD-gcj}
1070   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1071   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1072   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1073   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1074   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1075   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1076   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1077   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1078 else
1079   AR_FOR_BUILD="\$(AR)"
1080   AS_FOR_BUILD="\$(AS)"
1081   CC_FOR_BUILD="\$(CC)"
1082   CXX_FOR_BUILD="\$(CXX)"
1083   GCJ_FOR_BUILD="\$(GCJ)"
1084   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1085   GOC_FOR_BUILD="\$(GOC)"
1086   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1087   LD_FOR_BUILD="\$(LD)"
1088   NM_FOR_BUILD="\$(NM)"
1089   RANLIB_FOR_BUILD="\$(RANLIB)"
1090   WINDRES_FOR_BUILD="\$(WINDRES)"
1091   WINDMC_FOR_BUILD="\$(WINDMC)"
1092 fi
1093
1094 AC_PROG_CC
1095 AC_PROG_CXX
1096
1097 # We must set the default linker to the linker used by gcc for the correct
1098 # operation of libtool.  If LD is not defined and we are using gcc, try to
1099 # set the LD default to the ld used by gcc.
1100 if test -z "$LD"; then
1101   if test "$GCC" = yes; then
1102     case $build in
1103     *-*-mingw*)
1104       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1105     *)
1106       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1107     esac
1108     case $gcc_prog_ld in
1109     # Accept absolute paths.
1110     [[\\/]* | [A-Za-z]:[\\/]*)]
1111       LD="$gcc_prog_ld" ;;
1112     esac
1113   fi
1114 fi
1115
1116 ACX_PROG_GNAT
1117 ACX_PROG_CMP_IGNORE_INITIAL
1118
1119 # See if we are building gcc with C++.
1120 AC_ARG_ENABLE(build-with-cxx,
1121 [AS_HELP_STRING([--enable-build-with-cxx],
1122                 [build with C++ compiler instead of C compiler])],
1123 ENABLE_BUILD_WITH_CXX=$enableval,
1124 ENABLE_BUILD_WITH_CXX=no)
1125
1126 # Used for setting $lt_cv_objdir
1127 _LT_CHECK_OBJDIR
1128
1129 # Check for GMP, MPFR and MPC
1130 gmplibs="-lmpc -lmpfr -lgmp"
1131 gmpinc=
1132 have_gmp=no
1133
1134 # Specify a location for mpc
1135 # check for this first so it ends up on the link line before mpfr.
1136 AC_ARG_WITH(mpc,
1137 [AS_HELP_STRING([--with-mpc=PATH],
1138                 [specify prefix directory for installed MPC package.
1139                  Equivalent to --with-mpc-include=PATH/include
1140                  plus --with-mpc-lib=PATH/lib])])
1141 AC_ARG_WITH(mpc-include,
1142 [AS_HELP_STRING([--with-mpc-include=PATH],
1143                 [specify directory for installed MPC include files])])
1144 AC_ARG_WITH(mpc-lib,
1145 [AS_HELP_STRING([--with-mpc-lib=PATH],
1146                 [specify directory for the installed MPC library])])
1147
1148 if test "x$with_mpc" != x; then
1149   gmplibs="-L$with_mpc/lib $gmplibs"
1150   gmpinc="-I$with_mpc/include $gmpinc"
1151 fi
1152 if test "x$with_mpc_include" != x; then
1153   gmpinc="-I$with_mpc_include $gmpinc"
1154 fi
1155 if test "x$with_mpc_lib" != x; then
1156   gmplibs="-L$with_mpc_lib $gmplibs"
1157 fi
1158 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1159   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1160   gmpinc='-I$$s/mpc/src '"$gmpinc"
1161   # Do not test the mpc version.  Assume that it is sufficient, since
1162   # it is in the source tree, and the library has not been built yet
1163   # but it would be included on the link line in the version check below
1164   # hence making the test fail.
1165   have_gmp=yes
1166 fi
1167
1168 # Specify a location for mpfr
1169 # check for this first so it ends up on the link line before gmp.
1170 AC_ARG_WITH(mpfr-dir,
1171 [AS_HELP_STRING([--with-mpfr-dir=PATH], [this option has been REMOVED])],
1172 [AC_MSG_ERROR([The --with-mpfr-dir=PATH option has been removed.
1173 Use --with-mpfr=PATH or --with-mpfr-include=PATH plus --with-mpfr-lib=PATH])])
1174
1175 AC_ARG_WITH(mpfr,
1176 [AS_HELP_STRING([--with-mpfr=PATH],
1177                 [specify prefix directory for installed MPFR package.
1178                  Equivalent to --with-mpfr-include=PATH/include
1179                  plus --with-mpfr-lib=PATH/lib])])
1180 AC_ARG_WITH(mpfr-include,
1181 [AS_HELP_STRING([--with-mpfr-include=PATH],
1182                 [specify directory for installed MPFR include files])])
1183 AC_ARG_WITH(mpfr-lib,
1184 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1185                 [specify directory for the installed MPFR library])])
1186
1187 if test "x$with_mpfr" != x; then
1188   gmplibs="-L$with_mpfr/lib $gmplibs"
1189   gmpinc="-I$with_mpfr/include $gmpinc"
1190 fi
1191 if test "x$with_mpfr_include" != x; then
1192   gmpinc="-I$with_mpfr_include $gmpinc"
1193 fi
1194 if test "x$with_mpfr_lib" != x; then
1195   gmplibs="-L$with_mpfr_lib $gmplibs"
1196 fi
1197 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1198   gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/'"$lt_cv_objdir $gmplibs"
1199   gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr -I$$s/mpfr '"$gmpinc"
1200   extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/'"$lt_cv_objdir"
1201   # Do not test the mpfr version.  Assume that it is sufficient, since
1202   # it is in the source tree, and the library has not been built yet
1203   # but it would be included on the link line in the version check below
1204   # hence making the test fail.
1205   have_gmp=yes
1206 fi
1207
1208 # Specify a location for gmp
1209 AC_ARG_WITH(gmp-dir,
1210 [AS_HELP_STRING([--with-gmp-dir=PATH], [this option has been REMOVED])],
1211 [AC_MSG_ERROR([The --with-gmp-dir=PATH option has been removed.
1212 Use --with-gmp=PATH or --with-gmp-include=PATH plus --with-gmp-lib=PATH])])
1213
1214 AC_ARG_WITH(gmp,
1215 [AS_HELP_STRING([--with-gmp=PATH],
1216                 [specify prefix directory for the installed GMP package.
1217                  Equivalent to --with-gmp-include=PATH/include
1218                  plus --with-gmp-lib=PATH/lib])])
1219 AC_ARG_WITH(gmp-include,
1220 [AS_HELP_STRING([--with-gmp-include=PATH],
1221                 [specify directory for installed GMP include files])])
1222 AC_ARG_WITH(gmp-lib,
1223 [AS_HELP_STRING([--with-gmp-lib=PATH],
1224                 [specify directory for the installed GMP library])])
1225
1226
1227 if test "x$with_gmp" != x; then
1228   gmplibs="-L$with_gmp/lib $gmplibs"
1229   gmpinc="-I$with_gmp/include $gmpinc"
1230 fi
1231 if test "x$with_gmp_include" != x; then
1232   gmpinc="-I$with_gmp_include $gmpinc"
1233 fi
1234 if test "x$with_gmp_lib" != x; then
1235   gmplibs="-L$with_gmp_lib $gmplibs"
1236 fi
1237 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1238   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1239   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1240   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1241   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1242   # Do not test the gmp version.  Assume that it is sufficient, since
1243   # it is in the source tree, and the library has not been built yet
1244   # but it would be included on the link line in the version check below
1245   # hence making the test fail.
1246   have_gmp=yes
1247 fi
1248
1249 if test -d ${srcdir}/gcc && test "x$have_gmp" = xno; then
1250   have_gmp=yes
1251   saved_CFLAGS="$CFLAGS"
1252   CFLAGS="$CFLAGS $gmpinc"
1253   # Check for the recommended and required versions of GMP.
1254   AC_MSG_CHECKING([for the correct version of gmp.h])
1255   AC_TRY_COMPILE([#include "gmp.h"],[
1256   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1257   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1258   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,0)
1259   choke me
1260   #endif
1261   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1262   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1263   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1264   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1265   choke me
1266   #endif
1267   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1268    [AC_MSG_RESULT([no]); have_gmp=no])
1269
1270   # If we have GMP, check the MPFR version.
1271   if test x"$have_gmp" = xyes; then
1272     # Check for the recommended and required versions of MPFR.
1273     AC_MSG_CHECKING([for the correct version of mpfr.h])
1274     AC_TRY_COMPILE([#include <gmp.h>
1275     #include <mpfr.h>],[
1276     #if MPFR_VERSION < MPFR_VERSION_NUM(2,3,1)
1277     choke me
1278     #endif
1279     ], [AC_TRY_COMPILE([#include <gmp.h>
1280     #include <mpfr.h>],[
1281     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,2)
1282     choke me
1283     #endif
1284     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1285      [AC_MSG_RESULT([no]); have_gmp=no])
1286   fi
1287
1288   # Check for the MPC header version.
1289   if test x"$have_gmp" = xyes ; then
1290     # Check for the recommended and required versions of MPC.
1291     AC_MSG_CHECKING([for the correct version of mpc.h])
1292     AC_TRY_COMPILE([#include <mpc.h>],[
1293     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1294     choke me
1295     #endif
1296     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1297     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1298     choke me
1299     #endif
1300     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1301      [AC_MSG_RESULT([no]); have_gmp=no])
1302   fi
1303
1304   # Now check the MPFR library.
1305   if test x"$have_gmp" = xyes; then
1306     saved_LIBS="$LIBS"
1307     LIBS="$LIBS $gmplibs"
1308     AC_MSG_CHECKING([for the correct version of the gmp/mpfr/mpc libraries])
1309     AC_TRY_LINK([#include <mpc.h>],[
1310     mpfr_t n;
1311     mpfr_t x;
1312     mpc_t c;
1313     int t;
1314     mpfr_init (n);
1315     mpfr_init (x);
1316     mpfr_atan2 (n, n, x, GMP_RNDN);
1317     mpfr_erfc (n, x, GMP_RNDN);
1318     mpfr_subnormalize (x, t, GMP_RNDN);
1319     mpfr_clear(n);
1320     mpfr_clear(x);
1321     mpc_init2 (c, 53);
1322     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1323     mpc_cosh (c, c, MPC_RNDNN);
1324     mpc_pow (c, c, c, MPC_RNDNN);
1325     mpc_acosh (c, c, MPC_RNDNN);
1326     mpc_clear (c);
1327     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1328     LIBS="$saved_LIBS"
1329   fi
1330
1331   CFLAGS="$saved_CFLAGS"
1332
1333 # The library versions listed in the error message below should match
1334 # the HARD-minimums enforced above.
1335   if test x$have_gmp != xyes; then
1336     AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 2.3.1+ and MPC 0.8.0+.
1337 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1338 their locations.  Source code for these libraries can be found at
1339 their respective hosting sites as well as at
1340 ftp://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1341 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1342 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1343 make sure that you have installed both the libraries and the header
1344 files.  They may be located in separate packages.])
1345   fi
1346 fi
1347
1348 # Flags needed for both GMP, MPFR and/or MPC.
1349 AC_SUBST(gmplibs)
1350 AC_SUBST(gmpinc)
1351 AC_SUBST(extra_mpfr_configure_flags)
1352 AC_SUBST(extra_mpc_gmp_configure_flags)
1353 AC_SUBST(extra_mpc_mpfr_configure_flags)
1354
1355 # Allow host libstdc++ to be specified for static linking with PPL.
1356 AC_ARG_WITH(host-libstdcxx,
1357 [AS_HELP_STRING([--with-host-libstdcxx=L],
1358                 [use linker arguments L to link with libstdc++
1359                  when linking with PPL])])
1360
1361 case $with_host_libstdcxx in
1362   no|yes)
1363     AC_MSG_ERROR([-with-host-libstdcxx needs an argument])
1364     ;;
1365 esac
1366
1367 # Linker flags to use for stage1 or when not boostrapping.
1368 AC_ARG_WITH(stage1-ldflags,
1369 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1370 [if test "$withval" = "no" -o "$withval" = "yes"; then
1371    stage1_ldflags=
1372  else
1373    stage1_ldflags=$withval
1374  fi],
1375 [stage1_ldflags=])
1376 AC_SUBST(stage1_ldflags)
1377
1378 # Libraries to use for stage1 or when not bootstrapping.
1379 AC_ARG_WITH(stage1-libs,
1380 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1381 [if test "$withval" = "no" -o "$withval" = "yes"; then
1382    stage1_libs=
1383  else
1384    stage1_libs=$withval
1385  fi],
1386 [stage1_libs=$with_host_libstdcxx])
1387 AC_SUBST(stage1_libs)
1388
1389 # Libraries to use for stage2 and later builds.  This defaults to the
1390 # argument passed to --with-host-libstdcxx.
1391 AC_ARG_WITH(boot-libs,
1392 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1393 [if test "$withval" = "no" -o "$withval" = "yes"; then
1394    poststage1_libs=
1395  else
1396    poststage1_libs=$withval
1397  fi],
1398 [poststage1_libs=$with_host_libstdcxx])
1399 AC_SUBST(poststage1_libs)
1400
1401 # Linker flags to use for stage2 and later builds.
1402 AC_ARG_WITH(boot-ldflags,
1403 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1404                 [linker flags for stage2 and later])],
1405 [if test "$withval" = "no" -o "$withval" = "yes"; then
1406    poststage1_ldflags=
1407  else
1408    poststage1_ldflags=$withval
1409  fi],
1410 [poststage1_ldflags=
1411  # In stages 2 and 3, default to linking libstdc++ and libgcc
1412  # statically.  But if the user explicitly specified the libraries to
1413  # use, trust that they are doing what they want.
1414  if test "$poststage1_libs" = ""; then
1415    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1416  fi])
1417 AC_SUBST(poststage1_ldflags)
1418
1419 # Check for PPL
1420 ppllibs=
1421 pplinc=
1422 pwllib=
1423
1424 AC_ARG_WITH(ppl,
1425 [AS_HELP_STRING([--with-ppl=PATH],
1426                 [specify prefix directory for the installed PPL package.
1427                  Equivalent to --with-ppl-include=PATH/include
1428                  plus --with-ppl-lib=PATH/lib])])
1429 AC_ARG_WITH(ppl-include,
1430 [AS_HELP_STRING([--with-ppl-include=PATH],
1431                 [specify directory for installed PPL include files])])
1432 AC_ARG_WITH(ppl-lib,
1433 [AS_HELP_STRING([--with-ppl-lib=PATH],
1434                 [specify directory for the installed PPL library])])
1435
1436 AC_ARG_ENABLE(ppl-version-check,
1437 [AS_HELP_STRING([--disable-ppl-version-check],
1438                 [disable check for PPL version])])
1439
1440 case $with_ppl in
1441   yes | no | "")
1442     ;;
1443   *)
1444     ppllibs="-L$with_ppl/lib"
1445     pplinc="-I$with_ppl/include $pplinc"
1446     if test -d "$with_ppl/lib" && test -d "$with_ppl/include"; then
1447       with_ppl=yes
1448     else
1449       AC_MSG_ERROR([cannot find directories "$with_ppl/lib" or "$with_ppl/include"])
1450     fi
1451     ;;
1452 esac
1453
1454 if test x"$with_ppl_include" != x; then
1455   pplinc="-I$with_ppl_include $pplinc"
1456   with_ppl=yes
1457 fi
1458
1459 if test "x$with_ppl_lib" != x; then
1460   ppllibs="-L$with_ppl_lib"
1461   with_ppl=yes
1462 fi
1463
1464 if test x"$with_ppl$with_ppl_include$with_ppl_lib" = x && test -d ${srcdir}/ppl; then
1465   if test x"$enable_watchdog" = xyes; then
1466     pwllib="-lpwl"
1467   fi
1468   ppllibs='-L$$r/$(HOST_SUBDIR)/ppl/interfaces/C/'"$lt_cv_objdir"' -L$$r/$(HOST_SUBDIR)/ppl/src/'"$lt_cv_objdir"
1469   pplinc='-I$$r/$(HOST_SUBDIR)/ppl/src -I$$r/$(HOST_SUBDIR)/ppl/interfaces/C '
1470   enable_ppl_version_check=no
1471   with_ppl=yes
1472 fi
1473
1474 if test "x$with_ppl" != xno; then
1475   if test "x$pwllib" = x; then
1476     saved_LIBS="$LIBS"
1477     LIBS="$LIBS $ppllibs -lstdc++ -lm"
1478     AC_CHECK_LIB(pwl, PWL_handle_timeout, [pwllib="-lpwl"])
1479     LIBS="$saved_LIBS"
1480   fi
1481
1482   ppllibs="$ppllibs -lppl_c -lppl $pwllib -lgmpxx"
1483
1484   if test "$enable_ppl_version_check" != no; then
1485     saved_CFLAGS="$CFLAGS"
1486     CFLAGS="$CFLAGS $pplinc $gmpinc"
1487     AC_MSG_CHECKING([for version 0.11 (revision 0 or later) of PPL])
1488     AC_TRY_COMPILE([#include "ppl_c.h"],[
1489     #if PPL_VERSION_MAJOR != 0 || PPL_VERSION_MINOR < 11
1490     choke me
1491     #endif
1492     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); ppllibs= ; pplinc= ; with_ppl=no ])
1493     CFLAGS="$saved_CFLAGS"
1494   fi
1495 fi
1496
1497 # Flags needed for PPL
1498 AC_SUBST(ppllibs)
1499 AC_SUBST(pplinc)
1500
1501
1502 # Check for CLOOG
1503
1504 dnl Provide configure switches and initialize clooginc & clooglibs
1505 dnl with user input.
1506 CLOOG_INIT_FLAGS
1507 if test "x$with_ppl" = "xno"; then
1508   dnl Only execute fail-action, if CLooG has been requested.
1509   CLOOG_REQUESTED([graphite_requested=yes], [graphite_requested=no])
1510   if test "${graphite_requested}" = yes; then
1511     AC_MSG_ERROR([Unable to find a usable PPL.  See config.log for details.])
1512   fi
1513   with_cloog=no
1514 fi
1515 if test "x${with_cloog}" = x && test "x${with_cloog_include}" = x \
1516   && test "x${with_cloog_lib}" = x && test -d ${srcdir}/cloog; then
1517   clooglibs='-L$$r/$(HOST_SUBDIR)/cloog/'"$lt_cv_objdir"' '
1518   clooginc='-I$$r/$(HOST_SUBDIR)/cloog/include -I$$s/cloog/include '
1519 fi
1520 if test "x$with_cloog" != "xno"; then
1521   dnl The minimal version of CLooG required for Graphite.
1522   dnl
1523   dnl If we use CLooG-Legacy, the provided version information is
1524   dnl ignored.
1525   CLOOG_CHECK_VERSION(0,16,1)
1526
1527   dnl Only execute fail-action, if CLooG has been requested.
1528   CLOOG_IF_FAILED([
1529     AC_MSG_ERROR([Unable to find a usable CLooG.  See config.log for details.])])
1530 fi
1531
1532 # Check for LTO support.
1533 AC_ARG_ENABLE(lto,
1534 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1535 enable_lto=$enableval,
1536 enable_lto=yes; default_enable_lto=yes)
1537
1538 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1539   build_lto_plugin=yes
1540 ],[if test x"$default_enable_lto" = x"yes" ; then
1541     case $target in
1542       *-apple-darwin9 | *-cygwin* | *-mingw*) ;;
1543       # On other non-ELF platforms, LTO has yet to be validated.
1544       *) enable_lto=no ;;
1545     esac
1546   else
1547   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1548   # It would also be nice to check the binutils support, but we don't
1549   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1550   # warn during gcc/ subconfigure; unless you're bootstrapping with
1551   # -flto it won't be needed until after installation anyway.
1552     case $target in
1553       *-cygwin* | *-mingw* | *-apple-darwin*) ;;
1554       *) if test x"$enable_lto" = x"yes"; then
1555         AC_MSG_ERROR([LTO support is not enabled for this target.])
1556         fi
1557       ;;
1558     esac
1559   fi
1560   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1561   # Build it unless LTO was explicitly disabled.
1562   case $target in
1563     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1564     *) ;;
1565   esac
1566 ])
1567
1568
1569 # By default, C is the only stage 1 language.
1570 stage1_languages=,c,
1571
1572 # Target libraries that we bootstrap.
1573 bootstrap_target_libs=,target-libgcc,
1574
1575 # Figure out what language subdirectories are present.
1576 # Look if the user specified --enable-languages="..."; if not, use
1577 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1578 # go away some day.
1579 # NB:  embedded tabs in this IF block -- do not untabify
1580 if test -d ${srcdir}/gcc; then
1581   if test x"${enable_languages+set}" != xset; then
1582     if test x"${LANGUAGES+set}" = xset; then
1583       enable_languages="${LANGUAGES}"
1584         echo configure.in: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
1585     else
1586       enable_languages=all
1587     fi
1588   else
1589     if test x"${enable_languages}" = x ||
1590        test x"${enable_languages}" = xyes;
1591        then
1592       echo configure.in: --enable-languages needs at least one language argument 1>&2
1593       exit 1
1594     fi
1595   fi
1596   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
1597
1598   # 'f95' is the old name for the 'fortran' language. We issue a warning
1599   # and make the substitution.
1600   case ,${enable_languages}, in
1601     *,f95,*)
1602       echo configure.in: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
1603       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
1604       ;;
1605   esac
1606
1607   # First scan to see if an enabled language requires some other language.
1608   # We assume that a given config-lang.in will list all the language
1609   # front ends it requires, even if some are required indirectly.
1610   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1611     case ${lang_frag} in
1612       ..) ;;
1613       # The odd quoting in the next line works around
1614       # an apparent bug in bash 1.12 on linux.
1615       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1616       *)
1617         # From the config-lang.in, get $language, $lang_requires, and
1618         # $lang_requires_boot_languages.
1619         language=
1620         lang_requires=
1621         lang_requires_boot_languages=
1622         . ${lang_frag}
1623         for other in ${lang_requires} ${lang_requires_boot_languages}; do
1624           case ,${enable_languages}, in
1625             *,$other,*) ;;
1626             *,all,*) ;;
1627             *,$language,*)
1628               echo " \`$other' language required by \`$language'; enabling" 1>&2
1629               enable_languages="${enable_languages},${other}"
1630               ;;
1631           esac
1632         done
1633         for other in ${lang_requires_boot_languages} ; do
1634           if test "$other" != "c"; then
1635             case ,${enable_stage1_languages}, in
1636               *,$other,*) ;;
1637               *,all,*) ;;
1638               *)
1639                 case ,${enable_languages}, in
1640                   *,$language,*)
1641                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
1642                     enable_stage1_languages="$enable_stage1_languages,${other}"
1643                     ;;
1644                 esac
1645                 ;;
1646             esac
1647           fi
1648         done
1649         ;;
1650     esac
1651   done
1652
1653   new_enable_languages=,c,
1654
1655   # If LTO is enabled, add the LTO front end.
1656   extra_host_libiberty_configure_flags=
1657   if test "$enable_lto" = "yes" ; then
1658     case ,${enable_languages}, in
1659       *,lto,*) ;;
1660       *) enable_languages="${enable_languages},lto" ;;
1661     esac
1662     if test "${build_lto_plugin}" = "yes" ; then
1663       configdirs="$configdirs lto-plugin"
1664       extra_host_libiberty_configure_flags=--enable-shared
1665     fi
1666   fi
1667   AC_SUBST(extra_host_libiberty_configure_flags)
1668
1669   missing_languages=`echo ",$enable_languages," | sed -e s/,all,/,/ -e s/,c,/,/ `
1670   potential_languages=,c,
1671
1672   enabled_target_libs=
1673   disabled_target_libs=
1674
1675   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1676     case ${lang_frag} in
1677       ..) ;;
1678       # The odd quoting in the next line works around
1679       # an apparent bug in bash 1.12 on linux.
1680       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1681       *)
1682         # From the config-lang.in, get $language, $target_libs,
1683         # $lang_dirs, $boot_language, and $build_by_default
1684         language=
1685         target_libs=
1686         lang_dirs=
1687         subdir_requires=
1688         boot_language=no
1689         build_by_default=yes
1690         . ${lang_frag}
1691         if test x${language} = x; then
1692           echo "${lang_frag} doesn't set \$language." 1>&2
1693           exit 1
1694         fi
1695
1696         if test "$language" = "c++" \
1697            && test "$ENABLE_BUILD_WITH_CXX" = "yes"; then
1698           boot_language=yes
1699         fi
1700
1701         case ,${enable_languages}, in
1702           *,${language},*)
1703             # Language was explicitly selected; include it.
1704             add_this_lang=yes
1705             ;;
1706           *,all,*)
1707             # 'all' was selected, select it if it is a default language
1708             add_this_lang=${build_by_default}
1709             ;;
1710           *)
1711             add_this_lang=no
1712             ;;
1713         esac
1714
1715         # Disable languages that need other directories if these aren't available.
1716         for i in $subdir_requires; do
1717           test -f "$srcdir/gcc/$i/config-lang.in" && continue
1718           case ,${enable_languages}, in
1719             *,${language},*)
1720               # Specifically requested language; tell them.
1721               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
1722               ;;
1723             *)
1724               # Silently disable.
1725               add_this_lang=unsupported
1726               ;;
1727           esac
1728         done
1729
1730         # Disable Ada if no preexisting GNAT is available.
1731         case ,${enable_languages},:${language}:${have_gnat} in
1732           *,${language},*:ada:no)
1733             # Specifically requested language; tell them.
1734             AC_MSG_ERROR([GNAT is required to build $language])
1735             ;;
1736           *:ada:no)
1737             # Silently disable.
1738             add_this_lang=unsupported
1739             ;;
1740         esac
1741
1742         # Disable a language that is unsupported by the target.
1743         case " $unsupported_languages " in
1744           *" $language "*)
1745             add_this_lang=unsupported
1746             ;;
1747         esac
1748
1749         case $add_this_lang in
1750           unsupported)
1751             # Remove language-dependent dirs.
1752             disabled_target_libs="$disabled_target_libs $target_libs"
1753             noconfigdirs="$noconfigdirs $lang_dirs"
1754             ;;
1755           no)
1756             # Remove language-dependent dirs; still show language as supported.
1757             disabled_target_libs="$disabled_target_libs $target_libs"
1758             noconfigdirs="$noconfigdirs $lang_dirs"
1759             potential_languages="${potential_languages}${language},"
1760             ;;
1761           yes)
1762             new_enable_languages="${new_enable_languages}${language},"
1763             potential_languages="${potential_languages}${language},"
1764             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
1765             enabled_target_libs="$enabled_target_libs $target_libs"
1766             case "${boot_language}:,$enable_stage1_languages," in
1767               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
1768                 # Add to (comma-separated) list of stage 1 languages.
1769                 case ",$stage1_languages," in
1770                   *,$language,* | ,yes, | ,all,) ;;
1771                   *) stage1_languages="${stage1_languages}${language}," ;;
1772                 esac
1773                 # We need to bootstrap any supporting libraries.
1774                 bootstrap_target_libs="${bootstrap_target_libs}${target_libs},"
1775                 ;;
1776             esac
1777             ;;
1778         esac
1779         ;;
1780     esac
1781   done
1782
1783   # Add target libraries which are only needed for disabled languages
1784   # to noconfigdirs.
1785   if test -n "$disabled_target_libs"; then
1786     for dir in $disabled_target_libs; do
1787       case " $enabled_target_libs " in
1788       *" ${dir} "*) ;;
1789       *) noconfigdirs="$noconfigdirs $dir" ;;
1790       esac
1791     done
1792   fi
1793
1794   AC_ARG_ENABLE(stage1-languages,
1795   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
1796                   [choose additional languages to build during
1797                   stage1.  Mostly useful for compiler development])],
1798   [case ,${enable_stage1_languages}, in
1799     ,no,|,,)
1800       # Set it to something that will have no effect in the loop below
1801       enable_stage1_languages=c ;;
1802     ,yes,)
1803       enable_stage1_languages=`echo $new_enable_languages | \
1804         sed -e "s/^,//" -e "s/,$//" ` ;;
1805     *,all,*)
1806       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
1807         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
1808   esac
1809
1810   # Add "good" languages from enable_stage1_languages to stage1_languages,
1811   # while "bad" languages go in missing_languages.  Leave no duplicates.
1812   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
1813     case $potential_languages in
1814       *,$i,*)
1815         case $stage1_languages in
1816           *,$i,*) ;;
1817           *) stage1_languages="$stage1_languages$i," ;;
1818         esac ;;
1819       *)
1820         case $missing_languages in
1821           *,$i,*) ;;
1822           *) missing_languages="$missing_languages$i," ;;
1823         esac ;;
1824      esac
1825   done])
1826
1827   # Remove leading/trailing commas that were added for simplicity
1828   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
1829   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
1830   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
1831   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
1832
1833   if test "x$missing_languages" != x; then
1834     AC_MSG_ERROR([
1835 The following requested languages could not be built: ${missing_languages}
1836 Supported languages are: ${potential_languages}])
1837   fi
1838   if test "x$new_enable_languages" != "x$enable_languages"; then
1839     echo The following languages will be built: ${new_enable_languages}
1840     enable_languages="$new_enable_languages"
1841   fi
1842
1843   AC_SUBST(stage1_languages)
1844   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
1845 fi
1846
1847 # Handle --disable-<component> generically.
1848 for dir in $configdirs $build_configdirs $target_configdirs ; do
1849   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
1850   varname=`echo $dirname | sed -e s/+/_/g`
1851   if eval test x\${enable_${varname}} "=" xno ; then
1852     noconfigdirs="$noconfigdirs $dir"
1853   fi
1854 done
1855
1856 # Check for Boehm's garbage collector
1857 AC_ARG_ENABLE(objc-gc,
1858 [AS_HELP_STRING([--enable-objc-gc],
1859                 [enable use of Boehm's garbage collector with the
1860                  GNU Objective-C runtime])],
1861 [case ,${enable_languages},:${enable_objc_gc}:${noconfigdirs} in
1862   *,objc,*:*:yes:*target-boehm-gc*)
1863     AC_MSG_ERROR([Boehm's garbage collector was requested yet not supported in this configuration])
1864     ;;
1865 esac])
1866
1867 # Make sure we only build Boehm's garbage collector if required.
1868 case ,${enable_languages},:${enable_objc_gc} in
1869   *,objc,*:yes)
1870     # Keep target-boehm-gc if requested for Objective-C.
1871     ;;
1872   *)
1873     # Otherwise remove target-boehm-gc depending on target-libjava.
1874     if echo " ${noconfigdirs} " | grep "target-libjava" >/dev/null 2>&1; then
1875       noconfigdirs="$noconfigdirs target-boehm-gc"
1876     fi
1877     ;;
1878 esac
1879
1880 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
1881 # $build_configdirs and $target_configdirs.
1882 # If we have the source for $noconfigdirs entries, add them to $notsupp.
1883
1884 notsupp=""
1885 for dir in . $skipdirs $noconfigdirs ; do
1886   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
1887   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1888     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
1889     if test -r $srcdir/$dirname/configure ; then
1890       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1891         true
1892       else
1893         notsupp="$notsupp $dir"
1894       fi
1895     fi
1896   fi
1897   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1898     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
1899     if test -r $srcdir/$dirname/configure ; then
1900       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1901         true
1902       else
1903         notsupp="$notsupp $dir"
1904       fi
1905     fi
1906   fi
1907   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1908     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
1909     if test -r $srcdir/$dirname/configure ; then
1910       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1911         true
1912       else
1913         notsupp="$notsupp $dir"
1914       fi
1915     fi
1916   fi
1917 done
1918
1919 # Sometimes the tools are distributed with libiberty but with no other
1920 # libraries.  In that case, we don't want to build target-libiberty.
1921 # Don't let libgcc imply libiberty either.
1922 if test -n "${target_configdirs}" ; then
1923   libgcc=
1924   others=
1925   for i in `echo ${target_configdirs} | sed -e s/target-//g` ; do
1926     if test "$i" = "libgcc"; then
1927       libgcc=target-libgcc
1928     elif test "$i" != "libiberty" ; then
1929       if test -r $srcdir/$i/configure ; then
1930         others=yes;
1931         break;
1932       fi
1933     fi
1934   done
1935   if test -z "${others}" ; then
1936     target_configdirs=$libgcc
1937   fi
1938 fi
1939
1940 # Quietly strip out all directories which aren't configurable in this tree.
1941 # This relies on all configurable subdirectories being autoconfiscated, which
1942 # is now the case.
1943 build_configdirs_all="$build_configdirs"
1944 build_configdirs=
1945 for i in ${build_configdirs_all} ; do
1946   j=`echo $i | sed -e s/build-//g`
1947   if test -f ${srcdir}/$j/configure ; then
1948     build_configdirs="${build_configdirs} $i"
1949   fi
1950 done
1951
1952 configdirs_all="$configdirs"
1953 configdirs=
1954 for i in ${configdirs_all} ; do
1955   if test -f ${srcdir}/$i/configure ; then
1956     configdirs="${configdirs} $i"
1957   fi
1958 done
1959
1960 target_configdirs_all="$target_configdirs"
1961 target_configdirs=
1962 for i in ${target_configdirs_all} ; do
1963   j=`echo $i | sed -e s/target-//g`
1964   if test -f ${srcdir}/$j/configure ; then
1965     target_configdirs="${target_configdirs} $i"
1966   fi
1967 done
1968
1969 # Produce a warning message for the subdirs we can't configure.
1970 # This isn't especially interesting in the Cygnus tree, but in the individual
1971 # FSF releases, it's important to let people know when their machine isn't
1972 # supported by the one or two programs in a package.
1973
1974 if test -n "${notsupp}" && test -z "${norecursion}" ; then
1975   # If $appdirs is non-empty, at least one of those directories must still
1976   # be configured, or we error out.  (E.g., if the gas release supports a
1977   # specified target in some subdirs but not the gas subdir, we shouldn't
1978   # pretend that all is well.)
1979   if test -n "$appdirs" ; then
1980     for dir in $appdirs ; do
1981       if test -r $dir/Makefile.in ; then
1982         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1983           appdirs=""
1984           break
1985         fi
1986         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
1987           appdirs=""
1988           break
1989         fi
1990       fi
1991     done
1992     if test -n "$appdirs" ; then
1993       echo "*** This configuration is not supported by this package." 1>&2
1994       exit 1
1995     fi
1996   fi
1997   # Okay, some application will build, or we don't care to check.  Still
1998   # notify of subdirs not getting built.
1999   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2000   echo "    ${notsupp}" 1>&2
2001   echo "    (Any other directories should still work fine.)" 1>&2
2002 fi
2003
2004 case "$host" in
2005   *msdosdjgpp*)
2006     enable_gdbtk=no ;;
2007 esac
2008
2009 # To find our prefix, in gcc_cv_tool_prefix.
2010 ACX_TOOL_DIRS
2011
2012 copy_dirs=
2013
2014 AC_ARG_WITH([build-sysroot],
2015   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2016                   [use sysroot as the system root during the build])],
2017   [if test x"$withval" != x ; then
2018      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2019    fi],
2020   [SYSROOT_CFLAGS_FOR_TARGET=])
2021 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2022
2023 AC_ARG_WITH([debug-prefix-map],
2024   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2025                   [map A to B, C to D ... in debug information])],
2026   [if test x"$withval" != x; then
2027      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2028      for debug_map in $withval; do
2029        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2030      done
2031    fi],
2032   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2033 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2034
2035 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2036 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2037 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2038 # We want to ensure that TARGET libraries (which we know are built with
2039 # gcc) are built with "-O2 -g", so include those options when setting
2040 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2041 if test "x$CFLAGS_FOR_TARGET" = x; then
2042   CFLAGS_FOR_TARGET=$CFLAGS
2043   case " $CFLAGS " in
2044     *" -O2 "*) ;;
2045     *) CFLAGS_FOR_TARGET="-O2 $CFLAGS" ;;
2046   esac
2047   case " $CFLAGS " in
2048     *" -g "* | *" -g3 "*) ;;
2049     *) CFLAGS_FOR_TARGET="-g $CFLAGS" ;;
2050   esac
2051 fi
2052 AC_SUBST(CFLAGS_FOR_TARGET)
2053
2054 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2055   CXXFLAGS_FOR_TARGET=$CXXFLAGS
2056   case " $CXXFLAGS " in
2057     *" -O2 "*) ;;
2058     *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS" ;;
2059   esac
2060   case " $CXXFLAGS " in
2061     *" -g "* | *" -g3 "*) ;;
2062     *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS" ;;
2063   esac
2064 fi
2065 AC_SUBST(CXXFLAGS_FOR_TARGET)
2066
2067 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2068 # the named directory are copied to $(tooldir)/sys-include.
2069 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2070   if test x${is_cross_compiler} = xno ; then
2071     echo 1>&2 '***' --with-headers is only supported when cross compiling
2072     exit 1
2073   fi
2074   if test x"${with_headers}" != xyes ; then
2075     x=${gcc_cv_tool_prefix}
2076     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2077   fi
2078 fi
2079
2080 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2081 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2082 # are permitted.
2083 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2084   if test x${is_cross_compiler} = xno ; then
2085     echo 1>&2 '***' --with-libs is only supported when cross compiling
2086     exit 1
2087   fi
2088   if test x"${with_libs}" != xyes ; then
2089     # Copy the libraries in reverse order, so that files in the first named
2090     # library override files in subsequent libraries.
2091     x=${gcc_cv_tool_prefix}
2092     for l in ${with_libs}; do
2093       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2094     done
2095   fi
2096 fi
2097
2098 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2099 #
2100 # This is done by determining whether or not the appropriate directory
2101 # is available, and by checking whether or not specific configurations
2102 # have requested that this magic not happen.
2103 #
2104 # The command line options always override the explicit settings in
2105 # configure.in, and the settings in configure.in override this magic.
2106 #
2107 # If the default for a toolchain is to use GNU as and ld, and you don't
2108 # want to do that, then you should use the --without-gnu-as and
2109 # --without-gnu-ld options for the configure script.  Similarly, if
2110 # the default is to use the included zlib and you don't want to do that,
2111 # you should use the --with-system-zlib option for the configure script.
2112
2113 if test x${use_gnu_as} = x &&
2114    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2115   with_gnu_as=yes
2116   extra_host_args="$extra_host_args --with-gnu-as"
2117 fi
2118
2119 if test x${use_gnu_ld} = x &&
2120    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2121   with_gnu_ld=yes
2122   extra_host_args="$extra_host_args --with-gnu-ld"
2123 fi
2124
2125 if test x${use_included_zlib} = x &&
2126    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2127   :
2128 else
2129   with_system_zlib=yes
2130   extra_host_args="$extra_host_args --with-system-zlib"
2131 fi
2132
2133 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2134 # can detect this case.
2135
2136 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2137   with_newlib=yes
2138   extra_host_args="$extra_host_args --with-newlib"
2139 fi
2140
2141 # Handle ${copy_dirs}
2142 set fnord ${copy_dirs}
2143 shift
2144 while test $# != 0 ; do
2145   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2146     :
2147   else
2148     echo Copying $1 to $2
2149
2150     # Use the install script to create the directory and all required
2151     # parent directories.
2152     if test -d $2 ; then
2153       :
2154     else
2155       echo >config.temp
2156       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2157     fi
2158
2159     # Copy the directory, assuming we have tar.
2160     # FIXME: Should we use B in the second tar?  Not all systems support it.
2161     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2162
2163     # It is the responsibility of the user to correctly adjust all
2164     # symlinks.  If somebody can figure out how to handle them correctly
2165     # here, feel free to add the code.
2166
2167     echo $1 > $2/COPIED
2168   fi
2169   shift; shift
2170 done
2171
2172 # Determine a target-dependent exec_prefix that the installed
2173 # gcc will search in.  Keep this list sorted by triplet, with
2174 # the *-*-osname triplets last.
2175 md_exec_prefix=
2176 case "${target}" in
2177   alpha*-*-*vms*)
2178     md_exec_prefix=/gnu/lib/gcc-lib
2179     ;;
2180   i[[34567]]86-pc-msdosdjgpp*)
2181     md_exec_prefix=/dev/env/DJDIR/bin
2182     ;;
2183   i[[34567]]86-*-sco3.2v5*)
2184     if test $with_gnu_as = yes; then
2185       md_exec_prefix=/usr/gnu/bin
2186     else
2187       md_exec_prefix=/usr/ccs/bin/elf
2188     fi
2189     ;;
2190
2191   mn10300-*-* | \
2192   powerpc-*-chorusos* | \
2193   powerpc*-*-eabi* | \
2194   powerpc*-*-sysv* | \
2195   powerpc*-*-kaos* | \
2196   s390x-ibm-tpf*)
2197     md_exec_prefix=/usr/ccs/bin
2198     ;;
2199   sparc64-*-elf*)
2200     ;;
2201   v850*-*-*)
2202     md_exec_prefix=/usr/ccs/bin
2203     ;;
2204   xtensa*-*-elf*)
2205     ;;
2206
2207   *-*-beos* | \
2208   *-*-elf* | \
2209   *-*-hpux* | \
2210   *-*-netware* | \
2211   *-*-nto-qnx* | \
2212   *-*-rtems* | \
2213   *-*-solaris2* | \
2214   *-*-sysv[[45]]* | \
2215   *-*-vxworks* | \
2216   *-wrs-windiss)
2217     md_exec_prefix=/usr/ccs/bin
2218     ;;
2219 esac
2220
2221 extra_arflags_for_target=
2222 extra_nmflags_for_target=
2223 extra_ranlibflags_for_target=
2224 target_makefile_frag=/dev/null
2225 case "${target}" in
2226   spu-*-*)
2227     target_makefile_frag="config/mt-spu"
2228     ;;
2229   mips*-sde-elf*)
2230     target_makefile_frag="config/mt-sde"
2231     ;;
2232   mipsisa*-*-elfoabi*)
2233     target_makefile_frag="config/mt-mips-elfoabi"
2234     ;;
2235   mips*-*-*linux* | mips*-*-gnu*)
2236     target_makefile_frag="config/mt-mips-gnu"
2237     ;;
2238   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2239     target_makefile_frag="config/mt-gnu"
2240     ;;
2241   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2242     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2243     # commands to handle both 32-bit and 64-bit objects.  These flags are
2244     # harmless if we're using GNU nm or ar.
2245     extra_arflags_for_target=" -X32_64"
2246     extra_nmflags_for_target=" -B -X32_64"
2247     ;;
2248   *-*-darwin[[3-9]]*)
2249     # ranlib before Darwin10 requires the -c flag to look at common symbols.
2250     extra_ranlibflags_for_target=" -c"
2251     ;;
2252 esac
2253
2254 alphaieee_frag=/dev/null
2255 case $target in
2256   alpha*-*-*)
2257     # This just makes sure to use the -mieee option to build target libs.
2258     # This should probably be set individually by each library.
2259     alphaieee_frag="config/mt-alphaieee"
2260     ;;
2261 esac
2262
2263 # If --enable-target-optspace always use -Os instead of -O2 to build
2264 # the target libraries, similarly if it is not specified, use -Os
2265 # on selected platforms.
2266 ospace_frag=/dev/null
2267 case "${enable_target_optspace}:${target}" in
2268   yes:*)
2269     ospace_frag="config/mt-ospace"
2270     ;;
2271   :d30v-*)
2272     ospace_frag="config/mt-d30v"
2273     ;;
2274   :m32r-* | :d10v-* | :fr30-*)
2275     ospace_frag="config/mt-ospace"
2276     ;;
2277   no:* | :*)
2278     ;;
2279   *)
2280     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2281     ;;
2282 esac
2283
2284 # Default to using --with-stabs for certain targets.
2285 if test x${with_stabs} = x ; then
2286   case "${target}" in
2287   mips*-*-irix[[56]]*)
2288     ;;
2289   mips*-*-* | alpha*-*-osf*)
2290     with_stabs=yes;
2291     extra_host_args="${extra_host_args} --with-stabs"
2292     ;;
2293   esac
2294 fi
2295
2296 # hpux11 in 64bit mode has libraries in a weird place.  Arrange to find
2297 # them automatically.
2298 case "${host}" in
2299   hppa*64*-*-hpux11*)
2300     extra_host_args="$extra_host_args -x-libraries=/usr/lib/pa20_64 -x-includes=/usr/X11R6/include"
2301     ;;
2302 esac
2303
2304 # Some systems (e.g., one of the i386-aix systems the gas testers are
2305 # using) don't handle "\$" correctly, so don't use it here.
2306 tooldir='${exec_prefix}'/${target_noncanonical}
2307 build_tooldir=${tooldir}
2308
2309 # Create a .gdbinit file which runs the one in srcdir
2310 # and tells GDB to look there for source files.
2311
2312 if test -r ${srcdir}/.gdbinit ; then
2313   case ${srcdir} in
2314     .) ;;
2315     *) cat > ./.gdbinit <<EOF
2316 # ${NO_EDIT}
2317 dir ${srcdir}
2318 dir .
2319 source ${srcdir}/.gdbinit
2320 EOF
2321     ;;
2322   esac
2323 fi
2324
2325 # Make sure that the compiler is able to generate an executable.  If it
2326 # can't, we are probably in trouble.  We don't care whether we can run the
2327 # executable--we might be using a cross compiler--we only care whether it
2328 # can be created.  At this point the main configure script has set CC.
2329 we_are_ok=no
2330 echo "int main () { return 0; }" > conftest.c
2331 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2332 if test $? = 0 ; then
2333   if test -s conftest || test -s conftest.exe ; then
2334     we_are_ok=yes
2335   fi
2336 fi
2337 case $we_are_ok in
2338   no)
2339     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2340     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2341     rm -f conftest*
2342     exit 1
2343     ;;
2344 esac
2345 rm -f conftest*
2346
2347 # The Solaris /usr/ucb/cc compiler does not appear to work.
2348 case "${host}" in
2349   sparc-sun-solaris2*)
2350       CCBASE="`echo ${CC-cc} | sed 's/ .*$//'`"
2351       if test "`type $CCBASE | sed 's/^[[^/]]*//'`" = "/usr/ucb/cc" ; then
2352           could_use=
2353           test -d /opt/SUNWspro/bin && could_use="/opt/SUNWspro/bin"
2354           if test -d /opt/cygnus/bin ; then
2355               if test "$could_use" = "" ; then
2356                   could_use="/opt/cygnus/bin"
2357               else
2358                   could_use="$could_use or /opt/cygnus/bin"
2359               fi
2360           fi
2361         if test "$could_use" = "" ; then
2362             echo "Warning: compilation may fail because you're using"
2363             echo "/usr/ucb/cc.  You should change your PATH or CC "
2364             echo "variable and rerun configure."
2365         else
2366             echo "Warning: compilation may fail because you're using"
2367             echo "/usr/ucb/cc, when you should use the C compiler from"
2368             echo "$could_use.  You should change your"
2369             echo "PATH or CC variable and rerun configure."
2370         fi
2371       fi
2372   ;;
2373 esac
2374
2375 # Decide which environment variable is used to find dynamic libraries.
2376 case "${host}" in
2377   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2378   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2379   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2380   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2381 esac
2382
2383 # On systems where the dynamic library environment variable is PATH,
2384 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2385 # built executables to PATH.
2386 if test "$RPATH_ENVVAR" = PATH; then
2387   GCC_SHLIB_SUBDIR=/shlib
2388 else
2389   GCC_SHLIB_SUBDIR=
2390 fi
2391
2392 # Record target_configdirs and the configure arguments for target and
2393 # build configuration in Makefile.
2394 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
2395 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
2396
2397 # If we are building libgomp, bootstrap it.
2398 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
2399   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
2400 fi
2401
2402 # Determine whether gdb needs tk/tcl or not.
2403 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
2404 # and in that case we want gdb to be built without tk.  Ugh!
2405 # In fact I believe gdb is the *only* package directly dependent on tk,
2406 # so we should be able to put the 'maybe's in unconditionally and
2407 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
2408 # 100% sure that that's safe though.
2409
2410 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
2411 case "$enable_gdbtk" in
2412   no)
2413     GDB_TK="" ;;
2414   yes)
2415     GDB_TK="${gdb_tk}" ;;
2416   *)
2417     # Only add the dependency on gdbtk when GDBtk is part of the gdb
2418     # distro.  Eventually someone will fix this and move Insight, nee
2419     # gdbtk to a separate directory.
2420     if test -d ${srcdir}/gdb/gdbtk ; then
2421       GDB_TK="${gdb_tk}"
2422     else
2423       GDB_TK=""
2424     fi
2425     ;;
2426 esac
2427 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
2428 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
2429
2430 # Strip out unwanted targets.
2431
2432 # While at that, we remove Makefiles if we were started for recursive
2433 # configuration, so that the top-level Makefile reconfigures them,
2434 # like we used to do when configure itself was recursive.
2435
2436 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
2437 # but now we're fixing up the Makefile ourselves with the additional
2438 # commands passed to AC_CONFIG_FILES.  Use separate variables
2439 # extrasub-{build,host,target} not because there is any reason to split
2440 # the substitutions up that way, but only to remain below the limit of
2441 # 99 commands in a script, for HP-UX sed.
2442 # Do not nest @if/@endif pairs, because configure will not warn you at all.
2443
2444 AC_ARG_ENABLE([bootstrap],
2445 [AS_HELP_STRING([--enable-bootstrap],
2446                 [enable bootstrapping @<:@yes if native build@:>@])],,
2447 enable_bootstrap=default)
2448
2449 # Issue errors and warnings for invalid/strange bootstrap combinations.
2450 case "$configdirs" in
2451   *gcc*) have_compiler=yes ;;
2452   *) have_compiler=no ;;
2453 esac
2454
2455 case "$have_compiler:$host:$target:$enable_bootstrap" in
2456   *:*:*:no) ;;
2457
2458   # Default behavior.  Enable bootstrap if we have a compiler
2459   # and we are in a native configuration.
2460   yes:$build:$build:default)
2461     enable_bootstrap=yes ;;
2462
2463   *:*:*:default)
2464     enable_bootstrap=no ;;
2465
2466   # We have a compiler and we are in a native configuration, bootstrap is ok
2467   yes:$build:$build:yes)
2468     ;;
2469
2470   # Other configurations, but we have a compiler.  Assume the user knows
2471   # what he's doing.
2472   yes:*:*:yes)
2473     AC_MSG_WARN([trying to bootstrap a cross compiler])
2474     ;;
2475
2476   # No compiler: if they passed --enable-bootstrap explicitly, fail
2477   no:*:*:yes)
2478     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
2479
2480   # Fail if wrong command line
2481   *)
2482     AC_MSG_ERROR([invalid option for --enable-bootstrap])
2483     ;;
2484 esac
2485
2486 case ",$enable_languages,:$ENABLE_BUILD_WITH_CXX:$enable_bootstrap" in
2487   *,c++,*:yes:yes) ;;
2488   *:yes:yes)
2489     AC_MSG_ERROR([bootstrapping with --enable-build-with-cxx requires c++ in --enable-languages])
2490     ;;
2491 esac
2492
2493 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
2494   yes:yes:*\ gold\ *:*,c++,*) ;;
2495   yes:yes:*\ gold\ *:*)
2496     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
2497     ;;
2498 esac
2499
2500 # Adjust the toplevel makefile according to whether bootstrap was selected.
2501 case $enable_bootstrap in
2502   yes)
2503     bootstrap_suffix=bootstrap
2504     BUILD_CONFIG=bootstrap-debug
2505     ;;
2506   no)
2507     bootstrap_suffix=no-bootstrap
2508     BUILD_CONFIG=
2509     ;;
2510 esac
2511
2512 AC_MSG_CHECKING(for default BUILD_CONFIG)
2513
2514 AC_ARG_WITH([build-config],
2515   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2516                   [use config/NAME.mk build configuration])],
2517   [case $with_build_config in
2518    yes) with_build_config= ;;
2519    no) with_build_config= BUILD_CONFIG= ;;
2520    esac])
2521
2522 if test "x${with_build_config}" != x; then
2523   BUILD_CONFIG=$with_build_config
2524 else
2525   case $BUILD_CONFIG in
2526   bootstrap-debug)
2527     if echo "int f (void) { return 0; }" > conftest.c &&
2528        ${CC} -c conftest.c &&
2529        mv conftest.o conftest.o.g0 &&
2530        ${CC} -c -g conftest.c &&
2531        mv conftest.o conftest.o.g &&
2532        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
2533       :
2534     else
2535       BUILD_CONFIG=
2536     fi
2537     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2538     ;;
2539   esac
2540 fi
2541 AC_MSG_RESULT($BUILD_CONFIG)
2542 AC_SUBST(BUILD_CONFIG)
2543
2544 extrasub_build=
2545 for module in ${build_configdirs} ; do
2546   if test -z "${no_recursion}" \
2547      && test -f ${build_subdir}/${module}/Makefile; then
2548     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
2549     rm -f ${build_subdir}/${module}/Makefile
2550   fi
2551   extrasub_build="$extrasub_build
2552 /^@if build-$module\$/d
2553 /^@endif build-$module\$/d
2554 /^@if build-$module-$bootstrap_suffix\$/d
2555 /^@endif build-$module-$bootstrap_suffix\$/d"
2556 done
2557 extrasub_host=
2558 for module in ${configdirs} ; do
2559   if test -z "${no_recursion}"; then
2560     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
2561       if test -f ${file}; then
2562         echo 1>&2 "*** removing ${file} to force reconfigure"
2563         rm -f ${file}
2564       fi
2565     done
2566   fi
2567   extrasub_host="$extrasub_host
2568 /^@if $module\$/d
2569 /^@endif $module\$/d
2570 /^@if $module-$bootstrap_suffix\$/d
2571 /^@endif $module-$bootstrap_suffix\$/d"
2572 done
2573 extrasub_target=
2574 for module in ${target_configdirs} ; do
2575   if test -z "${no_recursion}" \
2576      && test -f ${target_subdir}/${module}/Makefile; then
2577     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
2578     rm -f ${target_subdir}/${module}/Makefile
2579   fi
2580
2581   # We only bootstrap target libraries listed in bootstrap_target_libs.
2582   case $bootstrap_target_libs in
2583     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
2584     *) target_bootstrap_suffix=no-bootstrap ;;
2585   esac
2586
2587   extrasub_target="$extrasub_target
2588 /^@if target-$module\$/d
2589 /^@endif target-$module\$/d
2590 /^@if target-$module-$target_bootstrap_suffix\$/d
2591 /^@endif target-$module-$target_bootstrap_suffix\$/d"
2592 done
2593
2594 # Do the final fixup along with target modules.
2595 extrasub_target="$extrasub_target
2596 /^@if /,/^@endif /d"
2597
2598 # Create the serialization dependencies.  This uses a temporary file.
2599
2600 AC_ARG_ENABLE([serial-configure],
2601 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
2602                 [force sequential configuration of
2603                  sub-packages for the host, target or build
2604                  machine, or all sub-packages])])
2605
2606 case ${enable_serial_configure} in
2607   yes)
2608     enable_serial_build_configure=yes
2609     enable_serial_host_configure=yes
2610     enable_serial_target_configure=yes
2611     ;;
2612 esac
2613
2614 # These force 'configure's to be done one at a time, to avoid problems
2615 # with contention over a shared config.cache.
2616 rm -f serdep.tmp
2617 echo '# serdep.tmp' > serdep.tmp
2618 olditem=
2619 test "x${enable_serial_build_configure}" = xyes &&
2620 for item in ${build_configdirs} ; do
2621   case ${olditem} in
2622     "") ;;
2623     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
2624   esac
2625   olditem=${item}
2626 done
2627 olditem=
2628 test "x${enable_serial_host_configure}" = xyes &&
2629 for item in ${configdirs} ; do
2630   case ${olditem} in
2631     "") ;;
2632     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
2633   esac
2634   olditem=${item}
2635 done
2636 olditem=
2637 test "x${enable_serial_target_configure}" = xyes &&
2638 for item in ${target_configdirs} ; do
2639   case ${olditem} in
2640     "") ;;
2641     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
2642   esac
2643   olditem=${item}
2644 done
2645 serialization_dependencies=serdep.tmp
2646 AC_SUBST_FILE(serialization_dependencies)
2647
2648 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
2649 # target, nonopt, and variable assignments.  These are the ones we
2650 # might not want to pass down to subconfigures.  The exception being
2651 # --cache-file=/dev/null, which is used to turn off the use of cache
2652 # files altogether, and which should be passed on to subconfigures.
2653 # Also strip program-prefix, program-suffix, and program-transform-name,
2654 # so that we can pass down a consistent program-transform-name.
2655 baseargs=
2656 tbaseargs=
2657 keep_next=no
2658 skip_next=no
2659 eval "set -- $ac_configure_args"
2660 for ac_arg
2661 do
2662   if test X"$skip_next" = X"yes"; then
2663     skip_next=no
2664     continue
2665   fi
2666   if test X"$keep_next" = X"yes"; then
2667     case $ac_arg in
2668       *\'*)
2669         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2670     esac
2671     baseargs="$baseargs '$ac_arg'"
2672     tbaseargs="$tbaseargs '$ac_arg'"
2673     keep_next=no
2674     continue
2675   fi
2676
2677   # Handle separated arguments.  Based on the logic generated by
2678   # autoconf 2.59.
2679   case $ac_arg in
2680     *=* | --config-cache | -C | -disable-* | --disable-* \
2681       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
2682       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
2683       | -with-* | --with-* | -without-* | --without-* | --x)
2684       separate_arg=no
2685       ;;
2686     -*)
2687       separate_arg=yes
2688       ;;
2689     *)
2690       separate_arg=no
2691       ;;
2692   esac
2693
2694   skip_targ=no
2695   case $ac_arg in
2696 changequote(,)
2697   --with-* | --without-*)
2698     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
2699
2700     case $libopt in
2701     *[-_]include)
2702       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
2703       ;;
2704     *[-_]lib)
2705       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
2706       ;;
2707     *)
2708       lib=$libopt
2709       ;;
2710     esac
2711 changequote([,])
2712
2713     case $lib in
2714     mpc | mpfr | gmp | ppl | cloog)
2715       # If we're processing --with-$lib, --with-$lib-include or
2716       # --with-$lib-lib, for one of the libs above, and target is
2717       # different from host, don't pass the current argument to any
2718       # target library's configure.
2719       if test x$is_cross_compiler = xyes; then
2720         skip_targ=yes
2721       fi
2722       ;;
2723     esac
2724     ;;
2725   esac
2726
2727   case "$ac_arg" in
2728     --cache-file=/dev/null | \
2729     -cache-file=/dev/null )
2730       # Handled here to avoid the test to skip args below.
2731       baseargs="$baseargs '$ac_arg'"
2732       tbaseargs="$tbaseargs '$ac_arg'"
2733       # Assert: $separate_arg should always be no.
2734       keep_next=$separate_arg
2735       ;;
2736     --no*)
2737       continue
2738       ;;
2739     --c* | \
2740     --sr* | \
2741     --ho* | \
2742     --bu* | \
2743     --t* | \
2744     --program-* | \
2745     -cache_file* | \
2746     -srcdir* | \
2747     -host* | \
2748     -build* | \
2749     -target* | \
2750     -program-prefix* | \
2751     -program-suffix* | \
2752     -program-transform-name* )
2753       skip_next=$separate_arg
2754       continue
2755       ;;
2756     -*)
2757       # An option.  Add it.
2758       case $ac_arg in
2759         *\'*)
2760           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2761       esac
2762       baseargs="$baseargs '$ac_arg'"
2763       if test X"$skip_targ" = Xno; then
2764         tbaseargs="$tbaseargs '$ac_arg'"
2765       fi
2766       keep_next=$separate_arg
2767       ;;
2768     *)
2769       # Either a variable assignment, or a nonopt (triplet).  Don't
2770       # pass it down; let the Makefile handle this.
2771       continue
2772       ;;
2773   esac
2774 done
2775 # Remove the initial space we just introduced and, as these will be
2776 # expanded by make, quote '$'.
2777 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
2778
2779 # Add in --program-transform-name, after --program-prefix and
2780 # --program-suffix have been applied to it.  Autoconf has already
2781 # doubled dollar signs and backslashes in program_transform_name; we want
2782 # the backslashes un-doubled, and then the entire thing wrapped in single
2783 # quotes, because this will be expanded first by make and then by the shell.
2784 # Also, because we want to override the logic in subdir configure scripts to
2785 # choose program_transform_name, replace any s,x,x, with s,y,y,.
2786 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
2787 ${program_transform_name}
2788 EOF_SED
2789 gcc_transform_name=`cat conftestsed.out`
2790 rm -f conftestsed.out
2791 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
2792 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
2793 if test "$silent" = yes; then
2794   baseargs="$baseargs --silent"
2795   tbaseargs="$tbaseargs --silent"
2796 fi
2797 baseargs="$baseargs --disable-option-checking"
2798 tbaseargs="$tbaseargs --disable-option-checking"
2799
2800 # Record and document user additions to sub configure arguments.
2801 AC_ARG_VAR([build_configargs],
2802            [additional configure arguments for build directories])
2803 AC_ARG_VAR([host_configargs],
2804            [additional configure arguments for host directories])
2805 AC_ARG_VAR([target_configargs],
2806            [additional configure arguments for target directories])
2807
2808 # For the build-side libraries, we just need to pretend we're native,
2809 # and not use the same cache file.  Multilibs are neither needed nor
2810 # desired.
2811 build_configargs="$build_configargs --cache-file=../config.cache ${baseargs}"
2812
2813 # For host modules, accept cache file option, or specification as blank.
2814 case "${cache_file}" in
2815 "") # empty
2816   cache_file_option="" ;;
2817 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
2818   cache_file_option="--cache-file=${cache_file}" ;;
2819 *) # relative path
2820   cache_file_option="--cache-file=../${cache_file}" ;;
2821 esac
2822
2823 # Host dirs don't like to share a cache file either, horribly enough.
2824 # This seems to be due to autoconf 2.5x stupidity.
2825 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}"
2826
2827 target_configargs="$target_configargs ${tbaseargs}"
2828
2829 # Passing a --with-cross-host argument lets the target libraries know
2830 # whether they are being built with a cross-compiler or being built
2831 # native.  However, it would be better to use other mechanisms to make the
2832 # sorts of decisions they want to make on this basis.  Please consider
2833 # this option to be deprecated.  FIXME.
2834 if test x${is_cross_compiler} = xyes ; then
2835   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
2836 fi
2837
2838 # Default to --enable-multilib.
2839 if test x${enable_multilib} = x ; then
2840   target_configargs="--enable-multilib ${target_configargs}"
2841 fi
2842
2843 # Pass --with-newlib if appropriate.  Note that target_configdirs has
2844 # changed from the earlier setting of with_newlib.
2845 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
2846   target_configargs="--with-newlib ${target_configargs}"
2847 fi
2848
2849 # Different target subdirs use different values of certain variables
2850 # (notably CXX).  Worse, multilibs use *lots* of different values.
2851 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
2852 # it doesn't automatically accept command-line overrides of them.
2853 # This means it's not safe for target subdirs to share a cache file,
2854 # which is disgusting, but there you have it.  Hopefully this can be
2855 # fixed in future.  It's still worthwhile to use a cache file for each
2856 # directory.  I think.
2857
2858 # Pass the appropriate --build, --host, --target and --cache-file arguments.
2859 # We need to pass --target, as newer autoconf's requires consistency
2860 # for target_alias and gcc doesn't manage it consistently.
2861 target_configargs="--cache-file=./config.cache ${target_configargs}"
2862
2863 FLAGS_FOR_TARGET=
2864 case " $target_configdirs " in
2865  *" newlib "*)
2866   case " $target_configargs " in
2867   *" --with-newlib "*)
2868    case "$target" in
2869     *-cygwin*)
2870       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/include -isystem $$s/winsup/cygwin/include -isystem $$s/winsup/w32api/include'
2871       ;;
2872    esac
2873
2874    # If we're not building GCC, don't discard standard headers.
2875    if test -d ${srcdir}/gcc; then
2876      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
2877
2878      if test "${build}" != "${host}"; then
2879        # On Canadian crosses, CC_FOR_TARGET will have already been set
2880        # by `configure', so we won't have an opportunity to add -Bgcc/
2881        # to it.  This is right: we don't want to search that directory
2882        # for binaries, but we want the header files in there, so add
2883        # them explicitly.
2884        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
2885
2886        # Someone might think of using the pre-installed headers on
2887        # Canadian crosses, in case the installed compiler is not fully
2888        # compatible with the compiler being built.  In this case, it
2889        # would be better to flag an error than risking having
2890        # incompatible object files being constructed.  We can't
2891        # guarantee that an error will be flagged, but let's hope the
2892        # compiler will do it, when presented with incompatible header
2893        # files.
2894      fi
2895    fi
2896
2897    case "${target}-${is_cross_compiler}" in
2898    i[[3456789]]86-*-linux*-no)
2899       # Here host == target, so we don't need to build gcc,
2900       # so we don't want to discard standard headers.
2901       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
2902       ;;
2903    *)
2904       # If we're building newlib, use its generic headers last, but search
2905       # for any libc-related directories first (so make it the last -B
2906       # switch).
2907       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
2908
2909       # If we're building libgloss, find the startup file, simulator library
2910       # and linker script.
2911       case " $target_configdirs " in
2912         *" libgloss "*)
2913         # Look for startup file, simulator library and maybe linker script.
2914         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
2915         # Look for libnosys.a in case the target needs it.
2916         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
2917         # Most targets have the linker script in the source directory.
2918         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
2919         ;;
2920       esac
2921       ;;
2922    esac
2923    ;;
2924   esac
2925   ;;
2926 esac
2927
2928 case "$target" in
2929   x86_64-*mingw* | *-w64-mingw*)
2930   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
2931   # however, use a symlink named 'mingw' in ${prefix} .
2932     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
2933     ;;
2934   *-mingw*)
2935   # MinGW can't be handled as Cygwin above since it does not use newlib.
2936     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
2937     ;;
2938 esac
2939
2940 # Allow the user to override the flags for
2941 # our build compiler if desired.
2942 if test x"${build}" = x"${host}" ; then
2943   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
2944   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
2945   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
2946 fi
2947
2948 # On Canadian crosses, we'll be searching the right directories for
2949 # the previously-installed cross compiler, so don't bother to add
2950 # flags for directories within the install tree of the compiler
2951 # being built; programs in there won't even run.
2952 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
2953   # Search for pre-installed headers if nothing else fits.
2954   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
2955 fi
2956
2957 if test "x${use_gnu_ld}" = x &&
2958    echo " ${configdirs} " | grep " ld " > /dev/null ; then
2959   # Arrange for us to find uninstalled linker scripts.
2960   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
2961 fi
2962
2963 # Search for other target-specific linker scripts and such.
2964 case "${target}" in
2965   mep*)
2966     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
2967     ;;
2968 esac
2969
2970 # Makefile fragments.
2971 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
2972 do
2973   eval fragval=\$$frag
2974   if test $fragval != /dev/null; then
2975     eval $frag=${srcdir}/$fragval
2976   fi
2977 done
2978 AC_SUBST_FILE(host_makefile_frag)
2979 AC_SUBST_FILE(target_makefile_frag)
2980 AC_SUBST_FILE(alphaieee_frag)
2981 AC_SUBST_FILE(ospace_frag)
2982
2983 # Miscellanea: directories, flags, etc.
2984 AC_SUBST(RPATH_ENVVAR)
2985 AC_SUBST(GCC_SHLIB_SUBDIR)
2986 AC_SUBST(tooldir)
2987 AC_SUBST(build_tooldir)
2988 AC_SUBST(CONFIGURE_GDB_TK)
2989 AC_SUBST(GDB_TK)
2990 AC_SUBST(INSTALL_GDB_TK)
2991
2992 # Build module lists & subconfigure args.
2993 AC_SUBST(build_configargs)
2994 AC_SUBST(build_configdirs)
2995
2996 # Host module lists & subconfigure args.
2997 AC_SUBST(host_configargs)
2998 AC_SUBST(configdirs)
2999 AC_SUBST(target_configdirs)
3000
3001 # Target module lists & subconfigure args.
3002 AC_SUBST(target_configargs)
3003
3004
3005 # Build tools.
3006 AC_SUBST(AR_FOR_BUILD)
3007 AC_SUBST(AS_FOR_BUILD)
3008 AC_SUBST(CC_FOR_BUILD)
3009 AC_SUBST(CFLAGS_FOR_BUILD)
3010 AC_SUBST(CXXFLAGS_FOR_BUILD)
3011 AC_SUBST(CXX_FOR_BUILD)
3012 AC_SUBST(DLLTOOL_FOR_BUILD)
3013 AC_SUBST(GCJ_FOR_BUILD)
3014 AC_SUBST(GFORTRAN_FOR_BUILD)
3015 AC_SUBST(GOC_FOR_BUILD)
3016 AC_SUBST(LDFLAGS_FOR_BUILD)
3017 AC_SUBST(LD_FOR_BUILD)
3018 AC_SUBST(NM_FOR_BUILD)
3019 AC_SUBST(RANLIB_FOR_BUILD)
3020 AC_SUBST(WINDMC_FOR_BUILD)
3021 AC_SUBST(WINDRES_FOR_BUILD)
3022 AC_SUBST(config_shell)
3023
3024 # Generate default definitions for YACC, M4, LEX and other programs that run
3025 # on the build machine.  These are used if the Makefile can't locate these
3026 # programs in objdir.
3027 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
3028
3029 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
3030 case " $build_configdirs " in
3031   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
3032   *" byacc "*) YACC='$$r/$(BUILD_SUBDIR)/byacc/byacc' ;;
3033 esac
3034
3035 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
3036 case " $build_configdirs " in
3037   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
3038 esac
3039
3040 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
3041 case " $build_configdirs " in
3042   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
3043 esac
3044
3045 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3046 case " $build_configdirs " in
3047   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3048   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
3049 esac
3050
3051 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3052 case " $build_configdirs " in
3053   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3054 esac
3055
3056 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3057 case " $build_configdirs " in
3058   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3059   *)
3060 changequote(,)
3061     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3062     # higher, else we use the "missing" dummy.
3063     if ${MAKEINFO} --version \
3064        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3065       :
3066     else
3067       MAKEINFO="$MISSING makeinfo"
3068     fi
3069     ;;
3070 changequote([,])
3071 esac
3072
3073 # FIXME: expect and dejagnu may become build tools?
3074
3075 AC_CHECK_PROGS(EXPECT, expect, expect)
3076 case " $configdirs " in
3077   *" expect "*)
3078     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3079     ;;
3080 esac
3081
3082 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3083 case " $configdirs " in
3084   *" dejagnu "*)
3085     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3086     ;;
3087 esac
3088
3089
3090 # Host tools.
3091 NCN_STRICT_CHECK_TOOLS(AR, ar)
3092 NCN_STRICT_CHECK_TOOLS(AS, as)
3093 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3094 NCN_STRICT_CHECK_TOOLS(LD, ld)
3095 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3096 NCN_STRICT_CHECK_TOOLS(NM, nm)
3097 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3098 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3099 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3100 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3101 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3102 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3103 AC_SUBST(CC)
3104 AC_SUBST(CXX)
3105 AC_SUBST(CFLAGS)
3106 AC_SUBST(CXXFLAGS)
3107
3108 # Target tools.
3109 AC_ARG_WITH([build-time-tools],
3110   [AS_HELP_STRING([--with-build-time-tools=PATH],
3111                   [use given path to find target tools during the build])],
3112   [case x"$withval" in
3113      x/*) ;;
3114      *)
3115        with_build_time_tools=
3116        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3117        ;;
3118    esac],
3119   [with_build_time_tools=])
3120
3121 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3122 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3123 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3124 NCN_STRICT_CHECK_TARGET_TOOLS(GCJ_FOR_TARGET, gcj)
3125 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3126 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3127
3128 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3129 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3130 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3131 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3132 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3133 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3134 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3135 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3136 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3137 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3138 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3139
3140 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3141
3142 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3143 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3144 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3145 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3146 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3147                 [gcc/g++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs],
3148                 c++)
3149 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3150                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs],
3151                 c++)
3152 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3153 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3154 GCC_TARGET_TOOL(gcj, GCJ_FOR_TARGET, GCJ,
3155                 [gcc/gcj -B$$r/$(HOST_SUBDIR)/gcc/], java)
3156 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3157                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3158 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3159                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3160 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3161 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3162 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3163 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3164 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3165 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3166 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3167 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3168
3169 AC_SUBST(FLAGS_FOR_TARGET)
3170 AC_SUBST(RAW_CXX_FOR_TARGET)
3171
3172 # Certain tools may need extra flags.
3173 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3174 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3175 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3176
3177 # When building target libraries, except in a Canadian cross, we use
3178 # the same toolchain as the compiler we just built.
3179 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3180 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3181 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3182 if test $host = $build; then
3183   case " $configdirs " in
3184     *" gcc "*)
3185       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3186       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3187       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3188       ;;
3189   esac
3190 fi
3191
3192 AC_SUBST(COMPILER_AS_FOR_TARGET)
3193 AC_SUBST(COMPILER_LD_FOR_TARGET)
3194 AC_SUBST(COMPILER_NM_FOR_TARGET)
3195
3196 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3197 AC_ARG_ENABLE(maintainer-mode,
3198 [AS_HELP_STRING([--enable-maintainer-mode],
3199                 [enable make rules and dependencies not useful
3200                  (and sometimes confusing) to the casual installer])],
3201       USE_MAINTAINER_MODE=$enableval,
3202       USE_MAINTAINER_MODE=no)
3203 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3204 AC_SUBST(MAINTAINER_MODE_TRUE)
3205 AC_SUBST(MAINTAINER_MODE_FALSE)
3206 if test "$USE_MAINTAINER_MODE" = yes; then
3207   MAINTAINER_MODE_TRUE=
3208   MAINTAINER_MODE_FALSE='#'
3209 else
3210   MAINTAINER_MODE_TRUE='#'
3211   MAINTAINER_MODE_FALSE=
3212 fi
3213 MAINT=$MAINTAINER_MODE_TRUE
3214 AC_SUBST(MAINT)dnl
3215
3216 # ---------------------
3217 # GCC bootstrap support
3218 # ---------------------
3219
3220 # Stage specific cflags for build.
3221 stage1_cflags="-g"
3222 case $build in
3223   vax-*-*)
3224     case ${GCC} in
3225       yes) stage1_cflags="-g -Wa,-J" ;;
3226       *) stage1_cflags="-g -J" ;;
3227     esac ;;
3228 esac
3229
3230 # This is aimed to mimic bootstrap with a non-GCC compiler to catch problems.
3231 if test "$GCC" = yes -a "$ENABLE_BUILD_WITH_CXX" != yes; then
3232   saved_CFLAGS="$CFLAGS"
3233
3234   # Pass -fkeep-inline-functions for stage 1 if the GCC version supports it.
3235   CFLAGS="$CFLAGS -fkeep-inline-functions"
3236   AC_MSG_CHECKING([whether -fkeep-inline-functions is supported])
3237   AC_TRY_COMPILE([
3238 #if (__GNUC__ < 3) \
3239     || (__GNUC__ == 3 && (__GNUC_MINOR__ < 3 \
3240                           || (__GNUC_MINOR__ == 3 && __GNUC_PATCHLEVEL__ < 1)))
3241 #error http://gcc.gnu.org/PR29382
3242 #endif
3243     ],,
3244     [AC_MSG_RESULT([yes]); stage1_cflags="$stage1_cflags -fkeep-inline-functions"],
3245     [AC_MSG_RESULT([no])])
3246
3247   CFLAGS="$saved_CFLAGS"
3248 fi
3249
3250 AC_SUBST(stage1_cflags)
3251
3252 # Enable --enable-checking in stage1 of the compiler.
3253 AC_ARG_ENABLE(stage1-checking,
3254 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3255                 [choose additional checking for stage1 of the compiler])],
3256 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3257 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3258   stage1_checking=--enable-checking=yes,types
3259 else
3260   stage1_checking=--enable-checking=$enable_checking,types
3261 fi])
3262 AC_SUBST(stage1_checking)
3263
3264 # Enable -Werror in bootstrap stage2 and later.
3265 AC_ARG_ENABLE(werror,
3266 [AS_HELP_STRING([--enable-werror],
3267                 [enable -Werror in bootstrap stage2 and later])], [],
3268 [if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3269   enable_werror=yes
3270 else
3271   enable_werror=no
3272 fi])
3273 case ${enable_werror} in
3274   yes) stage2_werror_flag="--enable-werror-always" ;;
3275   *) stage2_werror_flag="" ;;
3276 esac
3277 AC_SUBST(stage2_werror_flag)
3278
3279 # Specify what files to not compare during bootstrap.
3280
3281 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3282 case "$target" in
3283   hppa*64*-*-hpux*) ;;
3284   hppa*-*-hpux*) compare_exclusions="gcc/cc*-checksum\$(objext) | */libgcc/lib2funcs* | gcc/ada/*tools/*" ;;
3285 esac
3286 case " $configdirs " in
3287 *" ppl "*) compare_exclusions="$compare_exclusions | ppl/src/ppl-config.o" ;;
3288 esac
3289 AC_SUBST(compare_exclusions)
3290
3291 AC_CONFIG_FILES([Makefile],
3292   [sed "$extrasub_build" Makefile |
3293    sed "$extrasub_host" |
3294    sed "$extrasub_target" > mf$$
3295    mv -f mf$$ Makefile],
3296   [extrasub_build="$extrasub_build"
3297    extrasub_host="$extrasub_host"
3298    extrasub_target="$extrasub_target"])
3299 AC_OUTPUT