[u-boot.git] / arch / x86 / cpu / start16.S

/*
 *  U-boot - x86 Startup Code
 *
 * (C) Copyright 2008-2011
 * Graeme Russ, <[email protected]>
 *
 * (C) Copyright 2002,2003
 * Daniel Engström, Omicron Ceti AB, <[email protected]>
 *
 * See file CREDITS for list of people who contributed to this
 * project.
 *
 * This program is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License as
 * published by the Free Software Foundation; either version 2 of
 * the License, or (at your option) any later version.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with this program; if not, write to the Free Software
 * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
 * MA 02111-1307 USA
 */

#include <asm/global_data.h>
#include <asm/processor-flags.h>

#define BOOT_SEG	0xffff0000	/* linear segment of boot code */
#define a32		.byte 0x67;
#define o32		.byte 0x66;

.section .start16, "ax"
.code16
.globl start16
start16:
	/*
	 * First we let the BSP do some early initialization
	 * this code have to map the flash to its final position
	 */
	jmp	board_init16
.globl board_init16_ret
board_init16_ret:

	/* Turn of cache (this might require a 486-class CPU) */
	movl	%cr0, %eax
	orl	$(X86_CR0_NW | X86_CR0_CD), %eax
	movl	%eax, %cr0
	wbinvd

	/* load the temporary Global Descriptor Table */
o32 cs	lidt	idt_ptr
o32 cs	lgdt	gdt_ptr

	/* Now, we enter protected mode */
	movl	%cr0, %eax
	orl	$X86_CR0_PE, %eax
	movl	%eax, %cr0

	/* Flush the prefetch queue */
	jmp	ff
ff:
	/* Finally jump to the 32bit initialization code */
	movw	$code32start, %ax
	movw	%ax, %bp
o32 cs	ljmp	*(%bp)

	/* 48-bit far pointer */
code32start:
	.long	_start		/* offset */
	.word	0x10		/* segment */

idt_ptr:
	.word	0		/* limit */
	.long	0		/* base */

/*
 * The following Global Descriptor Table is just enough to get us into
 * 'Flat Protected Mode' - It will be discarded as soon as the final
 * GDT is setup in a safe location in RAM
 */
gdt_ptr:
	.word	0x20		/* limit (32 bytes = 4 GDT entries) */
	.long	BOOT_SEG + gdt	/* base */

	/* The GDT table ...
	 *
	 *	 Selector	Type
	 *	 0x00		NULL
	 *	 0x08		Unused
	 *	 0x10		32bit code
	 *	 0x18		32bit data/stack
	 */

gdt:
	.word	0, 0, 0, 0	/* NULL  */
	.word	0, 0, 0, 0	/* unused */

	.word	0xFFFF		/* 4Gb - (0x100000*0x1000 = 4Gb) */
	.word	0		/* base address = 0 */
	.word	0x9B00		/* code read/exec */
	.word	0x00CF		/* granularity = 4096, 386 (+5th nibble of limit) */

	.word	0xFFFF		/* 4Gb - (0x100000*0x1000 = 4Gb) */
	.word	0x0		/* base address = 0 */
	.word	0x9300		/* data read/write */
	.word	0x00CF		/* granularity = 4096, 386 (+5th nibble of limit) */
Commit	Line	Data
2262cfee	1	/*
fea25720	2	* U-boot - x86 Startup Code
2262cfee	3	*
dbf7115a GR	4	* (C) Copyright 2008-2011
	5	* Graeme Russ, <[email protected]>
	6	*
	7	* (C) Copyright 2002,2003
fa82f871	8	* Daniel Engström, Omicron Ceti AB, <[email protected]>
2262cfee WD	9	*
	10	* See file CREDITS for list of people who contributed to this
	11	* project.
	12	*
	13	* This program is free software; you can redistribute it and/or
	14	* modify it under the terms of the GNU General Public License as
	15	* published by the Free Software Foundation; either version 2 of
	16	* the License, or (at your option) any later version.
	17	*
	18	* This program is distributed in the hope that it will be useful,
	19	* but WITHOUT ANY WARRANTY; without even the implied warranty of
	20	* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
	21	* GNU General Public License for more details.
	22	*
	23	* You should have received a copy of the GNU General Public License
	24	* along with this program; if not, write to the Free Software
	25	* Foundation, Inc., 59 Temple Place, Suite 330, Boston,
	26	* MA 02111-1307 USA
	27	*/
	28
