[binutils.git] / ld / ldlex.l

%{

/* Copyright 1991, 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000, 2001
   Free Software Foundation, Inc.

This file is part of GLD, the Gnu Linker.

GLD is free software; you can redistribute it and/or modify
it under the terms of the GNU General Public License as published by
the Free Software Foundation; either version 2, or (at your option)
any later version.

GLD is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
GNU General Public License for more details.

You should have received a copy of the GNU General Public License
along with GLD; see the file COPYING.  If not, write to the Free
Software Foundation, 59 Temple Place - Suite 330, Boston, MA
02111-1307, USA.  */

/*
This was written by steve chamberlain
                    [email protected]
*/


#include <ansidecl.h>
#include <stdio.h>

#ifdef MPW
/* Prevent enum redefinition problems. */
#define TRUE_FALSE_ALREADY_DEFINED
#endif /* MPW */

#include "bfd.h"
#include "sysdep.h"
#include "safe-ctype.h"
#include "ld.h"
#include "ldgram.h"
#include "ldmisc.h"
#include "ldexp.h"
#include "ldlang.h"
#include "ldfile.h"
#include "ldlex.h"
#include "ldmain.h"
#include "libiberty.h"

/* The type of top-level parser input.
   yylex and yyparse (indirectly) both check this.  */
input_type parser_input;

/* Line number in the current input file.
   (FIXME Actually, it doesn't appear to get reset for each file?)  */
unsigned int lineno = 1;

/* The string we are currently lexing, or NULL if we are reading a
   file.  */
const char *lex_string = NULL;

/* Support for flex reading from more than one input file (stream).
   `include_stack' is flex's input state for each open file;
   `file_name_stack' is the file names.  `lineno_stack' is the current
   line numbers.

   If `include_stack_ptr' is 0, we haven't started reading anything yet.
   Otherwise, stack elements 0 through `include_stack_ptr - 1' are valid.  */

#undef YY_INPUT
#define YY_INPUT(buf,result,max_size) yy_input(buf, &result, max_size)

#define MAX_INCLUDE_DEPTH 10
static YY_BUFFER_STATE include_stack[MAX_INCLUDE_DEPTH];
static const char *file_name_stack[MAX_INCLUDE_DEPTH];
static unsigned int lineno_stack[MAX_INCLUDE_DEPTH];
static unsigned int include_stack_ptr = 0;
static int vers_node_nesting = 0;

static YY_BUFFER_STATE yy_create_string_buffer PARAMS ((const char *string,
							size_t size));
static void yy_input PARAMS ((char *, int *result, int max_size));

static void comment PARAMS ((void));
static void lex_warn_invalid PARAMS ((char *where, char *what));

/* STATES 
	EXPRESSION	definitely in an expression
	SCRIPT		definitely in a script
	BOTH		either EXPRESSION or SCRIPT
	DEFSYMEXP	in an argument to -defsym
        MRI             in an MRI script
	VERS_START	starting a Sun style mapfile
	VERS_SCRIPT	a Sun style mapfile
	VERS_NODE	a node within a Sun style mapfile
*/
#define RTOKEN(x)  {  yylval.token = x; return x; }

/* Some versions of flex want this.  */
#ifndef yywrap
int yywrap () { return 1; }
#endif
%}

%a 4000
%o 5000

CMDFILENAMECHAR   [_a-zA-Z0-9\/\.\\_\+\$\:\[\]\\\,\=\&\!\<\>\-\~]
CMDFILENAMECHAR1  [_a-zA-Z0-9\/\.\\_\+\$\:\[\]\\\,\=\&\!\<\>\~]
FILENAMECHAR1	[_a-zA-Z\/\.\\\$\_\~]
SYMBOLCHARN     [_a-zA-Z\/\.\\\$\_\~0-9]
FILENAMECHAR	[_a-zA-Z0-9\/\.\-\_\+\=\$\:\[\]\\\,\~]
WILDCHAR	[_a-zA-Z0-9\/\.\-\_\+\=\$\:\[\]\\\,\~\?\*]
WHITE		[ \t\n\r]+ 

NOCFILENAMECHAR	[_a-zA-Z0-9\/\.\-\_\+\$\:\[\]\\\~]

V_TAG [.$_a-zA-Z][._a-zA-Z0-9]*
V_IDENTIFIER [*?.$_a-zA-Z]([*?.$_a-zA-Z0-9]|::)*

%s SCRIPT
%s EXPRESSION
%s BOTH
%s DEFSYMEXP
%s MRI
%s VERS_START
%s VERS_SCRIPT
%s VERS_NODE
%%

  if (parser_input != input_selected)
    {
      /* The first token of the input determines the initial parser state.  */
      input_type t = parser_input;
      parser_input = input_selected;
      switch (t)
	{
	case input_script: return INPUT_SCRIPT; break;
	case input_mri_script: return INPUT_MRI_SCRIPT; break;
	case input_version_script: return INPUT_VERSION_SCRIPT; break;
	case input_defsym: return INPUT_DEFSYM; break;
	default: abort ();
	}
    }

<BOTH,SCRIPT,EXPRESSION>"/*"	{ comment(); }


<DEFSYMEXP>"-"                  { RTOKEN('-');}
<DEFSYMEXP>"+"                  { RTOKEN('+');}
<DEFSYMEXP>{FILENAMECHAR1}{SYMBOLCHARN}*   { yylval.name = xstrdup(yytext); return NAME; }
<DEFSYMEXP>"="                  { RTOKEN('='); }

<MRI,EXPRESSION>"$"([0-9A-Fa-f])+ {
  				yylval.integer = bfd_scan_vma (yytext+1, 0,16);
				return INT;
			}

<MRI,EXPRESSION>([0-9A-Fa-f])+(H|h|X|x|B|b|O|o|D|d) {
				   int ibase ;
				   switch (yytext[yyleng-1]) {
				    case 'X': 
				    case 'x':
				    case 'H':
				    case 'h':
				     ibase = 16;
				     break;
				    case 'O':
				    case 'o':
				     ibase = 8;
				     break;
				    case 'B':
				    case 'b':
				     ibase = 2;
				     break;
				    default:
				     ibase = 10;
				   }
				   yylval.integer = bfd_scan_vma (yytext, 0,
								  ibase);
				   return INT;
				 }
<SCRIPT,DEFSYMEXP,MRI,BOTH,EXPRESSION>((("$"|"0x")([0-9A-Fa-f])+)|(([0-9])+))(M|K|m|k)? {
				  char *s = yytext;

				  if (*s == '$')
				    ++s;
				  yylval.integer = bfd_scan_vma (s, 0, 0);
				  if (yytext[yyleng-1] == 'M'
				      || yytext[yyleng-1] == 'm')
				    yylval.integer *= 1024 * 1024;
				  if (yytext[yyleng-1] == 'K' 
				      || yytext[yyleng-1]=='k')
				    yylval.integer *= 1024;
				  return INT;
				}
