bitcoin-qt.pro

   1 TEMPLATE = app
   2 TARGET =
   3 VERSION = 0.6.99
   4 INCLUDEPATH += src src/json src/qt
   5 DEFINES += QT_GUI BOOST_THREAD_USE_LIB
   6 CONFIG += no_include_pwd
   7
   8 # for boost 1.37, add -mt to the boost libraries
   9 # use: qmake BOOST_LIB_SUFFIX=-mt
  10 # for boost thread win32 with _win32 sufix
  11 # use: BOOST_THREAD_LIB_SUFFIX=_win32-...
  12 # or when linking against a specific BerkelyDB version: BDB_LIB_SUFFIX=-4.8
  13
  14 # Dependency library locations can be customized with BOOST_INCLUDE_PATH,
  15 #    BOOST_LIB_PATH, BDB_INCLUDE_PATH, BDB_LIB_PATH
  16 #    OPENSSL_INCLUDE_PATH and OPENSSL_LIB_PATH respectively
  17
  18 OBJECTS_DIR = build
  19 MOC_DIR = build
  20 UI_DIR = build
  21
  22 # use: qmake "RELEASE=1"
  23 contains(RELEASE, 1) {
  24     # Mac: compile for maximum compatibility (10.5, 32-bit)
  25     macx:QMAKE_CXXFLAGS += -mmacosx-version-min=10.5 -arch i386 -isysroot /Developer/SDKs/MacOSX10.5.sdk
  26
  27     !windows:!macx {
  28         # Linux: static link
  29         LIBS += -Wl,-Bstatic
  30     }
  31 }
  32
  33 # use: qmake "USE_QRCODE=1"
  34 # libqrencode (http://fukuchi.org/works/qrencode/index.en.html) must be installed for support
  35 contains(USE_QRCODE, 1) {
  36     message(Building with QRCode support)
  37     DEFINES += USE_QRCODE
  38     LIBS += -lqrencode
  39 }
  40
  41 # use: qmake "USE_UPNP=1" ( enabled by default; default)
  42 #  or: qmake "USE_UPNP=0" (disabled by default)
  43 #  or: qmake "USE_UPNP=-" (not supported)
  44 # miniupnpc (http://miniupnp.free.fr/files/) must be installed for support
  45 contains(USE_UPNP, -) {
  46     message(Building without UPNP support)
  47 } else {
  48     message(Building with UPNP support)
  49     count(USE_UPNP, 0) {
  50         USE_UPNP=1
  51     }
  52     DEFINES += USE_UPNP=$$USE_UPNP STATICLIB
  53     INCLUDEPATH += $$MINIUPNPC_INCLUDE_PATH
  54     LIBS += $$join(MINIUPNPC_LIB_PATH,,-L,) -lminiupnpc
  55     win32:LIBS += -liphlpapi
  56 }
  57
  58 # use: qmake "USE_DBUS=1"
  59 contains(USE_DBUS, 1) {
  60     message(Building with DBUS (Freedesktop notifications) support)
  61     DEFINES += USE_DBUS
  62     QT += dbus
  63 }
  64
  65 # use: qmake "FIRST_CLASS_MESSAGING=1"
  66 contains(FIRST_CLASS_MESSAGING, 1) {
  67     message(Building with first-class messaging)
  68     DEFINES += FIRST_CLASS_MESSAGING
  69 }
  70
  71 contains(BITCOIN_NEED_QT_PLUGINS, 1) {
  72     DEFINES += BITCOIN_NEED_QT_PLUGINS
  73     QTPLUGIN += qcncodecs qjpcodecs qtwcodecs qkrcodecs qtaccessiblewidgets
  74 }
  75
  76 !windows {
  77     # for extra security against potential buffer overflows
  78     QMAKE_CXXFLAGS += -fstack-protector
  79     QMAKE_LFLAGS += -fstack-protector
  80     # do not enable this on windows, as it will result in a non-working executable!
  81 }
  82
  83 # regenerate src/build.h
  84 !windows || contains(USE_BUILD_INFO, 1) {
  85     genbuild.depends = FORCE
  86     genbuild.commands = cd $$PWD; share/genbuild.sh $$OUT_PWD/build/build.h
  87     genbuild.target = genbuildhook
  88     PRE_TARGETDEPS += genbuildhook
  89     QMAKE_EXTRA_TARGETS += genbuild
  90     DEFINES += HAVE_BUILD_INFO
  91 }
  92
  93 QMAKE_CXXFLAGS_WARN_ON = -fdiagnostics-show-option -Wall -Wextra -Wformat -Wformat-security -Wno-unused-parameter
  94
  95 # Input
  96 DEPENDPATH += src src/json src/qt
  97 HEADERS += src/qt/bitcoingui.h \
  98     src/qt/transactiontablemodel.h \
  99     src/qt/addresstablemodel.h \
 100     src/qt/optionsdialog.h \
 101     src/qt/sendcoinsdialog.h \
 102     src/qt/addressbookpage.h \
 103     src/qt/messagepage.h \
 104     src/qt/aboutdialog.h \
 105     src/qt/editaddressdialog.h \
 106     src/qt/bitcoinaddressvalidator.h \
 107     src/addrman.h \
 108     src/base58.h \
 109     src/bignum.h \
 110     src/checkpoints.h \
 111     src/compat.h \
 112     src/util.h \
 113     src/uint256.h \
 114     src/serialize.h \
 115     src/strlcpy.h \
 116     src/main.h \
 117     src/net.h \
 118     src/key.h \
 119     src/db.h \
 120     src/walletdb.h \
 121     src/script.h \
 122     src/init.h \
 123     src/irc.h \
 124     src/mruset.h \
 125     src/json/json_spirit_writer_template.h \
 126     src/json/json_spirit_writer.h \
 127     src/json/json_spirit_value.h \
 128     src/json/json_spirit_utils.h \
 129     src/json/json_spirit_stream_reader.h \
 130     src/json/json_spirit_reader_template.h \
 131     src/json/json_spirit_reader.h \
 132     src/json/json_spirit_error_position.h \
 133     src/json/json_spirit.h \
 134     src/qt/clientmodel.h \
 135     src/qt/guiutil.h \
 136     src/qt/transactionrecord.h \
 137     src/qt/guiconstants.h \
 138     src/qt/optionsmodel.h \
 139     src/qt/monitoreddatamapper.h \
 140     src/qt/transactiondesc.h \
 141     src/qt/transactiondescdialog.h \
 142     src/qt/bitcoinamountfield.h \
 143     src/wallet.h \
 144     src/keystore.h \
 145     src/qt/transactionfilterproxy.h \
 146     src/qt/transactionview.h \
 147     src/qt/walletmodel.h \
 148     src/bitcoinrpc.h \
 149     src/qt/overviewpage.h \
 150     src/qt/csvmodelwriter.h \
 151     src/crypter.h \
 152     src/qt/sendcoinsentry.h \
 153     src/qt/qvalidatedlineedit.h \
 154     src/qt/bitcoinunits.h \
 155     src/qt/qvaluecombobox.h \
 156     src/qt/askpassphrasedialog.h \
 157     src/protocol.h \
 158     src/qt/notificator.h \
 159     src/qt/qtipcserver.h \
 160     src/allocators.h \
 161     src/ui_interface.h \
 162     src/qt/rpcconsole.h
 163
 164 SOURCES += src/qt/bitcoin.cpp src/qt/bitcoingui.cpp \
 165     src/qt/transactiontablemodel.cpp \
 166     src/qt/addresstablemodel.cpp \
 167     src/qt/optionsdialog.cpp \
 168     src/qt/sendcoinsdialog.cpp \
 169     src/qt/addressbookpage.cpp \
 170     src/qt/messagepage.cpp \
 171     src/qt/aboutdialog.cpp \
 172     src/qt/editaddressdialog.cpp \
 173     src/qt/bitcoinaddressvalidator.cpp \
 174     src/version.cpp \
 175     src/util.cpp \
 176     src/netbase.cpp \
 177     src/key.cpp \
 178     src/script.cpp \
 179     src/main.cpp \
 180     src/init.cpp \
 181     src/net.cpp \
 182     src/irc.cpp \
 183     src/checkpoints.cpp \
 184     src/addrman.cpp \
 185     src/db.cpp \
 186     src/walletdb.cpp \
 187     src/json/json_spirit_writer.cpp \
 188     src/json/json_spirit_value.cpp \
 189     src/json/json_spirit_reader.cpp \
 190     src/qt/clientmodel.cpp \
 191     src/qt/guiutil.cpp \
 192     src/qt/transactionrecord.cpp \
 193     src/qt/optionsmodel.cpp \
 194     src/qt/monitoreddatamapper.cpp \
 195     src/qt/transactiondesc.cpp \
 196     src/qt/transactiondescdialog.cpp \
 197     src/qt/bitcoinstrings.cpp \
 198     src/qt/bitcoinamountfield.cpp \
 199     src/wallet.cpp \
 200     src/keystore.cpp \
 201     src/qt/transactionfilterproxy.cpp \
 202     src/qt/transactionview.cpp \
 203     src/qt/walletmodel.cpp \
 204     src/bitcoinrpc.cpp \
 205     src/rpcdump.cpp \
 206     src/qt/overviewpage.cpp \
 207     src/qt/csvmodelwriter.cpp \
 208     src/crypter.cpp \
 209     src/qt/sendcoinsentry.cpp \
 210     src/qt/qvalidatedlineedit.cpp \
 211     src/qt/bitcoinunits.cpp \
 212     src/qt/qvaluecombobox.cpp \
 213     src/qt/askpassphrasedialog.cpp \
 214     src/protocol.cpp \
 215     src/qt/notificator.cpp \
 216     src/qt/qtipcserver.cpp \
 217     src/qt/rpcconsole.cpp
 218
 219 RESOURCES += \
 220     src/qt/bitcoin.qrc
 221
 222 FORMS += \
 223     src/qt/forms/sendcoinsdialog.ui \
 224     src/qt/forms/addressbookpage.ui \
 225     src/qt/forms/messagepage.ui \
 226     src/qt/forms/aboutdialog.ui \
 227     src/qt/forms/editaddressdialog.ui \
 228     src/qt/forms/transactiondescdialog.ui \
 229     src/qt/forms/overviewpage.ui \
 230     src/qt/forms/sendcoinsentry.ui \
 231     src/qt/forms/askpassphrasedialog.ui \
 232     src/qt/forms/rpcconsole.ui
 233
 234 contains(USE_QRCODE, 1) {
 235 HEADERS += src/qt/qrcodedialog.h
 236 SOURCES += src/qt/qrcodedialog.cpp
 237 FORMS += src/qt/forms/qrcodedialog.ui
 238 }
 239
 240 contains(BITCOIN_QT_TEST, 1) {
 241 SOURCES += src/qt/test/test_main.cpp \
 242     src/qt/test/uritests.cpp
 243 HEADERS += src/qt/test/uritests.h
 244 DEPENDPATH += src/qt/test
 245 QT += testlib
 246 TARGET = bitcoin-qt_test
 247 DEFINES += BITCOIN_QT_TEST
 248 }
 249
 250 CODECFORTR = UTF-8
 251
 252 # for lrelease/lupdate
 253 # also add new translations to src/qt/bitcoin.qrc under translations/
 254 TRANSLATIONS = $$files(src/qt/locale/bitcoin_*.ts)
 255
 256 isEmpty(QMAKE_LRELEASE) {
 257     win32:QMAKE_LRELEASE = $$[QT_INSTALL_BINS]\\lrelease.exe
 258     else:QMAKE_LRELEASE = $$[QT_INSTALL_BINS]/lrelease
 259 }
 260 isEmpty(TS_DIR):TS_DIR = src/qt/locale
 261 # automatically build translations, so they can be included in resource file
 262 TSQM.name = lrelease ${QMAKE_FILE_IN}
 263 TSQM.input = TRANSLATIONS
 264 TSQM.output = $$TS_DIR/${QMAKE_FILE_BASE}.qm
 265 TSQM.commands = $$QMAKE_LRELEASE ${QMAKE_FILE_IN}
 266 TSQM.CONFIG = no_link
 267 QMAKE_EXTRA_COMPILERS += TSQM
 268 PRE_TARGETDEPS += compiler_TSQM_make_all
 269
 270 # "Other files" to show in Qt Creator
 271 OTHER_FILES += \
 272     doc/*.rst doc/*.txt doc/README README.md res/bitcoin-qt.rc
 273
 274 # platform specific defaults, if not overridden on command line
 275 isEmpty(BOOST_LIB_SUFFIX) {
 276     macx:BOOST_LIB_SUFFIX = -mt
 277     windows:BOOST_LIB_SUFFIX = -mgw44-mt-1_43
 278 }
 279
 280 isEmpty(BOOST_THREAD_LIB_SUFFIX) {
 281     BOOST_THREAD_LIB_SUFFIX = $$BOOST_LIB_SUFFIX
 282 }
 283
 284 isEmpty(BDB_LIB_PATH) {
 285     macx:BDB_LIB_PATH = /opt/local/lib/db48
 286 }
 287
 288 isEmpty(BDB_LIB_SUFFIX) {
 289     macx:BDB_LIB_SUFFIX = -4.8
 290 }
 291
 292 isEmpty(BDB_INCLUDE_PATH) {
 293     macx:BDB_INCLUDE_PATH = /opt/local/include/db48
 294 }
 295
 296 isEmpty(BOOST_LIB_PATH) {
 297     macx:BOOST_LIB_PATH = /opt/local/lib
 298 }
 299
 300 isEmpty(BOOST_INCLUDE_PATH) {
 301     macx:BOOST_INCLUDE_PATH = /opt/local/include
 302 }
 303
 304 windows:LIBS += -lws2_32 -lshlwapi
 305 windows:DEFINES += WIN32
 306 windows:RC_FILE = src/qt/res/bitcoin-qt.rc
 307
 308 windows:!contains(MINGW_THREAD_BUGFIX, 0) {
 309     # At least qmake's win32-g++-cross profile is missing the -lmingwthrd
 310     # thread-safety flag. GCC has -mthreads to enable this, but it doesn't
 311     # work with static linking. -lmingwthrd must come BEFORE -lmingw, so
 312     # it is prepended to QMAKE_LIBS_QT_ENTRY.
 313     # It can be turned off with MINGW_THREAD_BUGFIX=0, just in case it causes
 314     # any problems on some untested qmake profile now or in the future.
 315     DEFINES += _MT
 316     QMAKE_LIBS_QT_ENTRY = -lmingwthrd $$QMAKE_LIBS_QT_ENTRY
 317 }
 318
 319 !windows:!mac {
 320     DEFINES += LINUX
 321     LIBS += -lrt
 322 }
 323
 324 macx:HEADERS += src/qt/macdockiconhandler.h
 325 macx:OBJECTIVE_SOURCES += src/qt/macdockiconhandler.mm
 326 macx:LIBS += -framework Foundation -framework ApplicationServices -framework AppKit
 327 macx:DEFINES += MAC_OSX MSG_NOSIGNAL=0
 328 macx:ICON = src/qt/res/icons/bitcoin.icns
 329 macx:TARGET = "Bitcoin-Qt"
 330
 331 # Set libraries and includes at end, to use platform-defined defaults if not overridden
 332 INCLUDEPATH += $$BOOST_INCLUDE_PATH $$BDB_INCLUDE_PATH $$OPENSSL_INCLUDE_PATH $$QRENCODE_INCLUDE_PATH
 333 LIBS += $$join(BOOST_LIB_PATH,,-L,) $$join(BDB_LIB_PATH,,-L,) $$join(OPENSSL_LIB_PATH,,-L,) $$join(QRENCODE_LIB_PATH,,-L,)
 334 LIBS += -lssl -lcrypto -ldb_cxx$$BDB_LIB_SUFFIX
 335 # -lgdi32 has to happen after -lcrypto (see  #681)
 336 windows:LIBS += -lole32 -luuid -lgdi32
 337 LIBS += -lboost_system$$BOOST_LIB_SUFFIX -lboost_filesystem$$BOOST_LIB_SUFFIX -lboost_program_options$$BOOST_LIB_SUFFIX -lboost_thread$$BOOST_THREAD_LIB_SUFFIX
 338
 339 contains(RELEASE, 1) {
 340     !windows:!macx {
 341         # Linux: turn dynamic linking back on for c/c++ runtime libraries
 342         LIBS += -Wl,-Bdynamic
 343     }
 344 }
 345
 346 system($$QMAKE_LRELEASE -silent $$_PRO_FILE_)