c81b26be	29	#include <asm/global_data.h>
0c24c9cc	30	#include <asm/processor-flags.h>
2262cfee WD	31
	32	#define BOOT_SEG 0xffff0000 /* linear segment of boot code */
	33	#define a32 .byte 0x67;
	34	#define o32 .byte 0x66;
	35
	36	.section .start16, "ax"
	37	.code16
	38	.globl start16
8bde7f77	39	start16:
8ffb2e8f GR	40	/*
8ffb2e8f GR	41	* First we let the BSP do some early initialization
2262cfee WD	42	* this code have to map the flash to its final position
2262cfee WD	43	*/
2262cfee	44	jmp board_init16
88fa0a6e	45	.globl board_init16_ret
8bde7f77 WD	46	board_init16_ret:
8bde7f77 WD	47
2262cfee	48	/* Turn of cache (this might require a 486-class CPU) */
53677ef1	49	movl %cr0, %eax
7b3d5380	50	orl $(X86_CR0_NW \| X86_CR0_CD), %eax
53677ef1	51	movl %eax, %cr0
8bde7f77 WD	52	wbinvd
8bde7f77 WD	53
c14a3669	54	/* load the temporary Global Descriptor Table */
797960fd	55	o32 cs lidt idt_ptr
53677ef1	56	o32 cs lgdt gdt_ptr
2262cfee	57
2262cfee	58	/* Now, we enter protected mode */
53677ef1	59	movl %cr0, %eax
0c24c9cc	60	orl $X86_CR0_PE, %eax
53677ef1	61	movl %eax, %cr0
8bde7f77	62
2262cfee	63	/* Flush the prefetch queue */
53677ef1	64	jmp ff
2262cfee	65	ff:
2262cfee	66	/* Finally jump to the 32bit initialization code */
8bde7f77	67	movw $code32start, %ax
8ffb2e8f	68	movw %ax, %bp
2262cfee WD	69	o32 cs ljmp *(%bp)
	70
	71	/* 48-bit far pointer */
	72	code32start:
53677ef1 WD	73	.long _start /* offset */
53677ef1 WD	74	.word 0x10 /* segment */
2262cfee	75
797960fd GR	76	idt_ptr:
	77	.word 0 /* limit */
	78	.long 0 /* base */
	79
c14a3669 GR	80	/*
	81	* The following Global Descriptor Table is just enough to get us into
	82	* 'Flat Protected Mode' - It will be discarded as soon as the final
	83	* GDT is setup in a safe location in RAM
	84	*/
2262cfee	85	gdt_ptr:
c14a3669	86	.word 0x20 /* limit (32 bytes = 4 GDT entries) */
53677ef1	87	.long BOOT_SEG + gdt /* base */
2262cfee	88
8bde7f77	89	/* The GDT table ...
2262cfee	90	*
53677ef1 WD	91	* Selector Type
	92	* 0x00 NULL
	93	* 0x08 Unused
8bde7f77	94	* 0x10 32bit code
2262cfee	95	* 0x18 32bit data/stack
2262cfee WD	96	*/
	97
	98	gdt:
53677ef1 WD	99	.word 0, 0, 0, 0 /* NULL */
	100	.word 0, 0, 0, 0 /* unused */
	101
	102	.word 0xFFFF /* 4Gb - (0x1000000x1000 = 4Gb) /
	103	.word 0 /* base address = 0 */
	104	.word 0x9B00 /* code read/exec */
	105	.word 0x00CF /* granularity = 4096, 386 (+5th nibble of limit) */
	106
	107	.word 0xFFFF /* 4Gb - (0x1000000x1000 = 4Gb) /
	108	.word 0x0 /* base address = 0 */
	109	.word 0x9300 /* data read/write */
	110	.word 0x00CF /* granularity = 4096, 386 (+5th nibble of limit) */