<BOTH,SCRIPT,EXPRESSION,MRI>"]"		{ RTOKEN(']');}
<BOTH,SCRIPT,EXPRESSION,MRI>"["		{ RTOKEN('[');}
<BOTH,SCRIPT,EXPRESSION,MRI>"<<="	{ RTOKEN(LSHIFTEQ);}
<BOTH,SCRIPT,EXPRESSION,MRI>">>="	{ RTOKEN(RSHIFTEQ);}
<BOTH,SCRIPT,EXPRESSION,MRI>"||"	{ RTOKEN(OROR);}
<BOTH,SCRIPT,EXPRESSION,MRI>"=="	{ RTOKEN(EQ);}
<BOTH,SCRIPT,EXPRESSION,MRI>"!="	{ RTOKEN(NE);}
<BOTH,SCRIPT,EXPRESSION,MRI>">="	{ RTOKEN(GE);}
<BOTH,SCRIPT,EXPRESSION,MRI>"<="	{ RTOKEN(LE);}
<BOTH,SCRIPT,EXPRESSION,MRI>"<<"	{ RTOKEN(LSHIFT);}
<BOTH,SCRIPT,EXPRESSION,MRI>">>"	{ RTOKEN(RSHIFT);}
<BOTH,SCRIPT,EXPRESSION,MRI>"+="	{ RTOKEN(PLUSEQ);}
<BOTH,SCRIPT,EXPRESSION,MRI>"-="	{ RTOKEN(MINUSEQ);}
<BOTH,SCRIPT,EXPRESSION,MRI>"*="	{ RTOKEN(MULTEQ);}
<BOTH,SCRIPT,EXPRESSION,MRI>"/="	{ RTOKEN(DIVEQ);}
<BOTH,SCRIPT,EXPRESSION,MRI>"&="	{ RTOKEN(ANDEQ);}
<BOTH,SCRIPT,EXPRESSION,MRI>"|="	{ RTOKEN(OREQ);}
<BOTH,SCRIPT,EXPRESSION,MRI>"&&"	{ RTOKEN(ANDAND);}
<BOTH,SCRIPT,EXPRESSION,MRI>">"		{ RTOKEN('>');}
<BOTH,SCRIPT,EXPRESSION,MRI>","		{ RTOKEN(',');}
<BOTH,SCRIPT,EXPRESSION,MRI>"&"		{ RTOKEN('&');}
<BOTH,SCRIPT,EXPRESSION,MRI>"|"		{ RTOKEN('|');}
<BOTH,SCRIPT,EXPRESSION,MRI>"~"		{ RTOKEN('~');}
<BOTH,SCRIPT,EXPRESSION,MRI>"!"		{ RTOKEN('!');}
<BOTH,SCRIPT,EXPRESSION,MRI>"?"		{ RTOKEN('?');}
<BOTH,SCRIPT,EXPRESSION,MRI>"*"		{ RTOKEN('*');}
<BOTH,SCRIPT,EXPRESSION,MRI>"+"		{ RTOKEN('+');}
<BOTH,SCRIPT,EXPRESSION,MRI>"-"		{ RTOKEN('-');}
<BOTH,SCRIPT,EXPRESSION,MRI>"/"		{ RTOKEN('/');}
<BOTH,SCRIPT,EXPRESSION,MRI>"%"		{ RTOKEN('%');}
<BOTH,SCRIPT,EXPRESSION,MRI>"<"		{ RTOKEN('<');}
<BOTH,SCRIPT,EXPRESSION,MRI>"="          { RTOKEN('=');}
<BOTH,SCRIPT,EXPRESSION,MRI>"}"			{ RTOKEN('}') ; }
<BOTH,SCRIPT,EXPRESSION,MRI>"{"			{ RTOKEN('{'); }
<BOTH,SCRIPT,EXPRESSION,MRI>")"			{ RTOKEN(')');}
<BOTH,SCRIPT,EXPRESSION,MRI>"("			{ RTOKEN('(');}
<BOTH,SCRIPT,EXPRESSION,MRI>":"		{ RTOKEN(':'); }
<BOTH,SCRIPT,EXPRESSION,MRI>";"		{ RTOKEN(';');}
<BOTH,SCRIPT>"MEMORY"		{ RTOKEN(MEMORY);}
<BOTH,SCRIPT>"ORIGIN"		{ RTOKEN(ORIGIN);}
<BOTH,SCRIPT>"VERSION"		{ RTOKEN(VERSIONK);}
<EXPRESSION,BOTH,SCRIPT>"BLOCK"		{ RTOKEN(BLOCK);}
<EXPRESSION,BOTH,SCRIPT>"BIND"		{ RTOKEN(BIND);}
<BOTH,SCRIPT>"LENGTH"		{ RTOKEN(LENGTH);}
<EXPRESSION,BOTH,SCRIPT>"ALIGN"			{ RTOKEN(ALIGN_K);}
<EXPRESSION,BOTH,SCRIPT>"ADDR"			{ RTOKEN(ADDR);}
<EXPRESSION,BOTH,SCRIPT>"LOADADDR"		{ RTOKEN(LOADADDR);}
<EXPRESSION,BOTH>"MAX"			{ RTOKEN(MAX_K); }
<EXPRESSION,BOTH>"MIN"			{ RTOKEN(MIN_K); }
<EXPRESSION,BOTH>"ASSERT"		{ RTOKEN(ASSERT_K); }
<BOTH,SCRIPT>"ENTRY"			{ RTOKEN(ENTRY);}
<BOTH,SCRIPT,MRI>"EXTERN"		{ RTOKEN(EXTERN);}
<EXPRESSION,BOTH,SCRIPT>"NEXT"			{ RTOKEN(NEXT);}
<EXPRESSION,BOTH,SCRIPT>"sizeof_headers"	{ RTOKEN(SIZEOF_HEADERS);}
<EXPRESSION,BOTH,SCRIPT>"SIZEOF_HEADERS"	{ RTOKEN(SIZEOF_HEADERS);}
<BOTH,SCRIPT>"MAP"			{ RTOKEN(MAP);}
<EXPRESSION,BOTH,SCRIPT>"SIZEOF"		{ RTOKEN(SIZEOF);}
<BOTH,SCRIPT>"TARGET"		{ RTOKEN(TARGET_K);}
<BOTH,SCRIPT>"SEARCH_DIR"		{ RTOKEN(SEARCH_DIR);}
<BOTH,SCRIPT>"OUTPUT"		{ RTOKEN(OUTPUT);}
<BOTH,SCRIPT>"INPUT"			{ RTOKEN(INPUT);}
<EXPRESSION,BOTH,SCRIPT>"GROUP"		{ RTOKEN(GROUP);}
<EXPRESSION,BOTH,SCRIPT>"DEFINED"		{ RTOKEN(DEFINED);}
<BOTH,SCRIPT>"CREATE_OBJECT_SYMBOLS"	{ RTOKEN(CREATE_OBJECT_SYMBOLS);}
<BOTH,SCRIPT>"CONSTRUCTORS"		{ RTOKEN( CONSTRUCTORS);}
<BOTH,SCRIPT>"FORCE_COMMON_ALLOCATION" { RTOKEN(FORCE_COMMON_ALLOCATION);}
<BOTH,SCRIPT>"INHIBIT_COMMON_ALLOCATION" { RTOKEN(INHIBIT_COMMON_ALLOCATION);}
<BOTH,SCRIPT>"SECTIONS"		{ RTOKEN(SECTIONS);}
<BOTH,SCRIPT>"FILL"			{ RTOKEN(FILL);}
<BOTH,SCRIPT>"STARTUP"		{ RTOKEN(STARTUP);}
<BOTH,SCRIPT>"OUTPUT_FORMAT"		{ RTOKEN(OUTPUT_FORMAT);}
<BOTH,SCRIPT>"OUTPUT_ARCH"		{ RTOKEN( OUTPUT_ARCH);}
<BOTH,SCRIPT>"HLL"			{ RTOKEN(HLL);}
<BOTH,SCRIPT>"SYSLIB"		{ RTOKEN(SYSLIB);}
<BOTH,SCRIPT>"FLOAT"			{ RTOKEN(FLOAT);}
<BOTH,SCRIPT>"QUAD"			{ RTOKEN( QUAD);}
<BOTH,SCRIPT>"SQUAD"			{ RTOKEN( SQUAD);}
<BOTH,SCRIPT>"LONG"			{ RTOKEN( LONG);}
<BOTH,SCRIPT>"SHORT"			{ RTOKEN( SHORT);}
<BOTH,SCRIPT>"BYTE"			{ RTOKEN( BYTE);}
<BOTH,SCRIPT>"NOFLOAT"		{ RTOKEN(NOFLOAT);}
<EXPRESSION,BOTH,SCRIPT>"NOCROSSREFS"	{ RTOKEN(NOCROSSREFS);}
<BOTH,SCRIPT>"OVERLAY"			{ RTOKEN(OVERLAY); }
<BOTH,SCRIPT>"SORT"			{ RTOKEN(SORT); }
<EXPRESSION,BOTH,SCRIPT>"NOLOAD"	{ RTOKEN(NOLOAD);}
<EXPRESSION,BOTH,SCRIPT>"DSECT"		{ RTOKEN(DSECT);}
<EXPRESSION,BOTH,SCRIPT>"COPY"		{ RTOKEN(COPY);}
<EXPRESSION,BOTH,SCRIPT>"INFO"		{ RTOKEN(INFO);}
<EXPRESSION,BOTH,SCRIPT>"OVERLAY"	{ RTOKEN(OVERLAY);}
<BOTH,SCRIPT>"o"			{ RTOKEN(ORIGIN);}
<BOTH,SCRIPT>"org"			{ RTOKEN(ORIGIN);}
<BOTH,SCRIPT>"l"			{ RTOKEN( LENGTH);}
<BOTH,SCRIPT>"len"			{ RTOKEN( LENGTH);}
<BOTH,SCRIPT>"INCLUDE"			{ RTOKEN(INCLUDE);}
<BOTH,SCRIPT>"PHDRS"			{ RTOKEN (PHDRS); }
<EXPRESSION,BOTH,SCRIPT>"AT"			{ RTOKEN(AT);}
<EXPRESSION,BOTH,SCRIPT>"PROVIDE"		{ RTOKEN(PROVIDE); }
<EXPRESSION,BOTH,SCRIPT>"KEEP"		{ RTOKEN(KEEP); }
<EXPRESSION,BOTH,SCRIPT>"EXCLUDE_FILE"        { RTOKEN(EXCLUDE_FILE); }
<MRI>"#".*\n?			{ ++ lineno; }
<MRI>"\n"	                { ++ lineno;  RTOKEN(NEWLINE); }
<MRI>"*".*			{ /* Mri comment line */ }
<MRI>";".*			{ /* Mri comment line */ }
<MRI>"END"                      { RTOKEN(ENDWORD); }
<MRI>"ALIGNMOD"		{ RTOKEN(ALIGNMOD);}
<MRI>"ALIGN"		{ RTOKEN(ALIGN_K);}
<MRI>"CHIP"                     { RTOKEN(CHIP); }
<MRI>"BASE"                     { RTOKEN(BASE); }
<MRI>"ALIAS"                     { RTOKEN(ALIAS); }
<MRI>"TRUNCATE"                     { RTOKEN(TRUNCATE); }
<MRI>"LOAD"                     { RTOKEN(LOAD); }
<MRI>"PUBLIC"                   { RTOKEN(PUBLIC); }
<MRI>"ORDER"                    { RTOKEN(ORDER); }
<MRI>"NAME"                     { RTOKEN(NAMEWORD); }
<MRI>"FORMAT"                   { RTOKEN(FORMAT); }
<MRI>"CASE"                     { RTOKEN(CASE); }
<MRI>"START"                    { RTOKEN(START); }
<MRI>"LIST".*                   { RTOKEN(LIST); /* LIST and ignore to end of line */ }
<MRI>"SECT"			{ RTOKEN(SECT); }
<EXPRESSION,BOTH,SCRIPT,MRI>"ABSOLUTE"			{ RTOKEN(ABSOLUTE); }
<MRI>"end"                      { RTOKEN(ENDWORD); }
<MRI>"alignmod"		{ RTOKEN(ALIGNMOD);}
<MRI>"align"		{ RTOKEN(ALIGN_K);}
<MRI>"chip"                     { RTOKEN(CHIP); }
<MRI>"base"                     { RTOKEN(BASE); }
<MRI>"alias"                     { RTOKEN(ALIAS); }
<MRI>"truncate"                     { RTOKEN(TRUNCATE); }
<MRI>"load"                     { RTOKEN(LOAD); }
<MRI>"public"                   { RTOKEN(PUBLIC); }
<MRI>"order"                    { RTOKEN(ORDER); }
<MRI>"name"                     { RTOKEN(NAMEWORD); }
<MRI>"format"                   { RTOKEN(FORMAT); }
<MRI>"case"                     { RTOKEN(CASE); }
<MRI>"extern"                   { RTOKEN(EXTERN); }
<MRI>"start"                    { RTOKEN(START); }
<MRI>"list".*                   { RTOKEN(LIST); /* LIST and ignore to end of line */ }
<MRI>"sect"			{ RTOKEN(SECT); }
<EXPRESSION,BOTH,SCRIPT,MRI>"absolute"			{ RTOKEN(ABSOLUTE); }

