bitcoin-qt.pro

   1 TEMPLATE = app
   2 TARGET =
   3 VERSION = 0.5.0
   4 INCLUDEPATH += src src/json src/qt
   5 DEFINES += QT_GUI
   6 CONFIG += no_include_pwd
   7
   8 # for boost 1.37, add -mt to the boost libraries
   9 # use: qmake BOOST_LIB_SUFFIX=-mt
  10 # or when linking against a specific BerkelyDB version: BDB_LIB_SUFFIX=-4.8
  11
  12 # Dependency library locations can be customized with BOOST_INCLUDE_PATH,
  13 #    BOOST_LIB_PATH, BDB_INCLUDE_PATH, BDB_LIB_PATH
  14 #    OPENSSL_INCLUDE_PATH and OPENSSL_LIB_PATH respectively
  15
  16 OBJECTS_DIR = build
  17 MOC_DIR = build
  18 UI_DIR = build
  19
  20 # use: qmake "USE_UPNP=1" ( enabled by default; default)
  21 #  or: qmake "USE_UPNP=0" (disabled by default)
  22 #  or: qmake "USE_UPNP=-" (not supported)
  23 # miniupnpc (http://miniupnp.free.fr/files/) must be installed for support
  24 contains(USE_UPNP, -) {
  25     message(Building without UPNP support)
  26 } else {
  27     message(Building with UPNP support)
  28     count(USE_UPNP, 0) {
  29         USE_UPNP=1
  30     }
  31     DEFINES += USE_UPNP=$$USE_UPNP
  32     LIBS += -lminiupnpc
  33 }
  34
  35 # use: qmake "USE_DBUS=1"
  36 contains(USE_DBUS, 1) {
  37     message(Building with DBUS (Freedesktop notifications) support)
  38     DEFINES += USE_DBUS
  39     QT += dbus
  40 }
  41
  42 # use: qmake "USE_SSL=1"
  43 contains(USE_SSL, 1) {
  44     message(Building with SSL support for RPC)
  45     DEFINES += USE_SSL
  46 }
  47
  48 # for extra security against potential buffer overflows
  49 QMAKE_CXXFLAGS += -fstack-protector
  50 QMAKE_LFLAGS += -fstack-protector
  51
  52 # disable quite some warnings because bitcoin core "sins" a lot
  53 QMAKE_CXXFLAGS_WARN_ON = -fdiagnostics-show-option -Wall -Wno-invalid-offsetof -Wno-unused-variable -Wno-unused-parameter -Wno-sign-compare -Wno-char-subscripts  -Wno-unused-value -Wno-sequence-point -Wno-parentheses -Wno-unknown-pragmas -Wno-switch
  54
  55 # Input
  56 DEPENDPATH += src/qt src src json/include
  57 HEADERS += src/qt/bitcoingui.h \
  58     src/qt/transactiontablemodel.h \
  59     src/qt/addresstablemodel.h \
  60     src/qt/optionsdialog.h \
  61     src/qt/sendcoinsdialog.h \
  62     src/qt/addressbookpage.h \
  63     src/qt/aboutdialog.h \
  64     src/qt/editaddressdialog.h \
  65     src/qt/bitcoinaddressvalidator.h \
  66     src/base58.h \
  67     src/bignum.h \
  68     src/util.h \
  69     src/uint256.h \
  70     src/serialize.h \
  71     src/strlcpy.h \
  72     src/main.h \
  73     src/net.h \
  74     src/key.h \
  75     src/db.h \
  76     src/script.h \
  77     src/noui.h \
  78     src/init.h \
  79     src/headers.h \
  80     src/irc.h \
  81     src/json/json_spirit_writer_template.h \
  82     src/json/json_spirit_writer.h \
  83     src/json/json_spirit_value.h \
  84     src/json/json_spirit_utils.h \
  85     src/json/json_spirit_stream_reader.h \
  86     src/json/json_spirit_reader_template.h \
  87     src/json/json_spirit_reader.h \
  88     src/json/json_spirit_error_position.h \
  89     src/json/json_spirit.h \
  90     src/qt/clientmodel.h \
  91     src/qt/guiutil.h \
  92     src/qt/transactionrecord.h \
  93     src/qt/guiconstants.h \
  94     src/qt/optionsmodel.h \
  95     src/qt/monitoreddatamapper.h \
  96     src/qtui.h \
  97     src/qt/transactiondesc.h \
  98     src/qt/transactiondescdialog.h \
  99     src/qt/bitcoinamountfield.h \
 100     src/wallet.h \
 101     src/keystore.h \
 102     src/qt/transactionfilterproxy.h \
 103     src/qt/transactionview.h \
 104     src/qt/walletmodel.h \
 105     src/bitcoinrpc.h \
 106     src/qt/overviewpage.h \
 107     src/qt/csvmodelwriter.h \
 108     src/crypter.h \
 109     src/qt/sendcoinsentry.h \
 110     src/qt/qvalidatedlineedit.h \
 111     src/qt/bitcoinunits.h \
 112     src/qt/qvaluecombobox.h \
 113     src/qt/askpassphrasedialog.h \
 114     src/protocol.h \
 115     src/qt/notificator.h
 116
 117 SOURCES += src/qt/bitcoin.cpp src/qt/bitcoingui.cpp \
 118     src/qt/transactiontablemodel.cpp \
 119     src/qt/addresstablemodel.cpp \
 120     src/qt/optionsdialog.cpp \
 121     src/qt/sendcoinsdialog.cpp \
 122     src/qt/addressbookpage.cpp \
 123     src/qt/aboutdialog.cpp \
 124     src/qt/editaddressdialog.cpp \
 125     src/qt/bitcoinaddressvalidator.cpp \
 126     src/util.cpp \
 127     src/script.cpp \
 128     src/main.cpp \
 129     src/init.cpp \
 130     src/net.cpp \
 131     src/irc.cpp \
 132     src/db.cpp \
 133     src/json/json_spirit_writer.cpp \
 134     src/json/json_spirit_value.cpp \
 135     src/json/json_spirit_reader.cpp \
 136     src/qt/clientmodel.cpp \
 137     src/qt/guiutil.cpp \
 138     src/qt/transactionrecord.cpp \
 139     src/qt/optionsmodel.cpp \
 140     src/qt/monitoreddatamapper.cpp \
 141     src/qt/transactiondesc.cpp \
 142     src/qt/transactiondescdialog.cpp \
 143     src/qt/bitcoinstrings.cpp \
 144     src/qt/bitcoinamountfield.cpp \
 145     src/wallet.cpp \
 146     src/keystore.cpp \
 147     src/qt/transactionfilterproxy.cpp \
 148     src/qt/transactionview.cpp \
 149     src/qt/walletmodel.cpp \
 150     src/bitcoinrpc.cpp \
 151     src/qt/overviewpage.cpp \
 152     src/qt/csvmodelwriter.cpp \
 153     src/crypter.cpp \
 154     src/qt/sendcoinsentry.cpp \
 155     src/qt/qvalidatedlineedit.cpp \
 156     src/qt/bitcoinunits.cpp \
 157     src/qt/qvaluecombobox.cpp \
 158     src/qt/askpassphrasedialog.cpp \
 159     src/protocol.cpp \
 160     src/qt/notificator.cpp
 161
 162 RESOURCES += \
 163     src/qt/bitcoin.qrc
 164
 165 FORMS += \
 166     src/qt/forms/sendcoinsdialog.ui \
 167     src/qt/forms/addressbookpage.ui \
 168     src/qt/forms/aboutdialog.ui \
 169     src/qt/forms/editaddressdialog.ui \
 170     src/qt/forms/transactiondescdialog.ui \
 171     src/qt/forms/overviewpage.ui \
 172     src/qt/forms/sendcoinsentry.ui \
 173     src/qt/forms/askpassphrasedialog.ui
 174
 175 CODECFORTR = UTF-8
 176
 177 # for lrelease/lupdate
 178 # also add new translations to src/qt/bitcoin.qrc under translations/
 179 TRANSLATIONS = $$files(src/qt/locale/bitcoin_*.ts)
 180
 181 isEmpty(QMAKE_LRELEASE) {
 182     win32:QMAKE_LRELEASE = $$[QT_INSTALL_BINS]\lrelease.exe
 183     else:QMAKE_LRELEASE = $$[QT_INSTALL_BINS]/lrelease
 184 }
 185 isEmpty(TS_DIR):TS_DIR = src/qt/locale
 186 # automatically build translations, so they can be included in resource file
 187 TSQM.name = lrelease ${QMAKE_FILE_IN}
 188 TSQM.input = TRANSLATIONS
 189 TSQM.output = $$TS_DIR/${QMAKE_FILE_BASE}.qm
 190 TSQM.commands = $$QMAKE_LRELEASE ${QMAKE_FILE_IN}
 191 TSQM.CONFIG = no_link
 192 QMAKE_EXTRA_COMPILERS += TSQM
 193 PRE_TARGETDEPS += compiler_TSQM_make_all
 194
 195 # "Other files" to show in Qt Creator
 196 OTHER_FILES += \
 197     doc/*.rst doc/*.txt doc/README README.md
 198
 199 # platform specific defaults, if not overridden on command line
 200 isEmpty(BOOST_LIB_SUFFIX) {
 201     macx:BOOST_LIB_SUFFIX = -mt
 202     windows:BOOST_LIB_SUFFIX = -mgw44-mt-1_43
 203 }
 204
 205 isEmpty(BDB_LIB_PATH) {
 206     macx:BDB_LIB_PATH = /opt/local/lib/db48
 207 }
 208
 209 isEmpty(BDB_LIB_SUFFIX) {
 210     macx:BDB_LIB_SUFFIX = -4.8
 211 }
 212
 213 isEmpty(BDB_INCLUDE_PATH) {
 214     macx:BDB_INCLUDE_PATH = /opt/local/include/db48
 215 }
 216
 217 isEmpty(BOOST_LIB_PATH) {
 218     macx:BOOST_LIB_PATH = /opt/local/lib
 219 }
 220
 221 isEmpty(BOOST_INCLUDE_PATH) {
 222     macx:BOOST_INCLUDE_PATH = /opt/local/include
 223 }
 224
 225 windows:LIBS += -lws2_32 -lgdi32
 226 windows:DEFINES += WIN32
 227 windows:RC_FILE = src/qt/res/bitcoin-qt.rc
 228
 229 macx:HEADERS += src/qt/macdockiconhandler.h
 230 macx:OBJECTIVE_SOURCES += src/qt/macdockiconhandler.mm
 231 macx:LIBS += -framework Foundation -framework ApplicationServices -framework AppKit
 232 macx:DEFINES += MAC_OSX MSG_NOSIGNAL=0 BOOST_FILESYSTEM_VERSION=3
 233 macx:ICON = src/qt/res/icons/bitcoin.icns
 234 macx:TARGET = "Bitcoin-Qt"
 235
 236 # Set libraries and includes at end, to use platform-defined defaults if not overridden
 237 INCLUDEPATH += $$BOOST_INCLUDE_PATH $$BDB_INCLUDE_PATH $$OPENSSL_INCLUDE_PATH
 238 LIBS += $$join(BOOST_LIB_PATH,,-L,) $$join(BDB_LIB_PATH,,-L,) $$join(OPENSSL_LIB_PATH,,-L,)
 239 LIBS += -lssl -lcrypto -ldb_cxx$$BDB_LIB_SUFFIX
 240 LIBS += -lboost_system$$BOOST_LIB_SUFFIX -lboost_filesystem$$BOOST_LIB_SUFFIX -lboost_program_options$$BOOST_LIB_SUFFIX -lboost_thread$$BOOST_LIB_SUFFIX
 241
 242 system($$QMAKE_LRELEASE -silent $$_PRO_FILE_)