configure.ac

   1 dnl require autoconf 2.60 (AS_ECHO/AS_ECHO_N)
   2 AC_PREREQ([2.60])
   3 define(_CLIENT_VERSION_MAJOR, 0)
   4 define(_CLIENT_VERSION_MINOR, 9)
   5 define(_CLIENT_VERSION_REVISION, 99)
   6 define(_CLIENT_VERSION_BUILD, 0)
   7 define(_CLIENT_VERSION_IS_RELEASE, false)
   8 define(_COPYRIGHT_YEAR, 2014)
   9 AC_INIT([Bitcoin Core],[_CLIENT_VERSION_MAJOR._CLIENT_VERSION_MINOR._CLIENT_VERSION_REVISION],[[email protected]],[bitcoin])
  10 AC_CONFIG_AUX_DIR([src/build-aux])
  11 AC_CONFIG_MACRO_DIR([src/m4])
  12 LT_INIT([disable-shared])
  13 AC_CANONICAL_HOST
  14 AH_TOP([#ifndef BITCOIN_CONFIG_H])
  15 AH_TOP([#define BITCOIN_CONFIG_H])
  16 AH_BOTTOM([#endif //BITCOIN_CONFIG_H])
  17
  18 # This m4 will only be used if a system copy cannot be found. This is helpful
  19 # on systems where autotools are installed but the pkg-config macros are not in
  20 # a default location. It is currently used for building on OSX where autotools
  21 # are preinstalled but pkg-config comes from macports or homebrew. It should
  22 # probably be removed when building on <= 10.6 is no longer supported.
  23 m4_include([pkg.m4])
  24
  25 dnl faketime breaks configure and is only needed for make. Disable it here.
  26 unset FAKETIME
  27
  28 if test "x${CXXFLAGS+set}" = "xset"; then
  29   CXXFLAGS_overridden=yes
  30 else
  31   CXXFLAGS_overridden=no
  32 fi
  33
  34 dnl ==============================================================
  35 dnl Setup for automake
  36 dnl ==============================================================
  37
  38 AM_INIT_AUTOMAKE([no-define subdir-objects foreign])
  39
  40 dnl faketime messes with timestamps and causes configure to be re-run.
  41 dnl --disable-maintainer-mode can be used to bypass this.
  42 AM_MAINTAINER_MODE([enable])
  43
  44 dnl make the compilation flags quiet unless V=1 is used
  45 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  46
  47 # Enable wallet
  48 AC_ARG_ENABLE([wallet],
  49   [AS_HELP_STRING([--enable-wallet],
  50   [enable wallet (default is yes)])],
  51   [enable_wallet=$enableval],
  52   [enable_wallet=yes])
  53
  54 AC_ARG_WITH([miniupnpc],
  55   [AS_HELP_STRING([--with-miniupnpc],
  56   [enable UPNP (default is yes if libminiupnpc is found)])],
  57   [use_upnp=$withval],
  58   [use_upnp=auto])
  59
  60 AC_ARG_ENABLE([upnp-default],
  61   [AS_HELP_STRING([--enable-upnp-default],
  62   [if UPNP is enabled, turn it on at startup (default is no)])],
  63   [use_upnp_default=$enableval],
  64   [use_upnp_default=no])
  65
  66 AC_ARG_ENABLE(tests,
  67     AS_HELP_STRING([--enable-tests],[compile tests (default is yes)]),
  68     [use_tests=$enableval],
  69     [use_tests=yes])
  70
  71 AC_ARG_WITH([comparison-tool],
  72     AS_HELP_STRING([--with-comparison-tool],[path to java comparison tool (requires --enable-tests)]),
  73     [use_comparison_tool=$withval],
  74     [use_comparison_tool=no])
  75
  76 AC_ARG_ENABLE([comparison-tool-reorg-tests],
  77     AS_HELP_STRING([--enable-comparison-tool-reorg-tests],[enable expensive reorg tests in the comparison tool (default no)]),
  78     [use_comparison_tool_reorg_tests=$enableval],
  79     [use_comparison_tool_reorg_tests=no])
  80
  81 AC_ARG_WITH([qrencode],
  82   [AS_HELP_STRING([--with-qrencode],
  83   [enable QR code support (default is yes if qt is enabled and libqrencode is found)])],
  84   [use_qr=$withval],
  85   [use_qr=auto])
  86
  87 AC_ARG_ENABLE([hardening],
  88   [AS_HELP_STRING([--enable-hardening],
  89   [attempt to harden the resulting executables (default is yes)])],
  90   [use_hardening=$enableval],
  91   [use_hardening=yes])
  92
  93 AC_ARG_ENABLE([reduce-exports],
  94   [AS_HELP_STRING([--enable-reduce-exports],
  95   [attempt to reduce exported symbols in the resulting executables (default is yes)])],
  96   [use_reduce_exports=$enableval],
  97   [use_reduce_exports=auto])
  98
  99 AC_ARG_ENABLE([ccache],
 100   [AS_HELP_STRING([--enable-ccache],
 101   [use ccache for building (default is yes if ccache is found)])],
 102   [use_ccache=$enableval],
 103   [use_ccache=auto])
 104
 105 AC_ARG_ENABLE([lcov],
 106   [AS_HELP_STRING([--enable-lcov],
 107   [enable lcov testing (default is no)])],
 108   [use_lcov=yes],
 109   [use_lcov=no])
 110
 111 AC_ARG_ENABLE([glibc-back-compat],
 112   [AS_HELP_STRING([--enable-glibc-back-compat],
 113   [enable backwards compatibility with glibc and libstdc++])],
 114   [use_glibc_compat=$enableval],
 115   [use_glibc_compat=no])
 116
 117 AC_ARG_WITH([protoc-bindir],[AS_HELP_STRING([--with-protoc-bindir=BIN_DIR],[specify protoc bin path])], [protoc_bin_path=$withval], [])
 118
 119
 120 AC_CONFIG_SRCDIR([src])
 121 AC_CONFIG_HEADERS([src/config/bitcoin-config.h])
 122
 123 dnl Checks for programs.
 124 AC_PROG_CXX
 125 AC_PROG_CC
 126 AC_PROG_CPP
 127 AC_PROG_CXXCPP
 128 AC_PROG_INSTALL
 129 AC_PROG_OBJC
 130 AC_PROG_LN_S
 131 m4_ifdef([AC_PROG_OBJCXX],[AC_PROG_OBJCXX])
 132 AC_PROG_MKDIR_P
 133 AC_PROG_SED
 134 AC_PATH_TOOL(AR, ar)
 135 AC_PATH_TOOL(RANLIB, ranlib)
 136 AC_PATH_TOOL(STRIP, strip)
 137 AC_PATH_TOOL(GCOV, gcov)
 138 AC_PATH_PROG(LCOV, lcov)
 139 AC_PATH_PROG(JAVA, java)
 140 AC_PATH_PROG(GENHTML, genhtml)
 141 AC_PATH_PROG([GIT], [git])
 142 AC_PATH_PROG(CCACHE,ccache)
 143 AC_PATH_PROG(XGETTEXT,xgettext)
 144 AC_PATH_PROG(HEXDUMP,hexdump)
 145 PKG_PROG_PKG_CONFIG
 146
 147 # Enable debug
 148 AC_ARG_ENABLE([debug],
 149     [AS_HELP_STRING([--enable-debug],
 150                     [use debug compiler flags and macros (default is no)])],
 151     [enable_debug=$enableval],
 152     [enable_debug=no])
 153
 154 if test "x$enable_debug" = xyes; then
 155     if test "x$GCC" = xyes; then
 156         CFLAGS="-g3 -O0 -DDEBUG"
 157     fi
 158
 159     if test "x$GXX" = xyes; then
 160         CXXFLAGS="-g3 -O0 -DDEBUG"
 161     fi
 162 fi
 163
 164 ## TODO: Remove these hard-coded paths and flags. They are here for the sake of
 165 ##       compatibility with the legacy buildsystem.
 166 ##
 167 if test "x$CXXFLAGS_overridden" = "xno"; then
 168   CXXFLAGS="$CXXFLAGS -Wall -Wextra -Wformat -Wformat-security -Wno-unused-parameter"
 169 fi
 170 CPPFLAGS="$CPPFLAGS -DBOOST_SPIRIT_THREADSAFE -DHAVE_BUILD_INFO -D__STDC_FORMAT_MACROS"
 171
 172 AC_LANG_PUSH([C++])
 173
 174 use_pkgconfig=yes
 175 case $host in
 176   *mingw*)
 177
 178      #pkgconfig does more harm than good with MinGW
 179      use_pkgconfig=no
 180
 181      TARGET_OS=windows
 182      AC_CHECK_LIB([mingwthrd],      [main],, AC_MSG_ERROR(lib missing))
 183      AC_CHECK_LIB([kernel32],      [main],, AC_MSG_ERROR(lib missing))
 184      AC_CHECK_LIB([user32],      [main],, AC_MSG_ERROR(lib missing))
 185      AC_CHECK_LIB([gdi32],      [main],, AC_MSG_ERROR(lib missing))
 186      AC_CHECK_LIB([comdlg32],      [main],, AC_MSG_ERROR(lib missing))
 187      AC_CHECK_LIB([winspool],      [main],, AC_MSG_ERROR(lib missing))
 188      AC_CHECK_LIB([winmm],      [main],, AC_MSG_ERROR(lib missing))
 189      AC_CHECK_LIB([shell32],      [main],, AC_MSG_ERROR(lib missing))
 190      AC_CHECK_LIB([comctl32],      [main],, AC_MSG_ERROR(lib missing))
 191      AC_CHECK_LIB([ole32],      [main],, AC_MSG_ERROR(lib missing))
 192      AC_CHECK_LIB([oleaut32],      [main],, AC_MSG_ERROR(lib missing))
 193      AC_CHECK_LIB([uuid],      [main],, AC_MSG_ERROR(lib missing))
 194      AC_CHECK_LIB([rpcrt4],      [main],, AC_MSG_ERROR(lib missing))
 195      AC_CHECK_LIB([advapi32],      [main],, AC_MSG_ERROR(lib missing))
 196      AC_CHECK_LIB([ws2_32],      [main],, AC_MSG_ERROR(lib missing))
 197      AC_CHECK_LIB([mswsock],      [main],, AC_MSG_ERROR(lib missing))
 198      AC_CHECK_LIB([shlwapi],      [main],, AC_MSG_ERROR(lib missing))
 199      AC_CHECK_LIB([iphlpapi],      [main],, AC_MSG_ERROR(lib missing))
 200      AC_CHECK_LIB([crypt32],      [main],, AC_MSG_ERROR(lib missing))
 201
 202      AX_CHECK_LINK_FLAG([[-static-libgcc]],[LDFLAGS="$LDFLAGS -static-libgcc"])
 203      AX_CHECK_LINK_FLAG([[-static-libstdc++]],[LDFLAGS="$LDFLAGS -static-libstdc++"])
 204
 205      # -static is interpreted by libtool, where it has a different meaning.
 206      # In libtool-speak, it's -all-static.
 207      AX_CHECK_LINK_FLAG([[-static]],[LDFLAGS="$LDFLAGS -static"; LIBTOOL_LDFLAGS="$LIBTOOL_LDFLAGS -all-static"])
 208
 209      AC_PATH_PROG([MAKENSIS], [makensis], none)
 210      if test x$MAKENSIS = xnone; then
 211        AC_MSG_WARN("makensis not found. Cannot create installer.")
 212      fi
 213
 214      AC_PATH_TOOL(WINDRES, windres, none)
 215      if test x$WINDRES = xnone; then
 216        AC_MSG_ERROR("windres not found")
 217      fi
 218
 219      CPPFLAGS="$CPPFLAGS -D_MT -DWIN32 -D_WINDOWS -DBOOST_THREAD_USE_LIB"
 220      LEVELDB_TARGET_FLAGS="TARGET_OS=OS_WINDOWS_CROSSCOMPILE"
 221      if test "x$CXXFLAGS_overridden" = "xno"; then
 222        CXXFLAGS="$CXXFLAGS -w"
 223      fi
 224      case $host in
 225        i?86-*) WINDOWS_BITS=32 ;;
 226        x86_64-*) WINDOWS_BITS=64 ;;
 227        *) AC_MSG_ERROR("Could not determine win32/win64 for installer") ;;
 228      esac
 229      AC_SUBST(WINDOWS_BITS)
 230      ;;
 231   *darwin*)
 232      TARGET_OS=darwin
 233      LEVELDB_TARGET_FLAGS="TARGET_OS=Darwin"
 234      if  test x$cross_compiling != xyes; then
 235        BUILD_OS=darwin
 236        AC_CHECK_PROG([PORT],port, port)
 237        if test x$PORT = xport; then
 238          dnl add default macports paths
 239          CPPFLAGS="$CPPFLAGS -isystem /opt/local/include -I/opt/local/include/db48"
 240          LIBS="$LIBS -L/opt/local/lib -L/opt/local/lib/db48"
 241        fi
 242
 243        AC_CHECK_PROG([BREW],brew, brew)
 244        if test x$BREW = xbrew; then
 245          dnl add default homebrew paths
 246          openssl_prefix=`$BREW --prefix openssl`
 247          bdb_prefix=`$BREW --prefix berkeley-db4`
 248          export PKG_CONFIG_PATH="$openssl_prefix/lib/pkgconfig:$PKG_CONFIG_PATH"
 249          CPPFLAGS="$CPPFLAGS -I$bdb_prefix/include"
 250          LIBS="$LIBS -L$bdb_prefix/lib"
 251        fi
 252      else
 253        case $build_os in
 254          *darwin*)
 255            BUILD_OS=darwin
 256            ;;
 257          *)
 258            AC_PATH_TOOL([INSTALLNAMETOOL], [install_name_tool], install_name_tool)
 259            AC_PATH_TOOL([OTOOL], [otool], otool)
 260            AC_PATH_PROGS([GENISOIMAGE], [genisoimage mkisofs],genisoimage)
 261            ;;
 262        esac
 263      fi
 264
 265      CPPFLAGS="$CPPFLAGS -DMAC_OSX"
 266      ;;
 267    *linux*)
 268      TARGET_OS=linux
 269      ;;
 270    *)
 271      ;;
 272 esac
 273
 274 if test x$use_comparison_tool != xno; then
 275   AC_SUBST(JAVA_COMPARISON_TOOL, $use_comparison_tool)
 276 fi
 277
 278 if test x$use_comparison_tool_reorg_tests != xno; then
 279   if test x$use_comparison_tool == x; then
 280     AC_MSG_ERROR("comparison tool reorg tests but comparison tool was not specified")
 281   fi
 282   AC_SUBST(COMPARISON_TOOL_REORG_TESTS, 1)
 283 else
 284   AC_SUBST(COMPARISON_TOOL_REORG_TESTS, 0)
 285 fi
 286
 287 if test x$use_lcov == xyes; then
 288   if test x$LCOV == x; then
 289     AC_MSG_ERROR("lcov testing requested but lcov not found")
 290   fi
 291   if test x$GCOV == x; then
 292     AC_MSG_ERROR("lcov testing requested but gcov not found")
 293   fi
 294   if test x$JAVA == x; then
 295     AC_MSG_ERROR("lcov testing requested but java not found")
 296   fi
 297   if test x$GENHTML == x; then
 298     AC_MSG_ERROR("lcov testing requested but genhtml not found")
 299   fi
 300   if test x$use_comparison_tool == x; then
 301     AC_MSG_ERROR("lcov testing requested but comparison tool was not specified")
 302   fi
 303   LCOV="$LCOV --gcov-tool=$GCOV"
 304   AX_CHECK_COMPILE_FLAG([--coverage],[CXXFLAGS="$CXXFLAGS --coverage"],
 305     [AC_MSG_ERROR("lcov testing requested but --coverage flag does not work")])
 306 fi
 307
 308 dnl Require little endian
 309 AC_C_BIGENDIAN([AC_MSG_ERROR("Big Endian not supported")])
 310
 311 dnl Check for pthread compile/link requirements
 312 AX_PTHREAD
 313
 314 # The following macro will add the necessary defines to bitcoin-config.h, but
 315 # they also need to be passed down to any subprojects. Pull the results out of
 316 # the cache and add them to CPPFLAGS.
 317 AC_SYS_LARGEFILE
 318 # detect POSIX or GNU variant of strerror_r
 319 AC_FUNC_STRERROR_R
 320
 321 if test x$ac_cv_sys_file_offset_bits != x &&
 322    test x$ac_cv_sys_file_offset_bits != xno &&
 323    test x$ac_cv_sys_file_offset_bits != xunknown; then
 324   CPPFLAGS="$CPPFLAGS -D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits"
 325 fi
 326
 327 if test x$ac_cv_sys_large_files != x &&
 328    test x$ac_cv_sys_large_files != xno &&
 329    test x$ac_cv_sys_large_files != xunknown; then
 330   CPPFLAGS="$CPPFLAGS -D_LARGE_FILES=$ac_cv_sys_large_files"
 331 fi
 332
 333 AX_CHECK_LINK_FLAG([[-Wl,--large-address-aware]], [LDFLAGS="$LDFLAGS -Wl,--large-address-aware"])
 334
 335 if test x$use_glibc_compat != xno; then
 336
 337   #__fdelt_chk's params and return type have changed from long unsigned int to long int.
 338   # See which one is present here.
 339   AC_MSG_CHECKING(__fdelt_chk type)
 340   AC_TRY_COMPILE([#ifdef _FORTIFY_SOURCE
 341                     #undef _FORTIFY_SOURCE
 342                   #endif
 343                   #define _FORTIFY_SOURCE 2
 344                   #include <sys/select.h>
 345      extern "C" long unsigned int __fdelt_warn(long unsigned int);],[],
 346     [ fdelt_type="long unsigned int"],
 347     [ fdelt_type="long int"])
 348   AC_MSG_RESULT($fdelt_type)
 349   AC_DEFINE_UNQUOTED(FDELT_TYPE, $fdelt_type,[parameter and return value type for __fdelt_chk])
 350
 351 fi
 352
 353 if test x$use_hardening != xno; then
 354   AX_CHECK_COMPILE_FLAG([-Wstack-protector],[HARDENED_CXXFLAGS="$HARDENED_CXXFLAGS -Wstack-protector"])
 355   AX_CHECK_COMPILE_FLAG([-fstack-protector-all],[HARDENED_CXXFLAGS="$HARDENED_CXXFLAGS -fstack-protector-all"])
 356
 357   AX_CHECK_PREPROC_FLAG([-D_FORTIFY_SOURCE=2],[
 358     AX_CHECK_PREPROC_FLAG([-U_FORTIFY_SOURCE],[
 359       HARDENED_CPPFLAGS="$HARDENED_CPPFLAGS -U_FORTIFY_SOURCE"
 360     ])
 361     HARDENED_CPPFLAGS="$HARDENED_CPPFLAGS -D_FORTIFY_SOURCE=2"
 362   ])
 363
 364   AX_CHECK_LINK_FLAG([[-Wl,--dynamicbase]], [HARDENED_LDFLAGS="$HARDENED_LDFLAGS -Wl,--dynamicbase"])
 365   AX_CHECK_LINK_FLAG([[-Wl,--nxcompat]], [HARDENED_LDFLAGS="$HARDENED_LDFLAGS -Wl,--nxcompat"])
 366   AX_CHECK_LINK_FLAG([[-Wl,-z,relro]], [HARDENED_LDFLAGS="$HARDENED_LDFLAGS -Wl,-z,relro"])
 367   AX_CHECK_LINK_FLAG([[-Wl,-z,now]], [HARDENED_LDFLAGS="$HARDENED_LDFLAGS -Wl,-z,now"])
 368
 369   if test x$TARGET_OS != xwindows; then
 370     # All windows code is PIC, forcing it on just adds useless compile warnings
 371     AX_CHECK_COMPILE_FLAG([-fPIE],[HARDENED_CXXFLAGS="$HARDENED_CXXFLAGS -fPIE"])
 372     AX_CHECK_LINK_FLAG([[-pie]], [HARDENED_LDFLAGS="$HARDENED_LDFLAGS -pie"])
 373   fi
 374
 375   CXXFLAGS="$CXXFLAGS $HARDENED_CXXFLAGS"
 376   CPPFLAGS="$CPPFLAGS $HARDENED_CPPFLAGS"
 377   LDFLAGS="$LDFLAGS $HARDENED_LDFLAGS"
 378   OBJCXXFLAGS="$CXXFLAGS"
 379 fi
 380
 381 dnl this flag screws up non-darwin gcc even when the check fails. special-case it.
 382 if test x$TARGET_OS = xdarwin; then
 383   AX_CHECK_LINK_FLAG([[-Wl,-dead_strip]], [LDFLAGS="$LDFLAGS -Wl,-dead_strip"])
 384 fi
 385
 386 AC_CHECK_HEADERS([endian.h stdio.h stdlib.h unistd.h strings.h sys/types.h sys/stat.h sys/select.h sys/prctl.h])
 387 AC_SEARCH_LIBS([getaddrinfo_a], [anl], [AC_DEFINE(HAVE_GETADDRINFO_A, 1, [Define this symbol if you have getaddrinfo_a])])
 388 AC_SEARCH_LIBS([inet_pton], [nsl resolv], [AC_DEFINE(HAVE_INET_PTON, 1, [Define this symbol if you have inet_pton])])
 389
 390 AC_CHECK_DECLS([le32toh, le64toh, htole32, htole64, be32toh, be64toh, htobe32, htobe64],,,
 391                 [#if HAVE_ENDIAN_H
 392                  #include <endian.h>
 393                  #endif])
 394
 395 dnl Check for MSG_NOSIGNAL
 396 AC_MSG_CHECKING(for MSG_NOSIGNAL)
 397 AC_TRY_COMPILE([#include <sys/socket.h>],
 398  [ int f = MSG_NOSIGNAL; ],
 399  [ AC_MSG_RESULT(yes); AC_DEFINE(HAVE_MSG_NOSIGNAL, 1,[Define this symbol if you have MSG_NOSIGNAL]) ],
 400  [ AC_MSG_RESULT(no)]
 401 )
 402
 403 AC_SEARCH_LIBS([clock_gettime],[rt])
 404
 405 AC_MSG_CHECKING([for visibility attribute])
 406 AC_LINK_IFELSE([AC_LANG_SOURCE([
 407   int foo_def( void ) __attribute__((visibility("default")));
 408   int main(){}
 409   ])],
 410   [
 411     AC_DEFINE(HAVE_VISIBILITY_ATTRIBUTE,1,[Define if the visibility attribute is supported.])
 412     AC_MSG_RESULT(yes)
 413   ],
 414   [
 415     AC_MSG_RESULT(no)
 416     if test x$use_reduce_exports = xyes; then
 417       AC_MSG_ERROR([Cannot find a working visibility attribute. Use --disable-reduced-exports.])
 418     fi
 419       AC_MSG_WARN([Cannot find a working visibility attribute. Disabling reduced exports.])
 420       use_reduce_exports=no
 421   ]
 422 )
 423
 424 if test x$use_reduce_exports != xno; then
 425   AX_CHECK_COMPILE_FLAG([-fvisibility=hidden],[RE_CXXFLAGS="-fvisibility=hidden"],
 426   [
 427     if test x$use_reduce_exports = xyes; then
 428       AC_MSG_ERROR([Cannot set default symbol visibility. Use --disable-reduced-exports.])
 429     fi
 430     AC_MSG_WARN([Cannot set default symbol visibility. Disabling reduced exports.])
 431     use_reduce_exports=no
 432   ])
 433 fi
 434
 435 LEVELDB_CPPFLAGS=
 436 LIBLEVELDB=
 437 LIBMEMENV=
 438 AM_CONDITIONAL([EMBEDDED_LEVELDB],[true])
 439 AC_SUBST(LEVELDB_CPPFLAGS)
 440 AC_SUBST(LIBLEVELDB)
 441 AC_SUBST(LIBMEMENV)
 442
 443 if test x$enable_wallet != xno; then
 444     dnl Check for libdb_cxx only if wallet enabled
 445     BITCOIN_FIND_BDB48
 446 fi
 447
 448 dnl Check for libminiupnpc (optional)
 449 if test x$use_upnp != xno; then
 450   AC_CHECK_HEADERS(
 451     [miniupnpc/miniwget.h miniupnpc/miniupnpc.h miniupnpc/upnpcommands.h miniupnpc/upnperrors.h],
 452     [AC_CHECK_LIB([miniupnpc], [main],, [have_miniupnpc=no])],
 453     [have_miniupnpc=no]
 454   )
 455 fi
 456
 457 dnl Check for boost libs
 458 AX_BOOST_BASE
 459 AX_BOOST_SYSTEM
 460 AX_BOOST_FILESYSTEM
 461 AX_BOOST_PROGRAM_OPTIONS
 462 AX_BOOST_THREAD
 463 AX_BOOST_CHRONO
 464
 465
 466 if test x$use_reduce_exports != xno; then
 467   AC_MSG_CHECKING([for working boost reduced exports])
 468   TEMP_CPPFLAGS="$CPPFLAGS"
 469   CPPFLAGS="$BOOST_CPPFLAGS $CPPFLAGS"
 470   AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
 471       @%:@include <boost/version.hpp>
 472     ]], [[
 473       #if BOOST_VERSION >= 104900
 474       // Everything is okay
 475       #else
 476       #  error Boost version is too old
 477       #endif
 478     ]])],[
 479       AC_MSG_RESULT(yes)
 480     ],[:
 481     if test x$use_reduce_exports = xauto; then
 482       use_reduce_exports=no
 483     else
 484       if test x$use_reduce_exports = xyes; then
 485         AC_MSG_ERROR([boost versions < 1.49 are known to be broken with reduced exports. Use --disable-reduced-exports.])
 486       fi
 487     fi
 488     AC_MSG_RESULT(no)
 489     AC_MSG_WARN([boost versions < 1.49 are known to have symbol visibility issues. Disabling reduced exports.])
 490   ])
 491   CPPFLAGS="$TEMP_CPPFLAGS"
 492 fi
 493
 494 if test x$use_reduce_exports != xno; then
 495     CXXFLAGS="$CXXFLAGS $RE_CXXFLAGS"
 496     AX_CHECK_LINK_FLAG([[-Wl,--exclude-libs,ALL]], [RELDFLAGS="-Wl,--exclude-libs,ALL"])
 497 fi
 498
 499 if test x$use_tests = xyes; then
 500
 501   if test x$HEXDUMP = x; then
 502     AC_MSG_ERROR(hexdump is required for tests)
 503   fi
 504
 505
 506   AX_BOOST_UNIT_TEST_FRAMEWORK
 507
 508   dnl Determine if -DBOOST_TEST_DYN_LINK is needed
 509   AC_MSG_CHECKING([for dynamic linked boost test])
 510   TEMP_LIBS="$LIBS"
 511   LIBS="$LIBS $BOOST_UNIT_TEST_FRAMEWORK_LIB"
 512   TEMP_CPPFLAGS="$CPPFLAGS"
 513   CPPFLAGS="$CPPFLAGS $BOOST_CPPFLAGS"
 514   AC_LINK_IFELSE([AC_LANG_SOURCE([
 515        #define BOOST_TEST_DYN_LINK
 516        #define BOOST_TEST_MAIN
 517         #include <boost/test/unit_test.hpp>
 518
 519        ])],
 520     [AC_MSG_RESULT(yes)]
 521     [TESTDEFS="$TESTDEFS -DBOOST_TEST_DYN_LINK"],
 522     [AC_MSG_RESULT(no)])
 523   LIBS="$TEMP_LIBS"
 524   CPPFLAGS="$TEMP_CPPFLAGS"
 525 fi
 526
 527 BOOST_LIBS="$BOOST_LDFLAGS $BOOST_SYSTEM_LIB $BOOST_FILESYSTEM_LIB $BOOST_PROGRAM_OPTIONS_LIB $BOOST_THREAD_LIB"
 528
 529 dnl Boost >= 1.50 uses sleep_for rather than the now-deprecated sleep, however
 530 dnl it was broken from 1.50 to 1.52 when backed by nanosleep. Use sleep_for if
 531 dnl a working version is available, else fall back to sleep. sleep was removed
 532 dnl after 1.56.
 533 dnl If neither is available, abort.
 534 dnl If sleep_for is used, boost_chrono becomes a requirement.
 535 if test x$ax_cv_boost_chrono = xyes; then
 536 TEMP_LIBS="$LIBS"
 537 LIBS="$BOOST_LIBS $BOOST_CHRONO_LIB $LIBS"
 538 TEMP_CPPFLAGS="$CPPFLAGS"
 539 CPPFLAGS="$CPPFLAGS $BOOST_CPPFLAGS"
 540 AC_TRY_LINK([
 541   #include <boost/thread/thread.hpp>
 542   #include <boost/version.hpp>
 543   ],[
 544   #if BOOST_VERSION >= 105000 && (!defined(BOOST_HAS_NANOSLEEP) || BOOST_VERSION >= 105200)
 545       boost::this_thread::sleep_for(boost::chrono::milliseconds(0));
 546   #else
 547    choke me
 548   #endif
 549   ],
 550   [boost_sleep=yes; BOOST_LIBS="$BOOST_LIBS $BOOST_CHRONO_LIB";
 551      AC_DEFINE(HAVE_WORKING_BOOST_SLEEP_FOR, 1, [Define this symbol if boost sleep_for works])],
 552   [boost_sleep=no])
 553 LIBS="$TEMP_LIBS"
 554 CPPFLAGS="$TEMP_CPPFLAGS"
 555 fi
 556
 557 if test x$boost_sleep != xyes; then
 558 TEMP_LIBS="$LIBS"
 559 LIBS="$BOOST_LIBS $LIBS"
 560 TEMP_CPPFLAGS="$CPPFLAGS"
 561 CPPFLAGS="$CPPFLAGS $BOOST_CPPFLAGS"
 562 AC_TRY_LINK([
 563   #include <boost/version.hpp>
 564   #include <boost/thread.hpp>
 565   #include <boost/date_time/posix_time/posix_time_types.hpp>
 566   ],[
 567   #if BOOST_VERSION <= 105600
 568       boost::this_thread::sleep(boost::posix_time::milliseconds(0));
 569   #else
 570    choke me
 571   #endif
 572   ],
 573   [boost_sleep=yes; AC_DEFINE(HAVE_WORKING_BOOST_SLEEP, 1, [Define this symbol if boost sleep works])],
 574   [boost_sleep=no])
 575 LIBS="$TEMP_LIBS"
 576 CPPFLAGS="$TEMP_CPPFLAGS"
 577 fi
 578
 579 if test x$boost_sleep != xyes; then
 580   AC_MSG_ERROR(No working boost sleep implementation found. If on ubuntu 13.10 with libboost1.54-all-dev remove libboost.1.54-all-dev and use libboost1.53-all-dev)
 581 fi
 582
 583 AC_ARG_WITH([utils],
 584   [AS_HELP_STRING([--with-utils],
 585   [build bitcoin-cli bitcoin-tx (default=yes)])],
 586   [build_bitcoin_utils=$withval],
 587   [build_bitcoin_utils=yes])
 588
 589 AC_ARG_WITH([daemon],
 590   [AS_HELP_STRING([--with-daemon],
 591   [build bitcoind daemon (default=yes)])],
 592   [build_bitcoind=$withval],
 593   [build_bitcoind=yes])
 594
 595 BITCOIN_QT_INIT
 596
 597 if test x$use_pkgconfig = xyes; then
 598
 599   if test x"$PKG_CONFIG" == "x"; then
 600     AC_MSG_ERROR(pkg-config not found.)
 601   fi
 602
 603   : #NOP
 604   m4_ifdef(
 605     [PKG_CHECK_MODULES],
 606     [
 607       PKG_CHECK_MODULES([SSL], [libssl],, [AC_MSG_ERROR(openssl  not found.)])
 608       PKG_CHECK_MODULES([CRYPTO], [libcrypto],,[AC_MSG_ERROR(libcrypto  not found.)])
 609       BITCOIN_QT_CHECK([PKG_CHECK_MODULES([PROTOBUF], [protobuf], [have_protobuf=yes], [BITCOIN_QT_FAIL(libprotobuf not found)])])
 610       if test x$use_qr != xno; then
 611         BITCOIN_QT_CHECK([PKG_CHECK_MODULES([QR], [libqrencode], [have_qrencode=yes], [have_qrencode=no])])
 612       fi
 613     ]
 614   )
 615 else
 616   AC_CHECK_HEADER([openssl/crypto.h],,AC_MSG_ERROR(libcrypto headers missing))
 617   AC_CHECK_LIB([crypto],      [main],CRYPTO_LIBS=-lcrypto, AC_MSG_ERROR(libcrypto missing))
 618
 619   AC_CHECK_HEADER([openssl/ssl.h],, AC_MSG_ERROR(libssl headers missing),)
 620   AC_CHECK_LIB([ssl],         [main],SSL_LIBS=-lssl, AC_MSG_ERROR(libssl missing))
 621
 622   BITCOIN_QT_CHECK(AC_CHECK_LIB([protobuf] ,[main],,BITCOIN_QT_FAIL(libprotobuf not found)))
 623   if test x$use_qr != xno; then
 624     BITCOIN_QT_CHECK([AC_CHECK_LIB([qrencode], [main],, [have_qrencode=no])])
 625     BITCOIN_QT_CHECK([AC_CHECK_HEADER([qrencode.h],, have_qrencode=no)])
 626   fi
 627 fi
 628
 629 BITCOIN_QT_PATH_PROGS([PROTOC], [protoc],$protoc_bin_path)
 630
 631 AC_MSG_CHECKING([whether to build bitcoind])
 632 AM_CONDITIONAL([BUILD_BITCOIND], [test x$build_bitcoind = xyes])
 633 AC_MSG_RESULT($build_bitcoind)
 634
 635 AC_MSG_CHECKING([whether to build utils (bitcoin-cli bitcoin-tx)])
 636 AM_CONDITIONAL([BUILD_BITCOIN_UTILS], [test x$build_bitcoin_utils = xyes])
 637 AC_MSG_RESULT($build_bitcoin_utils)
 638
 639 dnl sets $bitcoin_enable_qt, $bitcoin_enable_qt_test, $bitcoin_enable_qt_dbus
 640 BITCOIN_QT_CONFIGURE([$use_pkgconfig], [qt4])
 641
 642 AC_LANG_POP
 643
 644 if test "x$use_ccache" != "xno"; then
 645   AC_MSG_CHECKING(if ccache should be used)
 646   if test x$CCACHE = x; then
 647     if test "x$use_ccache" = "xyes"; then
 648       AC_MSG_ERROR([ccache not found.]);
 649     else
 650       use_ccache=no
 651     fi
 652   else
 653     use_ccache=yes
 654     CC="$ac_cv_path_CCACHE $CC"
 655     CXX="$ac_cv_path_CCACHE $CXX"
 656   fi
 657   AC_MSG_RESULT($use_ccache)
 658 fi
 659 if test "x$use_ccache" = "xyes"; then
 660     AX_CHECK_PREPROC_FLAG([-Qunused-arguments],[CPPFLAGS="-Qunused-arguments $CPPFLAGS"])
 661 fi
 662
 663 dnl enable wallet
 664 AC_MSG_CHECKING([if wallet should be enabled])
 665 if test x$enable_wallet != xno; then
 666   AC_MSG_RESULT(yes)
 667   AC_DEFINE_UNQUOTED([ENABLE_WALLET],[1],[Define to 1 to enable wallet functions])
 668
 669 else
 670   AC_MSG_RESULT(no)
 671 fi
 672
 673 dnl enable upnp support
 674 AC_MSG_CHECKING([whether to build with support for UPnP])
 675 if test x$have_miniupnpc = xno; then
 676   if test x$use_upnp = xyes; then
 677      AC_MSG_ERROR("UPnP requested but cannot be built. use --without-miniupnpc")
 678   fi
 679   AC_MSG_RESULT(no)
 680 else
 681   if test x$use_upnp != xno; then
 682     AC_MSG_RESULT(yes)
 683     AC_MSG_CHECKING([whether to build with UPnP enabled by default])
 684     use_upnp=yes
 685     upnp_setting=0
 686     if test x$use_upnp_default != xno; then
 687       use_upnp_default=yes
 688       upnp_setting=1
 689     fi
 690     AC_MSG_RESULT($use_upnp_default)
 691     AC_DEFINE_UNQUOTED([USE_UPNP],[$upnp_setting],[UPnP support not compiled if undefined, otherwise value (0 or 1) determines default state])
 692     if test x$TARGET_OS = xwindows; then
 693       MINIUPNPC_CPPFLAGS="-DSTATICLIB -DMINIUPNP_STATICLIB"
 694     fi
 695   else
 696     AC_MSG_RESULT(no)
 697   fi
 698 fi
 699
 700 dnl these are only used when qt is enabled
 701 if test x$bitcoin_enable_qt != xno; then
 702   BUILD_QT=qt
 703   dnl enable dbus support
 704   AC_MSG_CHECKING([whether to build GUI with support for D-Bus])
 705   if test x$bitcoin_enable_qt_dbus != xno; then
 706     AC_DEFINE([USE_DBUS],[1],[Define if dbus support should be compiled in])
 707   fi
 708   AC_MSG_RESULT($bitcoin_enable_qt_dbus)
 709
 710   dnl enable qr support
 711   AC_MSG_CHECKING([whether to build GUI with support for QR codes])
 712   if test x$have_qrencode = xno; then
 713     if test x$use_qr == xyes; then
 714      AC_MSG_ERROR("QR support requested but cannot be built. use --without-qrencode")
 715     fi
 716     AC_MSG_RESULT(no)
 717   else
 718     if test x$use_qr != xno; then
 719       AC_MSG_RESULT(yes)
 720       AC_DEFINE([USE_QRCODE],[1],[Define if QR support should be compiled in])
 721       use_qr=yes
 722     else
 723       AC_MSG_RESULT(no)
 724     fi
 725   fi
 726
 727   if test x$XGETTEXT == x; then
 728     AC_MSG_WARN("xgettext is required to update qt translations")
 729   fi
 730
 731   AC_MSG_CHECKING([whether to build test_bitcoin-qt])
 732   if test x$use_tests$bitcoin_enable_qt_test = xyesyes; then
 733     AC_MSG_RESULT([yes])
 734     BUILD_TEST_QT="test"
 735   else
 736     AC_MSG_RESULT([no])
 737   fi
 738 fi
 739
 740 AC_MSG_CHECKING([whether to build test_bitcoin])
 741 if test x$use_tests = xyes; then
 742   AC_MSG_RESULT([yes])
 743   BUILD_TEST="test"
 744 else
 745   AC_MSG_RESULT([no])
 746 fi
 747
 748 AC_MSG_CHECKING([whether to reduce exports])
 749 if test x$use_reduce_exports != xno; then
 750   AC_MSG_RESULT([yes])
 751 else
 752   AC_MSG_RESULT([no])
 753 fi
 754
 755 if test x$build_bitcoin_utils$build_bitcoind$bitcoin_enable_qt$use_tests = xnononono; then
 756   AC_MSG_ERROR([No targets! Please specify at least one of: --with-utils --with-daemon --with-gui or --enable-tests])
 757 fi
 758
 759 AM_CONDITIONAL([TARGET_DARWIN], [test x$TARGET_OS = xdarwin])
 760 AM_CONDITIONAL([BUILD_DARWIN], [test x$BUILD_OS = xdarwin])
 761 AM_CONDITIONAL([TARGET_WINDOWS], [test x$TARGET_OS = xwindows])
 762 AM_CONDITIONAL([ENABLE_WALLET],[test x$enable_wallet == xyes])
 763 AM_CONDITIONAL([ENABLE_TESTS],[test x$use_tests == xyes])
 764 AM_CONDITIONAL([ENABLE_QT],[test x$bitcoin_enable_qt == xyes])
 765 AM_CONDITIONAL([ENABLE_QT_TESTS],[test x$use_tests$bitcoin_enable_qt_test = xyesyes])
 766 AM_CONDITIONAL([USE_QRCODE], [test x$use_qr = xyes])
 767 AM_CONDITIONAL([USE_LCOV],[test x$use_lcov == xyes])
 768 AM_CONDITIONAL([USE_COMPARISON_TOOL],[test x$use_comparison_tool != xno])
 769 AM_CONDITIONAL([USE_COMPARISON_TOOL_REORG_TESTS],[test x$use_comparison_tool_reorg_test != xno])
 770 AM_CONDITIONAL([GLIBC_BACK_COMPAT],[test x$use_glibc_compat = xyes])
 771 AM_CONDITIONAL([USE_LIBSECP256K1],[test x$use_libsecp256k1 = xyes])
 772
 773 AC_DEFINE(CLIENT_VERSION_MAJOR, _CLIENT_VERSION_MAJOR, [Major version])
 774 AC_DEFINE(CLIENT_VERSION_MINOR, _CLIENT_VERSION_MINOR, [Minor version])
 775 AC_DEFINE(CLIENT_VERSION_REVISION, _CLIENT_VERSION_REVISION, [Build revision])
 776 AC_DEFINE(CLIENT_VERSION_BUILD, _CLIENT_VERSION_BUILD, [Version Build])
 777 AC_DEFINE(CLIENT_VERSION_IS_RELEASE, _CLIENT_VERSION_IS_RELEASE, [Version is release])
 778 AC_DEFINE(COPYRIGHT_YEAR, _COPYRIGHT_YEAR, [Version is release])
 779 AC_SUBST(CLIENT_VERSION_MAJOR, _CLIENT_VERSION_MAJOR)
 780 AC_SUBST(CLIENT_VERSION_MINOR, _CLIENT_VERSION_MINOR)
 781 AC_SUBST(CLIENT_VERSION_REVISION, _CLIENT_VERSION_REVISION)
 782 AC_SUBST(CLIENT_VERSION_BUILD, _CLIENT_VERSION_BUILD)
 783 AC_SUBST(CLIENT_VERSION_IS_RELEASE, _CLIENT_VERSION_IS_RELEASE)
 784 AC_SUBST(COPYRIGHT_YEAR, _COPYRIGHT_YEAR)
 785
 786
 787 AC_SUBST(RELDFLAGS)
 788 AC_SUBST(LIBTOOL_LDFLAGS)
 789 AC_SUBST(USE_UPNP)
 790 AC_SUBST(USE_QRCODE)
 791 AC_SUBST(BOOST_LIBS)
 792 AC_SUBST(TESTDEFS)
 793 AC_SUBST(LEVELDB_TARGET_FLAGS)
 794 AC_SUBST(BUILD_TEST)
 795 AC_SUBST(BUILD_QT)
 796 AC_SUBST(BUILD_TEST_QT)
 797 AC_SUBST(MINIUPNPC_CPPFLAGS)
 798 AC_CONFIG_FILES([Makefile src/Makefile share/setup.nsi share/qt/Info.plist])
 799 AC_CONFIG_FILES([qa/pull-tester/run-bitcoind-for-test.sh],[chmod +x qa/pull-tester/run-bitcoind-for-test.sh])
 800 AC_CONFIG_FILES([qa/pull-tester/build-tests.sh],[chmod +x qa/pull-tester/build-tests.sh])
 801 AC_OUTPUT
 802
 803 dnl Taken from https://wiki.debian.org/RpathIssue
 804 case $host in
 805    *-*-linux-gnu)
 806      AC_MSG_RESULT([Fixing libtool for -rpath problems.])
 807      sed < libtool > libtool-2 \
 808      's/^hardcode_libdir_flag_spec.*$'/'hardcode_libdir_flag_spec=" -D__LIBTOOL_IS_A_FOOL__ "/'
 809      mv libtool-2 libtool
 810      chmod 755 libtool
 811    ;;
 812 esac