<MRI>{FILENAMECHAR1}{NOCFILENAMECHAR}*	{
/* Filename without commas, needed to parse mri stuff */
				 yylval.name = xstrdup(yytext); 
				  return NAME;
				}


<BOTH,EXPRESSION>{FILENAMECHAR1}{FILENAMECHAR}*	{
				 yylval.name = xstrdup(yytext); 
				  return NAME;
				}
<BOTH,EXPRESSION>"-l"{FILENAMECHAR}+ {
				  yylval.name = xstrdup (yytext + 2);
				  return LNAME;
				}
<SCRIPT>{WILDCHAR}* {
		/* Annoyingly, this pattern can match comments, and we have
		   longest match issues to consider.  So if the first two
		   characters are a comment opening, put the input back and
		   try again.  */
		if (yytext[0] == '/' && yytext[1] == '*')
		  {
		    yyless(2);
		    comment ();
		  }
		else
		  {
		    yylval.name = xstrdup(yytext);
		    return NAME;
		  }
	}

<EXPRESSION,BOTH,SCRIPT,VERS_NODE>"\""[^\"]*"\"" {
					/* No matter the state, quotes
					   give what's inside */
					yylval.name = xstrdup(yytext+1);
					yylval.name[yyleng-2] = 0;
					return NAME;
				}
<BOTH,SCRIPT,EXPRESSION>"\n"		{ lineno++;}
<MRI,BOTH,SCRIPT,EXPRESSION>[ \t\r]+	{ }

<VERS_NODE,VERS_SCRIPT>[:,;]	{ return *yytext; }

<VERS_NODE>global		{ RTOKEN(GLOBAL); }

<VERS_NODE>local		{ RTOKEN(LOCAL); }

<VERS_NODE>extern		{ RTOKEN(EXTERN); }

<VERS_NODE>{V_IDENTIFIER}	{ yylval.name = xstrdup (yytext);
				  return VERS_IDENTIFIER; }

<VERS_SCRIPT>{V_TAG}		{ yylval.name = xstrdup (yytext);
				  return VERS_TAG; }

<VERS_START>"{"			{ BEGIN(VERS_SCRIPT); return *yytext; }

<VERS_SCRIPT>"{"		{ BEGIN(VERS_NODE); 
				  vers_node_nesting = 0;
				  return *yytext;
				}
<VERS_SCRIPT>"}"		{ return *yytext; }
<VERS_NODE>"{"			{ vers_node_nesting++; return *yytext; }
<VERS_NODE>"}"			{ if (--vers_node_nesting < 0)
				    BEGIN(VERS_SCRIPT);
				  return *yytext;
				}

<VERS_START,VERS_NODE,VERS_SCRIPT>[\n]		{ lineno++; }

<VERS_START,VERS_NODE,VERS_SCRIPT>#.*		{ /* Eat up comments */ }

<VERS_START,VERS_NODE,VERS_SCRIPT>[ \t\r]+   	{ /* Eat up whitespace */ }

<<EOF>> {
  include_stack_ptr--;
    
  if (include_stack_ptr == 0) 
  {
    yyterminate();
  }
  else 
  {
    yy_switch_to_buffer(include_stack[include_stack_ptr]);

  }
  BEGIN(SCRIPT);
  ldfile_input_filename = file_name_stack[include_stack_ptr - 1];
  lineno = lineno_stack[include_stack_ptr - 1];

  return END;
}

<SCRIPT,MRI,VERS_START,VERS_SCRIPT,VERS_NODE>.	lex_warn_invalid(" in script", yytext);
<EXPRESSION,DEFSYMEXP,BOTH>.	lex_warn_invalid(" in expression", yytext);
    
%%
\f

/* Switch flex to reading script file NAME, open on FILE,
   saving the current input info on the include stack.  */

void
lex_push_file (file, name)
     FILE *file;
     const char *name;
{
  if (include_stack_ptr >= MAX_INCLUDE_DEPTH) 
    {
      einfo("%F:includes nested too deeply\n");
    }
  file_name_stack[include_stack_ptr] = name;
  lineno_stack[include_stack_ptr] = 1;
  include_stack[include_stack_ptr] = YY_CURRENT_BUFFER;

  include_stack_ptr++;
  yyin = file;
  yy_switch_to_buffer(yy_create_buffer(yyin, YY_BUF_SIZE));
  BEGIN (SCRIPT);
}

/* Return a newly created flex input buffer containing STRING,
   which is SIZE bytes long.  */

static YY_BUFFER_STATE 
yy_create_string_buffer (string, size)
     CONST char *string;
     size_t size;
{
  YY_BUFFER_STATE b;

  /* Calls to m-alloc get turned by sed into xm-alloc.  */
  b = (YY_BUFFER_STATE) malloc (sizeof (struct yy_buffer_state));
  b->yy_input_file = 0;
  b->yy_buf_size = size;

  /* yy_ch_buf has to be 2 characters longer than the size given because
     we need to put in 2 end-of-buffer characters.  */
  b->yy_ch_buf = (char *) malloc ((unsigned) (b->yy_buf_size + 3));

  b->yy_ch_buf[0] = '\n';
  strcpy (b->yy_ch_buf+1, string);
  b->yy_ch_buf[size+1] = YY_END_OF_BUFFER_CHAR;
  b->yy_ch_buf[size+2] = YY_END_OF_BUFFER_CHAR;
  b->yy_n_chars = size+1;
  b->yy_buf_pos = &b->yy_ch_buf[1];

  b->yy_is_our_buffer = 1;
  b->yy_is_interactive = 0;
  b->yy_at_bol = 1;
  b->yy_fill_buffer = 0;

  /* flex 2.4.7 changed the interface.  FIXME: We should not be using
     a flex internal interface in the first place!  */
#ifdef YY_BUFFER_NEW
  b->yy_buffer_status = YY_BUFFER_NEW;
#else
  b->yy_eof_status = EOF_NOT_SEEN;
#endif

  return b;
}

/* Switch flex to reading from STRING, saving the current input info
   on the include stack.  */

void
lex_redirect (string)
     CONST char *string;
{
  YY_BUFFER_STATE tmp;

  yy_init = 0;
  if (include_stack_ptr >= MAX_INCLUDE_DEPTH) 
    {
      einfo("%F: macros nested too deeply\n");
    }
  file_name_stack[include_stack_ptr] = "redirect";
  lineno_stack[include_stack_ptr] = 0;
  include_stack[include_stack_ptr] = YY_CURRENT_BUFFER;
  include_stack_ptr++;
  tmp = yy_create_string_buffer (string, strlen (string));
  yy_switch_to_buffer (tmp);
  BEGIN (SCRIPT);
}
\f
/* Functions to switch to a different flex start condition,
   saving the current start condition on `state_stack'.  */

static int state_stack[MAX_INCLUDE_DEPTH * 2];
static int *state_stack_p = state_stack;

void
ldlex_script ()
{
  *(state_stack_p)++ = yy_start;
  BEGIN (SCRIPT);
}

void
ldlex_mri_script ()
{
  *(state_stack_p)++ = yy_start;
  BEGIN (MRI);
}

void
ldlex_version_script ()
{
  *(state_stack_p)++ = yy_start;
  BEGIN (VERS_START);
}

void
ldlex_version_file ()
{
  *(state_stack_p)++ = yy_start;
  BEGIN (VERS_SCRIPT);
}

void
ldlex_defsym ()
{
  *(state_stack_p)++ = yy_start;
  BEGIN (DEFSYMEXP);
}
	   
void
ldlex_expression ()
{
  *(state_stack_p)++ = yy_start;
  BEGIN (EXPRESSION);
}

void
ldlex_both ()
{
  *(state_stack_p)++ = yy_start;
  BEGIN (BOTH);
}

void
ldlex_popstate ()
{
  yy_start = *(--state_stack_p);
}
\f

/* Place up to MAX_SIZE characters in BUF and return in *RESULT
   either the number of characters read, or 0 to indicate EOF.  */

static void
yy_input (buf, result, max_size)
     char *buf;
     int *result;
     int max_size;
{
  *result = 0; 
  if (yy_current_buffer->yy_input_file)
    {
      if (yyin)
	{
	  *result = read (fileno (yyin), (char *) buf, max_size);
	  if (*result < 0) 
	    einfo ("%F%P: read in flex scanner failed\n");
	}
    }
}

/* Eat the rest of a C-style comment.  */

static void
comment ()
{
  int c;

  while (1)
  {
    c = input();
    while (c != '*' && c != EOF) 
    {
      if (c == '\n')
	lineno++;
      c = input();
    }

    if (c == '*')
    {
      c = input();
      while (c == '*')
       c = input();
      if (c == '/')
       break;			/* found the end */
    }

    if (c == '\n')
      lineno++;

    if (c == EOF)
    {
      einfo( "%F%P: EOF in comment\n");
      break;
    }
  }
}

/* Warn the user about a garbage character WHAT in the input
   in context WHERE.  */

static void
lex_warn_invalid (where, what)
     char *where, *what;
{
  char buf[5];

  /* If we have found an input file whose format we do not recognize,
     and we are therefore treating it as a linker script, and we find
     an invalid character, then most likely this is a real object file
     of some different format.  Treat it as such.  */
  if (ldfile_assumed_script)
    {
      bfd_set_error (bfd_error_file_not_recognized);
      einfo ("%F%s: file not recognized: %E\n", ldfile_input_filename);
    }

  if (! ISPRINT (*what))
    {
      sprintf (buf, "\\%03o", (unsigned int) *what);
      what = buf;
    }

  einfo ("%P:%S: ignoring invalid character `%s'%s\n", what, where);
}
Commit	Line	Data
252b5132 RH	1	%{
252b5132 RH	2
3882b010	3	/* Copyright 1991, 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000, 2001
252b5132 RH	4	Free Software Foundation, Inc.
	5
	6	This file is part of GLD, the Gnu Linker.
	7
	8	GLD is free software; you can redistribute it and/or modify
	9	it under the terms of the GNU General Public License as published by
	10	the Free Software Foundation; either version 2, or (at your option)
	11	any later version.
	12
	13	GLD is distributed in the hope that it will be useful,
	14	but WITHOUT ANY WARRANTY; without even the implied warranty of
	15	MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
	16	GNU General Public License for more details.
	17
	18	You should have received a copy of the GNU General Public License
	19	along with GLD; see the file COPYING. If not, write to the Free
	20	Software Foundation, 59 Temple Place - Suite 330, Boston, MA
	21	02111-1307, USA. */
	22
	23	/*
	24	This was written by steve chamberlain
	25	[email protected]
	26	*/
	27
	28
	29	#include <ansidecl.h>
	30	#include <stdio.h>
252b5132 RH	31
	32	#ifdef MPW
	33	/* Prevent enum redefinition problems. */
	34	#define TRUE_FALSE_ALREADY_DEFINED
	35	#endif /* MPW */
	36
	37	#include "bfd.h"
	38	#include "sysdep.h"
3882b010	39	#include "safe-ctype.h"
252b5132 RH	40	#include "ld.h"
	41	#include "ldgram.h"
	42	#include "ldmisc.h"
	43	#include "ldexp.h"
	44	#include "ldlang.h"
	45	#include "ldfile.h"
	46	#include "ldlex.h"
	47	#include "ldmain.h"
d1b2b2dc	48	#include "libiberty.h"
252b5132 RH	49
	50	/* The type of top-level parser input.
	51	yylex and yyparse (indirectly) both check this. */
	52	input_type parser_input;
	53
	54	/* Line number in the current input file.
	55	(FIXME Actually, it doesn't appear to get reset for each file?) */
	56	unsigned int lineno = 1;
	57
	58	/* The string we are currently lexing, or NULL if we are reading a
	59	file. */
	60	const char *lex_string = NULL;
	61
	62	/* Support for flex reading from more than one input file (stream).
	63	`include_stack' is flex's input state for each open file;
	64	`file_name_stack' is the file names. `lineno_stack' is the current
	65	line numbers.
	66
	67	If `include_stack_ptr' is 0, we haven't started reading anything yet.
	68	Otherwise, stack elements 0 through `include_stack_ptr - 1' are valid. */
	69
	70	#undef YY_INPUT
	71	#define YY_INPUT(buf,result,max_size) yy_input(buf, &result, max_size)
	72
	73	#define MAX_INCLUDE_DEPTH 10
	74	static YY_BUFFER_STATE include_stack[MAX_INCLUDE_DEPTH];
	75	static const char *file_name_stack[MAX_INCLUDE_DEPTH];
	76	static unsigned int lineno_stack[MAX_INCLUDE_DEPTH];
	77	static unsigned int include_stack_ptr = 0;
	78	static int vers_node_nesting = 0;
	79
	80	static YY_BUFFER_STATE yy_create_string_buffer PARAMS ((const char *string,
	81	size_t size));
	82	static void yy_input PARAMS ((char , int result, int max_size));
	83
	84	static void comment PARAMS ((void));
	85	static void lex_warn_invalid PARAMS ((char where, char what));
	86
	87	/* STATES
	88	EXPRESSION definitely in an expression
	89	SCRIPT definitely in a script
	90	BOTH either EXPRESSION or SCRIPT
	91	DEFSYMEXP in an argument to -defsym
	92	MRI in an MRI script
	93	VERS_START starting a Sun style mapfile
	94	VERS_SCRIPT a Sun style mapfile
	95	VERS_NODE a node within a Sun style mapfile
	96	*/
	97	#define RTOKEN(x) { yylval.token = x; return x; }
	98
	99	/* Some versions of flex want this. */
	100	#ifndef yywrap
	101	int yywrap () { return 1; }
	102	#endif
	103	%}
	104
	105	%a 4000
	106	%o 5000
	107
	108	CMDFILENAMECHAR [_a-zA-Z0-9\/\.\\_\+\$\:\[\]\\\,\=\&\!\<\>\-\~]
	109	CMDFILENAMECHAR1 [_a-zA-Z0-9\/\.\\_\+\$\:\[\]\\\,\=\&\!\<\>\~]
	110	FILENAMECHAR1 [_a-zA-Z\/\.\\\$\_\~]
	111	SYMBOLCHARN [_a-zA-Z\/\.\\\$\_\~0-9]
	112	FILENAMECHAR [_a-zA-Z0-9\/\.\-\_\+\=\$\:\[\]\\\,\~]
113	WILDCHAR [_a-zA-Z0-9\/\.\-\_\+\=\$\:\[\]\\\,\~\?\*]
114	WHITE [ \t\n\r]+
115
116	NOCFILENAMECHAR [_a-zA-Z0-9\/\.\-\_\+\$\:\[\]\\\~]
117
118	V_TAG [.$_a-zA-Z][._a-zA-Z0-9]*
e06cae36	119	V_IDENTIFIER [?.$_a-zA-Z]([?.$_a-zA-Z0-9]\|::)*
252b5132 RH	120
	121	%s SCRIPT
	122	%s EXPRESSION
	123	%s BOTH
	124	%s DEFSYMEXP
	125	%s MRI
	126	%s VERS_START
	127	%s VERS_SCRIPT
	128	%s VERS_NODE
	129	%%
	130
	131	if (parser_input != input_selected)
	132	{
	133	/* The first token of the input determines the initial parser state. */
	134	input_type t = parser_input;
	135	parser_input = input_selected;
	136	switch (t)
	137	{
	138	case input_script: return INPUT_SCRIPT; break;
	139	case input_mri_script: return INPUT_MRI_SCRIPT; break;
	140	case input_version_script: return INPUT_VERSION_SCRIPT; break;
	141	case input_defsym: return INPUT_DEFSYM; break;
	142	default: abort ();
	143	}
	144	}
	145
	146	<BOTH,SCRIPT,EXPRESSION>"/*" { comment(); }
	147
	148
	149	<DEFSYMEXP>"-" { RTOKEN('-');}
	150	<DEFSYMEXP>"+" { RTOKEN('+');}
d1b2b2dc	151	<DEFSYMEXP>{FILENAMECHAR1}{SYMBOLCHARN}* { yylval.name = xstrdup(yytext); return NAME; }
252b5132 RH	152	<DEFSYMEXP>"=" { RTOKEN('='); }
	153
	154	<MRI,EXPRESSION>"$"([0-9A-Fa-f])+ {
	155	yylval.integer = bfd_scan_vma (yytext+1, 0,16);
	156	return INT;
	157	}
	158
	159	<MRI,EXPRESSION>([0-9A-Fa-f])+(H\|h\|X\|x\|B\|b\|O\|o\|D\|d) {
	160	int ibase ;
	161	switch (yytext[yyleng-1]) {
	162	case 'X':
	163	case 'x':
	164	case 'H':
	165	case 'h':
	166	ibase = 16;
	167	break;
	168	case 'O':
	169	case 'o':
	170	ibase = 8;
	171	break;
	172	case 'B':
	173	case 'b':
	174	ibase = 2;
	175	break;
	176	default:
	177	ibase = 10;
	178	}
	179	yylval.integer = bfd_scan_vma (yytext, 0,
	180	ibase);
	181	return INT;
	182	}
	183	<SCRIPT,DEFSYMEXP,MRI,BOTH,EXPRESSION>((("$"\|"0x")([0-9A-Fa-f])+)\|(([0-9])+))(M\|K\|m\|k)? {
	184	char *s = yytext;
	185
	186	if (*s == '$')
	187	++s;
	188	yylval.integer = bfd_scan_vma (s, 0, 0);
	189	if (yytext[yyleng-1] == 'M'
	190	\|\| yytext[yyleng-1] == 'm')
	191	yylval.integer = 1024 1024;
	192	if (yytext[yyleng-1] == 'K'
	193	\|\| yytext[yyleng-1]=='k')
	194	yylval.integer *= 1024;
	195	return INT;
	196	}
	197	<BOTH,SCRIPT,EXPRESSION,MRI>"]" { RTOKEN(']');}
	198	<BOTH,SCRIPT,EXPRESSION,MRI>"[" { RTOKEN('[');}
	199	<BOTH,SCRIPT,EXPRESSION,MRI>"<<=" { RTOKEN(LSHIFTEQ);}
	200	<BOTH,SCRIPT,EXPRESSION,MRI>">>=" { RTOKEN(RSHIFTEQ);}
	201	<BOTH,SCRIPT,EXPRESSION,MRI>"\|\|" { RTOKEN(OROR);}
	202	<BOTH,SCRIPT,EXPRESSION,MRI>"==" { RTOKEN(EQ);}
	203	<BOTH,SCRIPT,EXPRESSION,MRI>"!=" { RTOKEN(NE);}
	204	<BOTH,SCRIPT,EXPRESSION,MRI>">=" { RTOKEN(GE);}
	205	<BOTH,SCRIPT,EXPRESSION,MRI>"<=" { RTOKEN(LE);}
	206	<BOTH,SCRIPT,EXPRESSION,MRI>"<<" { RTOKEN(LSHIFT);}
	207	<BOTH,SCRIPT,EXPRESSION,MRI>">>" { RTOKEN(RSHIFT);}
	208	<BOTH,SCRIPT,EXPRESSION,MRI>"+=" { RTOKEN(PLUSEQ);}
	209	<BOTH,SCRIPT,EXPRESSION,MRI>"-=" { RTOKEN(MINUSEQ);}
	210	<BOTH,SCRIPT,EXPRESSION,MRI>"*=" { RTOKEN(MULTEQ);}
	211	<BOTH,SCRIPT,EXPRESSION,MRI>"/=" { RTOKEN(DIVEQ);}
	212	<BOTH,SCRIPT,EXPRESSION,MRI>"&=" { RTOKEN(ANDEQ);}
	213	<BOTH,SCRIPT,EXPRESSION,MRI>"\|=" { RTOKEN(OREQ);}
	214	<BOTH,SCRIPT,EXPRESSION,MRI>"&&" { RTOKEN(ANDAND);}
	215	<BOTH,SCRIPT,EXPRESSION,MRI>">" { RTOKEN('>');}
216	<BOTH,SCRIPT,EXPRESSION,MRI>"," { RTOKEN(',');}
217	<BOTH,SCRIPT,EXPRESSION,MRI>"&" { RTOKEN('&');}
218	<BOTH,SCRIPT,EXPRESSION,MRI>"\|" { RTOKEN('\|');}
219	<BOTH,SCRIPT,EXPRESSION,MRI>"~" { RTOKEN('~');}
220	<BOTH,SCRIPT,EXPRESSION,MRI>"!" { RTOKEN('!');}
221	<BOTH,SCRIPT,EXPRESSION,MRI>"?" { RTOKEN('?');}
222	<BOTH,SCRIPT,EXPRESSION,MRI>"" { RTOKEN('');}
223	<BOTH,SCRIPT,EXPRESSION,MRI>"+" { RTOKEN('+');}
224	<BOTH,SCRIPT,EXPRESSION,MRI>"-" { RTOKEN('-');}
225	<BOTH,SCRIPT,EXPRESSION,MRI>"/" { RTOKEN('/');}
226	<BOTH,SCRIPT,EXPRESSION,MRI>"%" { RTOKEN('%');}
227	<BOTH,SCRIPT,EXPRESSION,MRI>"<" { RTOKEN('<');}
228	<BOTH,SCRIPT,EXPRESSION,MRI>"=" { RTOKEN('=');}
229	<BOTH,SCRIPT,EXPRESSION,MRI>"}" { RTOKEN('}') ; }
230	<BOTH,SCRIPT,EXPRESSION,MRI>"{" { RTOKEN('{'); }
231	<BOTH,SCRIPT,EXPRESSION,MRI>")" { RTOKEN(')');}
232	<BOTH,SCRIPT,EXPRESSION,MRI>"(" { RTOKEN('(');}
233	<BOTH,SCRIPT,EXPRESSION,MRI>":" { RTOKEN(':'); }
234	<BOTH,SCRIPT,EXPRESSION,MRI>";" { RTOKEN(';');}
235	<BOTH,SCRIPT>"MEMORY" { RTOKEN(MEMORY);}
236	<BOTH,SCRIPT>"ORIGIN" { RTOKEN(ORIGIN);}
237	<BOTH,SCRIPT>"VERSION" { RTOKEN(VERSIONK);}
238	<EXPRESSION,BOTH,SCRIPT>"BLOCK" { RTOKEN(BLOCK);}
239	<EXPRESSION,BOTH,SCRIPT>"BIND" { RTOKEN(BIND);}
240	<BOTH,SCRIPT>"LENGTH" { RTOKEN(LENGTH);}
241	<EXPRESSION,BOTH,SCRIPT>"ALIGN" { RTOKEN(ALIGN_K);}
242	<EXPRESSION,BOTH,SCRIPT>"ADDR" { RTOKEN(ADDR);}
243	<EXPRESSION,BOTH,SCRIPT>"LOADADDR" { RTOKEN(LOADADDR);}
244	<EXPRESSION,BOTH>"MAX" { RTOKEN(MAX_K); }
245	<EXPRESSION,BOTH>"MIN" { RTOKEN(MIN_K); }
246	<EXPRESSION,BOTH>"ASSERT" { RTOKEN(ASSERT_K); }
247	<BOTH,SCRIPT>"ENTRY" { RTOKEN(ENTRY);}
248	<BOTH,SCRIPT,MRI>"EXTERN" { RTOKEN(EXTERN);}
249	<EXPRESSION,BOTH,SCRIPT>"NEXT" { RTOKEN(NEXT);}
250	<EXPRESSION,BOTH,SCRIPT>"sizeof_headers" { RTOKEN(SIZEOF_HEADERS);}
251	<EXPRESSION,BOTH,SCRIPT>"SIZEOF_HEADERS" { RTOKEN(SIZEOF_HEADERS);}
252	<BOTH,SCRIPT>"MAP" { RTOKEN(MAP);}
253	<EXPRESSION,BOTH,SCRIPT>"SIZEOF" { RTOKEN(SIZEOF);}
254	<BOTH,SCRIPT>"TARGET" { RTOKEN(TARGET_K);}
255	<BOTH,SCRIPT>"SEARCH_DIR" { RTOKEN(SEARCH_DIR);}
256	<BOTH,SCRIPT>"OUTPUT" { RTOKEN(OUTPUT);}
257	<BOTH,SCRIPT>"INPUT" { RTOKEN(INPUT);}
258	<EXPRESSION,BOTH,SCRIPT>"GROUP" { RTOKEN(GROUP);}
259	<EXPRESSION,BOTH,SCRIPT>"DEFINED" { RTOKEN(DEFINED);}
260	<BOTH,SCRIPT>"CREATE_OBJECT_SYMBOLS" { RTOKEN(CREATE_OBJECT_SYMBOLS);}
261	<BOTH,SCRIPT>"CONSTRUCTORS" { RTOKEN( CONSTRUCTORS);}
262	<BOTH,SCRIPT>"FORCE_COMMON_ALLOCATION" { RTOKEN(FORCE_COMMON_ALLOCATION);}
4818e05f	263	<BOTH,SCRIPT>"INHIBIT_COMMON_ALLOCATION" { RTOKEN(INHIBIT_COMMON_ALLOCATION);}
252b5132 RH	264	<BOTH,SCRIPT>"SECTIONS" { RTOKEN(SECTIONS);}
	265	<BOTH,SCRIPT>"FILL" { RTOKEN(FILL);}
	266	<BOTH,SCRIPT>"STARTUP" { RTOKEN(STARTUP);}
	267	<BOTH,SCRIPT>"OUTPUT_FORMAT" { RTOKEN(OUTPUT_FORMAT);}
	268	<BOTH,SCRIPT>"OUTPUT_ARCH" { RTOKEN( OUTPUT_ARCH);}
	269	<BOTH,SCRIPT>"HLL" { RTOKEN(HLL);}
	270	<BOTH,SCRIPT>"SYSLIB" { RTOKEN(SYSLIB);}
	271	<BOTH,SCRIPT>"FLOAT" { RTOKEN(FLOAT);}
	272	<BOTH,SCRIPT>"QUAD" { RTOKEN( QUAD);}
	273	<BOTH,SCRIPT>"SQUAD" { RTOKEN( SQUAD);}
	274	<BOTH,SCRIPT>"LONG" { RTOKEN( LONG);}
	275	<BOTH,SCRIPT>"SHORT" { RTOKEN( SHORT);}
	276	<BOTH,SCRIPT>"BYTE" { RTOKEN( BYTE);}
	277	<BOTH,SCRIPT>"NOFLOAT" { RTOKEN(NOFLOAT);}
	278	<EXPRESSION,BOTH,SCRIPT>"NOCROSSREFS" { RTOKEN(NOCROSSREFS);}
	279	<BOTH,SCRIPT>"OVERLAY" { RTOKEN(OVERLAY); }
	280	<BOTH,SCRIPT>"SORT" { RTOKEN(SORT); }
	281	<EXPRESSION,BOTH,SCRIPT>"NOLOAD" { RTOKEN(NOLOAD);}
	282	<EXPRESSION,BOTH,SCRIPT>"DSECT" { RTOKEN(DSECT);}
	283	<EXPRESSION,BOTH,SCRIPT>"COPY" { RTOKEN(COPY);}
	284	<EXPRESSION,BOTH,SCRIPT>"INFO" { RTOKEN(INFO);}
	285	<EXPRESSION,BOTH,SCRIPT>"OVERLAY" { RTOKEN(OVERLAY);}
	286	<BOTH,SCRIPT>"o" { RTOKEN(ORIGIN);}
	287	<BOTH,SCRIPT>"org" { RTOKEN(ORIGIN);}
	288	<BOTH,SCRIPT>"l" { RTOKEN( LENGTH);}
	289	<BOTH,SCRIPT>"len" { RTOKEN( LENGTH);}
	290	<BOTH,SCRIPT>"INCLUDE" { RTOKEN(INCLUDE);}
	291	<BOTH,SCRIPT>"PHDRS" { RTOKEN (PHDRS); }
	292	<EXPRESSION,BOTH,SCRIPT>"AT" { RTOKEN(AT);}
	293	<EXPRESSION,BOTH,SCRIPT>"PROVIDE" { RTOKEN(PROVIDE); }
	294	<EXPRESSION,BOTH,SCRIPT>"KEEP" { RTOKEN(KEEP); }
	295	<EXPRESSION,BOTH,SCRIPT>"EXCLUDE_FILE" { RTOKEN(EXCLUDE_FILE); }
	296	<MRI>"#".*\n? { ++ lineno; }
	297	<MRI>"\n" { ++ lineno; RTOKEN(NEWLINE); }
	298	<MRI>"". { /* Mri comment line */ }
	299	<MRI>";".* { /* Mri comment line */ }
	300	<MRI>"END" { RTOKEN(ENDWORD); }
	301	<MRI>"ALIGNMOD" { RTOKEN(ALIGNMOD);}
	302	<MRI>"ALIGN" { RTOKEN(ALIGN_K);}
	303	<MRI>"CHIP" { RTOKEN(CHIP); }
	304	<MRI>"BASE" { RTOKEN(BASE); }
	305	<MRI>"ALIAS" { RTOKEN(ALIAS); }
	306	<MRI>"TRUNCATE" { RTOKEN(TRUNCATE); }
	307	<MRI>"LOAD" { RTOKEN(LOAD); }
	308	<MRI>"PUBLIC" { RTOKEN(PUBLIC); }
	309	<MRI>"ORDER" { RTOKEN(ORDER); }
	310	<MRI>"NAME" { RTOKEN(NAMEWORD); }
	311	<MRI>"FORMAT" { RTOKEN(FORMAT); }
	312	<MRI>"CASE" { RTOKEN(CASE); }
	313	<MRI>"START" { RTOKEN(START); }
	314	<MRI>"LIST".* { RTOKEN(LIST); /* LIST and ignore to end of line */ }
	315	<MRI>"SECT" { RTOKEN(SECT); }
	316	<EXPRESSION,BOTH,SCRIPT,MRI>"ABSOLUTE" { RTOKEN(ABSOLUTE); }
	317	<MRI>"end" { RTOKEN(ENDWORD); }
	318	<MRI>"alignmod" { RTOKEN(ALIGNMOD);}
	319	<MRI>"align" { RTOKEN(ALIGN_K);}
	320	<MRI>"chip" { RTOKEN(CHIP); }
	321	<MRI>"base" { RTOKEN(BASE); }
	322	<MRI>"alias" { RTOKEN(ALIAS); }
	323	<MRI>"truncate" { RTOKEN(TRUNCATE); }
	324	<MRI>"load" { RTOKEN(LOAD); }
	325	<MRI>"public" { RTOKEN(PUBLIC); }
	326	<MRI>"order" { RTOKEN(ORDER); }
	327	<MRI>"name" { RTOKEN(NAMEWORD); }
328	<MRI>"format" { RTOKEN(FORMAT); }
329	<MRI>"case" { RTOKEN(CASE); }
330	<MRI>"extern" { RTOKEN(EXTERN); }
331	<MRI>"start" { RTOKEN(START); }
332	<MRI>"list".* { RTOKEN(LIST); /* LIST and ignore to end of line */ }
333	<MRI>"sect" { RTOKEN(SECT); }
334	<EXPRESSION,BOTH,SCRIPT,MRI>"absolute" { RTOKEN(ABSOLUTE); }
335
336	<MRI>{FILENAMECHAR1}{NOCFILENAMECHAR}* {
337	/* Filename without commas, needed to parse mri stuff */
d1b2b2dc	338	yylval.name = xstrdup(yytext);
252b5132 RH	339	return NAME;
	340	}
	341
	342
	343	<BOTH,EXPRESSION>{FILENAMECHAR1}{FILENAMECHAR}* {
d1b2b2dc	344	yylval.name = xstrdup(yytext);
252b5132 RH	345	return NAME;
	346	}
	347	<BOTH,EXPRESSION>"-l"{FILENAMECHAR}+ {
d1b2b2dc	348	yylval.name = xstrdup (yytext + 2);
252b5132 RH	349	return LNAME;
	350	}
	351	<SCRIPT>{WILDCHAR}* {
	352	/* Annoyingly, this pattern can match comments, and we have
	353	longest match issues to consider. So if the first two
	354	characters are a comment opening, put the input back and
	355	try again. */
	356	if (yytext[0] == '/' && yytext[1] == '*')
	357	{
	358	yyless(2);
	359	comment ();
	360	}
	361	else
	362	{
d1b2b2dc	363	yylval.name = xstrdup(yytext);
252b5132 RH	364	return NAME;
	365	}
	366	}
	367
	368	<EXPRESSION,BOTH,SCRIPT,VERS_NODE>"\""[^\"]*"\"" {
	369	/* No matter the state, quotes
	370	give what's inside */
d1b2b2dc	371	yylval.name = xstrdup(yytext+1);
252b5132 RH	372	yylval.name[yyleng-2] = 0;
	373	return NAME;
	374	}
	375	<BOTH,SCRIPT,EXPRESSION>"\n" { lineno++;}
	376	<MRI,BOTH,SCRIPT,EXPRESSION>[ \t\r]+ { }
	377
	378	<VERS_NODE,VERS_SCRIPT>[:,;] { return *yytext; }
	379
	380	<VERS_NODE>global { RTOKEN(GLOBAL); }
	381
	382	<VERS_NODE>local { RTOKEN(LOCAL); }
	383
	384	<VERS_NODE>extern { RTOKEN(EXTERN); }
	385
d1b2b2dc	386	<VERS_NODE>{V_IDENTIFIER} { yylval.name = xstrdup (yytext);
252b5132 RH	387	return VERS_IDENTIFIER; }
252b5132 RH	388
d1b2b2dc	389	<VERS_SCRIPT>{V_TAG} { yylval.name = xstrdup (yytext);
252b5132 RH	390	return VERS_TAG; }
	391
	392	<VERS_START>"{" { BEGIN(VERS_SCRIPT); return *yytext; }
	393
	394	<VERS_SCRIPT>"{" { BEGIN(VERS_NODE);
	395	vers_node_nesting = 0;
	396	return *yytext;
	397	}
	398	<VERS_SCRIPT>"}" { return *yytext; }
	399	<VERS_NODE>"{" { vers_node_nesting++; return *yytext; }
	400	<VERS_NODE>"}" { if (--vers_node_nesting < 0)
	401	BEGIN(VERS_SCRIPT);
	402	return *yytext;
	403	}
	404
	405	<VERS_START,VERS_NODE,VERS_SCRIPT>[\n] { lineno++; }
	406
	407	<VERS_START,VERS_NODE,VERS_SCRIPT>#.* { /* Eat up comments */ }
	408
	409	<VERS_START,VERS_NODE,VERS_SCRIPT>[ \t\r]+ { /* Eat up whitespace */ }
	410
	411	<<EOF>> {
	412	include_stack_ptr--;
	413
	414	if (include_stack_ptr == 0)
	415	{
	416	yyterminate();
	417	}
	418	else
	419	{
	420	yy_switch_to_buffer(include_stack[include_stack_ptr]);
	421
	422	}
	423	BEGIN(SCRIPT);
	424	ldfile_input_filename = file_name_stack[include_stack_ptr - 1];
	425	lineno = lineno_stack[include_stack_ptr - 1];
	426
	427	return END;
	428	}
	429
	430	<SCRIPT,MRI,VERS_START,VERS_SCRIPT,VERS_NODE>. lex_warn_invalid(" in script", yytext);
	431	<EXPRESSION,DEFSYMEXP,BOTH>. lex_warn_invalid(" in expression", yytext);
	432
	433	%%
	434	\f
	435
	436	/* Switch flex to reading script file NAME, open on FILE,
	437	saving the current input info on the include stack. */
	438
	439	void
	440	lex_push_file (file, name)
	441	FILE *file;
	442	const char *name;
	443	{
	444	if (include_stack_ptr >= MAX_INCLUDE_DEPTH)
	445	{
	446	einfo("%F:includes nested too deeply\n");
	447	}
	448	file_name_stack[include_stack_ptr] = name;
	449	lineno_stack[include_stack_ptr] = 1;
	450	include_stack[include_stack_ptr] = YY_CURRENT_BUFFER;
	451
	452	include_stack_ptr++;
	453	yyin = file;
454	yy_switch_to_buffer(yy_create_buffer(yyin, YY_BUF_SIZE));
455	BEGIN (SCRIPT);
456	}
457
458	/* Return a newly created flex input buffer containing STRING,
459	which is SIZE bytes long. */
460
461	static YY_BUFFER_STATE
462	yy_create_string_buffer (string, size)
463	CONST char *string;
464	size_t size;
465	{
466	YY_BUFFER_STATE b;
467
468	/* Calls to m-alloc get turned by sed into xm-alloc. */
469	b = (YY_BUFFER_STATE) malloc (sizeof (struct yy_buffer_state));
470	b->yy_input_file = 0;
471	b->yy_buf_size = size;
472
473	/* yy_ch_buf has to be 2 characters longer than the size given because
474	we need to put in 2 end-of-buffer characters. */
475	b->yy_ch_buf = (char *) malloc ((unsigned) (b->yy_buf_size + 3));
476
477	b->yy_ch_buf[0] = '\n';
478	strcpy (b->yy_ch_buf+1, string);
479	b->yy_ch_buf[size+1] = YY_END_OF_BUFFER_CHAR;
480	b->yy_ch_buf[size+2] = YY_END_OF_BUFFER_CHAR;
481	b->yy_n_chars = size+1;
482	b->yy_buf_pos = &b->yy_ch_buf[1];
483
dca7760f AM	484	b->yy_is_our_buffer = 1;
	485	b->yy_is_interactive = 0;
	486	b->yy_at_bol = 1;
	487	b->yy_fill_buffer = 0;
	488
252b5132 RH	489	/* flex 2.4.7 changed the interface. FIXME: We should not be using
	490	a flex internal interface in the first place! */
	491	#ifdef YY_BUFFER_NEW
	492	b->yy_buffer_status = YY_BUFFER_NEW;
	493	#else
	494	b->yy_eof_status = EOF_NOT_SEEN;
	495	#endif
	496
	497	return b;
	498	}
	499
	500	/* Switch flex to reading from STRING, saving the current input info
	501	on the include stack. */
	502
	503	void
	504	lex_redirect (string)
	505	CONST char *string;
	506	{
	507	YY_BUFFER_STATE tmp;
	508
	509	yy_init = 0;
	510	if (include_stack_ptr >= MAX_INCLUDE_DEPTH)
	511	{
	512	einfo("%F: macros nested too deeply\n");
	513	}
	514	file_name_stack[include_stack_ptr] = "redirect";
	515	lineno_stack[include_stack_ptr] = 0;
	516	include_stack[include_stack_ptr] = YY_CURRENT_BUFFER;
	517	include_stack_ptr++;
	518	tmp = yy_create_string_buffer (string, strlen (string));
	519	yy_switch_to_buffer (tmp);
	520	BEGIN (SCRIPT);
	521	}
	522	\f
	523	/* Functions to switch to a different flex start condition,
	524	saving the current start condition on `state_stack'. */
	525
	526	static int state_stack[MAX_INCLUDE_DEPTH * 2];
	527	static int *state_stack_p = state_stack;
	528
	529	void
	530	ldlex_script ()
	531	{
	532	*(state_stack_p)++ = yy_start;
	533	BEGIN (SCRIPT);
	534	}
	535
	536	void
	537	ldlex_mri_script ()
	538	{
	539	*(state_stack_p)++ = yy_start;
	540	BEGIN (MRI);
	541	}
	542
	543	void
	544	ldlex_version_script ()
	545	{
	546	*(state_stack_p)++ = yy_start;
	547	BEGIN (VERS_START);
	548	}
	549
	550	void
	551	ldlex_version_file ()
	552	{
553	*(state_stack_p)++ = yy_start;
554	BEGIN (VERS_SCRIPT);
555	}
556
557	void
558	ldlex_defsym ()
559	{
560	*(state_stack_p)++ = yy_start;
561	BEGIN (DEFSYMEXP);
562	}
563
564	void
565	ldlex_expression ()
566	{
567	*(state_stack_p)++ = yy_start;
568	BEGIN (EXPRESSION);
569	}
570
571	void
572	ldlex_both ()
573	{
574	*(state_stack_p)++ = yy_start;
575	BEGIN (BOTH);
576	}
577
578	void
579	ldlex_popstate ()
580	{
581	yy_start = *(--state_stack_p);
582	}
583	\f
584
585	/* Place up to MAX_SIZE characters in BUF and return in *RESULT
586	either the number of characters read, or 0 to indicate EOF. */
587
588	static void
589	yy_input (buf, result, max_size)
590	char *buf;
591	int *result;
592	int max_size;
593	{
594	*result = 0;
595	if (yy_current_buffer->yy_input_file)
596	{
597	if (yyin)
598	{
599	result = read (fileno (yyin), (char ) buf, max_size);
600	if (*result < 0)
601	einfo ("%F%P: read in flex scanner failed\n");
602	}
603	}
604	}
605
606	/* Eat the rest of a C-style comment. */
607
608	static void
609	comment ()
610	{
611	int c;
612
613	while (1)
614	{
615	c = input();
616	while (c != '*' && c != EOF)
617	{
618	if (c == '\n')
619	lineno++;
620	c = input();
621	}
622
623	if (c == '*')
624	{
625	c = input();
626	while (c == '*')
627	c = input();
628	if (c == '/')
629	break; /* found the end */
630	}
631
632	if (c == '\n')
633	lineno++;
634
635	if (c == EOF)
636	{
637	einfo( "%F%P: EOF in comment\n");
638	break;
639	}
640	}
641	}
642
643	/* Warn the user about a garbage character WHAT in the input
644	in context WHERE. */
645
646	static void
647	lex_warn_invalid (where, what)
648	char where, what;
649	{
650	char buf[5];
651
652	/* If we have found an input file whose format we do not recognize,
653	and we are therefore treating it as a linker script, and we find
654	an invalid character, then most likely this is a real object file
655	of some different format. Treat it as such. */
656	if (ldfile_assumed_script)
657	{
658	bfd_set_error (bfd_error_file_not_recognized);
659	einfo ("%F%s: file not recognized: %E\n", ldfile_input_filename);
660	}
661
3882b010	662	if (! ISPRINT (*what))
252b5132 RH	663	{
	664	sprintf (buf, "\\%03o", (unsigned int) *what);
	665	what = buf;
	666	}
	667
	668	einfo ("%P:%S: ignoring invalid character `%s'%s\n", what, where);
	669	}