bitcoin-qt.pro

   1 TEMPLATE = app
   2 TARGET =
   3 INCLUDEPATH += src src/json src/qt
   4 DEFINES += QT_GUI
   5 CONFIG += no_include_pwd
   6
   7 # for boost 1.37, add -mt to the boost libraries
   8 # use: qmake BOOST_LIB_SUFFIX=-mt
   9 # or when linking against a specific BerkelyDB version: BDB_LIB_SUFFIX=-4.8
  10
  11 # Dependency library locations can be customized with BOOST_INCLUDE_PATH,
  12 #    BOOST_LIB_PATH, BDB_INCLUDE_PATH, BDB_LIB_PATH
  13 #    OPENSSL_INCLUDE_PATH and OPENSSL_LIB_PATH respectively
  14
  15 OBJECTS_DIR = build
  16 MOC_DIR = build
  17 UI_DIR = build
  18
  19 # use: qmake "USE_UPNP=0" (disable by default) or "USE_UPNP=1" (enable by default)
  20 # miniupnpc (http://miniupnp.free.fr/files/) must be installed
  21 count(USE_UPNP, 1) {
  22     message(Building with UPNP support)
  23     DEFINES += USE_UPNP=$$USE_UPNP
  24     LIBS += -lminiupnpc
  25 }
  26
  27 # use: qmake "USE_DBUS=1"
  28 contains(USE_DBUS, 1) {
  29     message(Building with DBUS (Freedesktop notifications) support)
  30     DEFINES += USE_DBUS
  31     QT += dbus
  32 }
  33
  34 # use: qmake "USE_SSL=1"
  35 contains(USE_DBUS, 1) {
  36     message(Building with SSL support for RPC)
  37     DEFINES += USE_SSL
  38 }
  39
  40 # for extra security against potential buffer overflows
  41 QMAKE_CXXFLAGS += -fstack-protector
  42 QMAKE_LFLAGS += -fstack-protector
  43
  44 # disable quite some warnings because bitcoin core "sins" a lot
  45 QMAKE_CXXFLAGS_WARN_ON = -fdiagnostics-show-option -Wall -Wno-invalid-offsetof -Wno-unused-variable -Wno-unused-parameter -Wno-sign-compare -Wno-char-subscripts  -Wno-unused-value -Wno-sequence-point -Wno-parentheses -Wno-unknown-pragmas -Wno-switch
  46
  47 # Input
  48 DEPENDPATH += src/qt src src json/include
  49 HEADERS += src/qt/bitcoingui.h \
  50     src/qt/transactiontablemodel.h \
  51     src/qt/addresstablemodel.h \
  52     src/qt/optionsdialog.h \
  53     src/qt/sendcoinsdialog.h \
  54     src/qt/addressbookpage.h \
  55     src/qt/aboutdialog.h \
  56     src/qt/editaddressdialog.h \
  57     src/qt/bitcoinaddressvalidator.h \
  58     src/base58.h \
  59     src/bignum.h \
  60     src/util.h \
  61     src/uint256.h \
  62     src/serialize.h \
  63     src/strlcpy.h \
  64     src/main.h \
  65     src/net.h \
  66     src/key.h \
  67     src/db.h \
  68     src/script.h \
  69     src/noui.h \
  70     src/init.h \
  71     src/headers.h \
  72     src/irc.h \
  73     src/json/json_spirit_writer_template.h \
  74     src/json/json_spirit_writer.h \
  75     src/json/json_spirit_value.h \
  76     src/json/json_spirit_utils.h \
  77     src/json/json_spirit_stream_reader.h \
  78     src/json/json_spirit_reader_template.h \
  79     src/json/json_spirit_reader.h \
  80     src/json/json_spirit_error_position.h \
  81     src/json/json_spirit.h \
  82     src/qt/clientmodel.h \
  83     src/qt/guiutil.h \
  84     src/qt/transactionrecord.h \
  85     src/qt/guiconstants.h \
  86     src/qt/optionsmodel.h \
  87     src/qt/monitoreddatamapper.h \
  88     src/qtui.h \
  89     src/qt/transactiondesc.h \
  90     src/qt/transactiondescdialog.h \
  91     src/qt/bitcoinamountfield.h \
  92     src/wallet.h \
  93     src/keystore.h \
  94     src/qt/transactionfilterproxy.h \
  95     src/qt/transactionview.h \
  96     src/qt/walletmodel.h \
  97     src/bitcoinrpc.h \
  98     src/qt/overviewpage.h \
  99     src/qt/csvmodelwriter.h \
 100     src/crypter.h \
 101     src/qt/sendcoinsentry.h \
 102     src/qt/qvalidatedlineedit.h \
 103     src/qt/bitcoinunits.h \
 104     src/qt/qvaluecombobox.h \
 105     src/qt/askpassphrasedialog.h \
 106     src/protocol.h \
 107     src/qt/notificator.h
 108
 109 SOURCES += src/qt/bitcoin.cpp src/qt/bitcoingui.cpp \
 110     src/qt/transactiontablemodel.cpp \
 111     src/qt/addresstablemodel.cpp \
 112     src/qt/optionsdialog.cpp \
 113     src/qt/sendcoinsdialog.cpp \
 114     src/qt/addressbookpage.cpp \
 115     src/qt/aboutdialog.cpp \
 116     src/qt/editaddressdialog.cpp \
 117     src/qt/bitcoinaddressvalidator.cpp \
 118     src/util.cpp \
 119     src/script.cpp \
 120     src/main.cpp \
 121     src/init.cpp \
 122     src/net.cpp \
 123     src/irc.cpp \
 124     src/db.cpp \
 125     src/json/json_spirit_writer.cpp \
 126     src/json/json_spirit_value.cpp \
 127     src/json/json_spirit_reader.cpp \
 128     src/qt/clientmodel.cpp \
 129     src/qt/guiutil.cpp \
 130     src/qt/transactionrecord.cpp \
 131     src/qt/optionsmodel.cpp \
 132     src/qt/monitoreddatamapper.cpp \
 133     src/qt/transactiondesc.cpp \
 134     src/qt/transactiondescdialog.cpp \
 135     src/qt/bitcoinstrings.cpp \
 136     src/qt/bitcoinamountfield.cpp \
 137     src/wallet.cpp \
 138     src/keystore.cpp \
 139     src/qt/transactionfilterproxy.cpp \
 140     src/qt/transactionview.cpp \
 141     src/qt/walletmodel.cpp \
 142     src/bitcoinrpc.cpp \
 143     src/qt/overviewpage.cpp \
 144     src/qt/csvmodelwriter.cpp \
 145     src/crypter.cpp \
 146     src/qt/sendcoinsentry.cpp \
 147     src/qt/qvalidatedlineedit.cpp \
 148     src/qt/bitcoinunits.cpp \
 149     src/qt/qvaluecombobox.cpp \
 150     src/qt/askpassphrasedialog.cpp \
 151     src/protocol.cpp \
 152     src/qt/notificator.cpp
 153
 154 RESOURCES += \
 155     src/qt/bitcoin.qrc
 156
 157 FORMS += \
 158     src/qt/forms/sendcoinsdialog.ui \
 159     src/qt/forms/addressbookpage.ui \
 160     src/qt/forms/aboutdialog.ui \
 161     src/qt/forms/editaddressdialog.ui \
 162     src/qt/forms/transactiondescdialog.ui \
 163     src/qt/forms/overviewpage.ui \
 164     src/qt/forms/sendcoinsentry.ui \
 165     src/qt/forms/askpassphrasedialog.ui
 166
 167 CODECFORTR = UTF-8
 168
 169 # for lrelease/lupdate
 170 TRANSLATIONS = src/qt/locale/bitcoin_nl.ts src/qt/locale/bitcoin_de.ts \
 171                src/qt/locale/bitcoin_ru.ts
 172
 173 isEmpty(QMAKE_LRELEASE) {
 174     win32:QMAKE_LRELEASE = $$[QT_INSTALL_BINS]\lrelease.exe
 175     else:QMAKE_LRELEASE = $$[QT_INSTALL_BINS]/lrelease
 176 }
 177 isEmpty(TS_DIR):TS_DIR = src/qt/locale
 178 # automatically build translations, so they can be included in resource file
 179 TSQM.name = lrelease ${QMAKE_FILE_IN}
 180 TSQM.input = TRANSLATIONS
 181 TSQM.output = $$TS_DIR/${QMAKE_FILE_BASE}.qm
 182 TSQM.commands = $$QMAKE_LRELEASE ${QMAKE_FILE_IN}
 183 TSQM.CONFIG = no_link
 184 QMAKE_EXTRA_COMPILERS += TSQM
 185 PRE_TARGETDEPS += compiler_TSQM_make_all
 186
 187 # "Other files" to show in Qt Creator
 188 OTHER_FILES += \
 189     doc/*.rst doc/*.txt doc/README README.md
 190
 191 # platform specific defaults, if not overridden on command line
 192 isEmpty(BOOST_LIB_SUFFIX) {
 193     macx:BOOST_LIB_SUFFIX = -mt
 194     windows:BOOST_LIB_SUFFIX = -mgw44-mt-1_43
 195 }
 196
 197 isEmpty(BDB_LIB_PATH) {
 198     macx:BDB_LIB_PATH = /opt/local/lib/db48
 199 }
 200
 201 isEmpty(BDB_INCLUDE_PATH) {
 202     macx:BDB_INCLUDE_PATH = /opt/local/include/db48
 203 }
 204
 205 isEmpty(BOOST_LIB_PATH) {
 206     macx:BOOST_LIB_PATH = /opt/local/lib
 207 }
 208
 209 isEmpty(BOOST_INCLUDE_PATH) {
 210     macx:BOOST_INCLUDE_PATH = /opt/local/include
 211 }
 212
 213 windows:LIBS += -lws2_32 -lgdi32
 214 windows:DEFINES += __WXMSW__
 215 windows:RC_FILE = src/qt/res/bitcoin-qt.rc
 216
 217 macx:DEFINES += __WXMAC_OSX__ MSG_NOSIGNAL=0 BOOST_FILESYSTEM_VERSION=3
 218 macx:ICON = src/qt/res/icons/bitcoin.icns
 219 macx:TARGET = "Bitcoin Qt"
 220
 221 # Set libraries and includes at end, to use platform-defined defaults if not overridden
 222 INCLUDEPATH += $$BOOST_INCLUDE_PATH $$BDB_INCLUDE_PATH $$OPENSSL_INCLUDE_PATH
 223 LIBS += $$join(BOOST_LIB_PATH,,-L,) $$join(BDB_LIB_PATH,,-L,) $$join(OPENSSL_LIB_PATH,,-L,)
 224 LIBS += -lssl -lcrypto -ldb_cxx$$BDB_LIB_SUFFIX
 225 LIBS += -lboost_system$$BOOST_LIB_SUFFIX -lboost_filesystem$$BOOST_LIB_SUFFIX -lboost_program_options$$BOOST_LIB_SUFFIX -lboost_thread$$BOOST_LIB_SUFFIX
 226
 227 system($$QMAKE_LRELEASE -silent $$_PRO_FILE_)